lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Scalar::Util 'blessed';
   9
  10 our $VERSION   = '0.57';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use Moose::Meta::Class;
  15 use Moose::Meta::Role::Method;
  16 use Moose::Meta::Role::Method::Required;
  17
  18 use base 'Class::MOP::Module';
  19
  20 ## ------------------------------------------------------------------
  21 ## NOTE:
  22 ## I normally don't do this, but I am doing
  23 ## a whole bunch of meta-programmin in this
  24 ## module, so it just makes sense. For a clearer
  25 ## picture of what is going on in the next
  26 ## several lines of code, look at the really
  27 ## big comment at the end of this file (right
  28 ## before the POD).
  29 ## - SL
  30 ## ------------------------------------------------------------------
  31
  32 my $META = __PACKAGE__->meta;
  33
  34 ## ------------------------------------------------------------------
  35 ## attributes ...
  36
  37 # NOTE:
  38 # since roles are lazy, we hold all the attributes
  39 # of the individual role in 'statis' until which
  40 # time when it is applied to a class. This means
  41 # keeping a lot of things in hash maps, so we are
  42 # using a little of that meta-programmin' magic
  43 # here an saving lots of extra typin. And since
  44 # many of these attributes above require similar
  45 # functionality to support them, so we again use
  46 # the wonders of meta-programmin' to deliver a
  47 # very compact solution to this normally verbose
  48 # problem.
  49 # - SL
  50
  51 foreach my $action (
  52     {
  53         name        => 'excluded_roles_map',
  54         attr_reader => 'get_excluded_roles_map' ,
  55         methods     => {
  56             add       => 'add_excluded_roles',
  57             get_list  => 'get_excluded_roles_list',
  58             existence => 'excludes_role',
  59         }
  60     },
  61     {
  62         name        => 'required_methods',
  63         attr_reader => 'get_required_methods_map',
  64         methods     => {
  65             add       => 'add_required_methods',
  66             remove    => 'remove_required_methods',
  67             get_list  => 'get_required_method_list',
  68             existence => 'requires_method',
  69         }
  70     },
  71     {
  72         name        => 'attribute_map',
  73         attr_reader => 'get_attribute_map',
  74         methods     => {
  75             get       => 'get_attribute',
  76             get_list  => 'get_attribute_list',
  77             existence => 'has_attribute',
  78             remove    => 'remove_attribute',
  79         }
  80     }
  81 ) {
  82
  83     my $attr_reader = $action->{attr_reader};
  84     my $methods     = $action->{methods};
  85
  86     # create the attribute
  87     $META->add_attribute($action->{name} => (
  88         reader  => $attr_reader,
  89         default => sub { {} }
  90     ));
  91
  92     # create some helper methods
  93     $META->add_method($methods->{add} => sub {
  94         my ($self, @values) = @_;
  95         $self->$attr_reader->{$_} = undef foreach @values;
  96     }) if exists $methods->{add};
  97
  98     $META->add_method($methods->{get_list} => sub {
  99         my ($self) = @_;
 100         keys %{$self->$attr_reader};
 101     }) if exists $methods->{get_list};
 102
 103     $META->add_method($methods->{get} => sub {
 104         my ($self, $name) = @_;
 105         $self->$attr_reader->{$name}
 106     }) if exists $methods->{get};
 107
 108     $META->add_method($methods->{existence} => sub {
 109         my ($self, $name) = @_;
 110         exists $self->$attr_reader->{$name} ? 1 : 0;
 111     }) if exists $methods->{existence};
 112
 113     $META->add_method($methods->{remove} => sub {
 114         my ($self, @values) = @_;
 115         delete $self->$attr_reader->{$_} foreach @values;
 116     }) if exists $methods->{remove};
 117 }
 118
 119 ## some things don't always fit, so they go here ...
 120
 121 sub add_attribute {
 122     my $self = shift;
 123     my $name = shift;
 124     my $attr_desc;
 125     if (scalar @_ == 1 && ref($_[0]) eq 'HASH') {
 126         $attr_desc = $_[0];
 127     }
 128     else {
 129         $attr_desc = { @_ };
 130     }
 131     $self->get_attribute_map->{$name} = $attr_desc;
 132 }
 133
 134 # DEPRECATED
 135 # sub _clean_up_required_methods {
 136 #     my $self = shift;
 137 #     foreach my $method ($self->get_required_method_list) {
 138 #         $self->remove_required_methods($method)
 139 #             if $self->has_method($method);
 140 #     }
 141 # }
 142
 143 ## ------------------------------------------------------------------
 144 ## method modifiers
 145
 146 # NOTE:
 147 # the before/around/after method modifiers are
 148 # stored by name, but there can be many methods
 149 # then associated with that name. So again we have
 150 # lots of similar functionality, so we can do some
 151 # meta-programmin' and save some time.
 152 # - SL
 153
 154 foreach my $modifier_type (qw[ before around after ]) {
 155
 156     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 157
 158     # create the attribute ...
 159     $META->add_attribute("${modifier_type}_method_modifiers" => (
 160         reader  => $attr_reader,
 161         default => sub { {} }
 162     ));
 163
 164     # and some helper methods ...
 165     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 166         my ($self, $method_name) = @_;
 167         #return () unless exists $self->$attr_reader->{$method_name};
 168         @{$self->$attr_reader->{$method_name}};
 169     });
 170
 171     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 172         my ($self, $method_name) = @_;
 173         # NOTE:
 174         # for now we assume that if it exists,..
 175         # it has at least one modifier in it
 176         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 177     });
 178
 179     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 180         my ($self, $method_name, $method) = @_;
 181
 182         $self->$attr_reader->{$method_name} = []
 183             unless exists $self->$attr_reader->{$method_name};
 184
 185         my $modifiers = $self->$attr_reader->{$method_name};
 186
 187         # NOTE:
 188         # check to see that we aren't adding the
 189         # same code twice. We err in favor of the
 190         # first on here, this may not be as expected
 191         foreach my $modifier (@{$modifiers}) {
 192             return if $modifier == $method;
 193         }
 194
 195         push @{$modifiers} => $method;
 196     });
 197
 198 }
 199
 200 ## ------------------------------------------------------------------
 201 ## override method mofidiers
 202
 203 $META->add_attribute('override_method_modifiers' => (
 204     reader  => 'get_override_method_modifiers_map',
 205     default => sub { {} }
 206 ));
 207
 208 # NOTE:
 209 # these are a little different because there
 210 # can only be one per name, whereas the other
 211 # method modifiers can have multiples.
 212 # - SL
 213
 214 sub add_override_method_modifier {
 215     my ($self, $method_name, $method) = @_;
 216     (!$self->has_method($method_name))
 217         || Moose->throw_error("Cannot add an override of method '$method_name' " .
 218                    "because there is a local version of '$method_name'");
 219     $self->get_override_method_modifiers_map->{$method_name} = $method;
 220 }
 221
 222 sub has_override_method_modifier {
 223     my ($self, $method_name) = @_;
 224     # NOTE:
 225     # for now we assume that if it exists,..
 226     # it has at least one modifier in it
 227     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 228 }
 229
 230 sub get_override_method_modifier {
 231     my ($self, $method_name) = @_;
 232     $self->get_override_method_modifiers_map->{$method_name};
 233 }
 234
 235 ## general list accessor ...
 236
 237 sub get_method_modifier_list {
 238     my ($self, $modifier_type) = @_;
 239     my $accessor = "get_${modifier_type}_method_modifiers_map";
 240     keys %{$self->$accessor};
 241 }
 242
 243 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 244 sub update_package_cache_flag {
 245     my $self = shift;
 246     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 247 }
 248
 249
 250
 251 ## ------------------------------------------------------------------
 252 ## subroles
 253
 254 __PACKAGE__->meta->add_attribute('roles' => (
 255     reader  => 'get_roles',
 256     default => sub { [] }
 257 ));
 258
 259 sub add_role {
 260     my ($self, $role) = @_;
 261     (blessed($role) && $role->isa('Moose::Meta::Role'))
 262         || Moose->throw_error("Roles must be instances of Moose::Meta::Role");
 263     push @{$self->get_roles} => $role;
 264     $self->reset_package_cache_flag;
 265 }
 266
 267 sub calculate_all_roles {
 268     my $self = shift;
 269     my %seen;
 270     grep {
 271         !$seen{$_->name}++
 272     } ($self, map {
 273                   $_->calculate_all_roles
 274               } @{ $self->get_roles });
 275 }
 276
 277 sub does_role {
 278     my ($self, $role_name) = @_;
 279     (defined $role_name)
 280         || Moose->throw_error("You must supply a role name to look for");
 281     # if we are it,.. then return true
 282     return 1 if $role_name eq $self->name;
 283     # otherwise.. check our children
 284     foreach my $role (@{$self->get_roles}) {
 285         return 1 if $role->does_role($role_name);
 286     }
 287     return 0;
 288 }
 289
 290 ## ------------------------------------------------------------------
 291 ## methods
 292
 293 sub method_metaclass { 'Moose::Meta::Role::Method' }
 294
 295 sub get_method_map {
 296     my $self = shift;
 297
 298     my $current = Class::MOP::check_package_cache_flag($self->name);
 299
 300     if (defined $self->{'_package_cache_flag'} && $self->{'_package_cache_flag'} == $current) {
 301         return $self->{'methods'} ||= {};
 302     }
 303
 304     $self->{_package_cache_flag} = $current;
 305
 306     my $map  = $self->{'methods'} ||= {};
 307
 308     my $role_name        = $self->name;
 309     my $method_metaclass = $self->method_metaclass;
 310
 311     my %all_code = $self->get_all_package_symbols('CODE');
 312
 313     foreach my $symbol (keys %all_code) {
 314         my $code = $all_code{$symbol};
 315
 316         next if exists  $map->{$symbol} &&
 317                 defined $map->{$symbol} &&
 318                         $map->{$symbol}->body == $code;
 319
 320         my ($pkg, $name) = Class::MOP::get_code_info($code);
 321
 322         if ($pkg->can('meta')
 323             # NOTE:
 324             # we don't know what ->meta we are calling
 325             # here, so we need to be careful cause it
 326             # just might blow up at us, or just complain
 327             # loudly (in the case of Curses.pm) so we
 328             # just be a little overly cautious here.
 329             # - SL
 330             && eval { no warnings; blessed($pkg->meta) } # FIXME calls meta
 331             && $pkg->meta->isa('Moose::Meta::Role')) {
 332             my $role = $pkg->meta->name;
 333             next unless $self->does_role($role);
 334         }
 335         else {
 336             # NOTE:
 337             # in 5.10 constant.pm the constants show up
 338             # as being in the right package, but in pre-5.10
 339             # they show up as constant::__ANON__ so we
 340             # make an exception here to be sure that things
 341             # work as expected in both.
 342             # - SL
 343             unless ($pkg eq 'constant' && $name eq '__ANON__') {
 344                 next if ($pkg  || '') ne $role_name ||
 345                         (($name || '') ne '__ANON__' && ($pkg  || '') ne $role_name);
 346             }
 347         }
 348
 349         $map->{$symbol} = $method_metaclass->wrap(
 350             $code,
 351             package_name => $role_name,
 352             name         => $name
 353         );
 354     }
 355
 356     return $map;
 357 }
 358
 359 sub get_method {
 360     my ($self, $name) = @_;
 361     $self->get_method_map->{$name};
 362 }
 363
 364 sub has_method {
 365     my ($self, $name) = @_;
 366     exists $self->get_method_map->{$name} ? 1 : 0
 367 }
 368
 369 # FIXME this is copypasated from Class::MOP::Class
 370 # refactor to inherit from some common base
 371 sub wrap_method_body {
 372     my ( $self, %args ) = @_;
 373
 374     ('CODE' eq ref $args{body})
 375         || Moose->throw_error("Your code block must be a CODE reference");
 376
 377     $self->method_metaclass->wrap(
 378         package_name => $self->name,
 379         %args,
 380     );
 381 }
 382
 383 sub add_method {
 384     my ($self, $method_name, $method) = @_;
 385     (defined $method_name && $method_name)
 386     || Moose->throw_error("You must define a method name");
 387
 388     my $body;
 389     if (blessed($method)) {
 390         $body = $method->body;
 391         if ($method->package_name ne $self->name) {
 392             $method = $method->clone(
 393                 package_name => $self->name,
 394                 name         => $method_name
 395             ) if $method->can('clone');
 396         }
 397     }
 398     else {
 399         $body = $method;
 400         $method = $self->wrap_method_body( body => $body, name => $method_name );
 401     }
 402
 403     $method->attach_to_class($self);
 404
 405     $self->get_method_map->{$method_name} = $method;
 406
 407     my $full_method_name = ($self->name . '::' . $method_name);
 408     $self->add_package_symbol(
 409         { sigil => '&', type => 'CODE', name => $method_name },
 410         Class::MOP::subname($full_method_name => $body)
 411     );
 412
 413     $self->update_package_cache_flag; # still valid, since we just added the method to the map, and if it was invalid before that then get_method_map updated it
 414 }
 415
 416 sub find_method_by_name { (shift)->get_method(@_) }
 417
 418 sub get_method_list {
 419     my $self = shift;
 420     grep { !/^meta$/ } keys %{$self->get_method_map};
 421 }
 422
 423 sub alias_method {
 424     my $self = shift;
 425
 426     $self->add_method(@_);
 427 }
 428
 429 ## ------------------------------------------------------------------
 430 ## role construction
 431 ## ------------------------------------------------------------------
 432
 433 sub apply {
 434     my ($self, $other, @args) = @_;
 435
 436     (blessed($other))
 437         || Moose->throw_error("You must pass in an blessed instance");
 438
 439     if ($other->isa('Moose::Meta::Role')) {
 440         require Moose::Meta::Role::Application::ToRole;
 441         return Moose::Meta::Role::Application::ToRole->new(@args)->apply($self, $other);
 442     }
 443     elsif ($other->isa('Moose::Meta::Class')) {
 444         require Moose::Meta::Role::Application::ToClass;
 445         return Moose::Meta::Role::Application::ToClass->new(@args)->apply($self, $other);
 446     }
 447     else {
 448         require Moose::Meta::Role::Application::ToInstance;
 449         return Moose::Meta::Role::Application::ToInstance->new(@args)->apply($self, $other);
 450     }
 451 }
 452
 453 sub combine {
 454     my ($class, @role_specs) = @_;
 455
 456     require Moose::Meta::Role::Application::RoleSummation;
 457     require Moose::Meta::Role::Composite;
 458
 459     my (@roles, %role_params);
 460     while (@role_specs) {
 461         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 462         push @roles => $role->meta;
 463         next unless defined $params;
 464         $role_params{$role} = $params;
 465     }
 466
 467     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 468     Moose::Meta::Role::Application::RoleSummation->new(
 469         role_params => \%role_params
 470     )->apply($c);
 471
 472     return $c;
 473 }
 474
 475 #####################################################################
 476 ## NOTE:
 477 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 478 ## MooseX::AttributeHelpers module). It is here as a reference to
 479 ## make it easier to see what is happening above with all the meta
 480 ## programming. - SL
 481 #####################################################################
 482 #
 483 # has 'roles' => (
 484 #     metaclass => 'Collection::Array',
 485 #     reader    => 'get_roles',
 486 #     isa       => 'ArrayRef[Moose::Meta::Roles]',
 487 #     default   => sub { [] },
 488 #     provides  => {
 489 #         'push' => 'add_role',
 490 #     }
 491 # );
 492 #
 493 # has 'excluded_roles_map' => (
 494 #     metaclass => 'Collection::Hash',
 495 #     reader    => 'get_excluded_roles_map',
 496 #     isa       => 'HashRef[Str]',
 497 #     provides  => {
 498 #         # Not exactly set, cause it sets multiple
 499 #         'set'    => 'add_excluded_roles',
 500 #         'keys'   => 'get_excluded_roles_list',
 501 #         'exists' => 'excludes_role',
 502 #     }
 503 # );
 504 #
 505 # has 'attribute_map' => (
 506 #     metaclass => 'Collection::Hash',
 507 #     reader    => 'get_attribute_map',
 508 #     isa       => 'HashRef[Str]',
 509 #     provides => {
 510 #         # 'set'  => 'add_attribute' # has some special crap in it
 511 #         'get'    => 'get_attribute',
 512 #         'keys'   => 'get_attribute_list',
 513 #         'exists' => 'has_attribute',
 514 #         # Not exactly delete, cause it sets multiple
 515 #         'delete' => 'remove_attribute',
 516 #     }
 517 # );
 518 #
 519 # has 'required_methods' => (
 520 #     metaclass => 'Collection::Hash',
 521 #     reader    => 'get_required_methods_map',
 522 #     isa       => 'HashRef[Str]',
 523 #     provides  => {
 524 #         # not exactly set, or delete since it works for multiple
 525 #         'set'    => 'add_required_methods',
 526 #         'delete' => 'remove_required_methods',
 527 #         'keys'   => 'get_required_method_list',
 528 #         'exists' => 'requires_method',
 529 #     }
 530 # );
 531 #
 532 # # the before, around and after modifiers are
 533 # # HASH keyed by method-name, with ARRAY of
 534 # # CODE refs to apply in that order
 535 #
 536 # has 'before_method_modifiers' => (
 537 #     metaclass => 'Collection::Hash',
 538 #     reader    => 'get_before_method_modifiers_map',
 539 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 540 #     provides  => {
 541 #         'keys'   => 'get_before_method_modifiers',
 542 #         'exists' => 'has_before_method_modifiers',
 543 #         # This actually makes sure there is an
 544 #         # ARRAY at the given key, and pushed onto
 545 #         # it. It also checks for duplicates as well
 546 #         # 'add'  => 'add_before_method_modifier'
 547 #     }
 548 # );
 549 #
 550 # has 'after_method_modifiers' => (
 551 #     metaclass => 'Collection::Hash',
 552 #     reader    =>'get_after_method_modifiers_map',
 553 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 554 #     provides  => {
 555 #         'keys'   => 'get_after_method_modifiers',
 556 #         'exists' => 'has_after_method_modifiers',
 557 #         # This actually makes sure there is an
 558 #         # ARRAY at the given key, and pushed onto
 559 #         # it. It also checks for duplicates as well
 560 #         # 'add'  => 'add_after_method_modifier'
 561 #     }
 562 # );
 563 #
 564 # has 'around_method_modifiers' => (
 565 #     metaclass => 'Collection::Hash',
 566 #     reader    =>'get_around_method_modifiers_map',
 567 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 568 #     provides  => {
 569 #         'keys'   => 'get_around_method_modifiers',
 570 #         'exists' => 'has_around_method_modifiers',
 571 #         # This actually makes sure there is an
 572 #         # ARRAY at the given key, and pushed onto
 573 #         # it. It also checks for duplicates as well
 574 #         # 'add'  => 'add_around_method_modifier'
 575 #     }
 576 # );
 577 #
 578 # # override is similar to the other modifiers
 579 # # except that it is not an ARRAY of code refs
 580 # # but instead just a single name->code mapping
 581 #
 582 # has 'override_method_modifiers' => (
 583 #     metaclass => 'Collection::Hash',
 584 #     reader    =>'get_override_method_modifiers_map',
 585 #     isa       => 'HashRef[CodeRef]',
 586 #     provides  => {
 587 #         'keys'   => 'get_override_method_modifier',
 588 #         'exists' => 'has_override_method_modifier',
 589 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 590 #     }
 591 # );
 592 #
 593 #####################################################################
 594
 595
 596 1;
 597
 598 __END__
 599
 600 =pod
 601
 602 =head1 NAME
 603
 604 Moose::Meta::Role - The Moose Role metaclass
 605
 606 =head1 DESCRIPTION
 607
 608 Please see L<Moose::Role> for more information about roles.
 609 For the most part, this has no user-serviceable parts inside
 610 this module. It's API is still subject to some change (although
 611 probably not that much really).
 612
 613 =head1 METHODS
 614
 615 =over 4
 616
 617 =item B<meta>
 618
 619 =item B<new>
 620
 621 =item B<apply>
 622
 623 =item B<apply_to_metaclass_instance>
 624
 625 =item B<combine>
 626
 627 =back
 628
 629 =over 4
 630
 631 =item B<name>
 632
 633 =item B<version>
 634
 635 =item B<role_meta>
 636
 637 =back
 638
 639 =over 4
 640
 641 =item B<get_roles>
 642
 643 =item B<add_role>
 644
 645 =item B<does_role>
 646
 647 =back
 648
 649 =over 4
 650
 651 =item B<add_excluded_roles>
 652
 653 =item B<excludes_role>
 654
 655 =item B<get_excluded_roles_list>
 656
 657 =item B<get_excluded_roles_map>
 658
 659 =item B<calculate_all_roles>
 660
 661 =back
 662
 663 =over 4
 664
 665 =item B<method_metaclass>
 666
 667 =item B<find_method_by_name>
 668
 669 =item B<get_method>
 670
 671 =item B<has_method>
 672
 673 =item B<add_method>
 674
 675 =item B<wrap_method_body>
 676
 677 =item B<alias_method>
 678
 679 =item B<get_method_list>
 680
 681 =item B<get_method_map>
 682
 683 =item B<update_package_cache_flag>
 684
 685 =item B<reset_package_cache_flag>
 686
 687 =back
 688
 689 =over 4
 690
 691 =item B<add_attribute>
 692
 693 =item B<has_attribute>
 694
 695 =item B<get_attribute>
 696
 697 =item B<get_attribute_list>
 698
 699 =item B<get_attribute_map>
 700
 701 =item B<remove_attribute>
 702
 703 =back
 704
 705 =over 4
 706
 707 =item B<add_required_methods>
 708
 709 =item B<remove_required_methods>
 710
 711 =item B<get_required_method_list>
 712
 713 =item B<get_required_methods_map>
 714
 715 =item B<requires_method>
 716
 717 =back
 718
 719 =over 4
 720
 721 =item B<add_after_method_modifier>
 722
 723 =item B<add_around_method_modifier>
 724
 725 =item B<add_before_method_modifier>
 726
 727 =item B<add_override_method_modifier>
 728
 729 =over 4
 730
 731 =back
 732
 733 =item B<has_after_method_modifiers>
 734
 735 =item B<has_around_method_modifiers>
 736
 737 =item B<has_before_method_modifiers>
 738
 739 =item B<has_override_method_modifier>
 740
 741 =over 4
 742
 743 =back
 744
 745 =item B<get_after_method_modifiers>
 746
 747 =item B<get_around_method_modifiers>
 748
 749 =item B<get_before_method_modifiers>
 750
 751 =item B<get_method_modifier_list>
 752
 753 =over 4
 754
 755 =back
 756
 757 =item B<get_override_method_modifier>
 758
 759 =item B<get_after_method_modifiers_map>
 760
 761 =item B<get_around_method_modifiers_map>
 762
 763 =item B<get_before_method_modifiers_map>
 764
 765 =item B<get_override_method_modifiers_map>
 766
 767 =back
 768
 769 =head1 BUGS
 770
 771 All complex software has bugs lurking in it, and this module is no
 772 exception. If you find a bug please either email me, or add the bug
 773 to cpan-RT.
 774
 775 =head1 AUTHOR
 776
 777 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 778
 779 =head1 COPYRIGHT AND LICENSE
 780
 781 Copyright 2006-2008 by Infinity Interactive, Inc.
 782
 783 L<http://www.iinteractive.com>
 784
 785 This library is free software; you can redistribute it and/or modify
 786 it under the same terms as Perl itself.
 787
 788 =cut