lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Carp         'confess';
   9 use Scalar::Util 'blessed';
  10 use B            'svref_2object';
  11
  12 use Moose::Meta::Class;
  13
  14 our $VERSION = '0.04';
  15
  16 ## Attributes
  17
  18 ## the meta for the role package
  19
  20 __PACKAGE__->meta->add_attribute('_role_meta' => (
  21     reader   => '_role_meta',
  22     init_arg => ':role_meta'
  23 ));
  24
  25 ## roles
  26
  27 __PACKAGE__->meta->add_attribute('roles' => (
  28     reader  => 'get_roles',
  29     default => sub { [] }
  30 ));
  31
  32 ## excluded roles
  33
  34 __PACKAGE__->meta->add_attribute('excluded_roles_map' => (
  35     reader  => 'get_excluded_roles_map',
  36     default => sub { {} }
  37 ));
  38
  39 ## attributes
  40
  41 __PACKAGE__->meta->add_attribute('attribute_map' => (
  42     reader   => 'get_attribute_map',
  43     default  => sub { {} }
  44 ));
  45
  46 ## required methods
  47
  48 __PACKAGE__->meta->add_attribute('required_methods' => (
  49     reader  => 'get_required_methods_map',
  50     default => sub { {} }
  51 ));
  52
  53 ## Methods
  54
  55 sub new {
  56     my $class   = shift;
  57     my %options = @_;
  58     $options{':role_meta'} = Moose::Meta::Class->initialize(
  59         $options{role_name},
  60         ':method_metaclass' => 'Moose::Meta::Role::Method'
  61     ) unless defined $options{':role_meta'} &&
  62              $options{':role_meta'}->isa('Moose::Meta::Class');
  63     my $self = $class->meta->new_object(%options);
  64     return $self;
  65 }
  66
  67 ## subroles
  68
  69 sub add_role {
  70     my ($self, $role) = @_;
  71     (blessed($role) && $role->isa('Moose::Meta::Role'))
  72         || confess "Roles must be instances of Moose::Meta::Role";
  73     push @{$self->get_roles} => $role;
  74 }
  75
  76 sub calculate_all_roles {
  77     my $self = shift;
  78     my %seen;
  79     grep { !$seen{$_->name}++ } $self, map { $_->calculate_all_roles } @{ $self->get_roles };
  80 }
  81
  82 sub does_role {
  83     my ($self, $role_name) = @_;
  84     (defined $role_name)
  85         || confess "You must supply a role name to look for";
  86     # if we are it,.. then return true
  87     return 1 if $role_name eq $self->name;
  88     # otherwise.. check our children
  89     foreach my $role (@{$self->get_roles}) {
  90         return 1 if $role->does_role($role_name);
  91     }
  92     return 0;
  93 }
  94
  95 ## excluded roles
  96
  97 sub add_excluded_roles {
  98     my ($self, @excluded_role_names) = @_;
  99     $self->get_excluded_roles_map->{$_} = undef foreach @excluded_role_names;
 100 }
 101
 102 sub get_excluded_roles_list {
 103     my ($self) = @_;
 104     keys %{$self->get_excluded_roles_map};
 105 }
 106
 107 sub excludes_role {
 108     my ($self, $role_name) = @_;
 109     exists $self->get_excluded_roles_map->{$role_name} ? 1 : 0;
 110 }
 111
 112 ## required methods
 113
 114 sub add_required_methods {
 115     my ($self, @methods) = @_;
 116     $self->get_required_methods_map->{$_} = undef foreach @methods;
 117 }
 118
 119 sub remove_required_methods {
 120     my ($self, @methods) = @_;
 121     delete $self->get_required_methods_map->{$_} foreach @methods;
 122 }
 123
 124 sub get_required_method_list {
 125     my ($self) = @_;
 126     keys %{$self->get_required_methods_map};
 127 }
 128
 129 sub requires_method {
 130     my ($self, $method_name) = @_;
 131     exists $self->get_required_methods_map->{$method_name} ? 1 : 0;
 132 }
 133
 134 sub _clean_up_required_methods {
 135     my $self = shift;
 136     foreach my $method ($self->get_required_method_list) {
 137         $self->remove_required_methods($method)
 138             if $self->has_method($method);
 139     }
 140 }
 141
 142 ## methods
 143
 144 # NOTE:
 145 # we delegate to some role_meta methods for convience here
 146 # the Moose::Meta::Role is meant to be a read-only interface
 147 # to the underlying role package, if you want to manipulate
 148 # that, just use ->role_meta
 149
 150 sub name    { (shift)->_role_meta->name    }
 151 sub version { (shift)->_role_meta->version }
 152
 153 sub get_method          { (shift)->_role_meta->get_method(@_)         }
 154 sub find_method_by_name { (shift)->_role_meta->find_method_by_name(@_) }
 155 sub has_method          { (shift)->_role_meta->has_method(@_)         }
 156 sub alias_method        { (shift)->_role_meta->alias_method(@_)       }
 157 sub get_method_list {
 158     my ($self) = @_;
 159     grep {
 160         # NOTE:
 161         # this is a kludge for now,... these functions
 162         # should not be showing up in the list at all,
 163         # but they do, so we need to switch Moose::Role
 164         # and Moose to use Sub::Exporter to prevent this
 165         !/^(meta|has|extends|blessed|confess|augment|inner|override|super|before|after|around|with|requires)$/
 166     } $self->_role_meta->get_method_list;
 167 }
 168
 169 # ... however the items in statis (attributes & method modifiers)
 170 # can be removed and added to through this API
 171
 172 # attributes
 173
 174 sub add_attribute {
 175     my $self = shift;
 176     my $name = shift;
 177     my $attr_desc;
 178     if (scalar @_ == 1 && ref($_[0]) eq 'HASH') {
 179         $attr_desc = $_[0];
 180     }
 181     else {
 182         $attr_desc = { @_ };
 183     }
 184     $self->get_attribute_map->{$name} = $attr_desc;
 185 }
 186
 187 sub has_attribute {
 188     my ($self, $name) = @_;
 189     exists $self->get_attribute_map->{$name} ? 1 : 0;
 190 }
 191
 192 sub get_attribute {
 193     my ($self, $name) = @_;
 194     $self->get_attribute_map->{$name}
 195 }
 196
 197 sub remove_attribute {
 198     my ($self, $name) = @_;
 199     delete $self->get_attribute_map->{$name}
 200 }
 201
 202 sub get_attribute_list {
 203     my ($self) = @_;
 204     keys %{$self->get_attribute_map};
 205 }
 206
 207
 208 ## applying a role to a class ...
 209
 210 sub _check_excluded_roles {
 211     my ($self, $other) = @_;
 212     if ($other->excludes_role($self->name)) {
 213         confess "Conflict detected: " . $other->name . " excludes role '" . $self->name . "'";
 214     }
 215     foreach my $excluded_role_name ($self->get_excluded_roles_list) {
 216         if ($other->does_role($excluded_role_name)) {
 217             confess "The class " . $other->name . " does the excluded role '$excluded_role_name'";
 218         }
 219         else {
 220             if ($other->isa('Moose::Meta::Role')) {
 221                 $other->add_excluded_roles($excluded_role_name);
 222             }
 223             # else -> ignore it :)
 224         }
 225     }
 226 }
 227
 228 sub _check_required_methods {
 229     my ($self, $other) = @_;
 230     # NOTE:
 231     # we might need to move this down below the
 232     # the attributes so that we can require any
 233     # attribute accessors. However I am thinking
 234     # that maybe those are somehow exempt from
 235     # the require methods stuff.
 236     foreach my $required_method_name ($self->get_required_method_list) {
 237
 238         unless ($other->find_method_by_name($required_method_name)) {
 239             if ($other->isa('Moose::Meta::Role')) {
 240                 $other->add_required_methods($required_method_name);
 241             }
 242             else {
 243                 confess "'" . $self->name . "' requires the method '$required_method_name' " .
 244                         "to be implemented by '" . $other->name . "'";
 245             }
 246         }
 247     }
 248 }
 249
 250 sub _apply_attributes {
 251     my ($self, $other) = @_;
 252     foreach my $attribute_name ($self->get_attribute_list) {
 253         # it if it has one already
 254         if ($other->has_attribute($attribute_name) &&
 255             # make sure we haven't seen this one already too
 256             $other->get_attribute($attribute_name) != $self->get_attribute($attribute_name)) {
 257             # see if we are being composed
 258             # into a role or not
 259             if ($other->isa('Moose::Meta::Role')) {
 260                 # all attribute conflicts between roles
 261                 # result in an immediate fatal error
 262                 confess "Role '" . $self->name . "' has encountered an attribute conflict " .
 263                         "during composition. This is fatal error and cannot be disambiguated.";
 264             }
 265             else {
 266                 # but if this is a class, we
 267                 # can safely skip adding the
 268                 # attribute to the class
 269                 next;
 270             }
 271         }
 272         else {
 273             $other->add_attribute(
 274                 $attribute_name,
 275                 $self->get_attribute($attribute_name)
 276             );
 277         }
 278     }
 279 }
 280
 281 sub _apply_methods {
 282     my ($self, $other) = @_;
 283     foreach my $method_name ($self->get_method_list) {
 284         # it if it has one already
 285         if ($other->has_method($method_name) &&
 286             # and if they are not the same thing ...
 287             $other->get_method($method_name) != $self->get_method($method_name)) {
 288             # see if we are composing into a role
 289             if ($other->isa('Moose::Meta::Role')) {
 290                 # method conflicts between roles result
 291                 # in the method becoming a requirement
 292                 $other->add_required_methods($method_name);
 293                 # NOTE:
 294                 # we have to remove the method from our
 295                 # role, if this is being called from combine()
 296                 # which means the meta is an anon class
 297                 # this *may* cause problems later, but it
 298                 # is probably fairly safe to assume that
 299                 # anon classes will only be used internally
 300                 # or by people who know what they are doing
 301                 $other->_role_meta->remove_method($method_name)
 302                     if $other->_role_meta->name =~ /__ANON__/;
 303             }
 304             else {
 305                 next;
 306             }
 307         }
 308         else {
 309             # add it, although it could be overriden
 310             $other->alias_method(
 311                 $method_name,
 312                 $self->get_method($method_name)
 313             );
 314         }
 315     }
 316 }
 317
 318 sub apply {
 319     my ($self, $other) = @_;
 320
 321     $self->_check_excluded_roles($other);
 322     $self->_check_required_methods($other);
 323
 324     $self->_apply_attributes($other);
 325     $self->_apply_methods($other);
 326
 327     $other->add_role($self);
 328 }
 329
 330 sub combine {
 331     my ($class, @roles) = @_;
 332
 333     my $combined = $class->new(
 334         ':role_meta' => Moose::Meta::Class->create_anon_class()
 335     );
 336
 337     foreach my $role (@roles) {
 338         $role->apply($combined);
 339     }
 340
 341     $combined->_clean_up_required_methods;
 342
 343     return $combined;
 344 }
 345
 346 package Moose::Meta::Role::Method;
 347
 348 use strict;
 349 use warnings;
 350
 351 our $VERSION = '0.01';
 352
 353 use base 'Class::MOP::Method';
 354
 355 1;
 356
 357 __END__
 358
 359 =pod
 360
 361 =head1 NAME
 362
 363 Moose::Meta::Role - The Moose Role metaclass
 364
 365 =head1 DESCRIPTION
 366
 367 Moose's Roles are being actively developed, please see L<Moose::Role>
 368 for more information. For the most part, this has no user-serviceable
 369 parts inside. It's API is still subject to some change (although
 370 probably not that much really).
 371
 372 =head1 METHODS
 373
 374 =over 4
 375
 376 =item B<meta>
 377
 378 =item B<new>
 379
 380 =item B<apply>
 381
 382 =item B<combine>
 383
 384 =back
 385
 386 =over 4
 387
 388 =item B<name>
 389
 390 =item B<version>
 391
 392 =item B<role_meta>
 393
 394 =back
 395
 396 =over 4
 397
 398 =item B<get_roles>
 399
 400 =item B<add_role>
 401
 402 =item B<does_role>
 403
 404 =back
 405
 406 =over 4
 407
 408 =item B<add_excluded_roles>
 409
 410 =item B<excludes_role>
 411
 412 =item B<get_excluded_roles_list>
 413
 414 =item B<get_excluded_roles_map>
 415
 416 =item B<calculate_all_roles>
 417
 418 =back
 419
 420 =over 4
 421
 422 =item B<find_method_by_name>
 423
 424 =item B<get_method>
 425
 426 =item B<has_method>
 427
 428 =item B<alias_method>
 429
 430 =item B<get_method_list>
 431
 432 =back
 433
 434 =over 4
 435
 436 =item B<add_attribute>
 437
 438 =item B<has_attribute>
 439
 440 =item B<get_attribute>
 441
 442 =item B<get_attribute_list>
 443
 444 =item B<get_attribute_map>
 445
 446 =item B<remove_attribute>
 447
 448 =back
 449
 450 =over 4
 451
 452 =item B<add_required_methods>
 453
 454 =item B<remove_required_methods>
 455
 456 =item B<get_required_method_list>
 457
 458 =item B<get_required_methods_map>
 459
 460 =item B<requires_method>
 461
 462 =back
 463
 464 =head1 BUGS
 465
 466 All complex software has bugs lurking in it, and this module is no
 467 exception. If you find a bug please either email me, or add the bug
 468 to cpan-RT.
 469
 470 =head1 AUTHOR
 471
 472 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 473
 474 =head1 COPYRIGHT AND LICENSE
 475
 476 Copyright 2006 by Infinity Interactive, Inc.
 477
 478 L<http://www.iinteractive.com>
 479
 480 This library is free software; you can redistribute it and/or modify
 481 it under the same terms as Perl itself.
 482
 483 =cut