lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Scalar::Util 'blessed';
   9 use Carp         'confess';
  10 use Devel::GlobalDestruction 'in_global_destruction';
  11
  12 our $VERSION   = '1.14';
  13 $VERSION = eval $VERSION;
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 use Moose::Meta::Class;
  17 use Moose::Meta::Role::Attribute;
  18 use Moose::Meta::Role::Method;
  19 use Moose::Meta::Role::Method::Required;
  20 use Moose::Meta::Role::Method::Conflicting;
  21 use Moose::Util qw( ensure_all_roles );
  22 use Class::MOP::MiniTrait;
  23
  24 use base 'Class::MOP::Module',
  25          'Class::MOP::Mixin::HasAttributes',
  26          'Class::MOP::Mixin::HasMethods';
  27
  28 Class::MOP::MiniTrait::apply(__PACKAGE__, 'Moose::Meta::Object::Trait');
  29
  30 ## ------------------------------------------------------------------
  31 ## NOTE:
  32 ## I normally don't do this, but I am doing
  33 ## a whole bunch of meta-programmin in this
  34 ## module, so it just makes sense. For a clearer
  35 ## picture of what is going on in the next
  36 ## several lines of code, look at the really
  37 ## big comment at the end of this file (right
  38 ## before the POD).
  39 ## - SL
  40 ## ------------------------------------------------------------------
  41
  42 my $META = __PACKAGE__->meta;
  43
  44 ## ------------------------------------------------------------------
  45 ## attributes ...
  46
  47 # NOTE:
  48 # since roles are lazy, we hold all the attributes
  49 # of the individual role in 'statis' until which
  50 # time when it is applied to a class. This means
  51 # keeping a lot of things in hash maps, so we are
  52 # using a little of that meta-programmin' magic
  53 # here an saving lots of extra typin. And since
  54 # many of these attributes above require similar
  55 # functionality to support them, so we again use
  56 # the wonders of meta-programmin' to deliver a
  57 # very compact solution to this normally verbose
  58 # problem.
  59 # - SL
  60
  61 foreach my $action (
  62     {
  63         name        => 'excluded_roles_map',
  64         attr_reader => 'get_excluded_roles_map' ,
  65         methods     => {
  66             add       => 'add_excluded_roles',
  67             get_keys  => 'get_excluded_roles_list',
  68             existence => 'excludes_role',
  69         }
  70     },
  71     {
  72         name        => 'required_methods',
  73         attr_reader => 'get_required_methods_map',
  74         methods     => {
  75             remove     => 'remove_required_methods',
  76             get_values => 'get_required_method_list',
  77             existence  => 'requires_method',
  78         }
  79     },
  80 ) {
  81
  82     my $attr_reader = $action->{attr_reader};
  83     my $methods     = $action->{methods};
  84
  85     # create the attribute
  86     $META->add_attribute($action->{name} => (
  87         reader  => $attr_reader,
  88         default => sub { {} }
  89     ));
  90
  91     # create some helper methods
  92     $META->add_method($methods->{add} => sub {
  93         my ($self, @values) = @_;
  94         $self->$attr_reader->{$_} = undef foreach @values;
  95     }) if exists $methods->{add};
  96
  97     $META->add_method($methods->{get_keys} => sub {
  98         my ($self) = @_;
  99         keys %{$self->$attr_reader};
 100     }) if exists $methods->{get_keys};
 101
 102     $META->add_method($methods->{get_values} => sub {
 103         my ($self) = @_;
 104         values %{$self->$attr_reader};
 105     }) if exists $methods->{get_values};
 106
 107     $META->add_method($methods->{get} => sub {
 108         my ($self, $name) = @_;
 109         $self->$attr_reader->{$name}
 110     }) if exists $methods->{get};
 111
 112     $META->add_method($methods->{existence} => sub {
 113         my ($self, $name) = @_;
 114         exists $self->$attr_reader->{$name} ? 1 : 0;
 115     }) if exists $methods->{existence};
 116
 117     $META->add_method($methods->{remove} => sub {
 118         my ($self, @values) = @_;
 119         delete $self->$attr_reader->{$_} foreach @values;
 120     }) if exists $methods->{remove};
 121 }
 122
 123 $META->add_attribute(
 124     'method_metaclass',
 125     reader  => 'method_metaclass',
 126     default => 'Moose::Meta::Role::Method',
 127 );
 128
 129 $META->add_attribute(
 130     'required_method_metaclass',
 131     reader  => 'required_method_metaclass',
 132     default => 'Moose::Meta::Role::Method::Required',
 133 );
 134
 135 $META->add_attribute(
 136     'conflicting_method_metaclass',
 137     reader  => 'conflicting_method_metaclass',
 138     default => 'Moose::Meta::Role::Method::Conflicting',
 139 );
 140
 141 $META->add_attribute(
 142     'application_to_class_class',
 143     reader  => 'application_to_class_class',
 144     default => 'Moose::Meta::Role::Application::ToClass',
 145 );
 146
 147 $META->add_attribute(
 148     'application_to_role_class',
 149     reader  => 'application_to_role_class',
 150     default => 'Moose::Meta::Role::Application::ToRole',
 151 );
 152
 153 $META->add_attribute(
 154     'application_to_instance_class',
 155     reader  => 'application_to_instance_class',
 156     default => 'Moose::Meta::Role::Application::ToInstance',
 157 );
 158
 159 # More or less copied from Moose::Meta::Class
 160 sub initialize {
 161     my $class = shift;
 162     my $pkg   = shift;
 163     return Class::MOP::get_metaclass_by_name($pkg)
 164         || $class->SUPER::initialize(
 165         $pkg,
 166         'attribute_metaclass' => 'Moose::Meta::Role::Attribute',
 167         @_
 168         );
 169 }
 170
 171 sub reinitialize {
 172     my $self = shift;
 173     my $pkg  = shift;
 174
 175     my $meta = blessed $pkg ? $pkg : Class::MOP::class_of($pkg);
 176
 177     my %existing_classes;
 178     if ($meta) {
 179         %existing_classes = map { $_ => $meta->$_() } qw(
 180             attribute_metaclass
 181             method_metaclass
 182             wrapped_method_metaclass
 183             required_method_metaclass
 184             conflicting_method_metaclass
 185             application_to_class_class
 186             application_to_role_class
 187             application_to_instance_class
 188         );
 189     }
 190
 191     # don't need to remove generated metaobjects here yet, since we don't
 192     # yet generate anything in roles. this may change in the future though...
 193     # keep an eye on that
 194     my $new_meta = $self->SUPER::reinitialize(
 195         $pkg,
 196         %existing_classes,
 197         @_,
 198     );
 199     $new_meta->_restore_metaobjects_from($meta)
 200         if $meta && $meta->isa('Moose::Meta::Role');
 201     return $new_meta;
 202 }
 203
 204 sub _restore_metaobjects_from {
 205     my $self = shift;
 206     my ($old_meta) = @_;
 207
 208     $self->_restore_metamethods_from($old_meta);
 209     $self->_restore_metaattributes_from($old_meta);
 210 }
 211
 212 sub add_attribute {
 213     my $self = shift;
 214
 215     if (blessed $_[0] && ! $_[0]->isa('Moose::Meta::Role::Attribute') ) {
 216         my $class = ref $_[0];
 217         Moose->throw_error( "Cannot add a $class as an attribute to a role" );
 218     }
 219     elsif (!blessed($_[0]) && defined($_[0]) && $_[0] =~ /^\+(.*)/) {
 220         Moose->throw_error( "has '+attr' is not supported in roles" );
 221     }
 222
 223     return $self->SUPER::add_attribute(@_);
 224 }
 225
 226 sub _attach_attribute {
 227     my ( $self, $attribute ) = @_;
 228
 229     $attribute->attach_to_role($self);
 230 }
 231
 232 sub add_required_methods {
 233     my $self = shift;
 234
 235     for (@_) {
 236         my $method = $_;
 237         if (!blessed($method)) {
 238             $method = $self->required_method_metaclass->new(
 239                 name => $method,
 240             );
 241         }
 242         $self->get_required_methods_map->{$method->name} = $method;
 243     }
 244 }
 245
 246 sub add_conflicting_method {
 247     my $self = shift;
 248
 249     my $method;
 250     if (@_ == 1 && blessed($_[0])) {
 251         $method = shift;
 252     }
 253     else {
 254         $method = $self->conflicting_method_metaclass->new(@_);
 255     }
 256
 257     $self->add_required_methods($method);
 258 }
 259
 260 ## ------------------------------------------------------------------
 261 ## method modifiers
 262
 263 # NOTE:
 264 # the before/around/after method modifiers are
 265 # stored by name, but there can be many methods
 266 # then associated with that name. So again we have
 267 # lots of similar functionality, so we can do some
 268 # meta-programmin' and save some time.
 269 # - SL
 270
 271 foreach my $modifier_type (qw[ before around after ]) {
 272
 273     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 274
 275     # create the attribute ...
 276     $META->add_attribute("${modifier_type}_method_modifiers" => (
 277         reader  => $attr_reader,
 278         default => sub { {} }
 279     ));
 280
 281     # and some helper methods ...
 282     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 283         my ($self, $method_name) = @_;
 284         #return () unless exists $self->$attr_reader->{$method_name};
 285         my $mm = $self->$attr_reader->{$method_name};
 286         $mm ? @$mm : ();
 287     });
 288
 289     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 290         my ($self, $method_name) = @_;
 291         # NOTE:
 292         # for now we assume that if it exists,..
 293         # it has at least one modifier in it
 294         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 295     });
 296
 297     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 298         my ($self, $method_name, $method) = @_;
 299
 300         $self->$attr_reader->{$method_name} = []
 301             unless exists $self->$attr_reader->{$method_name};
 302
 303         my $modifiers = $self->$attr_reader->{$method_name};
 304
 305         # NOTE:
 306         # check to see that we aren't adding the
 307         # same code twice. We err in favor of the
 308         # first on here, this may not be as expected
 309         foreach my $modifier (@{$modifiers}) {
 310             return if $modifier == $method;
 311         }
 312
 313         push @{$modifiers} => $method;
 314     });
 315
 316 }
 317
 318 ## ------------------------------------------------------------------
 319 ## override method mofidiers
 320
 321 $META->add_attribute('override_method_modifiers' => (
 322     reader  => 'get_override_method_modifiers_map',
 323     default => sub { {} }
 324 ));
 325
 326 # NOTE:
 327 # these are a little different because there
 328 # can only be one per name, whereas the other
 329 # method modifiers can have multiples.
 330 # - SL
 331
 332 sub add_override_method_modifier {
 333     my ($self, $method_name, $method) = @_;
 334     (!$self->has_method($method_name))
 335         || Moose->throw_error("Cannot add an override of method '$method_name' " .
 336                    "because there is a local version of '$method_name'");
 337     $self->get_override_method_modifiers_map->{$method_name} = $method;
 338 }
 339
 340 sub has_override_method_modifier {
 341     my ($self, $method_name) = @_;
 342     # NOTE:
 343     # for now we assume that if it exists,..
 344     # it has at least one modifier in it
 345     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 346 }
 347
 348 sub get_override_method_modifier {
 349     my ($self, $method_name) = @_;
 350     $self->get_override_method_modifiers_map->{$method_name};
 351 }
 352
 353 ## general list accessor ...
 354
 355 sub get_method_modifier_list {
 356     my ($self, $modifier_type) = @_;
 357     my $accessor = "get_${modifier_type}_method_modifiers_map";
 358     keys %{$self->$accessor};
 359 }
 360
 361 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 362 sub update_package_cache_flag {
 363     my $self = shift;
 364     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 365 }
 366
 367
 368
 369 ## ------------------------------------------------------------------
 370 ## subroles
 371
 372 $META->add_attribute('roles' => (
 373     reader  => 'get_roles',
 374     default => sub { [] }
 375 ));
 376
 377 sub add_role {
 378     my ($self, $role) = @_;
 379     (blessed($role) && $role->isa('Moose::Meta::Role'))
 380         || Moose->throw_error("Roles must be instances of Moose::Meta::Role");
 381     push @{$self->get_roles} => $role;
 382     $self->reset_package_cache_flag;
 383 }
 384
 385 sub calculate_all_roles {
 386     my $self = shift;
 387     my %seen;
 388     grep {
 389         !$seen{$_->name}++
 390     } ($self, map {
 391                   $_->calculate_all_roles
 392               } @{ $self->get_roles });
 393 }
 394
 395 sub does_role {
 396     my ($self, $role) = @_;
 397     (defined $role)
 398         || Moose->throw_error("You must supply a role name to look for");
 399     my $role_name = blessed $role ? $role->name : $role;
 400     # if we are it,.. then return true
 401     return 1 if $role_name eq $self->name;
 402     # otherwise.. check our children
 403     foreach my $role (@{$self->get_roles}) {
 404         return 1 if $role->does_role($role_name);
 405     }
 406     return 0;
 407 }
 408
 409 sub find_method_by_name { (shift)->get_method(@_) }
 410
 411 ## ------------------------------------------------------------------
 412 ## role construction
 413 ## ------------------------------------------------------------------
 414
 415 sub apply {
 416     my ($self, $other, %args) = @_;
 417
 418     (blessed($other))
 419         || Moose->throw_error("You must pass in an blessed instance");
 420
 421     my $application_class;
 422     if ($other->isa('Moose::Meta::Role')) {
 423         $application_class = $self->application_to_role_class;
 424     }
 425     elsif ($other->isa('Moose::Meta::Class')) {
 426         $application_class = $self->application_to_class_class;
 427     }
 428     else {
 429         $application_class = $self->application_to_instance_class;
 430     }
 431
 432     Class::MOP::load_class($application_class);
 433     return $application_class->new(%args)->apply($self, $other, \%args);
 434 }
 435
 436 sub composition_class_roles { }
 437
 438 sub combine {
 439     my ($class, @role_specs) = @_;
 440
 441     require Moose::Meta::Role::Composite;
 442
 443     my (@roles, %role_params);
 444     while (@role_specs) {
 445         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 446         my $requested_role
 447             = blessed $role
 448             ? $role
 449             : Class::MOP::class_of($role);
 450
 451         my $actual_role = $requested_role->_role_for_combination($params);
 452         push @roles => $actual_role;
 453
 454         next unless defined $params;
 455         $role_params{$actual_role->name} = $params;
 456     }
 457
 458     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 459     return $c->apply_params(\%role_params);
 460 }
 461
 462 sub _role_for_combination {
 463     my ($self, $params) = @_;
 464     return $self;
 465 }
 466
 467 sub create {
 468     my ( $role, $package_name, %options ) = @_;
 469
 470     $options{package} = $package_name;
 471
 472     (ref $options{attributes} eq 'HASH')
 473         || confess "You must pass a HASH ref of attributes"
 474             if exists $options{attributes};
 475
 476     (ref $options{methods} eq 'HASH')
 477         || confess "You must pass a HASH ref of methods"
 478             if exists $options{methods};
 479
 480     my (%initialize_options) = %options;
 481     delete @initialize_options{qw(
 482         package
 483         attributes
 484         methods
 485         version
 486         authority
 487     )};
 488
 489     my $meta = $role->initialize( $package_name => %initialize_options );
 490
 491     $meta->_instantiate_module( $options{version}, $options{authority} );
 492
 493     # FIXME totally lame
 494     $meta->add_method('meta' => sub {
 495         $role->initialize(ref($_[0]) || $_[0]);
 496     });
 497
 498     if (exists $options{attributes}) {
 499         foreach my $attribute_name (keys %{$options{attributes}}) {
 500             my $attr = $options{attributes}->{$attribute_name};
 501             $meta->add_attribute(
 502                 $attribute_name => blessed $attr ? $attr : %{$attr} );
 503         }
 504     }
 505
 506     if (exists $options{methods}) {
 507         foreach my $method_name (keys %{$options{methods}}) {
 508             $meta->add_method($method_name, $options{methods}->{$method_name});
 509         }
 510     }
 511
 512     Class::MOP::weaken_metaclass($meta->name)
 513         if $meta->is_anon_role;
 514
 515     return $meta;
 516 }
 517
 518 sub consumers {
 519     my $self = shift;
 520     my @consumers;
 521     for my $meta (Class::MOP::get_all_metaclass_instances) {
 522         next if $meta->name eq $self->name;
 523         next unless $meta->isa('Moose::Meta::Class')
 524                  || $meta->isa('Moose::Meta::Role');
 525         push @consumers, $meta->name
 526             if $meta->does_role($self->name);
 527     }
 528     return @consumers;
 529 }
 530
 531 # anonymous roles. most of it is copied straight out of Class::MOP::Class.
 532 # an intrepid hacker might find great riches if he unifies this code with that
 533 # code in Class::MOP::Module or Class::MOP::Package
 534 {
 535     # NOTE:
 536     # this should be sufficient, if you have a
 537     # use case where it is not, write a test and
 538     # I will change it.
 539     my $ANON_ROLE_SERIAL = 0;
 540
 541     # NOTE:
 542     # we need a sufficiently annoying prefix
 543     # this should suffice for now, this is
 544     # used in a couple of places below, so
 545     # need to put it up here for now.
 546     my $ANON_ROLE_PREFIX = 'Moose::Meta::Role::__ANON__::SERIAL::';
 547
 548     sub is_anon_role {
 549         my $self = shift;
 550         no warnings 'uninitialized';
 551         $self->name =~ /^$ANON_ROLE_PREFIX/;
 552     }
 553
 554     sub create_anon_role {
 555         my ($role, %options) = @_;
 556         my $package_name = $ANON_ROLE_PREFIX . ++$ANON_ROLE_SERIAL;
 557         return $role->create($package_name, %options);
 558     }
 559
 560     # NOTE:
 561     # this will only get called for
 562     # anon-roles, all other calls
 563     # are assumed to occur during
 564     # global destruction and so don't
 565     # really need to be handled explicitly
 566     sub DESTROY {
 567         my $self = shift;
 568
 569         return if in_global_destruction(); # it'll happen soon anyway and this just makes things more complicated
 570
 571         no warnings 'uninitialized';
 572         return unless $self->name =~ /^$ANON_ROLE_PREFIX/;
 573
 574         # XXX: is this necessary for us? I don't understand what it's doing
 575         # -sartak
 576
 577         # Moose does a weird thing where it replaces the metaclass for
 578         # class when fixing metaclass incompatibility. In that case,
 579         # we don't want to clean out the namespace now. We can detect
 580         # that because Moose will explicitly update the singleton
 581         # cache in Class::MOP.
 582         #my $current_meta = Class::MOP::get_metaclass_by_name($self->name);
 583         #return if $current_meta ne $self;
 584
 585         my ($serial_id) = ($self->name =~ /^$ANON_ROLE_PREFIX(\d+)/);
 586         no strict 'refs';
 587         foreach my $key (keys %{$ANON_ROLE_PREFIX . $serial_id}) {
 588             delete ${$ANON_ROLE_PREFIX . $serial_id}{$key};
 589         }
 590         delete ${'main::' . $ANON_ROLE_PREFIX}{$serial_id . '::'};
 591     }
 592 }
 593
 594 #####################################################################
 595 ## NOTE:
 596 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 597 ## MooseX::AttributeHelpers module). It is here as a reference to
 598 ## make it easier to see what is happening above with all the meta
 599 ## programming. - SL
 600 #####################################################################
 601 #
 602 # has 'roles' => (
 603 #     metaclass => 'Array',
 604 #     reader    => 'get_roles',
 605 #     isa       => 'ArrayRef[Moose::Meta::Role]',
 606 #     default   => sub { [] },
 607 #     provides  => {
 608 #         'push' => 'add_role',
 609 #     }
 610 # );
 611 #
 612 # has 'excluded_roles_map' => (
 613 #     metaclass => 'Hash',
 614 #     reader    => 'get_excluded_roles_map',
 615 #     isa       => 'HashRef[Str]',
 616 #     provides  => {
 617 #         # Not exactly set, cause it sets multiple
 618 #         'set'    => 'add_excluded_roles',
 619 #         'keys'   => 'get_excluded_roles_list',
 620 #         'exists' => 'excludes_role',
 621 #     }
 622 # );
 623 #
 624 # has 'required_methods' => (
 625 #     metaclass => 'Hash',
 626 #     reader    => 'get_required_methods_map',
 627 #     isa       => 'HashRef[Moose::Meta::Role::Method::Required]',
 628 #     provides  => {
 629 #         # not exactly set, or delete since it works for multiple
 630 #         'set'    => 'add_required_methods',
 631 #         'delete' => 'remove_required_methods',
 632 #         'keys'   => 'get_required_method_list',
 633 #         'exists' => 'requires_method',
 634 #     }
 635 # );
 636 #
 637 # # the before, around and after modifiers are
 638 # # HASH keyed by method-name, with ARRAY of
 639 # # CODE refs to apply in that order
 640 #
 641 # has 'before_method_modifiers' => (
 642 #     metaclass => 'Hash',
 643 #     reader    => 'get_before_method_modifiers_map',
 644 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 645 #     provides  => {
 646 #         'keys'   => 'get_before_method_modifiers',
 647 #         'exists' => 'has_before_method_modifiers',
 648 #         # This actually makes sure there is an
 649 #         # ARRAY at the given key, and pushed onto
 650 #         # it. It also checks for duplicates as well
 651 #         # 'add'  => 'add_before_method_modifier'
 652 #     }
 653 # );
 654 #
 655 # has 'after_method_modifiers' => (
 656 #     metaclass => 'Hash',
 657 #     reader    =>'get_after_method_modifiers_map',
 658 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 659 #     provides  => {
 660 #         'keys'   => 'get_after_method_modifiers',
 661 #         'exists' => 'has_after_method_modifiers',
 662 #         # This actually makes sure there is an
 663 #         # ARRAY at the given key, and pushed onto
 664 #         # it. It also checks for duplicates as well
 665 #         # 'add'  => 'add_after_method_modifier'
 666 #     }
 667 # );
 668 #
 669 # has 'around_method_modifiers' => (
 670 #     metaclass => 'Hash',
 671 #     reader    =>'get_around_method_modifiers_map',
 672 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 673 #     provides  => {
 674 #         'keys'   => 'get_around_method_modifiers',
 675 #         'exists' => 'has_around_method_modifiers',
 676 #         # This actually makes sure there is an
 677 #         # ARRAY at the given key, and pushed onto
 678 #         # it. It also checks for duplicates as well
 679 #         # 'add'  => 'add_around_method_modifier'
 680 #     }
 681 # );
 682 #
 683 # # override is similar to the other modifiers
 684 # # except that it is not an ARRAY of code refs
 685 # # but instead just a single name->code mapping
 686 #
 687 # has 'override_method_modifiers' => (
 688 #     metaclass => 'Hash',
 689 #     reader    =>'get_override_method_modifiers_map',
 690 #     isa       => 'HashRef[CodeRef]',
 691 #     provides  => {
 692 #         'keys'   => 'get_override_method_modifier',
 693 #         'exists' => 'has_override_method_modifier',
 694 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 695 #     }
 696 # );
 697 #
 698 #####################################################################
 699
 700
 701 1;
 702
 703 __END__
 704
 705 =pod
 706
 707 =head1 NAME
 708
 709 Moose::Meta::Role - The Moose Role metaclass
 710
 711 =head1 DESCRIPTION
 712
 713 This class is a subclass of L<Class::MOP::Module> that provides
 714 additional Moose-specific functionality.
 715
 716 It's API looks a lot like L<Moose::Meta::Class>, but internally it
 717 implements many things differently. This may change in the future.
 718
 719 =head1 INHERITANCE
 720
 721 C<Moose::Meta::Role> is a subclass of L<Class::MOP::Module>.
 722
 723 =head1 METHODS
 724
 725 =head2 Construction
 726
 727 =over 4
 728
 729 =item B<< Moose::Meta::Role->initialize($role_name) >>
 730
 731 This method creates a new role object with the provided name.
 732
 733 =item B<< Moose::Meta::Role->combine( [ $role => { ... } ], [ $role ], ... ) >>
 734
 735 This method accepts a list of array references. Each array reference
 736 should contain a role name or L<Moose::Meta::Role> object as its first element. The second element is
 737 an optional hash reference. The hash reference can contain C<-excludes>
 738 and C<-alias> keys to control how methods are composed from the role.
 739
 740 The return value is a new L<Moose::Meta::Role::Composite> that
 741 represents the combined roles.
 742
 743 =item B<< $metarole->composition_class_roles >>
 744
 745 When combining multiple roles using C<combine>, this method is used to obtain a
 746 list of role names to be applied to the L<Moose::Meta::Role::Composite>
 747 instance returned by C<combine>. The default implementation returns an empty
 748 list. Extensions that need to hook into role combination may wrap this method
 749 to return additional role names.
 750
 751 =item B<< Moose::Meta::Role->create($name, %options) >>
 752
 753 This method is identical to the L<Moose::Meta::Class> C<create>
 754 method.
 755
 756 =item B<< Moose::Meta::Role->create_anon_role >>
 757
 758 This method is identical to the L<Moose::Meta::Class>
 759 C<create_anon_class> method.
 760
 761 =item B<< $metarole->is_anon_role >>
 762
 763 Returns true if the role is an anonymous role.
 764
 765 =item B<< $metarole->consumers >>
 766
 767 Returns a list of names of classes and roles which consume this role.
 768
 769 =back
 770
 771 =head2 Role application
 772
 773 =over 4
 774
 775 =item B<< $metarole->apply( $thing, @options ) >>
 776
 777 This method applies a role to the given C<$thing>. That can be another
 778 L<Moose::Meta::Role>, object, a L<Moose::Meta::Class> object, or a
 779 (non-meta) object instance.
 780
 781 The options are passed directly to the constructor for the appropriate
 782 L<Moose::Meta::Role::Application> subclass.
 783
 784 Note that this will apply the role even if the C<$thing> in question already
 785 C<does> this role.  L<Moose::Util/does_role> is a convenient wrapper for
 786 finding out if role application is necessary.
 787
 788 =back
 789
 790 =head2 Roles and other roles
 791
 792 =over 4
 793
 794 =item B<< $metarole->get_roles >>
 795
 796 This returns an array reference of roles which this role does. This
 797 list may include duplicates.
 798
 799 =item B<< $metarole->calculate_all_roles >>
 800
 801 This returns a I<unique> list of all roles that this role does, and
 802 all the roles that its roles do.
 803
 804 =item B<< $metarole->does_role($role) >>
 805
 806 Given a role I<name> or L<Moose::Meta::Role> object, returns true if this role
 807 does the given role.
 808
 809 =item B<< $metarole->add_role($role) >>
 810
 811 Given a L<Moose::Meta::Role> object, this adds the role to the list of
 812 roles that the role does.
 813
 814 =item B<< $metarole->get_excluded_roles_list >>
 815
 816 Returns a list of role names which this role excludes.
 817
 818 =item B<< $metarole->excludes_role($role_name) >>
 819
 820 Given a role I<name>, returns true if this role excludes the named
 821 role.
 822
 823 =item B<< $metarole->add_excluded_roles(@role_names) >>
 824
 825 Given one or more role names, adds those roles to the list of excluded
 826 roles.
 827
 828 =back
 829
 830 =head2 Methods
 831
 832 The methods for dealing with a role's methods are all identical in API
 833 and behavior to the same methods in L<Class::MOP::Class>.
 834
 835 =over 4
 836
 837 =item B<< $metarole->method_metaclass >>
 838
 839 Returns the method metaclass name for the role. This defaults to
 840 L<Moose::Meta::Role::Method>.
 841
 842 =item B<< $metarole->get_method($name) >>
 843
 844 =item B<< $metarole->has_method($name) >>
 845
 846 =item B<< $metarole->add_method( $name, $body ) >>
 847
 848 =item B<< $metarole->get_method_list >>
 849
 850 =item B<< $metarole->find_method_by_name($name) >>
 851
 852 These methods are all identical to the methods of the same name in
 853 L<Class::MOP::Package>
 854
 855 =back
 856
 857 =head2 Attributes
 858
 859 As with methods, the methods for dealing with a role's attribute are
 860 all identical in API and behavior to the same methods in
 861 L<Class::MOP::Class>.
 862
 863 However, attributes stored in this class are I<not> stored as
 864 objects. Rather, the attribute definition is stored as a hash
 865 reference. When a role is composed into a class, this hash reference
 866 is passed directly to the metaclass's C<add_attribute> method.
 867
 868 This is quite likely to change in the future.
 869
 870 =over 4
 871
 872 =item B<< $metarole->get_attribute($attribute_name) >>
 873
 874 =item B<< $metarole->has_attribute($attribute_name) >>
 875
 876 =item B<< $metarole->get_attribute_list >>
 877
 878 =item B<< $metarole->add_attribute($name, %options) >>
 879
 880 =item B<< $metarole->remove_attribute($attribute_name) >>
 881
 882 =back
 883
 884 =head2 Required methods
 885
 886 =over 4
 887
 888 =item B<< $metarole->get_required_method_list >>
 889
 890 Returns the list of methods required by the role.
 891
 892 =item B<< $metarole->requires_method($name) >>
 893
 894 Returns true if the role requires the named method.
 895
 896 =item B<< $metarole->add_required_methods(@names) >>
 897
 898 Adds the named methods to the role's list of required methods.
 899
 900 =item B<< $metarole->remove_required_methods(@names) >>
 901
 902 Removes the named methods from the role's list of required methods.
 903
 904 =item B<< $metarole->add_conflicting_method(%params) >>
 905
 906 Instantiate the parameters as a L<Moose::Meta::Role::Method::Conflicting>
 907 object, then add it to the required method list.
 908
 909 =back
 910
 911 =head2 Method modifiers
 912
 913 These methods act like their counterparts in L<Class::MOP::Class> and
 914 L<Moose::Meta::Class>.
 915
 916 However, method modifiers are simply stored internally, and are not
 917 applied until the role itself is applied to a class.
 918
 919 =over 4
 920
 921 =item B<< $metarole->add_after_method_modifier($method_name, $method) >>
 922
 923 =item B<< $metarole->add_around_method_modifier($method_name, $method) >>
 924
 925 =item B<< $metarole->add_before_method_modifier($method_name, $method) >>
 926
 927 =item B<< $metarole->add_override_method_modifier($method_name, $method) >>
 928
 929 These methods all add an appropriate modifier to the internal list of
 930 modifiers.
 931
 932 =item B<< $metarole->has_after_method_modifiers >>
 933
 934 =item B<< $metarole->has_around_method_modifiers >>
 935
 936 =item B<< $metarole->has_before_method_modifiers >>
 937
 938 =item B<< $metarole->has_override_method_modifier >>
 939
 940 Return true if the role has any modifiers of the given type.
 941
 942 =item B<< $metarole->get_after_method_modifiers($method_name) >>
 943
 944 =item B<< $metarole->get_around_method_modifiers($method_name) >>
 945
 946 =item B<< $metarole->get_before_method_modifiers($method_name) >>
 947
 948 Given a method name, returns a list of the appropriate modifiers for
 949 that method.
 950
 951 =item B<< $metarole->get_override_method_modifier($method_name) >>
 952
 953 Given a method name, returns the override method modifier for that
 954 method, if it has one.
 955
 956 =back
 957
 958 =head2 Introspection
 959
 960 =over 4
 961
 962 =item B<< Moose::Meta::Role->meta >>
 963
 964 This will return a L<Class::MOP::Class> instance for this class.
 965
 966 =back
 967
 968 =head1 BUGS
 969
 970 See L<Moose/BUGS> for details on reporting bugs.
 971
 972 =head1 AUTHOR
 973
 974 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 975
 976 =head1 COPYRIGHT AND LICENSE
 977
 978 Copyright 2006-2010 by Infinity Interactive, Inc.
 979
 980 L<http://www.iinteractive.com>
 981
 982 This library is free software; you can redistribute it and/or modify
 983 it under the same terms as Perl itself.
 984
 985 =cut