lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Scalar::Util 'blessed';
   9 use Carp         'confess';
  10 use Devel::GlobalDestruction 'in_global_destruction';
  11
  12 use Moose::Meta::Class;
  13 use Moose::Meta::Role::Attribute;
  14 use Moose::Meta::Role::Method;
  15 use Moose::Meta::Role::Method::Required;
  16 use Moose::Meta::Role::Method::Conflicting;
  17 use Moose::Meta::Method::Meta;
  18 use Moose::Util qw( ensure_all_roles );
  19 use Class::MOP::MiniTrait;
  20
  21 use base 'Class::MOP::Module',
  22          'Class::MOP::Mixin::HasAttributes',
  23          'Class::MOP::Mixin::HasMethods';
  24
  25 Class::MOP::MiniTrait::apply(__PACKAGE__, 'Moose::Meta::Object::Trait');
  26
  27 ## ------------------------------------------------------------------
  28 ## NOTE:
  29 ## I normally don't do this, but I am doing
  30 ## a whole bunch of meta-programmin in this
  31 ## module, so it just makes sense. For a clearer
  32 ## picture of what is going on in the next
  33 ## several lines of code, look at the really
  34 ## big comment at the end of this file (right
  35 ## before the POD).
  36 ## - SL
  37 ## ------------------------------------------------------------------
  38
  39 my $META = __PACKAGE__->meta;
  40
  41 ## ------------------------------------------------------------------
  42 ## attributes ...
  43
  44 # NOTE:
  45 # since roles are lazy, we hold all the attributes
  46 # of the individual role in 'statis' until which
  47 # time when it is applied to a class. This means
  48 # keeping a lot of things in hash maps, so we are
  49 # using a little of that meta-programmin' magic
  50 # here an saving lots of extra typin. And since
  51 # many of these attributes above require similar
  52 # functionality to support them, so we again use
  53 # the wonders of meta-programmin' to deliver a
  54 # very compact solution to this normally verbose
  55 # problem.
  56 # - SL
  57
  58 foreach my $action (
  59     {
  60         name        => 'excluded_roles_map',
  61         attr_reader => 'get_excluded_roles_map' ,
  62         methods     => {
  63             add       => 'add_excluded_roles',
  64             get_keys  => 'get_excluded_roles_list',
  65             existence => 'excludes_role',
  66         }
  67     },
  68     {
  69         name        => 'required_methods',
  70         attr_reader => 'get_required_methods_map',
  71         methods     => {
  72             remove     => 'remove_required_methods',
  73             get_values => 'get_required_method_list',
  74             existence  => 'requires_method',
  75         }
  76     },
  77 ) {
  78
  79     my $attr_reader = $action->{attr_reader};
  80     my $methods     = $action->{methods};
  81
  82     # create the attribute
  83     $META->add_attribute($action->{name} => (
  84         reader  => $attr_reader,
  85         default => sub { {} }
  86     ));
  87
  88     # create some helper methods
  89     $META->add_method($methods->{add} => sub {
  90         my ($self, @values) = @_;
  91         $self->$attr_reader->{$_} = undef foreach @values;
  92     }) if exists $methods->{add};
  93
  94     $META->add_method($methods->{get_keys} => sub {
  95         my ($self) = @_;
  96         keys %{$self->$attr_reader};
  97     }) if exists $methods->{get_keys};
  98
  99     $META->add_method($methods->{get_values} => sub {
 100         my ($self) = @_;
 101         values %{$self->$attr_reader};
 102     }) if exists $methods->{get_values};
 103
 104     $META->add_method($methods->{get} => sub {
 105         my ($self, $name) = @_;
 106         $self->$attr_reader->{$name}
 107     }) if exists $methods->{get};
 108
 109     $META->add_method($methods->{existence} => sub {
 110         my ($self, $name) = @_;
 111         exists $self->$attr_reader->{$name} ? 1 : 0;
 112     }) if exists $methods->{existence};
 113
 114     $META->add_method($methods->{remove} => sub {
 115         my ($self, @values) = @_;
 116         delete $self->$attr_reader->{$_} foreach @values;
 117     }) if exists $methods->{remove};
 118 }
 119
 120 $META->add_attribute(
 121     'method_metaclass',
 122     reader  => 'method_metaclass',
 123     default => 'Moose::Meta::Role::Method',
 124 );
 125
 126 $META->add_attribute(
 127     'required_method_metaclass',
 128     reader  => 'required_method_metaclass',
 129     default => 'Moose::Meta::Role::Method::Required',
 130 );
 131
 132 $META->add_attribute(
 133     'conflicting_method_metaclass',
 134     reader  => 'conflicting_method_metaclass',
 135     default => 'Moose::Meta::Role::Method::Conflicting',
 136 );
 137
 138 $META->add_attribute(
 139     'application_to_class_class',
 140     reader  => 'application_to_class_class',
 141     default => 'Moose::Meta::Role::Application::ToClass',
 142 );
 143
 144 $META->add_attribute(
 145     'application_to_role_class',
 146     reader  => 'application_to_role_class',
 147     default => 'Moose::Meta::Role::Application::ToRole',
 148 );
 149
 150 $META->add_attribute(
 151     'application_to_instance_class',
 152     reader  => 'application_to_instance_class',
 153     default => 'Moose::Meta::Role::Application::ToInstance',
 154 );
 155
 156 $META->add_attribute(
 157     'applied_attribute_metaclass',
 158     reader  => 'applied_attribute_metaclass',
 159     default => 'Moose::Meta::Attribute',
 160 );
 161
 162 # More or less copied from Moose::Meta::Class
 163 sub initialize {
 164     my $class = shift;
 165     my $pkg   = shift;
 166
 167     if (defined(my $meta = Class::MOP::get_metaclass_by_name($pkg))) {
 168         return $meta;
 169     }
 170
 171     my %options = @_;
 172
 173     my $meta = $class->SUPER::initialize(
 174         $pkg,
 175         'attribute_metaclass' => 'Moose::Meta::Role::Attribute',
 176         %options,
 177     );
 178
 179     Class::MOP::weaken_metaclass($pkg) if $options{weaken};
 180
 181     return $meta;
 182 }
 183
 184 sub reinitialize {
 185     my $self = shift;
 186     my $pkg  = shift;
 187
 188     my $meta = blessed $pkg ? $pkg : Class::MOP::class_of($pkg);
 189
 190     my %existing_classes;
 191     if ($meta) {
 192         %existing_classes = map { $_ => $meta->$_() } qw(
 193             attribute_metaclass
 194             method_metaclass
 195             wrapped_method_metaclass
 196             required_method_metaclass
 197             conflicting_method_metaclass
 198             application_to_class_class
 199             application_to_role_class
 200             application_to_instance_class
 201             applied_attribute_metaclass
 202         );
 203     }
 204
 205     my %options = @_;
 206     $options{weaken} = Class::MOP::metaclass_is_weak($meta->name)
 207         if !exists $options{weaken}
 208         && blessed($meta)
 209         && $meta->isa('Moose::Meta::Role');
 210
 211     # don't need to remove generated metaobjects here yet, since we don't
 212     # yet generate anything in roles. this may change in the future though...
 213     # keep an eye on that
 214     my $new_meta = $self->SUPER::reinitialize(
 215         $pkg,
 216         %existing_classes,
 217         %options,
 218     );
 219     $new_meta->_restore_metaobjects_from($meta)
 220         if $meta && $meta->isa('Moose::Meta::Role');
 221     return $new_meta;
 222 }
 223
 224 sub _restore_metaobjects_from {
 225     my $self = shift;
 226     my ($old_meta) = @_;
 227
 228     $self->_restore_metamethods_from($old_meta);
 229     $self->_restore_metaattributes_from($old_meta);
 230
 231     for my $role ( @{ $old_meta->get_roles } ) {
 232         $self->add_role($role);
 233     }
 234 }
 235
 236 sub add_attribute {
 237     my $self = shift;
 238
 239     if (blessed $_[0] && ! $_[0]->isa('Moose::Meta::Role::Attribute') ) {
 240         my $class = ref $_[0];
 241         Moose->throw_error( "Cannot add a $class as an attribute to a role" );
 242     }
 243     elsif (!blessed($_[0]) && defined($_[0]) && $_[0] =~ /^\+(.*)/) {
 244         Moose->throw_error( "has '+attr' is not supported in roles" );
 245     }
 246
 247     return $self->SUPER::add_attribute(@_);
 248 }
 249
 250 sub _attach_attribute {
 251     my ( $self, $attribute ) = @_;
 252
 253     $attribute->attach_to_role($self);
 254 }
 255
 256 sub add_required_methods {
 257     my $self = shift;
 258
 259     for (@_) {
 260         my $method = $_;
 261         if (!blessed($method)) {
 262             $method = $self->required_method_metaclass->new(
 263                 name => $method,
 264             );
 265         }
 266         $self->get_required_methods_map->{$method->name} = $method;
 267     }
 268 }
 269
 270 sub add_conflicting_method {
 271     my $self = shift;
 272
 273     my $method;
 274     if (@_ == 1 && blessed($_[0])) {
 275         $method = shift;
 276     }
 277     else {
 278         $method = $self->conflicting_method_metaclass->new(@_);
 279     }
 280
 281     $self->add_required_methods($method);
 282 }
 283
 284 ## ------------------------------------------------------------------
 285 ## method modifiers
 286
 287 # NOTE:
 288 # the before/around/after method modifiers are
 289 # stored by name, but there can be many methods
 290 # then associated with that name. So again we have
 291 # lots of similar functionality, so we can do some
 292 # meta-programmin' and save some time.
 293 # - SL
 294
 295 foreach my $modifier_type (qw[ before around after ]) {
 296
 297     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 298
 299     # create the attribute ...
 300     $META->add_attribute("${modifier_type}_method_modifiers" => (
 301         reader  => $attr_reader,
 302         default => sub { {} }
 303     ));
 304
 305     # and some helper methods ...
 306     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 307         my ($self, $method_name) = @_;
 308         #return () unless exists $self->$attr_reader->{$method_name};
 309         my $mm = $self->$attr_reader->{$method_name};
 310         $mm ? @$mm : ();
 311     });
 312
 313     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 314         my ($self, $method_name) = @_;
 315         # NOTE:
 316         # for now we assume that if it exists,..
 317         # it has at least one modifier in it
 318         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 319     });
 320
 321     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 322         my ($self, $method_name, $method) = @_;
 323
 324         $self->$attr_reader->{$method_name} = []
 325             unless exists $self->$attr_reader->{$method_name};
 326
 327         my $modifiers = $self->$attr_reader->{$method_name};
 328
 329         # NOTE:
 330         # check to see that we aren't adding the
 331         # same code twice. We err in favor of the
 332         # first on here, this may not be as expected
 333         foreach my $modifier (@{$modifiers}) {
 334             return if $modifier == $method;
 335         }
 336
 337         push @{$modifiers} => $method;
 338     });
 339
 340 }
 341
 342 ## ------------------------------------------------------------------
 343 ## override method mofidiers
 344
 345 $META->add_attribute('override_method_modifiers' => (
 346     reader  => 'get_override_method_modifiers_map',
 347     default => sub { {} }
 348 ));
 349
 350 # NOTE:
 351 # these are a little different because there
 352 # can only be one per name, whereas the other
 353 # method modifiers can have multiples.
 354 # - SL
 355
 356 sub add_override_method_modifier {
 357     my ($self, $method_name, $method) = @_;
 358     (!$self->has_method($method_name))
 359         || Moose->throw_error("Cannot add an override of method '$method_name' " .
 360                    "because there is a local version of '$method_name'");
 361     $self->get_override_method_modifiers_map->{$method_name} = $method;
 362 }
 363
 364 sub has_override_method_modifier {
 365     my ($self, $method_name) = @_;
 366     # NOTE:
 367     # for now we assume that if it exists,..
 368     # it has at least one modifier in it
 369     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 370 }
 371
 372 sub get_override_method_modifier {
 373     my ($self, $method_name) = @_;
 374     $self->get_override_method_modifiers_map->{$method_name};
 375 }
 376
 377 ## general list accessor ...
 378
 379 sub get_method_modifier_list {
 380     my ($self, $modifier_type) = @_;
 381     my $accessor = "get_${modifier_type}_method_modifiers_map";
 382     keys %{$self->$accessor};
 383 }
 384
 385 sub _meta_method_class { 'Moose::Meta::Method::Meta' }
 386
 387 ## ------------------------------------------------------------------
 388 ## subroles
 389
 390 $META->add_attribute('roles' => (
 391     reader  => 'get_roles',
 392     default => sub { [] }
 393 ));
 394
 395 sub add_role {
 396     my ($self, $role) = @_;
 397     (blessed($role) && $role->isa('Moose::Meta::Role'))
 398         || Moose->throw_error("Roles must be instances of Moose::Meta::Role");
 399     push @{$self->get_roles} => $role;
 400     $self->reset_package_cache_flag;
 401 }
 402
 403 sub calculate_all_roles {
 404     my $self = shift;
 405     my %seen;
 406     grep {
 407         !$seen{$_->name}++
 408     } ($self, map {
 409                   $_->calculate_all_roles
 410               } @{ $self->get_roles });
 411 }
 412
 413 sub does_role {
 414     my ($self, $role) = @_;
 415     (defined $role)
 416         || Moose->throw_error("You must supply a role name to look for");
 417     my $role_name = blessed $role ? $role->name : $role;
 418     # if we are it,.. then return true
 419     return 1 if $role_name eq $self->name;
 420     # otherwise.. check our children
 421     foreach my $role (@{$self->get_roles}) {
 422         return 1 if $role->does_role($role_name);
 423     }
 424     return 0;
 425 }
 426
 427 sub find_method_by_name { (shift)->get_method(@_) }
 428
 429 ## ------------------------------------------------------------------
 430 ## role construction
 431 ## ------------------------------------------------------------------
 432
 433 sub apply {
 434     my ($self, $other, %args) = @_;
 435
 436     (blessed($other))
 437         || Moose->throw_error("You must pass in an blessed instance");
 438
 439     my $application_class;
 440     if ($other->isa('Moose::Meta::Role')) {
 441         $application_class = $self->application_to_role_class;
 442     }
 443     elsif ($other->isa('Moose::Meta::Class')) {
 444         $application_class = $self->application_to_class_class;
 445     }
 446     else {
 447         $application_class = $self->application_to_instance_class;
 448     }
 449
 450     Class::MOP::load_class($application_class);
 451
 452     my $deprecation_check = 0;
 453
 454     if ( exists $args{excludes} && !exists $args{'-excludes'} ) {
 455         $args{'-excludes'} = delete $args{excludes};
 456         $deprecation_check = 1;
 457     }
 458     if ( exists $args{alias} && !exists $args{'-alias'} ) {
 459         $args{'-alias'} = delete $args{alias};
 460         $deprecation_check = 1;
 461     }
 462
 463     if ( $deprecation_check ) {
 464         Moose::Deprecated::deprecated(
 465             feature => 'alias or excludes',
 466             message =>
 467                 'The alias and excludes options for role application'.
 468                 ' have been renamed -alias and -excludes'.
 469                 " (${\$other->name} is consuming ${\$self->name}".
 470                 " - do you need to upgrade ${\$other->name}?).".
 471                 ' This will be an error in Moose 2.0200.'
 472         );
 473     }
 474
 475     if ( exists $args{'-excludes'} ) {
 476         # I wish we had coercion here :)
 477         $args{'-excludes'} = (
 478             ref $args{'-excludes'} eq 'ARRAY'
 479             ? $args{'-excludes'}
 480             : [ $args{'-excludes'} ]
 481         );
 482     }
 483
 484     return $application_class->new(%args)->apply($self, $other, \%args);
 485 }
 486
 487 sub composition_class_roles { }
 488
 489 sub combine {
 490     my ($class, @role_specs) = @_;
 491
 492     require Moose::Meta::Role::Composite;
 493
 494     my (@roles, %role_params);
 495     while (@role_specs) {
 496         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 497         my $requested_role
 498             = blessed $role
 499             ? $role
 500             : Class::MOP::class_of($role);
 501
 502         my $actual_role = $requested_role->_role_for_combination($params);
 503         push @roles => $actual_role;
 504
 505         next unless defined $params;
 506         $role_params{$actual_role->name} = $params;
 507     }
 508
 509     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 510     return $c->apply_params(\%role_params);
 511 }
 512
 513 sub _role_for_combination {
 514     my ($self, $params) = @_;
 515     return $self;
 516 }
 517
 518 sub create {
 519     my ( $role, $package_name, %options ) = @_;
 520
 521     $options{package} = $package_name;
 522
 523     (ref $options{attributes} eq 'HASH')
 524         || confess "You must pass a HASH ref of attributes"
 525             if exists $options{attributes};
 526
 527     (ref $options{methods} eq 'HASH')
 528         || confess "You must pass a HASH ref of methods"
 529             if exists $options{methods};
 530
 531     $options{meta_name} = 'meta'
 532         unless exists $options{meta_name};
 533
 534     my (%initialize_options) = %options;
 535     delete @initialize_options{qw(
 536         package
 537         attributes
 538         methods
 539         meta_name
 540         version
 541         authority
 542     )};
 543
 544     my $meta = $role->initialize( $package_name => %initialize_options );
 545
 546     $meta->_instantiate_module( $options{version}, $options{authority} );
 547
 548     $meta->_add_meta_method($options{meta_name})
 549         if defined $options{meta_name};
 550
 551     if (exists $options{attributes}) {
 552         foreach my $attribute_name (keys %{$options{attributes}}) {
 553             my $attr = $options{attributes}->{$attribute_name};
 554             $meta->add_attribute(
 555                 $attribute_name => blessed $attr ? $attr : %{$attr} );
 556         }
 557     }
 558
 559     if (exists $options{methods}) {
 560         foreach my $method_name (keys %{$options{methods}}) {
 561             $meta->add_method($method_name, $options{methods}->{$method_name});
 562         }
 563     }
 564
 565     return $meta;
 566 }
 567
 568 sub consumers {
 569     my $self = shift;
 570     my @consumers;
 571     for my $meta (Class::MOP::get_all_metaclass_instances) {
 572         next if $meta->name eq $self->name;
 573         next unless $meta->isa('Moose::Meta::Class')
 574                  || $meta->isa('Moose::Meta::Role');
 575         push @consumers, $meta->name
 576             if $meta->does_role($self->name);
 577     }
 578     return @consumers;
 579 }
 580
 581 # anonymous roles. most of it is copied straight out of Class::MOP::Class.
 582 # an intrepid hacker might find great riches if he unifies this code with that
 583 # code in Class::MOP::Module or Class::MOP::Package
 584 {
 585     # NOTE:
 586     # this should be sufficient, if you have a
 587     # use case where it is not, write a test and
 588     # I will change it.
 589     my $ANON_ROLE_SERIAL = 0;
 590
 591     # NOTE:
 592     # we need a sufficiently annoying prefix
 593     # this should suffice for now, this is
 594     # used in a couple of places below, so
 595     # need to put it up here for now.
 596     my $ANON_ROLE_PREFIX = 'Moose::Meta::Role::__ANON__::SERIAL::';
 597
 598     sub is_anon_role {
 599         my $self = shift;
 600         no warnings 'uninitialized';
 601         $self->name =~ /^$ANON_ROLE_PREFIX/;
 602     }
 603
 604     sub create_anon_role {
 605         my ($role, %options) = @_;
 606         $options{weaken} = 1 unless exists $options{weaken};
 607         my $package_name = $ANON_ROLE_PREFIX . ++$ANON_ROLE_SERIAL;
 608         return $role->create($package_name, %options);
 609     }
 610
 611     # NOTE:
 612     # this will only get called for
 613     # anon-roles, all other calls
 614     # are assumed to occur during
 615     # global destruction and so don't
 616     # really need to be handled explicitly
 617     sub DESTROY {
 618         my $self = shift;
 619
 620         return if in_global_destruction(); # it'll happen soon anyway and this just makes things more complicated
 621
 622         no warnings 'uninitialized';
 623         return unless $self->name =~ /^$ANON_ROLE_PREFIX/;
 624
 625         # Moose does a weird thing where it replaces the metaclass for
 626         # class when fixing metaclass incompatibility. In that case,
 627         # we don't want to clean out the namespace now. We can detect
 628         # that because Moose will explicitly update the singleton
 629         # cache in Class::MOP.
 630         my $current_meta = Class::MOP::get_metaclass_by_name($self->name);
 631         return if $current_meta ne $self;
 632
 633         my ($serial_id) = ($self->name =~ /^$ANON_ROLE_PREFIX(\d+)/);
 634         no strict 'refs';
 635         foreach my $key (keys %{$ANON_ROLE_PREFIX . $serial_id}) {
 636             delete ${$ANON_ROLE_PREFIX . $serial_id}{$key};
 637         }
 638         delete ${'main::' . $ANON_ROLE_PREFIX}{$serial_id . '::'};
 639     }
 640 }
 641
 642 #####################################################################
 643 ## NOTE:
 644 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 645 ## MooseX::AttributeHelpers module). It is here as a reference to
 646 ## make it easier to see what is happening above with all the meta
 647 ## programming. - SL
 648 #####################################################################
 649 #
 650 # has 'roles' => (
 651 #     metaclass => 'Array',
 652 #     reader    => 'get_roles',
 653 #     isa       => 'ArrayRef[Moose::Meta::Role]',
 654 #     default   => sub { [] },
 655 #     provides  => {
 656 #         'push' => 'add_role',
 657 #     }
 658 # );
 659 #
 660 # has 'excluded_roles_map' => (
 661 #     metaclass => 'Hash',
 662 #     reader    => 'get_excluded_roles_map',
 663 #     isa       => 'HashRef[Str]',
 664 #     provides  => {
 665 #         # Not exactly set, cause it sets multiple
 666 #         'set'    => 'add_excluded_roles',
 667 #         'keys'   => 'get_excluded_roles_list',
 668 #         'exists' => 'excludes_role',
 669 #     }
 670 # );
 671 #
 672 # has 'required_methods' => (
 673 #     metaclass => 'Hash',
 674 #     reader    => 'get_required_methods_map',
 675 #     isa       => 'HashRef[Moose::Meta::Role::Method::Required]',
 676 #     provides  => {
 677 #         # not exactly set, or delete since it works for multiple
 678 #         'set'    => 'add_required_methods',
 679 #         'delete' => 'remove_required_methods',
 680 #         'keys'   => 'get_required_method_list',
 681 #         'exists' => 'requires_method',
 682 #     }
 683 # );
 684 #
 685 # # the before, around and after modifiers are
 686 # # HASH keyed by method-name, with ARRAY of
 687 # # CODE refs to apply in that order
 688 #
 689 # has 'before_method_modifiers' => (
 690 #     metaclass => 'Hash',
 691 #     reader    => 'get_before_method_modifiers_map',
 692 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 693 #     provides  => {
 694 #         'keys'   => 'get_before_method_modifiers',
 695 #         'exists' => 'has_before_method_modifiers',
 696 #         # This actually makes sure there is an
 697 #         # ARRAY at the given key, and pushed onto
 698 #         # it. It also checks for duplicates as well
 699 #         # 'add'  => 'add_before_method_modifier'
 700 #     }
 701 # );
 702 #
 703 # has 'after_method_modifiers' => (
 704 #     metaclass => 'Hash',
 705 #     reader    =>'get_after_method_modifiers_map',
 706 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 707 #     provides  => {
 708 #         'keys'   => 'get_after_method_modifiers',
 709 #         'exists' => 'has_after_method_modifiers',
 710 #         # This actually makes sure there is an
 711 #         # ARRAY at the given key, and pushed onto
 712 #         # it. It also checks for duplicates as well
 713 #         # 'add'  => 'add_after_method_modifier'
 714 #     }
 715 # );
 716 #
 717 # has 'around_method_modifiers' => (
 718 #     metaclass => 'Hash',
 719 #     reader    =>'get_around_method_modifiers_map',
 720 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 721 #     provides  => {
 722 #         'keys'   => 'get_around_method_modifiers',
 723 #         'exists' => 'has_around_method_modifiers',
 724 #         # This actually makes sure there is an
 725 #         # ARRAY at the given key, and pushed onto
 726 #         # it. It also checks for duplicates as well
 727 #         # 'add'  => 'add_around_method_modifier'
 728 #     }
 729 # );
 730 #
 731 # # override is similar to the other modifiers
 732 # # except that it is not an ARRAY of code refs
 733 # # but instead just a single name->code mapping
 734 #
 735 # has 'override_method_modifiers' => (
 736 #     metaclass => 'Hash',
 737 #     reader    =>'get_override_method_modifiers_map',
 738 #     isa       => 'HashRef[CodeRef]',
 739 #     provides  => {
 740 #         'keys'   => 'get_override_method_modifier',
 741 #         'exists' => 'has_override_method_modifier',
 742 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 743 #     }
 744 # );
 745 #
 746 #####################################################################
 747
 748
 749 1;
 750
 751 # ABSTRACT: The Moose Role metaclass
 752
 753 __END__
 754
 755 =pod
 756
 757 =head1 DESCRIPTION
 758
 759 This class is a subclass of L<Class::MOP::Module> that provides
 760 additional Moose-specific functionality.
 761
 762 It's API looks a lot like L<Moose::Meta::Class>, but internally it
 763 implements many things differently. This may change in the future.
 764
 765 =head1 INHERITANCE
 766
 767 C<Moose::Meta::Role> is a subclass of L<Class::MOP::Module>.
 768
 769 =head1 METHODS
 770
 771 =head2 Construction
 772
 773 =over 4
 774
 775 =item B<< Moose::Meta::Role->initialize($role_name) >>
 776
 777 This method creates a new role object with the provided name.
 778
 779 =item B<< Moose::Meta::Role->combine( [ $role => { ... } ], [ $role ], ... ) >>
 780
 781 This method accepts a list of array references. Each array reference
 782 should contain a role name or L<Moose::Meta::Role> object as its first element. The second element is
 783 an optional hash reference. The hash reference can contain C<-excludes>
 784 and C<-alias> keys to control how methods are composed from the role.
 785
 786 The return value is a new L<Moose::Meta::Role::Composite> that
 787 represents the combined roles.
 788
 789 =item B<< $metarole->composition_class_roles >>
 790
 791 When combining multiple roles using C<combine>, this method is used to obtain a
 792 list of role names to be applied to the L<Moose::Meta::Role::Composite>
 793 instance returned by C<combine>. The default implementation returns an empty
 794 list. Extensions that need to hook into role combination may wrap this method
 795 to return additional role names.
 796
 797 =item B<< Moose::Meta::Role->create($name, %options) >>
 798
 799 This method is identical to the L<Moose::Meta::Class> C<create>
 800 method.
 801
 802 =item B<< Moose::Meta::Role->create_anon_role >>
 803
 804 This method is identical to the L<Moose::Meta::Class>
 805 C<create_anon_class> method.
 806
 807 =item B<< $metarole->is_anon_role >>
 808
 809 Returns true if the role is an anonymous role.
 810
 811 =item B<< $metarole->consumers >>
 812
 813 Returns a list of names of classes and roles which consume this role.
 814
 815 =back
 816
 817 =head2 Role application
 818
 819 =over 4
 820
 821 =item B<< $metarole->apply( $thing, @options ) >>
 822
 823 This method applies a role to the given C<$thing>. That can be another
 824 L<Moose::Meta::Role>, object, a L<Moose::Meta::Class> object, or a
 825 (non-meta) object instance.
 826
 827 The options are passed directly to the constructor for the appropriate
 828 L<Moose::Meta::Role::Application> subclass.
 829
 830 Note that this will apply the role even if the C<$thing> in question already
 831 C<does> this role.  L<Moose::Util/does_role> is a convenient wrapper for
 832 finding out if role application is necessary.
 833
 834 =back
 835
 836 =head2 Roles and other roles
 837
 838 =over 4
 839
 840 =item B<< $metarole->get_roles >>
 841
 842 This returns an array reference of roles which this role does. This
 843 list may include duplicates.
 844
 845 =item B<< $metarole->calculate_all_roles >>
 846
 847 This returns a I<unique> list of all roles that this role does, and
 848 all the roles that its roles do.
 849
 850 =item B<< $metarole->does_role($role) >>
 851
 852 Given a role I<name> or L<Moose::Meta::Role> object, returns true if this role
 853 does the given role.
 854
 855 =item B<< $metarole->add_role($role) >>
 856
 857 Given a L<Moose::Meta::Role> object, this adds the role to the list of
 858 roles that the role does.
 859
 860 =item B<< $metarole->get_excluded_roles_list >>
 861
 862 Returns a list of role names which this role excludes.
 863
 864 =item B<< $metarole->excludes_role($role_name) >>
 865
 866 Given a role I<name>, returns true if this role excludes the named
 867 role.
 868
 869 =item B<< $metarole->add_excluded_roles(@role_names) >>
 870
 871 Given one or more role names, adds those roles to the list of excluded
 872 roles.
 873
 874 =back
 875
 876 =head2 Methods
 877
 878 The methods for dealing with a role's methods are all identical in API
 879 and behavior to the same methods in L<Class::MOP::Class>.
 880
 881 =over 4
 882
 883 =item B<< $metarole->method_metaclass >>
 884
 885 Returns the method metaclass name for the role. This defaults to
 886 L<Moose::Meta::Role::Method>.
 887
 888 =item B<< $metarole->get_method($name) >>
 889
 890 =item B<< $metarole->has_method($name) >>
 891
 892 =item B<< $metarole->add_method( $name, $body ) >>
 893
 894 =item B<< $metarole->get_method_list >>
 895
 896 =item B<< $metarole->find_method_by_name($name) >>
 897
 898 These methods are all identical to the methods of the same name in
 899 L<Class::MOP::Package>
 900
 901 =back
 902
 903 =head2 Attributes
 904
 905 As with methods, the methods for dealing with a role's attribute are
 906 all identical in API and behavior to the same methods in
 907 L<Class::MOP::Class>.
 908
 909 However, attributes stored in this class are I<not> stored as
 910 objects. Rather, the attribute definition is stored as a hash
 911 reference. When a role is composed into a class, this hash reference
 912 is passed directly to the metaclass's C<add_attribute> method.
 913
 914 This is quite likely to change in the future.
 915
 916 =over 4
 917
 918 =item B<< $metarole->get_attribute($attribute_name) >>
 919
 920 =item B<< $metarole->has_attribute($attribute_name) >>
 921
 922 =item B<< $metarole->get_attribute_list >>
 923
 924 =item B<< $metarole->add_attribute($name, %options) >>
 925
 926 =item B<< $metarole->remove_attribute($attribute_name) >>
 927
 928 =back
 929
 930 =head2 Required methods
 931
 932 =over 4
 933
 934 =item B<< $metarole->get_required_method_list >>
 935
 936 Returns the list of methods required by the role.
 937
 938 =item B<< $metarole->requires_method($name) >>
 939
 940 Returns true if the role requires the named method.
 941
 942 =item B<< $metarole->add_required_methods(@names) >>
 943
 944 Adds the named methods to the role's list of required methods.
 945
 946 =item B<< $metarole->remove_required_methods(@names) >>
 947
 948 Removes the named methods from the role's list of required methods.
 949
 950 =item B<< $metarole->add_conflicting_method(%params) >>
 951
 952 Instantiate the parameters as a L<Moose::Meta::Role::Method::Conflicting>
 953 object, then add it to the required method list.
 954
 955 =back
 956
 957 =head2 Method modifiers
 958
 959 These methods act like their counterparts in L<Class::MOP::Class> and
 960 L<Moose::Meta::Class>.
 961
 962 However, method modifiers are simply stored internally, and are not
 963 applied until the role itself is applied to a class.
 964
 965 =over 4
 966
 967 =item B<< $metarole->add_after_method_modifier($method_name, $method) >>
 968
 969 =item B<< $metarole->add_around_method_modifier($method_name, $method) >>
 970
 971 =item B<< $metarole->add_before_method_modifier($method_name, $method) >>
 972
 973 =item B<< $metarole->add_override_method_modifier($method_name, $method) >>
 974
 975 These methods all add an appropriate modifier to the internal list of
 976 modifiers.
 977
 978 =item B<< $metarole->has_after_method_modifiers >>
 979
 980 =item B<< $metarole->has_around_method_modifiers >>
 981
 982 =item B<< $metarole->has_before_method_modifiers >>
 983
 984 =item B<< $metarole->has_override_method_modifier >>
 985
 986 Return true if the role has any modifiers of the given type.
 987
 988 =item B<< $metarole->get_after_method_modifiers($method_name) >>
 989
 990 =item B<< $metarole->get_around_method_modifiers($method_name) >>
 991
 992 =item B<< $metarole->get_before_method_modifiers($method_name) >>
 993
 994 Given a method name, returns a list of the appropriate modifiers for
 995 that method.
 996
 997 =item B<< $metarole->get_override_method_modifier($method_name) >>
 998
 999 Given a method name, returns the override method modifier for that
1000 method, if it has one.
1001
1002 =back
1003
1004 =head2 Introspection
1005
1006 =over 4
1007
1008 =item B<< Moose::Meta::Role->meta >>
1009
1010 This will return a L<Class::MOP::Class> instance for this class.
1011
1012 =back
1013
1014 =head1 BUGS
1015
1016 See L<Moose/BUGS> for details on reporting bugs.
1017
1018 =cut