lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Carp         'confess';
   9 use Scalar::Util 'blessed';
  10
  11 our $VERSION   = '0.54';
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use Moose::Meta::Class;
  15 use Moose::Meta::Role::Method;
  16 use Moose::Meta::Role::Method::Required;
  17
  18 use base 'Class::MOP::Module';
  19
  20 ## ------------------------------------------------------------------
  21 ## NOTE:
  22 ## I normally don't do this, but I am doing
  23 ## a whole bunch of meta-programmin in this
  24 ## module, so it just makes sense. For a clearer
  25 ## picture of what is going on in the next
  26 ## several lines of code, look at the really
  27 ## big comment at the end of this file (right
  28 ## before the POD).
  29 ## - SL
  30 ## ------------------------------------------------------------------
  31
  32 my $META = __PACKAGE__->meta;
  33
  34 ## ------------------------------------------------------------------
  35 ## attributes ...
  36
  37 # NOTE:
  38 # since roles are lazy, we hold all the attributes
  39 # of the individual role in 'statis' until which
  40 # time when it is applied to a class. This means
  41 # keeping a lot of things in hash maps, so we are
  42 # using a little of that meta-programmin' magic
  43 # here an saving lots of extra typin. And since
  44 # many of these attributes above require similar
  45 # functionality to support them, so we again use
  46 # the wonders of meta-programmin' to deliver a
  47 # very compact solution to this normally verbose
  48 # problem.
  49 # - SL
  50
  51 foreach my $action (
  52     {
  53         name        => 'excluded_roles_map',
  54         attr_reader => 'get_excluded_roles_map' ,
  55         methods     => {
  56             add       => 'add_excluded_roles',
  57             get_list  => 'get_excluded_roles_list',
  58             existence => 'excludes_role',
  59         }
  60     },
  61     {
  62         name        => 'required_methods',
  63         attr_reader => 'get_required_methods_map',
  64         methods     => {
  65             add       => 'add_required_methods',
  66             remove    => 'remove_required_methods',
  67             get_list  => 'get_required_method_list',
  68             existence => 'requires_method',
  69         }
  70     },
  71     {
  72         name        => 'attribute_map',
  73         attr_reader => 'get_attribute_map',
  74         methods     => {
  75             get       => 'get_attribute',
  76             get_list  => 'get_attribute_list',
  77             existence => 'has_attribute',
  78             remove    => 'remove_attribute',
  79         }
  80     }
  81 ) {
  82
  83     my $attr_reader = $action->{attr_reader};
  84     my $methods     = $action->{methods};
  85
  86     # create the attribute
  87     $META->add_attribute($action->{name} => (
  88         reader  => $attr_reader,
  89         default => sub { {} }
  90     ));
  91
  92     # create some helper methods
  93     $META->add_method($methods->{add} => sub {
  94         my ($self, @values) = @_;
  95         $self->$attr_reader->{$_} = undef foreach @values;
  96     }) if exists $methods->{add};
  97
  98     $META->add_method($methods->{get_list} => sub {
  99         my ($self) = @_;
 100         keys %{$self->$attr_reader};
 101     }) if exists $methods->{get_list};
 102
 103     $META->add_method($methods->{get} => sub {
 104         my ($self, $name) = @_;
 105         $self->$attr_reader->{$name}
 106     }) if exists $methods->{get};
 107
 108     $META->add_method($methods->{existence} => sub {
 109         my ($self, $name) = @_;
 110         exists $self->$attr_reader->{$name} ? 1 : 0;
 111     }) if exists $methods->{existence};
 112
 113     $META->add_method($methods->{remove} => sub {
 114         my ($self, @values) = @_;
 115         delete $self->$attr_reader->{$_} foreach @values;
 116     }) if exists $methods->{remove};
 117 }
 118
 119 ## some things don't always fit, so they go here ...
 120
 121 sub add_attribute {
 122     my $self = shift;
 123     my $name = shift;
 124     my $attr_desc;
 125     if (scalar @_ == 1 && ref($_[0]) eq 'HASH') {
 126         $attr_desc = $_[0];
 127     }
 128     else {
 129         $attr_desc = { @_ };
 130     }
 131     $self->get_attribute_map->{$name} = $attr_desc;
 132 }
 133
 134 # DEPRECATED
 135 # sub _clean_up_required_methods {
 136 #     my $self = shift;
 137 #     foreach my $method ($self->get_required_method_list) {
 138 #         $self->remove_required_methods($method)
 139 #             if $self->has_method($method);
 140 #     }
 141 # }
 142
 143 ## ------------------------------------------------------------------
 144 ## method modifiers
 145
 146 # NOTE:
 147 # the before/around/after method modifiers are
 148 # stored by name, but there can be many methods
 149 # then associated with that name. So again we have
 150 # lots of similar functionality, so we can do some
 151 # meta-programmin' and save some time.
 152 # - SL
 153
 154 foreach my $modifier_type (qw[ before around after ]) {
 155
 156     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 157
 158     # create the attribute ...
 159     $META->add_attribute("${modifier_type}_method_modifiers" => (
 160         reader  => $attr_reader,
 161         default => sub { {} }
 162     ));
 163
 164     # and some helper methods ...
 165     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 166         my ($self, $method_name) = @_;
 167         #return () unless exists $self->$attr_reader->{$method_name};
 168         @{$self->$attr_reader->{$method_name}};
 169     });
 170
 171     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 172         my ($self, $method_name) = @_;
 173         # NOTE:
 174         # for now we assume that if it exists,..
 175         # it has at least one modifier in it
 176         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 177     });
 178
 179     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 180         my ($self, $method_name, $method) = @_;
 181
 182         $self->$attr_reader->{$method_name} = []
 183             unless exists $self->$attr_reader->{$method_name};
 184
 185         my $modifiers = $self->$attr_reader->{$method_name};
 186
 187         # NOTE:
 188         # check to see that we aren't adding the
 189         # same code twice. We err in favor of the
 190         # first on here, this may not be as expected
 191         foreach my $modifier (@{$modifiers}) {
 192             return if $modifier == $method;
 193         }
 194
 195         push @{$modifiers} => $method;
 196     });
 197
 198 }
 199
 200 ## ------------------------------------------------------------------
 201 ## override method mofidiers
 202
 203 $META->add_attribute('override_method_modifiers' => (
 204     reader  => 'get_override_method_modifiers_map',
 205     default => sub { {} }
 206 ));
 207
 208 # NOTE:
 209 # these are a little different because there
 210 # can only be one per name, whereas the other
 211 # method modifiers can have multiples.
 212 # - SL
 213
 214 sub add_override_method_modifier {
 215     my ($self, $method_name, $method) = @_;
 216     (!$self->has_method($method_name))
 217         || confess "Cannot add an override of method '$method_name' " .
 218                    "because there is a local version of '$method_name'";
 219     $self->get_override_method_modifiers_map->{$method_name} = $method;
 220 }
 221
 222 sub has_override_method_modifier {
 223     my ($self, $method_name) = @_;
 224     # NOTE:
 225     # for now we assume that if it exists,..
 226     # it has at least one modifier in it
 227     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 228 }
 229
 230 sub get_override_method_modifier {
 231     my ($self, $method_name) = @_;
 232     $self->get_override_method_modifiers_map->{$method_name};
 233 }
 234
 235 ## general list accessor ...
 236
 237 sub get_method_modifier_list {
 238     my ($self, $modifier_type) = @_;
 239     my $accessor = "get_${modifier_type}_method_modifiers_map";
 240     keys %{$self->$accessor};
 241 }
 242
 243 ## ------------------------------------------------------------------
 244 ## subroles
 245
 246 __PACKAGE__->meta->add_attribute('roles' => (
 247     reader  => 'get_roles',
 248     default => sub { [] }
 249 ));
 250
 251 sub add_role {
 252     my ($self, $role) = @_;
 253     (blessed($role) && $role->isa('Moose::Meta::Role'))
 254         || confess "Roles must be instances of Moose::Meta::Role";
 255     push @{$self->get_roles} => $role;
 256 }
 257
 258 sub calculate_all_roles {
 259     my $self = shift;
 260     my %seen;
 261     grep {
 262         !$seen{$_->name}++
 263     } ($self, map {
 264                   $_->calculate_all_roles
 265               } @{ $self->get_roles });
 266 }
 267
 268 sub does_role {
 269     my ($self, $role_name) = @_;
 270     (defined $role_name)
 271         || confess "You must supply a role name to look for";
 272     # if we are it,.. then return true
 273     return 1 if $role_name eq $self->name;
 274     # otherwise.. check our children
 275     foreach my $role (@{$self->get_roles}) {
 276         return 1 if $role->does_role($role_name);
 277     }
 278     return 0;
 279 }
 280
 281 ## ------------------------------------------------------------------
 282 ## methods
 283
 284 sub method_metaclass { 'Moose::Meta::Role::Method' }
 285
 286 sub get_method_map {
 287     my $self = shift;
 288     my $map  = {};
 289
 290     my $role_name        = $self->name;
 291     my $method_metaclass = $self->method_metaclass;
 292
 293     my %all_code = $self->get_all_package_symbols('CODE');
 294
 295     foreach my $symbol (keys %all_code) {
 296         my $code = $all_code{$symbol};
 297
 298         my ($pkg, $name) = Class::MOP::get_code_info($code);
 299
 300         if ($pkg->can('meta')
 301             # NOTE:
 302             # we don't know what ->meta we are calling
 303             # here, so we need to be careful cause it
 304             # just might blow up at us, or just complain
 305             # loudly (in the case of Curses.pm) so we
 306             # just be a little overly cautious here.
 307             # - SL
 308             && eval { no warnings; blessed($pkg->meta) }
 309             && $pkg->meta->isa('Moose::Meta::Role')) {
 310             my $role = $pkg->meta->name;
 311             next unless $self->does_role($role);
 312         }
 313         else {
 314             # NOTE:
 315             # in 5.10 constant.pm the constants show up
 316             # as being in the right package, but in pre-5.10
 317             # they show up as constant::__ANON__ so we
 318             # make an exception here to be sure that things
 319             # work as expected in both.
 320             # - SL
 321             unless ($pkg eq 'constant' && $name eq '__ANON__') {
 322                 next if ($pkg  || '') ne $role_name ||
 323                         (($name || '') ne '__ANON__' && ($pkg  || '') ne $role_name);
 324             }
 325         }
 326
 327         $map->{$symbol} = $method_metaclass->wrap(
 328             $code,
 329             package_name => $role_name,
 330             name         => $name
 331         );
 332     }
 333
 334     return $map;
 335 }
 336
 337 sub get_method {
 338     my ($self, $name) = @_;
 339     $self->get_method_map->{$name};
 340 }
 341
 342 sub has_method {
 343     my ($self, $name) = @_;
 344     exists $self->get_method_map->{$name} ? 1 : 0
 345 }
 346
 347 sub find_method_by_name { (shift)->get_method(@_) }
 348
 349 sub get_method_list {
 350     my $self = shift;
 351     grep { !/^meta$/ } keys %{$self->get_method_map};
 352 }
 353
 354 sub alias_method {
 355     my ($self, $method_name, $method) = @_;
 356     (defined $method_name && $method_name)
 357         || confess "You must define a method name";
 358
 359     my $body = (blessed($method) ? $method->body : $method);
 360     ('CODE' eq ref($body))
 361         || confess "Your code block must be a CODE reference";
 362
 363     $self->add_package_symbol(
 364         { sigil => '&', type => 'CODE', name => $method_name },
 365         $body
 366     );
 367 }
 368
 369 ## ------------------------------------------------------------------
 370 ## role construction
 371 ## ------------------------------------------------------------------
 372
 373 sub apply {
 374     my ($self, $other, @args) = @_;
 375
 376     (blessed($other))
 377         || confess "You must pass in an blessed instance";
 378
 379     if ($other->isa('Moose::Meta::Role')) {
 380         require Moose::Meta::Role::Application::ToRole;
 381         return Moose::Meta::Role::Application::ToRole->new(@args)->apply($self, $other);
 382     }
 383     elsif ($other->isa('Moose::Meta::Class')) {
 384         require Moose::Meta::Role::Application::ToClass;
 385         return Moose::Meta::Role::Application::ToClass->new(@args)->apply($self, $other);
 386     }
 387     else {
 388         require Moose::Meta::Role::Application::ToInstance;
 389         return Moose::Meta::Role::Application::ToInstance->new(@args)->apply($self, $other);
 390     }
 391 }
 392
 393 sub combine {
 394     my ($class, @role_specs) = @_;
 395
 396     require Moose::Meta::Role::Application::RoleSummation;
 397     require Moose::Meta::Role::Composite;
 398
 399     my (@roles, %role_params);
 400     while (@role_specs) {
 401         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 402         push @roles => $role->meta;
 403         next unless defined $params;
 404         $role_params{$role} = $params;
 405     }
 406
 407     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 408     Moose::Meta::Role::Application::RoleSummation->new(
 409         role_params => \%role_params
 410     )->apply($c);
 411
 412     return $c;
 413 }
 414
 415 #####################################################################
 416 ## NOTE:
 417 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 418 ## MooseX::AttributeHelpers module). It is here as a reference to
 419 ## make it easier to see what is happening above with all the meta
 420 ## programming. - SL
 421 #####################################################################
 422 #
 423 # has 'roles' => (
 424 #     metaclass => 'Collection::Array',
 425 #     reader    => 'get_roles',
 426 #     isa       => 'ArrayRef[Moose::Meta::Roles]',
 427 #     default   => sub { [] },
 428 #     provides  => {
 429 #         'push' => 'add_role',
 430 #     }
 431 # );
 432 #
 433 # has 'excluded_roles_map' => (
 434 #     metaclass => 'Collection::Hash',
 435 #     reader    => 'get_excluded_roles_map',
 436 #     isa       => 'HashRef[Str]',
 437 #     provides  => {
 438 #         # Not exactly set, cause it sets multiple
 439 #         'set'    => 'add_excluded_roles',
 440 #         'keys'   => 'get_excluded_roles_list',
 441 #         'exists' => 'excludes_role',
 442 #     }
 443 # );
 444 #
 445 # has 'attribute_map' => (
 446 #     metaclass => 'Collection::Hash',
 447 #     reader    => 'get_attribute_map',
 448 #     isa       => 'HashRef[Str]',
 449 #     provides => {
 450 #         # 'set'  => 'add_attribute' # has some special crap in it
 451 #         'get'    => 'get_attribute',
 452 #         'keys'   => 'get_attribute_list',
 453 #         'exists' => 'has_attribute',
 454 #         # Not exactly delete, cause it sets multiple
 455 #         'delete' => 'remove_attribute',
 456 #     }
 457 # );
 458 #
 459 # has 'required_methods' => (
 460 #     metaclass => 'Collection::Hash',
 461 #     reader    => 'get_required_methods_map',
 462 #     isa       => 'HashRef[Str]',
 463 #     provides  => {
 464 #         # not exactly set, or delete since it works for multiple
 465 #         'set'    => 'add_required_methods',
 466 #         'delete' => 'remove_required_methods',
 467 #         'keys'   => 'get_required_method_list',
 468 #         'exists' => 'requires_method',
 469 #     }
 470 # );
 471 #
 472 # # the before, around and after modifiers are
 473 # # HASH keyed by method-name, with ARRAY of
 474 # # CODE refs to apply in that order
 475 #
 476 # has 'before_method_modifiers' => (
 477 #     metaclass => 'Collection::Hash',
 478 #     reader    => 'get_before_method_modifiers_map',
 479 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 480 #     provides  => {
 481 #         'keys'   => 'get_before_method_modifiers',
 482 #         'exists' => 'has_before_method_modifiers',
 483 #         # This actually makes sure there is an
 484 #         # ARRAY at the given key, and pushed onto
 485 #         # it. It also checks for duplicates as well
 486 #         # 'add'  => 'add_before_method_modifier'
 487 #     }
 488 # );
 489 #
 490 # has 'after_method_modifiers' => (
 491 #     metaclass => 'Collection::Hash',
 492 #     reader    =>'get_after_method_modifiers_map',
 493 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 494 #     provides  => {
 495 #         'keys'   => 'get_after_method_modifiers',
 496 #         'exists' => 'has_after_method_modifiers',
 497 #         # This actually makes sure there is an
 498 #         # ARRAY at the given key, and pushed onto
 499 #         # it. It also checks for duplicates as well
 500 #         # 'add'  => 'add_after_method_modifier'
 501 #     }
 502 # );
 503 #
 504 # has 'around_method_modifiers' => (
 505 #     metaclass => 'Collection::Hash',
 506 #     reader    =>'get_around_method_modifiers_map',
 507 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 508 #     provides  => {
 509 #         'keys'   => 'get_around_method_modifiers',
 510 #         'exists' => 'has_around_method_modifiers',
 511 #         # This actually makes sure there is an
 512 #         # ARRAY at the given key, and pushed onto
 513 #         # it. It also checks for duplicates as well
 514 #         # 'add'  => 'add_around_method_modifier'
 515 #     }
 516 # );
 517 #
 518 # # override is similar to the other modifiers
 519 # # except that it is not an ARRAY of code refs
 520 # # but instead just a single name->code mapping
 521 #
 522 # has 'override_method_modifiers' => (
 523 #     metaclass => 'Collection::Hash',
 524 #     reader    =>'get_override_method_modifiers_map',
 525 #     isa       => 'HashRef[CodeRef]',
 526 #     provides  => {
 527 #         'keys'   => 'get_override_method_modifier',
 528 #         'exists' => 'has_override_method_modifier',
 529 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 530 #     }
 531 # );
 532 #
 533 #####################################################################
 534
 535
 536 1;
 537
 538 __END__
 539
 540 =pod
 541
 542 =head1 NAME
 543
 544 Moose::Meta::Role - The Moose Role metaclass
 545
 546 =head1 DESCRIPTION
 547
 548 Please see L<Moose::Role> for more information about roles.
 549 For the most part, this has no user-serviceable parts inside
 550 this module. It's API is still subject to some change (although
 551 probably not that much really).
 552
 553 =head1 METHODS
 554
 555 =over 4
 556
 557 =item B<meta>
 558
 559 =item B<new>
 560
 561 =item B<apply>
 562
 563 =item B<combine>
 564
 565 =back
 566
 567 =over 4
 568
 569 =item B<name>
 570
 571 =item B<version>
 572
 573 =item B<role_meta>
 574
 575 =back
 576
 577 =over 4
 578
 579 =item B<get_roles>
 580
 581 =item B<add_role>
 582
 583 =item B<does_role>
 584
 585 =back
 586
 587 =over 4
 588
 589 =item B<add_excluded_roles>
 590
 591 =item B<excludes_role>
 592
 593 =item B<get_excluded_roles_list>
 594
 595 =item B<get_excluded_roles_map>
 596
 597 =item B<calculate_all_roles>
 598
 599 =back
 600
 601 =over 4
 602
 603 =item B<method_metaclass>
 604
 605 =item B<find_method_by_name>
 606
 607 =item B<get_method>
 608
 609 =item B<has_method>
 610
 611 =item B<alias_method>
 612
 613 =item B<get_method_list>
 614
 615 =item B<get_method_map>
 616
 617 =item B<update_package_cache_flag>
 618
 619 =item B<reset_package_cache_flag>
 620
 621 =back
 622
 623 =over 4
 624
 625 =item B<add_attribute>
 626
 627 =item B<has_attribute>
 628
 629 =item B<get_attribute>
 630
 631 =item B<get_attribute_list>
 632
 633 =item B<get_attribute_map>
 634
 635 =item B<remove_attribute>
 636
 637 =back
 638
 639 =over 4
 640
 641 =item B<add_required_methods>
 642
 643 =item B<remove_required_methods>
 644
 645 =item B<get_required_method_list>
 646
 647 =item B<get_required_methods_map>
 648
 649 =item B<requires_method>
 650
 651 =back
 652
 653 =over 4
 654
 655 =item B<add_after_method_modifier>
 656
 657 =item B<add_around_method_modifier>
 658
 659 =item B<add_before_method_modifier>
 660
 661 =item B<add_override_method_modifier>
 662
 663 =over 4
 664
 665 =back
 666
 667 =item B<has_after_method_modifiers>
 668
 669 =item B<has_around_method_modifiers>
 670
 671 =item B<has_before_method_modifiers>
 672
 673 =item B<has_override_method_modifier>
 674
 675 =over 4
 676
 677 =back
 678
 679 =item B<get_after_method_modifiers>
 680
 681 =item B<get_around_method_modifiers>
 682
 683 =item B<get_before_method_modifiers>
 684
 685 =item B<get_method_modifier_list>
 686
 687 =over 4
 688
 689 =back
 690
 691 =item B<get_override_method_modifier>
 692
 693 =item B<get_after_method_modifiers_map>
 694
 695 =item B<get_around_method_modifiers_map>
 696
 697 =item B<get_before_method_modifiers_map>
 698
 699 =item B<get_override_method_modifiers_map>
 700
 701 =back
 702
 703 =head1 BUGS
 704
 705 All complex software has bugs lurking in it, and this module is no
 706 exception. If you find a bug please either email me, or add the bug
 707 to cpan-RT.
 708
 709 =head1 AUTHOR
 710
 711 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 712
 713 =head1 COPYRIGHT AND LICENSE
 714
 715 Copyright 2006-2008 by Infinity Interactive, Inc.
 716
 717 L<http://www.iinteractive.com>
 718
 719 This library is free software; you can redistribute it and/or modify
 720 it under the same terms as Perl itself.
 721
 722 =cut