lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Scalar::Util 'blessed';
   9 use Carp         'confess';
  10
  11 our $VERSION   = '0.73';
  12 $VERSION = eval $VERSION;
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use Moose::Meta::Class;
  16 use Moose::Meta::Role::Method;
  17 use Moose::Meta::Role::Method::Required;
  18
  19 use base 'Class::MOP::Module';
  20
  21 ## ------------------------------------------------------------------
  22 ## NOTE:
  23 ## I normally don't do this, but I am doing
  24 ## a whole bunch of meta-programmin in this
  25 ## module, so it just makes sense. For a clearer
  26 ## picture of what is going on in the next
  27 ## several lines of code, look at the really
  28 ## big comment at the end of this file (right
  29 ## before the POD).
  30 ## - SL
  31 ## ------------------------------------------------------------------
  32
  33 my $META = __PACKAGE__->meta;
  34
  35 ## ------------------------------------------------------------------
  36 ## attributes ...
  37
  38 # NOTE:
  39 # since roles are lazy, we hold all the attributes
  40 # of the individual role in 'statis' until which
  41 # time when it is applied to a class. This means
  42 # keeping a lot of things in hash maps, so we are
  43 # using a little of that meta-programmin' magic
  44 # here an saving lots of extra typin. And since
  45 # many of these attributes above require similar
  46 # functionality to support them, so we again use
  47 # the wonders of meta-programmin' to deliver a
  48 # very compact solution to this normally verbose
  49 # problem.
  50 # - SL
  51
  52 foreach my $action (
  53     {
  54         name        => 'excluded_roles_map',
  55         attr_reader => 'get_excluded_roles_map' ,
  56         methods     => {
  57             add       => 'add_excluded_roles',
  58             get_list  => 'get_excluded_roles_list',
  59             existence => 'excludes_role',
  60         }
  61     },
  62     {
  63         name        => 'required_methods',
  64         attr_reader => 'get_required_methods_map',
  65         methods     => {
  66             add       => 'add_required_methods',
  67             remove    => 'remove_required_methods',
  68             get_list  => 'get_required_method_list',
  69             existence => 'requires_method',
  70         }
  71     },
  72     {
  73         name        => 'attribute_map',
  74         attr_reader => 'get_attribute_map',
  75         methods     => {
  76             get       => 'get_attribute',
  77             get_list  => 'get_attribute_list',
  78             existence => 'has_attribute',
  79             remove    => 'remove_attribute',
  80         }
  81     }
  82 ) {
  83
  84     my $attr_reader = $action->{attr_reader};
  85     my $methods     = $action->{methods};
  86
  87     # create the attribute
  88     $META->add_attribute($action->{name} => (
  89         reader  => $attr_reader,
  90         default => sub { {} }
  91     ));
  92
  93     # create some helper methods
  94     $META->add_method($methods->{add} => sub {
  95         my ($self, @values) = @_;
  96         $self->$attr_reader->{$_} = undef foreach @values;
  97     }) if exists $methods->{add};
  98
  99     $META->add_method($methods->{get_list} => sub {
 100         my ($self) = @_;
 101         keys %{$self->$attr_reader};
 102     }) if exists $methods->{get_list};
 103
 104     $META->add_method($methods->{get} => sub {
 105         my ($self, $name) = @_;
 106         $self->$attr_reader->{$name}
 107     }) if exists $methods->{get};
 108
 109     $META->add_method($methods->{existence} => sub {
 110         my ($self, $name) = @_;
 111         exists $self->$attr_reader->{$name} ? 1 : 0;
 112     }) if exists $methods->{existence};
 113
 114     $META->add_method($methods->{remove} => sub {
 115         my ($self, @values) = @_;
 116         delete $self->$attr_reader->{$_} foreach @values;
 117     }) if exists $methods->{remove};
 118 }
 119
 120 ## some things don't always fit, so they go here ...
 121
 122 sub add_attribute {
 123     my $self = shift;
 124     my $name = shift;
 125     unless ( defined $name && $name ) {
 126         require Moose;
 127         Moose->throw_error("You must provide a name for the attribute");
 128     }
 129     my $attr_desc;
 130     if (scalar @_ == 1 && ref($_[0]) eq 'HASH') {
 131         $attr_desc = $_[0];
 132     }
 133     else {
 134         $attr_desc = { @_ };
 135     }
 136     $self->get_attribute_map->{$name} = $attr_desc;
 137 }
 138
 139 # DEPRECATED
 140 # sub _clean_up_required_methods {
 141 #     my $self = shift;
 142 #     foreach my $method ($self->get_required_method_list) {
 143 #         $self->remove_required_methods($method)
 144 #             if $self->has_method($method);
 145 #     }
 146 # }
 147
 148 ## ------------------------------------------------------------------
 149 ## method modifiers
 150
 151 # NOTE:
 152 # the before/around/after method modifiers are
 153 # stored by name, but there can be many methods
 154 # then associated with that name. So again we have
 155 # lots of similar functionality, so we can do some
 156 # meta-programmin' and save some time.
 157 # - SL
 158
 159 foreach my $modifier_type (qw[ before around after ]) {
 160
 161     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 162
 163     # create the attribute ...
 164     $META->add_attribute("${modifier_type}_method_modifiers" => (
 165         reader  => $attr_reader,
 166         default => sub { {} }
 167     ));
 168
 169     # and some helper methods ...
 170     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 171         my ($self, $method_name) = @_;
 172         #return () unless exists $self->$attr_reader->{$method_name};
 173         @{$self->$attr_reader->{$method_name}};
 174     });
 175
 176     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 177         my ($self, $method_name) = @_;
 178         # NOTE:
 179         # for now we assume that if it exists,..
 180         # it has at least one modifier in it
 181         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 182     });
 183
 184     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 185         my ($self, $method_name, $method) = @_;
 186
 187         $self->$attr_reader->{$method_name} = []
 188             unless exists $self->$attr_reader->{$method_name};
 189
 190         my $modifiers = $self->$attr_reader->{$method_name};
 191
 192         # NOTE:
 193         # check to see that we aren't adding the
 194         # same code twice. We err in favor of the
 195         # first on here, this may not be as expected
 196         foreach my $modifier (@{$modifiers}) {
 197             return if $modifier == $method;
 198         }
 199
 200         push @{$modifiers} => $method;
 201     });
 202
 203 }
 204
 205 ## ------------------------------------------------------------------
 206 ## override method mofidiers
 207
 208 $META->add_attribute('override_method_modifiers' => (
 209     reader  => 'get_override_method_modifiers_map',
 210     default => sub { {} }
 211 ));
 212
 213 # NOTE:
 214 # these are a little different because there
 215 # can only be one per name, whereas the other
 216 # method modifiers can have multiples.
 217 # - SL
 218
 219 sub add_override_method_modifier {
 220     my ($self, $method_name, $method) = @_;
 221     (!$self->has_method($method_name))
 222         || Moose->throw_error("Cannot add an override of method '$method_name' " .
 223                    "because there is a local version of '$method_name'");
 224     $self->get_override_method_modifiers_map->{$method_name} = $method;
 225 }
 226
 227 sub has_override_method_modifier {
 228     my ($self, $method_name) = @_;
 229     # NOTE:
 230     # for now we assume that if it exists,..
 231     # it has at least one modifier in it
 232     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 233 }
 234
 235 sub get_override_method_modifier {
 236     my ($self, $method_name) = @_;
 237     $self->get_override_method_modifiers_map->{$method_name};
 238 }
 239
 240 ## general list accessor ...
 241
 242 sub get_method_modifier_list {
 243     my ($self, $modifier_type) = @_;
 244     my $accessor = "get_${modifier_type}_method_modifiers_map";
 245     keys %{$self->$accessor};
 246 }
 247
 248 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 249 sub update_package_cache_flag {
 250     my $self = shift;
 251     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 252 }
 253
 254
 255
 256 ## ------------------------------------------------------------------
 257 ## subroles
 258
 259 $META->add_attribute('roles' => (
 260     reader  => 'get_roles',
 261     default => sub { [] }
 262 ));
 263
 264 sub add_role {
 265     my ($self, $role) = @_;
 266     (blessed($role) && $role->isa('Moose::Meta::Role'))
 267         || Moose->throw_error("Roles must be instances of Moose::Meta::Role");
 268     push @{$self->get_roles} => $role;
 269     $self->reset_package_cache_flag;
 270 }
 271
 272 sub calculate_all_roles {
 273     my $self = shift;
 274     my %seen;
 275     grep {
 276         !$seen{$_->name}++
 277     } ($self, map {
 278                   $_->calculate_all_roles
 279               } @{ $self->get_roles });
 280 }
 281
 282 sub does_role {
 283     my ($self, $role_name) = @_;
 284     (defined $role_name)
 285         || Moose->throw_error("You must supply a role name to look for");
 286     # if we are it,.. then return true
 287     return 1 if $role_name eq $self->name;
 288     # otherwise.. check our children
 289     foreach my $role (@{$self->get_roles}) {
 290         return 1 if $role->does_role($role_name);
 291     }
 292     return 0;
 293 }
 294
 295 ## ------------------------------------------------------------------
 296 ## methods
 297
 298 sub method_metaclass { 'Moose::Meta::Role::Method' }
 299
 300 sub get_method_map {
 301     my $self = shift;
 302
 303     my $current = Class::MOP::check_package_cache_flag($self->name);
 304
 305     if (defined $self->{'_package_cache_flag'} && $self->{'_package_cache_flag'} == $current) {
 306         return $self->{'methods'} ||= {};
 307     }
 308
 309     $self->{_package_cache_flag} = $current;
 310
 311     my $map  = $self->{'methods'} ||= {};
 312
 313     my $role_name        = $self->name;
 314     my $method_metaclass = $self->method_metaclass;
 315
 316     my $all_code = $self->get_all_package_symbols('CODE');
 317
 318     foreach my $symbol (keys %{ $all_code }) {
 319         my $code = $all_code->{$symbol};
 320
 321         next if exists  $map->{$symbol} &&
 322                 defined $map->{$symbol} &&
 323                         $map->{$symbol}->body == $code;
 324
 325         my ($pkg, $name) = Class::MOP::get_code_info($code);
 326         my $meta = Class::MOP::class_of($pkg);
 327
 328         if ($meta && $meta->isa('Moose::Meta::Role')) {
 329             my $role = $meta->name;
 330             next unless $self->does_role($role);
 331         }
 332         else {
 333             # NOTE:
 334             # in 5.10 constant.pm the constants show up
 335             # as being in the right package, but in pre-5.10
 336             # they show up as constant::__ANON__ so we
 337             # make an exception here to be sure that things
 338             # work as expected in both.
 339             # - SL
 340             unless ($pkg eq 'constant' && $name eq '__ANON__') {
 341                 next if ($pkg  || '') ne $role_name ||
 342                         (($name || '') ne '__ANON__' && ($pkg  || '') ne $role_name);
 343             }
 344         }
 345
 346         $map->{$symbol} = $method_metaclass->wrap(
 347             $code,
 348             package_name => $role_name,
 349             name         => $name
 350         );
 351     }
 352
 353     return $map;
 354 }
 355
 356 sub get_method {
 357     my ($self, $name) = @_;
 358     $self->get_method_map->{$name};
 359 }
 360
 361 sub has_method {
 362     my ($self, $name) = @_;
 363     exists $self->get_method_map->{$name} ? 1 : 0
 364 }
 365
 366 # FIXME this is copy-pasted from Class::MOP::Class
 367 # refactor to inherit from some common base
 368 sub wrap_method_body {
 369     my ( $self, %args ) = @_;
 370
 371     ('CODE' eq ref $args{body})
 372         || Moose->throw_error("Your code block must be a CODE reference");
 373
 374     $self->method_metaclass->wrap(
 375         package_name => $self->name,
 376         %args,
 377     );
 378 }
 379
 380 sub add_method {
 381     my ($self, $method_name, $method) = @_;
 382     (defined $method_name && $method_name)
 383     || Moose->throw_error("You must define a method name");
 384
 385     my $body;
 386     if (blessed($method)) {
 387         $body = $method->body;
 388         if ($method->package_name ne $self->name) {
 389             $method = $method->clone(
 390                 package_name => $self->name,
 391                 name         => $method_name
 392             ) if $method->can('clone');
 393         }
 394     }
 395     else {
 396         $body = $method;
 397         $method = $self->wrap_method_body( body => $body, name => $method_name );
 398     }
 399
 400     $method->attach_to_class($self);
 401
 402     $self->get_method_map->{$method_name} = $method;
 403
 404     my $full_method_name = ($self->name . '::' . $method_name);
 405     $self->add_package_symbol(
 406         { sigil => '&', type => 'CODE', name => $method_name },
 407         Class::MOP::subname($full_method_name => $body)
 408     );
 409
 410     $self->update_package_cache_flag; # still valid, since we just added the method to the map, and if it was invalid before that then get_method_map updated it
 411 }
 412
 413 sub find_method_by_name { (shift)->get_method(@_) }
 414
 415 sub get_method_list {
 416     my $self = shift;
 417     grep { !/^meta$/ } keys %{$self->get_method_map};
 418 }
 419
 420 sub alias_method {
 421     my $self = shift;
 422
 423     $self->add_method(@_);
 424 }
 425
 426 ## ------------------------------------------------------------------
 427 ## role construction
 428 ## ------------------------------------------------------------------
 429
 430 sub apply {
 431     my ($self, $other, @args) = @_;
 432
 433     (blessed($other))
 434         || Moose->throw_error("You must pass in an blessed instance");
 435
 436     if ($other->isa('Moose::Meta::Role')) {
 437         require Moose::Meta::Role::Application::ToRole;
 438         return Moose::Meta::Role::Application::ToRole->new(@args)->apply($self, $other);
 439     }
 440     elsif ($other->isa('Moose::Meta::Class')) {
 441         require Moose::Meta::Role::Application::ToClass;
 442         return Moose::Meta::Role::Application::ToClass->new(@args)->apply($self, $other);
 443     }
 444     else {
 445         require Moose::Meta::Role::Application::ToInstance;
 446         return Moose::Meta::Role::Application::ToInstance->new(@args)->apply($self, $other);
 447     }
 448 }
 449
 450 sub combine {
 451     my ($class, @role_specs) = @_;
 452
 453     require Moose::Meta::Role::Application::RoleSummation;
 454     require Moose::Meta::Role::Composite;
 455
 456     my (@roles, %role_params);
 457     while (@role_specs) {
 458         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 459         push @roles => $role->meta;
 460         next unless defined $params;
 461         $role_params{$role} = $params;
 462     }
 463
 464     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 465     Moose::Meta::Role::Application::RoleSummation->new(
 466         role_params => \%role_params
 467     )->apply($c);
 468
 469     return $c;
 470 }
 471
 472 sub create {
 473     my ( $role, $package_name, %options ) = @_;
 474
 475     $options{package} = $package_name;
 476
 477     (ref $options{attributes} eq 'HASH')
 478         || confess "You must pass a HASH ref of attributes"
 479             if exists $options{attributes};
 480
 481     (ref $options{methods} eq 'HASH')
 482         || confess "You must pass a HASH ref of methods"
 483             if exists $options{methods};
 484
 485     $role->SUPER::create(%options);
 486
 487     my (%initialize_options) = %options;
 488     delete @initialize_options{qw(
 489         package
 490         attributes
 491         methods
 492         version
 493         authority
 494     )};
 495
 496     my $meta = $role->initialize( $package_name => %initialize_options );
 497
 498     # FIXME totally lame
 499     $meta->add_method('meta' => sub {
 500         $role->initialize(ref($_[0]) || $_[0]);
 501     });
 502
 503     if (exists $options{attributes}) {
 504         foreach my $attribute_name (keys %{$options{attributes}}) {
 505             my $attr = $options{attributes}->{$attribute_name};
 506             $meta->add_attribute($attribute_name => $attr);
 507         }
 508     }
 509
 510     if (exists $options{methods}) {
 511         foreach my $method_name (keys %{$options{methods}}) {
 512             $meta->add_method($method_name, $options{methods}->{$method_name});
 513         }
 514     }
 515
 516     Class::MOP::weaken_metaclass($meta->name)
 517         if $meta->is_anon_role;
 518
 519     return $meta;
 520 }
 521
 522 # anonymous roles. most of it is copied straight out of Class::MOP::Class.
 523 # an intrepid hacker might find great riches if he unifies this code with that
 524 # code in Class::MOP::Module or Class::MOP::Package
 525 {
 526     # NOTE:
 527     # this should be sufficient, if you have a
 528     # use case where it is not, write a test and
 529     # I will change it.
 530     my $ANON_ROLE_SERIAL = 0;
 531
 532     # NOTE:
 533     # we need a sufficiently annoying prefix
 534     # this should suffice for now, this is
 535     # used in a couple of places below, so
 536     # need to put it up here for now.
 537     my $ANON_ROLE_PREFIX = 'Moose::Meta::Role::__ANON__::SERIAL::';
 538
 539     sub is_anon_role {
 540         my $self = shift;
 541         no warnings 'uninitialized';
 542         $self->name =~ /^$ANON_ROLE_PREFIX/;
 543     }
 544
 545     sub create_anon_role {
 546         my ($role, %options) = @_;
 547         my $package_name = $ANON_ROLE_PREFIX . ++$ANON_ROLE_SERIAL;
 548         return $role->create($package_name, %options);
 549     }
 550
 551     # NOTE:
 552     # this will only get called for
 553     # anon-roles, all other calls
 554     # are assumed to occur during
 555     # global destruction and so don't
 556     # really need to be handled explicitly
 557     sub DESTROY {
 558         my $self = shift;
 559
 560         return if Class::MOP::in_global_destruction(); # it'll happen soon anyway and this just makes things more complicated
 561
 562         no warnings 'uninitialized';
 563         return unless $self->name =~ /^$ANON_ROLE_PREFIX/;
 564
 565         # XXX: is this necessary for us? I don't understand what it's doing
 566         # -sartak
 567
 568         # Moose does a weird thing where it replaces the metaclass for
 569         # class when fixing metaclass incompatibility. In that case,
 570         # we don't want to clean out the namespace now. We can detect
 571         # that because Moose will explicitly update the singleton
 572         # cache in Class::MOP.
 573         #my $current_meta = Class::MOP::get_metaclass_by_name($self->name);
 574         #return if $current_meta ne $self;
 575
 576         my ($serial_id) = ($self->name =~ /^$ANON_ROLE_PREFIX(\d+)/);
 577         no strict 'refs';
 578         foreach my $key (keys %{$ANON_ROLE_PREFIX . $serial_id}) {
 579             delete ${$ANON_ROLE_PREFIX . $serial_id}{$key};
 580         }
 581         delete ${'main::' . $ANON_ROLE_PREFIX}{$serial_id . '::'};
 582     }
 583 }
 584
 585 #####################################################################
 586 ## NOTE:
 587 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 588 ## MooseX::AttributeHelpers module). It is here as a reference to
 589 ## make it easier to see what is happening above with all the meta
 590 ## programming. - SL
 591 #####################################################################
 592 #
 593 # has 'roles' => (
 594 #     metaclass => 'Collection::Array',
 595 #     reader    => 'get_roles',
 596 #     isa       => 'ArrayRef[Moose::Meta::Roles]',
 597 #     default   => sub { [] },
 598 #     provides  => {
 599 #         'push' => 'add_role',
 600 #     }
 601 # );
 602 #
 603 # has 'excluded_roles_map' => (
 604 #     metaclass => 'Collection::Hash',
 605 #     reader    => 'get_excluded_roles_map',
 606 #     isa       => 'HashRef[Str]',
 607 #     provides  => {
 608 #         # Not exactly set, cause it sets multiple
 609 #         'set'    => 'add_excluded_roles',
 610 #         'keys'   => 'get_excluded_roles_list',
 611 #         'exists' => 'excludes_role',
 612 #     }
 613 # );
 614 #
 615 # has 'attribute_map' => (
 616 #     metaclass => 'Collection::Hash',
 617 #     reader    => 'get_attribute_map',
 618 #     isa       => 'HashRef[Str]',
 619 #     provides => {
 620 #         # 'set'  => 'add_attribute' # has some special crap in it
 621 #         'get'    => 'get_attribute',
 622 #         'keys'   => 'get_attribute_list',
 623 #         'exists' => 'has_attribute',
 624 #         # Not exactly delete, cause it sets multiple
 625 #         'delete' => 'remove_attribute',
 626 #     }
 627 # );
 628 #
 629 # has 'required_methods' => (
 630 #     metaclass => 'Collection::Hash',
 631 #     reader    => 'get_required_methods_map',
 632 #     isa       => 'HashRef[Str]',
 633 #     provides  => {
 634 #         # not exactly set, or delete since it works for multiple
 635 #         'set'    => 'add_required_methods',
 636 #         'delete' => 'remove_required_methods',
 637 #         'keys'   => 'get_required_method_list',
 638 #         'exists' => 'requires_method',
 639 #     }
 640 # );
 641 #
 642 # # the before, around and after modifiers are
 643 # # HASH keyed by method-name, with ARRAY of
 644 # # CODE refs to apply in that order
 645 #
 646 # has 'before_method_modifiers' => (
 647 #     metaclass => 'Collection::Hash',
 648 #     reader    => 'get_before_method_modifiers_map',
 649 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 650 #     provides  => {
 651 #         'keys'   => 'get_before_method_modifiers',
 652 #         'exists' => 'has_before_method_modifiers',
 653 #         # This actually makes sure there is an
 654 #         # ARRAY at the given key, and pushed onto
 655 #         # it. It also checks for duplicates as well
 656 #         # 'add'  => 'add_before_method_modifier'
 657 #     }
 658 # );
 659 #
 660 # has 'after_method_modifiers' => (
 661 #     metaclass => 'Collection::Hash',
 662 #     reader    =>'get_after_method_modifiers_map',
 663 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 664 #     provides  => {
 665 #         'keys'   => 'get_after_method_modifiers',
 666 #         'exists' => 'has_after_method_modifiers',
 667 #         # This actually makes sure there is an
 668 #         # ARRAY at the given key, and pushed onto
 669 #         # it. It also checks for duplicates as well
 670 #         # 'add'  => 'add_after_method_modifier'
 671 #     }
 672 # );
 673 #
 674 # has 'around_method_modifiers' => (
 675 #     metaclass => 'Collection::Hash',
 676 #     reader    =>'get_around_method_modifiers_map',
 677 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 678 #     provides  => {
 679 #         'keys'   => 'get_around_method_modifiers',
 680 #         'exists' => 'has_around_method_modifiers',
 681 #         # This actually makes sure there is an
 682 #         # ARRAY at the given key, and pushed onto
 683 #         # it. It also checks for duplicates as well
 684 #         # 'add'  => 'add_around_method_modifier'
 685 #     }
 686 # );
 687 #
 688 # # override is similar to the other modifiers
 689 # # except that it is not an ARRAY of code refs
 690 # # but instead just a single name->code mapping
 691 #
 692 # has 'override_method_modifiers' => (
 693 #     metaclass => 'Collection::Hash',
 694 #     reader    =>'get_override_method_modifiers_map',
 695 #     isa       => 'HashRef[CodeRef]',
 696 #     provides  => {
 697 #         'keys'   => 'get_override_method_modifier',
 698 #         'exists' => 'has_override_method_modifier',
 699 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 700 #     }
 701 # );
 702 #
 703 #####################################################################
 704
 705
 706 1;
 707
 708 __END__
 709
 710 =pod
 711
 712 =head1 NAME
 713
 714 Moose::Meta::Role - The Moose Role metaclass
 715
 716 =head1 DESCRIPTION
 717
 718 This class is a subclass of L<Class::MOP::Module> that provides
 719 additional Moose-specific functionality.
 720
 721 It's API looks a lot like L<Moose::Meta::Class>, but internally it
 722 implements many things differently. This may change in the future.
 723
 724 =head1 INHERITANCE
 725
 726 C<Moose::Meta::Role> is a subclass of L<Class::MOP::Module>.
 727
 728 =head1 METHODS
 729
 730 =head2 Construction
 731
 732 =over 4
 733
 734 =item B<< Moose::Meta::Role->initialize($role_name) >>
 735
 736 This method creates a new role object with the provided name.
 737
 738 =item B<< Moose::Meta::Role->combine( [ $role => { ... } ], [ $role ], ... ) >>
 739
 740 This method accepts a list of array references. Each array reference
 741 should contain a role name as its first element. The second element is
 742 an optional hash reference. The hash reference can contain C<exclude>
 743 and C<alias> keys to control how methods are composed from the role.
 744
 745 The return value is a new L<Moose::Meta::Role::Composite> that
 746 represents the combined roles.
 747
 748 =item B<< Moose::Meta::Role->create($name, %options) >>
 749
 750 This method is identical to the L<Moose::Meta::Class> C<create>
 751 method.
 752
 753 =item B<< Moose::Meta::Role->create_anon_role >>
 754
 755 This method is identical to the L<Moose::Meta::Class>
 756 C<create_anon_class> method.
 757
 758 =item B<< $metarole->is_anon_role >>
 759
 760 Returns true if the role is an anonymous role.
 761
 762 =back
 763
 764 =head2 Role application
 765
 766 =over 4
 767
 768 =item B<< $metarole->apply( $thing, @options ) >>
 769
 770 This method applies a role to the given C<$thing>. That can be another
 771 L<Moose::Meta::Role>, object, a L<Moose::Meta::Class> object, or a
 772 (non-meta) object instance.
 773
 774 The options are passed directly to the constructor for the appropriate
 775 L<Moose::Meta::Role::Application> subclass.
 776
 777 =back
 778
 779 =head2 Roles and other roles
 780
 781 =over 4
 782
 783 =item B<< $metarole->get_roles >>
 784
 785 This returns an array reference of roles which this role does. This
 786 list may include duplicates.
 787
 788 =item B<< $metarole->calculate_all_roles >>
 789
 790 This returns a I<unique> list of all roles that this role does, and
 791 all the roles that its roles do.
 792
 793 =item B<< $metarole->does_role($role_name) >>
 794
 795 Given a role I<name>, returns true if this role does the given
 796 role.
 797
 798 =item B<< $metarole->add_role($role) >>
 799
 800 Given a L<Moose::Meta::Role> object, this adds the role to the list of
 801 roles that the role does.
 802
 803 =item B<< $metarole->get_excluded_roles_list >>
 804
 805 Returns a list of role names which this role excludes.
 806
 807 =item B<< $metarole->excludes_role($role_name) >>
 808
 809 Given a role I<name>, returns true if this role excludes the named
 810 role.
 811
 812 =item B<< $metarole->add_excluded_roles(@role_names) >>
 813
 814 Given one or more role names, adds those roles to the list of excluded
 815 roles.
 816
 817 =back
 818
 819 =head2 Methods
 820
 821 The methods for dealing with a role's methods are all identical in API
 822 and behavior to the same methods in L<Class::MOP::Class>.
 823
 824 =over 4
 825
 826 =item B<< $metarole->method_metaclass >>
 827
 828 Returns the method metaclass name for the role. This defaults to
 829 L<Moose::Meta::Role::Method>.
 830
 831 =item B<< $metarole->get_method($name) >>
 832
 833 =item B<< $metarole->has_method($name) >>
 834
 835 =item B<< $metarole->add_method( $name, $body ) >>
 836
 837 =item B<< $metarole->get_method_list >>
 838
 839 =item B<< $metarole->get_method_map >>
 840
 841 =item B<< $metarole->find_method_by_name($name) >>
 842
 843 These methods are all identical to the methods of the same name in
 844 L<Class::MOP::Class>
 845
 846 =back
 847
 848 =head2 Attributes
 849
 850 As with methods, the methods for dealing with a role's attribute are
 851 all identical in API and behavior to the same methods in
 852 L<Class::MOP::Class>.
 853
 854 However, attributes stored in this class are I<not> stored as
 855 objects. Rather, the attribute definition is stored as a hash
 856 reference. When a role is composed into a class, this hash reference
 857 is passed directly to the metaclass's C<add_attribute> method.
 858
 859 This is quite likely to change in the future.
 860
 861 =over 4
 862
 863 =item B<< $metarole->get_attribute($attribute_name) >>
 864
 865 =item B<< $metarole->has_attribute($attribute_name) >>
 866
 867 =item B<< $metarole->get_attribute_map >>
 868
 869 =item B<< $metarole->get_attribute_list >>
 870
 871 =item B<< $metarole->add_attribute($name, %options) >>
 872
 873 =item B<< $metarole->remove_attribute($attribute_name) >>
 874
 875 =back
 876
 877 =head2 Required methods
 878
 879 =over 4
 880
 881 =item B<< $metarole->get_required_method_list >>
 882
 883 Returns the list of methods required by the role.
 884
 885 =item B<< $metarole->requires_method($name) >>
 886
 887 Returns true if the role requires the named method.
 888
 889 =item B<< $metarole->add_required_methods(@names >>
 890
 891 Adds the named methods to the roles list of required methods.
 892
 893 =item B<< $metarole->remove_required_methods(@names) >>
 894
 895 Removes the named methods to the roles list of required methods.
 896
 897 =back
 898
 899 =head2 Method modifiers
 900
 901 These methods act like their counterparts in L<Class::Mop::Class> and
 902 L<Moose::Meta::Class>.
 903
 904 However, method modifiers are simply stored internally, and are not
 905 applied until the role itself is applied to a class.
 906
 907 =over 4
 908
 909 =item B<< $metarole->add_after_method_modifier($method_name, $method) >>
 910
 911 =item B<< $metarole->add_around_method_modifier($method_name, $method) >>
 912
 913 =item B<< $metarole->add_before_method_modifier($method_name, $method) >>
 914
 915 =item B<< $metarole->add_override_method_modifier($method_name, $method) >>
 916
 917 These methods all add an appropriate modifier to the internal list of
 918 modifiers.
 919
 920 =item B<< $metarole->has_after_method_modifiers >>
 921
 922 =item B<< $metarole->has_around_method_modifiers >>
 923
 924 =item B<< $metarole->has_before_method_modifiers >>
 925
 926 =item B<< $metarole->has_override_method_modifier >>
 927
 928 Return true if the role has any modifiers of the given type.
 929
 930 =item B<< $metarole->get_after_method_modifiers($method_name) >>
 931
 932 =item B<< $metarole->get_around_method_modifiers($method_name) >>
 933
 934 =item B<< $metarole->get_before_method_modifiers($method_name) >>
 935
 936 Given a method name, returns a list of the appropriate modifiers for
 937 that method.
 938
 939 =item B<< $metarole->get_override_method_modifier($method_name) >>
 940
 941 Given a method name, returns the override method modifier for that
 942 method, if it has one.
 943
 944 =back
 945
 946 =head2 Introspection
 947
 948 =over 4
 949
 950 =item B<< Moose::Meta::Role->meta >>
 951
 952 This will return a L<Class::MOP::Class> instance for this class.
 953
 954 =back
 955
 956 =head1 BUGS
 957
 958 All complex software has bugs lurking in it, and this module is no
 959 exception. If you find a bug please either email me, or add the bug
 960 to cpan-RT.
 961
 962 =head1 AUTHOR
 963
 964 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 965
 966 =head1 COPYRIGHT AND LICENSE
 967
 968 Copyright 2006-2009 by Infinity Interactive, Inc.
 969
 970 L<http://www.iinteractive.com>
 971
 972 This library is free software; you can redistribute it and/or modify
 973 it under the same terms as Perl itself.
 974
 975 =cut