lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Scalar::Util 'blessed';
   9 use Carp         'confess';
  10
  11 our $VERSION   = '0.61';
  12 $VERSION = eval $VERSION;
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use Moose::Meta::Class;
  16 use Moose::Meta::Role::Method;
  17 use Moose::Meta::Role::Method::Required;
  18
  19 use base 'Class::MOP::Module';
  20
  21 ## ------------------------------------------------------------------
  22 ## NOTE:
  23 ## I normally don't do this, but I am doing
  24 ## a whole bunch of meta-programmin in this
  25 ## module, so it just makes sense. For a clearer
  26 ## picture of what is going on in the next
  27 ## several lines of code, look at the really
  28 ## big comment at the end of this file (right
  29 ## before the POD).
  30 ## - SL
  31 ## ------------------------------------------------------------------
  32
  33 my $META = __PACKAGE__->meta;
  34
  35 ## ------------------------------------------------------------------
  36 ## attributes ...
  37
  38 # NOTE:
  39 # since roles are lazy, we hold all the attributes
  40 # of the individual role in 'statis' until which
  41 # time when it is applied to a class. This means
  42 # keeping a lot of things in hash maps, so we are
  43 # using a little of that meta-programmin' magic
  44 # here an saving lots of extra typin. And since
  45 # many of these attributes above require similar
  46 # functionality to support them, so we again use
  47 # the wonders of meta-programmin' to deliver a
  48 # very compact solution to this normally verbose
  49 # problem.
  50 # - SL
  51
  52 foreach my $action (
  53     {
  54         name        => 'excluded_roles_map',
  55         attr_reader => 'get_excluded_roles_map' ,
  56         methods     => {
  57             add       => 'add_excluded_roles',
  58             get_list  => 'get_excluded_roles_list',
  59             existence => 'excludes_role',
  60         }
  61     },
  62     {
  63         name        => 'required_methods',
  64         attr_reader => 'get_required_methods_map',
  65         methods     => {
  66             add       => 'add_required_methods',
  67             remove    => 'remove_required_methods',
  68             get_list  => 'get_required_method_list',
  69             existence => 'requires_method',
  70         }
  71     },
  72     {
  73         name        => 'attribute_map',
  74         attr_reader => 'get_attribute_map',
  75         methods     => {
  76             get       => 'get_attribute',
  77             get_list  => 'get_attribute_list',
  78             existence => 'has_attribute',
  79             remove    => 'remove_attribute',
  80         }
  81     }
  82 ) {
  83
  84     my $attr_reader = $action->{attr_reader};
  85     my $methods     = $action->{methods};
  86
  87     # create the attribute
  88     $META->add_attribute($action->{name} => (
  89         reader  => $attr_reader,
  90         default => sub { {} }
  91     ));
  92
  93     # create some helper methods
  94     $META->add_method($methods->{add} => sub {
  95         my ($self, @values) = @_;
  96         $self->$attr_reader->{$_} = undef foreach @values;
  97     }) if exists $methods->{add};
  98
  99     $META->add_method($methods->{get_list} => sub {
 100         my ($self) = @_;
 101         keys %{$self->$attr_reader};
 102     }) if exists $methods->{get_list};
 103
 104     $META->add_method($methods->{get} => sub {
 105         my ($self, $name) = @_;
 106         $self->$attr_reader->{$name}
 107     }) if exists $methods->{get};
 108
 109     $META->add_method($methods->{existence} => sub {
 110         my ($self, $name) = @_;
 111         exists $self->$attr_reader->{$name} ? 1 : 0;
 112     }) if exists $methods->{existence};
 113
 114     $META->add_method($methods->{remove} => sub {
 115         my ($self, @values) = @_;
 116         delete $self->$attr_reader->{$_} foreach @values;
 117     }) if exists $methods->{remove};
 118 }
 119
 120 ## some things don't always fit, so they go here ...
 121
 122 sub add_attribute {
 123     my $self = shift;
 124     my $name = shift;
 125     (defined $name && $name)
 126         || Moose->throw_error("You must provide a name for the attribute");
 127     my $attr_desc;
 128     if (scalar @_ == 1 && ref($_[0]) eq 'HASH') {
 129         $attr_desc = $_[0];
 130     }
 131     else {
 132         $attr_desc = { @_ };
 133     }
 134     $self->get_attribute_map->{$name} = $attr_desc;
 135 }
 136
 137 # DEPRECATED
 138 # sub _clean_up_required_methods {
 139 #     my $self = shift;
 140 #     foreach my $method ($self->get_required_method_list) {
 141 #         $self->remove_required_methods($method)
 142 #             if $self->has_method($method);
 143 #     }
 144 # }
 145
 146 ## ------------------------------------------------------------------
 147 ## method modifiers
 148
 149 # NOTE:
 150 # the before/around/after method modifiers are
 151 # stored by name, but there can be many methods
 152 # then associated with that name. So again we have
 153 # lots of similar functionality, so we can do some
 154 # meta-programmin' and save some time.
 155 # - SL
 156
 157 foreach my $modifier_type (qw[ before around after ]) {
 158
 159     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 160
 161     # create the attribute ...
 162     $META->add_attribute("${modifier_type}_method_modifiers" => (
 163         reader  => $attr_reader,
 164         default => sub { {} }
 165     ));
 166
 167     # and some helper methods ...
 168     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 169         my ($self, $method_name) = @_;
 170         #return () unless exists $self->$attr_reader->{$method_name};
 171         @{$self->$attr_reader->{$method_name}};
 172     });
 173
 174     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 175         my ($self, $method_name) = @_;
 176         # NOTE:
 177         # for now we assume that if it exists,..
 178         # it has at least one modifier in it
 179         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 180     });
 181
 182     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 183         my ($self, $method_name, $method) = @_;
 184
 185         $self->$attr_reader->{$method_name} = []
 186             unless exists $self->$attr_reader->{$method_name};
 187
 188         my $modifiers = $self->$attr_reader->{$method_name};
 189
 190         # NOTE:
 191         # check to see that we aren't adding the
 192         # same code twice. We err in favor of the
 193         # first on here, this may not be as expected
 194         foreach my $modifier (@{$modifiers}) {
 195             return if $modifier == $method;
 196         }
 197
 198         push @{$modifiers} => $method;
 199     });
 200
 201 }
 202
 203 ## ------------------------------------------------------------------
 204 ## override method mofidiers
 205
 206 $META->add_attribute('override_method_modifiers' => (
 207     reader  => 'get_override_method_modifiers_map',
 208     default => sub { {} }
 209 ));
 210
 211 # NOTE:
 212 # these are a little different because there
 213 # can only be one per name, whereas the other
 214 # method modifiers can have multiples.
 215 # - SL
 216
 217 sub add_override_method_modifier {
 218     my ($self, $method_name, $method) = @_;
 219     (!$self->has_method($method_name))
 220         || Moose->throw_error("Cannot add an override of method '$method_name' " .
 221                    "because there is a local version of '$method_name'");
 222     $self->get_override_method_modifiers_map->{$method_name} = $method;
 223 }
 224
 225 sub has_override_method_modifier {
 226     my ($self, $method_name) = @_;
 227     # NOTE:
 228     # for now we assume that if it exists,..
 229     # it has at least one modifier in it
 230     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 231 }
 232
 233 sub get_override_method_modifier {
 234     my ($self, $method_name) = @_;
 235     $self->get_override_method_modifiers_map->{$method_name};
 236 }
 237
 238 ## general list accessor ...
 239
 240 sub get_method_modifier_list {
 241     my ($self, $modifier_type) = @_;
 242     my $accessor = "get_${modifier_type}_method_modifiers_map";
 243     keys %{$self->$accessor};
 244 }
 245
 246 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 247 sub update_package_cache_flag {
 248     my $self = shift;
 249     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 250 }
 251
 252
 253
 254 ## ------------------------------------------------------------------
 255 ## subroles
 256
 257 __PACKAGE__->meta->add_attribute('roles' => (
 258     reader  => 'get_roles',
 259     default => sub { [] }
 260 ));
 261
 262 sub add_role {
 263     my ($self, $role) = @_;
 264     (blessed($role) && $role->isa('Moose::Meta::Role'))
 265         || Moose->throw_error("Roles must be instances of Moose::Meta::Role");
 266     push @{$self->get_roles} => $role;
 267     $self->reset_package_cache_flag;
 268 }
 269
 270 sub calculate_all_roles {
 271     my $self = shift;
 272     my %seen;
 273     grep {
 274         !$seen{$_->name}++
 275     } ($self, map {
 276                   $_->calculate_all_roles
 277               } @{ $self->get_roles });
 278 }
 279
 280 sub does_role {
 281     my ($self, $role_name) = @_;
 282     (defined $role_name)
 283         || Moose->throw_error("You must supply a role name to look for");
 284     # if we are it,.. then return true
 285     return 1 if $role_name eq $self->name;
 286     # otherwise.. check our children
 287     foreach my $role (@{$self->get_roles}) {
 288         return 1 if $role->does_role($role_name);
 289     }
 290     return 0;
 291 }
 292
 293 ## ------------------------------------------------------------------
 294 ## methods
 295
 296 sub method_metaclass { 'Moose::Meta::Role::Method' }
 297
 298 sub get_method_map {
 299     my $self = shift;
 300
 301     my $current = Class::MOP::check_package_cache_flag($self->name);
 302
 303     if (defined $self->{'_package_cache_flag'} && $self->{'_package_cache_flag'} == $current) {
 304         return $self->{'methods'} ||= {};
 305     }
 306
 307     $self->{_package_cache_flag} = $current;
 308
 309     my $map  = $self->{'methods'} ||= {};
 310
 311     my $role_name        = $self->name;
 312     my $method_metaclass = $self->method_metaclass;
 313
 314     my %all_code = $self->get_all_package_symbols('CODE');
 315
 316     foreach my $symbol (keys %all_code) {
 317         my $code = $all_code{$symbol};
 318
 319         next if exists  $map->{$symbol} &&
 320                 defined $map->{$symbol} &&
 321                         $map->{$symbol}->body == $code;
 322
 323         my ($pkg, $name) = Class::MOP::get_code_info($code);
 324
 325         if ($pkg->can('meta')
 326             # NOTE:
 327             # we don't know what ->meta we are calling
 328             # here, so we need to be careful cause it
 329             # just might blow up at us, or just complain
 330             # loudly (in the case of Curses.pm) so we
 331             # just be a little overly cautious here.
 332             # - SL
 333             && eval { no warnings; blessed($pkg->meta) } # FIXME calls meta
 334             && $pkg->meta->isa('Moose::Meta::Role')) {
 335             my $role = $pkg->meta->name;
 336             next unless $self->does_role($role);
 337         }
 338         else {
 339             # NOTE:
 340             # in 5.10 constant.pm the constants show up
 341             # as being in the right package, but in pre-5.10
 342             # they show up as constant::__ANON__ so we
 343             # make an exception here to be sure that things
 344             # work as expected in both.
 345             # - SL
 346             unless ($pkg eq 'constant' && $name eq '__ANON__') {
 347                 next if ($pkg  || '') ne $role_name ||
 348                         (($name || '') ne '__ANON__' && ($pkg  || '') ne $role_name);
 349             }
 350         }
 351
 352         $map->{$symbol} = $method_metaclass->wrap(
 353             $code,
 354             package_name => $role_name,
 355             name         => $name
 356         );
 357     }
 358
 359     return $map;
 360 }
 361
 362 sub get_method {
 363     my ($self, $name) = @_;
 364     $self->get_method_map->{$name};
 365 }
 366
 367 sub has_method {
 368     my ($self, $name) = @_;
 369     exists $self->get_method_map->{$name} ? 1 : 0
 370 }
 371
 372 # FIXME this is copy-pasted from Class::MOP::Class
 373 # refactor to inherit from some common base
 374 sub wrap_method_body {
 375     my ( $self, %args ) = @_;
 376
 377     ('CODE' eq ref $args{body})
 378         || Moose->throw_error("Your code block must be a CODE reference");
 379
 380     $self->method_metaclass->wrap(
 381         package_name => $self->name,
 382         %args,
 383     );
 384 }
 385
 386 sub add_method {
 387     my ($self, $method_name, $method) = @_;
 388     (defined $method_name && $method_name)
 389     || Moose->throw_error("You must define a method name");
 390
 391     my $body;
 392     if (blessed($method)) {
 393         $body = $method->body;
 394         if ($method->package_name ne $self->name) {
 395             $method = $method->clone(
 396                 package_name => $self->name,
 397                 name         => $method_name
 398             ) if $method->can('clone');
 399         }
 400     }
 401     else {
 402         $body = $method;
 403         $method = $self->wrap_method_body( body => $body, name => $method_name );
 404     }
 405
 406     $method->attach_to_class($self);
 407
 408     $self->get_method_map->{$method_name} = $method;
 409
 410     my $full_method_name = ($self->name . '::' . $method_name);
 411     $self->add_package_symbol(
 412         { sigil => '&', type => 'CODE', name => $method_name },
 413         Class::MOP::subname($full_method_name => $body)
 414     );
 415
 416     $self->update_package_cache_flag; # still valid, since we just added the method to the map, and if it was invalid before that then get_method_map updated it
 417 }
 418
 419 sub find_method_by_name { (shift)->get_method(@_) }
 420
 421 sub get_method_list {
 422     my $self = shift;
 423     grep { !/^meta$/ } keys %{$self->get_method_map};
 424 }
 425
 426 sub alias_method {
 427     my $self = shift;
 428
 429     $self->add_method(@_);
 430 }
 431
 432 ## ------------------------------------------------------------------
 433 ## role construction
 434 ## ------------------------------------------------------------------
 435
 436 sub apply {
 437     my ($self, $other, @args) = @_;
 438
 439     (blessed($other))
 440         || Moose->throw_error("You must pass in an blessed instance");
 441
 442     if ($other->isa('Moose::Meta::Role')) {
 443         require Moose::Meta::Role::Application::ToRole;
 444         return Moose::Meta::Role::Application::ToRole->new(@args)->apply($self, $other);
 445     }
 446     elsif ($other->isa('Moose::Meta::Class')) {
 447         require Moose::Meta::Role::Application::ToClass;
 448         return Moose::Meta::Role::Application::ToClass->new(@args)->apply($self, $other);
 449     }
 450     else {
 451         require Moose::Meta::Role::Application::ToInstance;
 452         return Moose::Meta::Role::Application::ToInstance->new(@args)->apply($self, $other);
 453     }
 454 }
 455
 456 sub combine {
 457     my ($class, @role_specs) = @_;
 458
 459     require Moose::Meta::Role::Application::RoleSummation;
 460     require Moose::Meta::Role::Composite;
 461
 462     my (@roles, %role_params);
 463     while (@role_specs) {
 464         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 465         push @roles => $role->meta;
 466         next unless defined $params;
 467         $role_params{$role} = $params;
 468     }
 469
 470     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 471     Moose::Meta::Role::Application::RoleSummation->new(
 472         role_params => \%role_params
 473     )->apply($c);
 474
 475     return $c;
 476 }
 477
 478 sub create {
 479     my ( $role, $package_name, %options ) = @_;
 480
 481     $options{package} = $package_name;
 482
 483     (ref $options{attributes} eq 'HASH')
 484         || confess "You must pass a HASH ref of attributes"
 485             if exists $options{attributes};
 486
 487     (ref $options{methods} eq 'HASH')
 488         || confess "You must pass a HASH ref of methods"
 489             if exists $options{methods};
 490
 491     $role->SUPER::create(%options);
 492
 493     my (%initialize_options) = %options;
 494     delete @initialize_options{qw(
 495         package
 496         attributes
 497         methods
 498         version
 499         authority
 500     )};
 501
 502     my $meta = $role->initialize( $package_name => %initialize_options );
 503
 504     # FIXME totally lame
 505     $meta->add_method('meta' => sub {
 506         $role->initialize(ref($_[0]) || $_[0]);
 507     });
 508
 509     if (exists $options{attributes}) {
 510         foreach my $attribute_name (keys %{$options{attributes}}) {
 511             my $attr = $options{attributes}->{$attribute_name};
 512             $meta->add_attribute($attribute_name => $attr);
 513         }
 514     }
 515
 516     if (exists $options{methods}) {
 517         foreach my $method_name (keys %{$options{methods}}) {
 518             $meta->add_method($method_name, $options{methods}->{$method_name});
 519         }
 520     }
 521
 522     return $meta;
 523 }
 524
 525 # anonymous roles. most of it is copied straight out of Class::MOP::Class.
 526 # an intrepid hacker might find great riches if he unifies this code with that
 527 # code in Class::MOP::Module or Class::MOP::Package
 528 {
 529     # NOTE:
 530     # this should be sufficient, if you have a
 531     # use case where it is not, write a test and
 532     # I will change it.
 533     my $ANON_ROLE_SERIAL = 0;
 534
 535     # NOTE:
 536     # we need a sufficiently annoying prefix
 537     # this should suffice for now, this is
 538     # used in a couple of places below, so
 539     # need to put it up here for now.
 540     my $ANON_ROLE_PREFIX = 'Moose::Meta::Role::__ANON__::SERIAL::';
 541
 542     sub is_anon_role {
 543         my $self = shift;
 544         no warnings 'uninitialized';
 545         $self->name =~ /^$ANON_ROLE_PREFIX/;
 546     }
 547
 548     sub create_anon_role {
 549         my ($role, %options) = @_;
 550         my $package_name = $ANON_ROLE_PREFIX . ++$ANON_ROLE_SERIAL;
 551         return $role->create($package_name, %options);
 552     }
 553
 554     # NOTE:
 555     # this will only get called for
 556     # anon-roles, all other calls
 557     # are assumed to occur during
 558     # global destruction and so don't
 559     # really need to be handled explicitly
 560     sub DESTROY {
 561         my $self = shift;
 562
 563         return if Class::MOP::in_global_destruction(); # it'll happen soon anyway and this just makes things more complicated
 564
 565         no warnings 'uninitialized';
 566         return unless $self->name =~ /^$ANON_ROLE_PREFIX/;
 567
 568         # XXX: is this necessary for us? I don't understand what it's doing
 569         # -sartak
 570
 571         # Moose does a weird thing where it replaces the metaclass for
 572         # class when fixing metaclass incompatibility. In that case,
 573         # we don't want to clean out the namespace now. We can detect
 574         # that because Moose will explicitly update the singleton
 575         # cache in Class::MOP.
 576         #my $current_meta = Class::MOP::get_metaclass_by_name($self->name);
 577         #return if $current_meta ne $self;
 578
 579         my ($serial_id) = ($self->name =~ /^$ANON_ROLE_PREFIX(\d+)/);
 580         no strict 'refs';
 581         foreach my $key (keys %{$ANON_ROLE_PREFIX . $serial_id}) {
 582             delete ${$ANON_ROLE_PREFIX . $serial_id}{$key};
 583         }
 584         delete ${'main::' . $ANON_ROLE_PREFIX}{$serial_id . '::'};
 585     }
 586 }
 587
 588 #####################################################################
 589 ## NOTE:
 590 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 591 ## MooseX::AttributeHelpers module). It is here as a reference to
 592 ## make it easier to see what is happening above with all the meta
 593 ## programming. - SL
 594 #####################################################################
 595 #
 596 # has 'roles' => (
 597 #     metaclass => 'Collection::Array',
 598 #     reader    => 'get_roles',
 599 #     isa       => 'ArrayRef[Moose::Meta::Roles]',
 600 #     default   => sub { [] },
 601 #     provides  => {
 602 #         'push' => 'add_role',
 603 #     }
 604 # );
 605 #
 606 # has 'excluded_roles_map' => (
 607 #     metaclass => 'Collection::Hash',
 608 #     reader    => 'get_excluded_roles_map',
 609 #     isa       => 'HashRef[Str]',
 610 #     provides  => {
 611 #         # Not exactly set, cause it sets multiple
 612 #         'set'    => 'add_excluded_roles',
 613 #         'keys'   => 'get_excluded_roles_list',
 614 #         'exists' => 'excludes_role',
 615 #     }
 616 # );
 617 #
 618 # has 'attribute_map' => (
 619 #     metaclass => 'Collection::Hash',
 620 #     reader    => 'get_attribute_map',
 621 #     isa       => 'HashRef[Str]',
 622 #     provides => {
 623 #         # 'set'  => 'add_attribute' # has some special crap in it
 624 #         'get'    => 'get_attribute',
 625 #         'keys'   => 'get_attribute_list',
 626 #         'exists' => 'has_attribute',
 627 #         # Not exactly delete, cause it sets multiple
 628 #         'delete' => 'remove_attribute',
 629 #     }
 630 # );
 631 #
 632 # has 'required_methods' => (
 633 #     metaclass => 'Collection::Hash',
 634 #     reader    => 'get_required_methods_map',
 635 #     isa       => 'HashRef[Str]',
 636 #     provides  => {
 637 #         # not exactly set, or delete since it works for multiple
 638 #         'set'    => 'add_required_methods',
 639 #         'delete' => 'remove_required_methods',
 640 #         'keys'   => 'get_required_method_list',
 641 #         'exists' => 'requires_method',
 642 #     }
 643 # );
 644 #
 645 # # the before, around and after modifiers are
 646 # # HASH keyed by method-name, with ARRAY of
 647 # # CODE refs to apply in that order
 648 #
 649 # has 'before_method_modifiers' => (
 650 #     metaclass => 'Collection::Hash',
 651 #     reader    => 'get_before_method_modifiers_map',
 652 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 653 #     provides  => {
 654 #         'keys'   => 'get_before_method_modifiers',
 655 #         'exists' => 'has_before_method_modifiers',
 656 #         # This actually makes sure there is an
 657 #         # ARRAY at the given key, and pushed onto
 658 #         # it. It also checks for duplicates as well
 659 #         # 'add'  => 'add_before_method_modifier'
 660 #     }
 661 # );
 662 #
 663 # has 'after_method_modifiers' => (
 664 #     metaclass => 'Collection::Hash',
 665 #     reader    =>'get_after_method_modifiers_map',
 666 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 667 #     provides  => {
 668 #         'keys'   => 'get_after_method_modifiers',
 669 #         'exists' => 'has_after_method_modifiers',
 670 #         # This actually makes sure there is an
 671 #         # ARRAY at the given key, and pushed onto
 672 #         # it. It also checks for duplicates as well
 673 #         # 'add'  => 'add_after_method_modifier'
 674 #     }
 675 # );
 676 #
 677 # has 'around_method_modifiers' => (
 678 #     metaclass => 'Collection::Hash',
 679 #     reader    =>'get_around_method_modifiers_map',
 680 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 681 #     provides  => {
 682 #         'keys'   => 'get_around_method_modifiers',
 683 #         'exists' => 'has_around_method_modifiers',
 684 #         # This actually makes sure there is an
 685 #         # ARRAY at the given key, and pushed onto
 686 #         # it. It also checks for duplicates as well
 687 #         # 'add'  => 'add_around_method_modifier'
 688 #     }
 689 # );
 690 #
 691 # # override is similar to the other modifiers
 692 # # except that it is not an ARRAY of code refs
 693 # # but instead just a single name->code mapping
 694 #
 695 # has 'override_method_modifiers' => (
 696 #     metaclass => 'Collection::Hash',
 697 #     reader    =>'get_override_method_modifiers_map',
 698 #     isa       => 'HashRef[CodeRef]',
 699 #     provides  => {
 700 #         'keys'   => 'get_override_method_modifier',
 701 #         'exists' => 'has_override_method_modifier',
 702 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 703 #     }
 704 # );
 705 #
 706 #####################################################################
 707
 708
 709 1;
 710
 711 __END__
 712
 713 =pod
 714
 715 =head1 NAME
 716
 717 Moose::Meta::Role - The Moose Role metaclass
 718
 719 =head1 DESCRIPTION
 720
 721 Please see L<Moose::Role> for more information about roles.
 722 For the most part, this has no user-serviceable parts inside
 723 this module. It's API is still subject to some change (although
 724 probably not that much really).
 725
 726 =head1 METHODS
 727
 728 =over 4
 729
 730 =item B<meta>
 731
 732 =item B<new>
 733
 734 =item B<apply>
 735
 736 =item B<apply_to_metaclass_instance>
 737
 738 =item B<combine>
 739
 740 =back
 741
 742 =over 4
 743
 744 =item B<name>
 745
 746 =item B<version>
 747
 748 =item B<role_meta>
 749
 750 =back
 751
 752 =over 4
 753
 754 =item B<get_roles>
 755
 756 =item B<add_role>
 757
 758 =item B<does_role>
 759
 760 =back
 761
 762 =over 4
 763
 764 =item B<add_excluded_roles>
 765
 766 =item B<excludes_role>
 767
 768 =item B<get_excluded_roles_list>
 769
 770 =item B<get_excluded_roles_map>
 771
 772 =item B<calculate_all_roles>
 773
 774 =back
 775
 776 =over 4
 777
 778 =item B<method_metaclass>
 779
 780 =item B<find_method_by_name>
 781
 782 =item B<get_method>
 783
 784 =item B<has_method>
 785
 786 =item B<add_method>
 787
 788 =item B<wrap_method_body>
 789
 790 =item B<alias_method>
 791
 792 =item B<get_method_list>
 793
 794 =item B<get_method_map>
 795
 796 =item B<update_package_cache_flag>
 797
 798 =item B<reset_package_cache_flag>
 799
 800 =back
 801
 802 =over 4
 803
 804 =item B<add_attribute>
 805
 806 =item B<has_attribute>
 807
 808 =item B<get_attribute>
 809
 810 =item B<get_attribute_list>
 811
 812 =item B<get_attribute_map>
 813
 814 =item B<remove_attribute>
 815
 816 =back
 817
 818 =over 4
 819
 820 =item B<add_required_methods>
 821
 822 =item B<remove_required_methods>
 823
 824 =item B<get_required_method_list>
 825
 826 =item B<get_required_methods_map>
 827
 828 =item B<requires_method>
 829
 830 =back
 831
 832 =over 4
 833
 834 =item B<add_after_method_modifier>
 835
 836 =item B<add_around_method_modifier>
 837
 838 =item B<add_before_method_modifier>
 839
 840 =item B<add_override_method_modifier>
 841
 842 =over 4
 843
 844 =back
 845
 846 =item B<has_after_method_modifiers>
 847
 848 =item B<has_around_method_modifiers>
 849
 850 =item B<has_before_method_modifiers>
 851
 852 =item B<has_override_method_modifier>
 853
 854 =over 4
 855
 856 =back
 857
 858 =item B<get_after_method_modifiers>
 859
 860 =item B<get_around_method_modifiers>
 861
 862 =item B<get_before_method_modifiers>
 863
 864 =item B<get_method_modifier_list>
 865
 866 =over 4
 867
 868 =back
 869
 870 =item B<get_override_method_modifier>
 871
 872 =item B<get_after_method_modifiers_map>
 873
 874 =item B<get_around_method_modifiers_map>
 875
 876 =item B<get_before_method_modifiers_map>
 877
 878 =item B<get_override_method_modifiers_map>
 879
 880 =back
 881
 882 =over 4
 883
 884 =item B<create>
 885
 886 =item B<create_anon_role>
 887
 888 =item B<is_anon_role>
 889
 890 =back
 891
 892 =head1 BUGS
 893
 894 All complex software has bugs lurking in it, and this module is no
 895 exception. If you find a bug please either email me, or add the bug
 896 to cpan-RT.
 897
 898 =head1 AUTHOR
 899
 900 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 901
 902 =head1 COPYRIGHT AND LICENSE
 903
 904 Copyright 2006-2008 by Infinity Interactive, Inc.
 905
 906 L<http://www.iinteractive.com>
 907
 908 This library is free software; you can redistribute it and/or modify
 909 it under the same terms as Perl itself.
 910
 911 =cut