lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Scalar::Util 'blessed';
   9 use Carp         'confess';
  10 use Sub::Name    'subname';
  11 use Devel::GlobalDestruction 'in_global_destruction';
  12
  13 our $VERSION   = '0.85';
  14 $VERSION = eval $VERSION;
  15 our $AUTHORITY = 'cpan:STEVAN';
  16
  17 use Moose::Meta::Class;
  18 use Moose::Meta::Role::Method;
  19 use Moose::Meta::Role::Method::Required;
  20 use Moose::Meta::Role::Method::Conflicting;
  21
  22 use base 'Class::MOP::Module';
  23
  24 ## ------------------------------------------------------------------
  25 ## NOTE:
  26 ## I normally don't do this, but I am doing
  27 ## a whole bunch of meta-programmin in this
  28 ## module, so it just makes sense. For a clearer
  29 ## picture of what is going on in the next
  30 ## several lines of code, look at the really
  31 ## big comment at the end of this file (right
  32 ## before the POD).
  33 ## - SL
  34 ## ------------------------------------------------------------------
  35
  36 my $META = __PACKAGE__->meta;
  37
  38 ## ------------------------------------------------------------------
  39 ## attributes ...
  40
  41 # NOTE:
  42 # since roles are lazy, we hold all the attributes
  43 # of the individual role in 'statis' until which
  44 # time when it is applied to a class. This means
  45 # keeping a lot of things in hash maps, so we are
  46 # using a little of that meta-programmin' magic
  47 # here an saving lots of extra typin. And since
  48 # many of these attributes above require similar
  49 # functionality to support them, so we again use
  50 # the wonders of meta-programmin' to deliver a
  51 # very compact solution to this normally verbose
  52 # problem.
  53 # - SL
  54
  55 foreach my $action (
  56     {
  57         name        => 'excluded_roles_map',
  58         attr_reader => 'get_excluded_roles_map' ,
  59         methods     => {
  60             add       => 'add_excluded_roles',
  61             get_keys  => 'get_excluded_roles_list',
  62             existence => 'excludes_role',
  63         }
  64     },
  65     {
  66         name        => 'required_methods',
  67         attr_reader => 'get_required_methods_map',
  68         methods     => {
  69             remove     => 'remove_required_methods',
  70             get_values => 'get_required_method_list',
  71             existence  => 'requires_method',
  72         }
  73     },
  74     {
  75         name        => 'attribute_map',
  76         attr_reader => 'get_attribute_map',
  77         methods     => {
  78             get       => 'get_attribute',
  79             get_keys  => 'get_attribute_list',
  80             existence => 'has_attribute',
  81             remove    => 'remove_attribute',
  82         }
  83     }
  84 ) {
  85
  86     my $attr_reader = $action->{attr_reader};
  87     my $methods     = $action->{methods};
  88
  89     # create the attribute
  90     $META->add_attribute($action->{name} => (
  91         reader  => $attr_reader,
  92         default => sub { {} }
  93     ));
  94
  95     # create some helper methods
  96     $META->add_method($methods->{add} => sub {
  97         my ($self, @values) = @_;
  98         $self->$attr_reader->{$_} = undef foreach @values;
  99     }) if exists $methods->{add};
 100
 101     $META->add_method($methods->{get_keys} => sub {
 102         my ($self) = @_;
 103         keys %{$self->$attr_reader};
 104     }) if exists $methods->{get_keys};
 105
 106     $META->add_method($methods->{get_values} => sub {
 107         my ($self) = @_;
 108         values %{$self->$attr_reader};
 109     }) if exists $methods->{get_values};
 110
 111     $META->add_method($methods->{get} => sub {
 112         my ($self, $name) = @_;
 113         $self->$attr_reader->{$name}
 114     }) if exists $methods->{get};
 115
 116     $META->add_method($methods->{existence} => sub {
 117         my ($self, $name) = @_;
 118         exists $self->$attr_reader->{$name} ? 1 : 0;
 119     }) if exists $methods->{existence};
 120
 121     $META->add_method($methods->{remove} => sub {
 122         my ($self, @values) = @_;
 123         delete $self->$attr_reader->{$_} foreach @values;
 124     }) if exists $methods->{remove};
 125 }
 126
 127 $META->add_attribute(
 128     'method_metaclass',
 129     reader  => 'method_metaclass',
 130     default => 'Moose::Meta::Role::Method',
 131 );
 132
 133 $META->add_attribute(
 134     'required_method_metaclass',
 135     reader  => 'required_method_metaclass',
 136     default => 'Moose::Meta::Role::Method::Required',
 137 );
 138
 139 $META->add_attribute(
 140     'conflicting_method_metaclass',
 141     reader  => 'conflicting_method_metaclass',
 142     default => 'Moose::Meta::Role::Method::Conflicting',
 143 );
 144
 145 ## some things don't always fit, so they go here ...
 146
 147 sub add_attribute {
 148     my $self = shift;
 149     my $name = shift;
 150     unless ( defined $name && $name ) {
 151         require Moose;
 152         Moose->throw_error("You must provide a name for the attribute");
 153     }
 154     my $attr_desc;
 155     if (scalar @_ == 1 && ref($_[0]) eq 'HASH') {
 156         $attr_desc = $_[0];
 157     }
 158     else {
 159         $attr_desc = { @_ };
 160     }
 161     $self->get_attribute_map->{$name} = $attr_desc;
 162 }
 163
 164 sub add_required_methods {
 165     my $self = shift;
 166
 167     for (@_) {
 168         my $method = $_;
 169         if (!blessed($method)) {
 170             $method = $self->required_method_metaclass->new(
 171                 name => $method,
 172             );
 173         }
 174         $self->get_required_methods_map->{$method->name} = $method;
 175     }
 176 }
 177
 178 sub add_conflicting_method {
 179     my $self = shift;
 180
 181     my $method;
 182     if (@_ == 1 && blessed($_[0])) {
 183         $method = shift;
 184     }
 185     else {
 186         $method = $self->conflicting_method_metaclass->new(@_);
 187     }
 188
 189     $self->add_required_methods($method);
 190 }
 191
 192 ## ------------------------------------------------------------------
 193 ## method modifiers
 194
 195 # NOTE:
 196 # the before/around/after method modifiers are
 197 # stored by name, but there can be many methods
 198 # then associated with that name. So again we have
 199 # lots of similar functionality, so we can do some
 200 # meta-programmin' and save some time.
 201 # - SL
 202
 203 foreach my $modifier_type (qw[ before around after ]) {
 204
 205     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 206
 207     # create the attribute ...
 208     $META->add_attribute("${modifier_type}_method_modifiers" => (
 209         reader  => $attr_reader,
 210         default => sub { {} }
 211     ));
 212
 213     # and some helper methods ...
 214     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 215         my ($self, $method_name) = @_;
 216         #return () unless exists $self->$attr_reader->{$method_name};
 217         my $mm = $self->$attr_reader->{$method_name};
 218         $mm ? @$mm : ();
 219     });
 220
 221     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 222         my ($self, $method_name) = @_;
 223         # NOTE:
 224         # for now we assume that if it exists,..
 225         # it has at least one modifier in it
 226         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 227     });
 228
 229     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 230         my ($self, $method_name, $method) = @_;
 231
 232         $self->$attr_reader->{$method_name} = []
 233             unless exists $self->$attr_reader->{$method_name};
 234
 235         my $modifiers = $self->$attr_reader->{$method_name};
 236
 237         # NOTE:
 238         # check to see that we aren't adding the
 239         # same code twice. We err in favor of the
 240         # first on here, this may not be as expected
 241         foreach my $modifier (@{$modifiers}) {
 242             return if $modifier == $method;
 243         }
 244
 245         push @{$modifiers} => $method;
 246     });
 247
 248 }
 249
 250 ## ------------------------------------------------------------------
 251 ## override method mofidiers
 252
 253 $META->add_attribute('override_method_modifiers' => (
 254     reader  => 'get_override_method_modifiers_map',
 255     default => sub { {} }
 256 ));
 257
 258 # NOTE:
 259 # these are a little different because there
 260 # can only be one per name, whereas the other
 261 # method modifiers can have multiples.
 262 # - SL
 263
 264 sub add_override_method_modifier {
 265     my ($self, $method_name, $method) = @_;
 266     (!$self->has_method($method_name))
 267         || Moose->throw_error("Cannot add an override of method '$method_name' " .
 268                    "because there is a local version of '$method_name'");
 269     $self->get_override_method_modifiers_map->{$method_name} = $method;
 270 }
 271
 272 sub has_override_method_modifier {
 273     my ($self, $method_name) = @_;
 274     # NOTE:
 275     # for now we assume that if it exists,..
 276     # it has at least one modifier in it
 277     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 278 }
 279
 280 sub get_override_method_modifier {
 281     my ($self, $method_name) = @_;
 282     $self->get_override_method_modifiers_map->{$method_name};
 283 }
 284
 285 ## general list accessor ...
 286
 287 sub get_method_modifier_list {
 288     my ($self, $modifier_type) = @_;
 289     my $accessor = "get_${modifier_type}_method_modifiers_map";
 290     keys %{$self->$accessor};
 291 }
 292
 293 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 294 sub update_package_cache_flag {
 295     my $self = shift;
 296     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 297 }
 298
 299
 300
 301 ## ------------------------------------------------------------------
 302 ## subroles
 303
 304 $META->add_attribute('roles' => (
 305     reader  => 'get_roles',
 306     default => sub { [] }
 307 ));
 308
 309 sub add_role {
 310     my ($self, $role) = @_;
 311     (blessed($role) && $role->isa('Moose::Meta::Role'))
 312         || Moose->throw_error("Roles must be instances of Moose::Meta::Role");
 313     push @{$self->get_roles} => $role;
 314     $self->reset_package_cache_flag;
 315 }
 316
 317 sub calculate_all_roles {
 318     my $self = shift;
 319     my %seen;
 320     grep {
 321         !$seen{$_->name}++
 322     } ($self, map {
 323                   $_->calculate_all_roles
 324               } @{ $self->get_roles });
 325 }
 326
 327 sub does_role {
 328     my ($self, $role_name) = @_;
 329     (defined $role_name)
 330         || Moose->throw_error("You must supply a role name to look for");
 331     # if we are it,.. then return true
 332     return 1 if $role_name eq $self->name;
 333     # otherwise.. check our children
 334     foreach my $role (@{$self->get_roles}) {
 335         return 1 if $role->does_role($role_name);
 336     }
 337     return 0;
 338 }
 339
 340 ## ------------------------------------------------------------------
 341 ## methods
 342
 343 sub get_method_map {
 344     my $self = shift;
 345
 346     my $current = Class::MOP::check_package_cache_flag($self->name);
 347
 348     if (defined $self->{'_package_cache_flag'} && $self->{'_package_cache_flag'} == $current) {
 349         return $self->{'methods'} ||= {};
 350     }
 351
 352     $self->{_package_cache_flag} = $current;
 353
 354     my $map  = $self->{'methods'} ||= {};
 355
 356     my $role_name        = $self->name;
 357     my $method_metaclass = $self->method_metaclass;
 358
 359     my $all_code = $self->get_all_package_symbols('CODE');
 360
 361     foreach my $symbol (keys %{ $all_code }) {
 362         my $code = $all_code->{$symbol};
 363
 364         next if exists  $map->{$symbol} &&
 365                 defined $map->{$symbol} &&
 366                         $map->{$symbol}->body == $code;
 367
 368         my ($pkg, $name) = Class::MOP::get_code_info($code);
 369         my $meta = Class::MOP::class_of($pkg);
 370
 371         if ($meta && $meta->isa('Moose::Meta::Role')) {
 372             my $role = $meta->name;
 373             next unless $self->does_role($role);
 374         }
 375         else {
 376             # NOTE:
 377             # in 5.10 constant.pm the constants show up
 378             # as being in the right package, but in pre-5.10
 379             # they show up as constant::__ANON__ so we
 380             # make an exception here to be sure that things
 381             # work as expected in both.
 382             # - SL
 383             unless ($pkg eq 'constant' && $name eq '__ANON__') {
 384                 next if ($pkg  || '') ne $role_name ||
 385                         (($name || '') ne '__ANON__' && ($pkg  || '') ne $role_name);
 386             }
 387         }
 388
 389         $map->{$symbol} = $method_metaclass->wrap(
 390             $code,
 391             package_name => $role_name,
 392             name         => $name
 393         );
 394     }
 395
 396     return $map;
 397 }
 398
 399 sub get_method {
 400     my ($self, $name) = @_;
 401     $self->get_method_map->{$name};
 402 }
 403
 404 sub has_method {
 405     my ($self, $name) = @_;
 406     exists $self->get_method_map->{$name} ? 1 : 0
 407 }
 408
 409 # FIXME this is copy-pasted from Class::MOP::Class
 410 # refactor to inherit from some common base
 411 sub wrap_method_body {
 412     my ( $self, %args ) = @_;
 413
 414     ('CODE' eq ref $args{body})
 415         || Moose->throw_error("Your code block must be a CODE reference");
 416
 417     $self->method_metaclass->wrap(
 418         package_name => $self->name,
 419         %args,
 420     );
 421 }
 422
 423 sub add_method {
 424     my ($self, $method_name, $method) = @_;
 425     (defined $method_name && $method_name)
 426     || Moose->throw_error("You must define a method name");
 427
 428     my $body;
 429     if (blessed($method)) {
 430         $body = $method->body;
 431         if ($method->package_name ne $self->name) {
 432             $method = $method->clone(
 433                 package_name => $self->name,
 434                 name         => $method_name
 435             ) if $method->can('clone');
 436         }
 437     }
 438     else {
 439         $body = $method;
 440         $method = $self->wrap_method_body( body => $body, name => $method_name );
 441     }
 442
 443     $method->attach_to_class($self);
 444
 445     $self->get_method_map->{$method_name} = $method;
 446
 447     my $full_method_name = ($self->name . '::' . $method_name);
 448     $self->add_package_symbol(
 449         { sigil => '&', type => 'CODE', name => $method_name },
 450         subname($full_method_name => $body)
 451     );
 452
 453     $self->update_package_cache_flag; # still valid, since we just added the method to the map, and if it was invalid before that then get_method_map updated it
 454 }
 455
 456 sub find_method_by_name { (shift)->get_method(@_) }
 457
 458 sub get_method_list {
 459     my $self = shift;
 460     grep { !/^meta$/ } keys %{$self->get_method_map};
 461 }
 462
 463 sub alias_method {
 464     Carp::cluck("The alias_method method is deprecated. Use add_method instead.\n");
 465
 466     my $self = shift;
 467
 468     $self->add_method(@_);
 469 }
 470
 471 ## ------------------------------------------------------------------
 472 ## role construction
 473 ## ------------------------------------------------------------------
 474
 475 sub apply {
 476     my ($self, $other, @args) = @_;
 477
 478     (blessed($other))
 479         || Moose->throw_error("You must pass in an blessed instance");
 480
 481     if ($other->isa('Moose::Meta::Role')) {
 482         require Moose::Meta::Role::Application::ToRole;
 483         return Moose::Meta::Role::Application::ToRole->new(@args)->apply($self, $other);
 484     }
 485     elsif ($other->isa('Moose::Meta::Class')) {
 486         require Moose::Meta::Role::Application::ToClass;
 487         return Moose::Meta::Role::Application::ToClass->new(@args)->apply($self, $other);
 488     }
 489     else {
 490         require Moose::Meta::Role::Application::ToInstance;
 491         return Moose::Meta::Role::Application::ToInstance->new(@args)->apply($self, $other);
 492     }
 493 }
 494
 495 sub combine {
 496     my ($class, @role_specs) = @_;
 497
 498     require Moose::Meta::Role::Application::RoleSummation;
 499     require Moose::Meta::Role::Composite;
 500
 501     my (@roles, %role_params);
 502     while (@role_specs) {
 503         my ($role_name, $params) = @{ splice @role_specs, 0, 1 };
 504         my $requested_role = Class::MOP::class_of($role_name);
 505
 506         my $actual_role = $requested_role->_role_for_combination($params);
 507         push @roles => $actual_role;
 508
 509         next unless defined $params;
 510         $role_params{$actual_role->name} = $params;
 511     }
 512
 513     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 514     Moose::Meta::Role::Application::RoleSummation->new(
 515         role_params => \%role_params
 516     )->apply($c);
 517
 518     return $c;
 519 }
 520
 521 sub _role_for_combination {
 522     my ($self, $params) = @_;
 523     return $self;
 524 }
 525
 526 sub create {
 527     my ( $role, $package_name, %options ) = @_;
 528
 529     $options{package} = $package_name;
 530
 531     (ref $options{attributes} eq 'HASH')
 532         || confess "You must pass a HASH ref of attributes"
 533             if exists $options{attributes};
 534
 535     (ref $options{methods} eq 'HASH')
 536         || confess "You must pass a HASH ref of methods"
 537             if exists $options{methods};
 538
 539     my (%initialize_options) = %options;
 540     delete @initialize_options{qw(
 541         package
 542         attributes
 543         methods
 544         version
 545         authority
 546     )};
 547
 548     my $meta = $role->initialize( $package_name => %initialize_options );
 549
 550     $meta->_instantiate_module( $options{version}, $options{authority} );
 551
 552     # FIXME totally lame
 553     $meta->add_method('meta' => sub {
 554         $role->initialize(ref($_[0]) || $_[0]);
 555     });
 556
 557     if (exists $options{attributes}) {
 558         foreach my $attribute_name (keys %{$options{attributes}}) {
 559             my $attr = $options{attributes}->{$attribute_name};
 560             $meta->add_attribute($attribute_name => $attr);
 561         }
 562     }
 563
 564     if (exists $options{methods}) {
 565         foreach my $method_name (keys %{$options{methods}}) {
 566             $meta->add_method($method_name, $options{methods}->{$method_name});
 567         }
 568     }
 569
 570     Class::MOP::weaken_metaclass($meta->name)
 571         if $meta->is_anon_role;
 572
 573     return $meta;
 574 }
 575
 576 # anonymous roles. most of it is copied straight out of Class::MOP::Class.
 577 # an intrepid hacker might find great riches if he unifies this code with that
 578 # code in Class::MOP::Module or Class::MOP::Package
 579 {
 580     # NOTE:
 581     # this should be sufficient, if you have a
 582     # use case where it is not, write a test and
 583     # I will change it.
 584     my $ANON_ROLE_SERIAL = 0;
 585
 586     # NOTE:
 587     # we need a sufficiently annoying prefix
 588     # this should suffice for now, this is
 589     # used in a couple of places below, so
 590     # need to put it up here for now.
 591     my $ANON_ROLE_PREFIX = 'Moose::Meta::Role::__ANON__::SERIAL::';
 592
 593     sub is_anon_role {
 594         my $self = shift;
 595         no warnings 'uninitialized';
 596         $self->name =~ /^$ANON_ROLE_PREFIX/;
 597     }
 598
 599     sub create_anon_role {
 600         my ($role, %options) = @_;
 601         my $package_name = $ANON_ROLE_PREFIX . ++$ANON_ROLE_SERIAL;
 602         return $role->create($package_name, %options);
 603     }
 604
 605     # NOTE:
 606     # this will only get called for
 607     # anon-roles, all other calls
 608     # are assumed to occur during
 609     # global destruction and so don't
 610     # really need to be handled explicitly
 611     sub DESTROY {
 612         my $self = shift;
 613
 614         return if in_global_destruction(); # it'll happen soon anyway and this just makes things more complicated
 615
 616         no warnings 'uninitialized';
 617         return unless $self->name =~ /^$ANON_ROLE_PREFIX/;
 618
 619         # XXX: is this necessary for us? I don't understand what it's doing
 620         # -sartak
 621
 622         # Moose does a weird thing where it replaces the metaclass for
 623         # class when fixing metaclass incompatibility. In that case,
 624         # we don't want to clean out the namespace now. We can detect
 625         # that because Moose will explicitly update the singleton
 626         # cache in Class::MOP.
 627         #my $current_meta = Class::MOP::get_metaclass_by_name($self->name);
 628         #return if $current_meta ne $self;
 629
 630         my ($serial_id) = ($self->name =~ /^$ANON_ROLE_PREFIX(\d+)/);
 631         no strict 'refs';
 632         foreach my $key (keys %{$ANON_ROLE_PREFIX . $serial_id}) {
 633             delete ${$ANON_ROLE_PREFIX . $serial_id}{$key};
 634         }
 635         delete ${'main::' . $ANON_ROLE_PREFIX}{$serial_id . '::'};
 636     }
 637 }
 638
 639 #####################################################################
 640 ## NOTE:
 641 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 642 ## MooseX::AttributeHelpers module). It is here as a reference to
 643 ## make it easier to see what is happening above with all the meta
 644 ## programming. - SL
 645 #####################################################################
 646 #
 647 # has 'roles' => (
 648 #     metaclass => 'Collection::Array',
 649 #     reader    => 'get_roles',
 650 #     isa       => 'ArrayRef[Moose::Meta::Role]',
 651 #     default   => sub { [] },
 652 #     provides  => {
 653 #         'push' => 'add_role',
 654 #     }
 655 # );
 656 #
 657 # has 'excluded_roles_map' => (
 658 #     metaclass => 'Collection::Hash',
 659 #     reader    => 'get_excluded_roles_map',
 660 #     isa       => 'HashRef[Str]',
 661 #     provides  => {
 662 #         # Not exactly set, cause it sets multiple
 663 #         'set'    => 'add_excluded_roles',
 664 #         'keys'   => 'get_excluded_roles_list',
 665 #         'exists' => 'excludes_role',
 666 #     }
 667 # );
 668 #
 669 # has 'attribute_map' => (
 670 #     metaclass => 'Collection::Hash',
 671 #     reader    => 'get_attribute_map',
 672 #     isa       => 'HashRef[Str]',
 673 #     provides => {
 674 #         # 'set'  => 'add_attribute' # has some special crap in it
 675 #         'get'    => 'get_attribute',
 676 #         'keys'   => 'get_attribute_list',
 677 #         'exists' => 'has_attribute',
 678 #         # Not exactly delete, cause it sets multiple
 679 #         'delete' => 'remove_attribute',
 680 #     }
 681 # );
 682 #
 683 # has 'required_methods' => (
 684 #     metaclass => 'Collection::Hash',
 685 #     reader    => 'get_required_methods_map',
 686 #     isa       => 'HashRef[Moose::Meta::Role::Method::Required]',
 687 #     provides  => {
 688 #         # not exactly set, or delete since it works for multiple
 689 #         'set'    => 'add_required_methods',
 690 #         'delete' => 'remove_required_methods',
 691 #         'keys'   => 'get_required_method_list',
 692 #         'exists' => 'requires_method',
 693 #     }
 694 # );
 695 #
 696 # # the before, around and after modifiers are
 697 # # HASH keyed by method-name, with ARRAY of
 698 # # CODE refs to apply in that order
 699 #
 700 # has 'before_method_modifiers' => (
 701 #     metaclass => 'Collection::Hash',
 702 #     reader    => 'get_before_method_modifiers_map',
 703 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 704 #     provides  => {
 705 #         'keys'   => 'get_before_method_modifiers',
 706 #         'exists' => 'has_before_method_modifiers',
 707 #         # This actually makes sure there is an
 708 #         # ARRAY at the given key, and pushed onto
 709 #         # it. It also checks for duplicates as well
 710 #         # 'add'  => 'add_before_method_modifier'
 711 #     }
 712 # );
 713 #
 714 # has 'after_method_modifiers' => (
 715 #     metaclass => 'Collection::Hash',
 716 #     reader    =>'get_after_method_modifiers_map',
 717 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 718 #     provides  => {
 719 #         'keys'   => 'get_after_method_modifiers',
 720 #         'exists' => 'has_after_method_modifiers',
 721 #         # This actually makes sure there is an
 722 #         # ARRAY at the given key, and pushed onto
 723 #         # it. It also checks for duplicates as well
 724 #         # 'add'  => 'add_after_method_modifier'
 725 #     }
 726 # );
 727 #
 728 # has 'around_method_modifiers' => (
 729 #     metaclass => 'Collection::Hash',
 730 #     reader    =>'get_around_method_modifiers_map',
 731 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 732 #     provides  => {
 733 #         'keys'   => 'get_around_method_modifiers',
 734 #         'exists' => 'has_around_method_modifiers',
 735 #         # This actually makes sure there is an
 736 #         # ARRAY at the given key, and pushed onto
 737 #         # it. It also checks for duplicates as well
 738 #         # 'add'  => 'add_around_method_modifier'
 739 #     }
 740 # );
 741 #
 742 # # override is similar to the other modifiers
 743 # # except that it is not an ARRAY of code refs
 744 # # but instead just a single name->code mapping
 745 #
 746 # has 'override_method_modifiers' => (
 747 #     metaclass => 'Collection::Hash',
 748 #     reader    =>'get_override_method_modifiers_map',
 749 #     isa       => 'HashRef[CodeRef]',
 750 #     provides  => {
 751 #         'keys'   => 'get_override_method_modifier',
 752 #         'exists' => 'has_override_method_modifier',
 753 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 754 #     }
 755 # );
 756 #
 757 #####################################################################
 758
 759
 760 1;
 761
 762 __END__
 763
 764 =pod
 765
 766 =head1 NAME
 767
 768 Moose::Meta::Role - The Moose Role metaclass
 769
 770 =head1 DESCRIPTION
 771
 772 This class is a subclass of L<Class::MOP::Module> that provides
 773 additional Moose-specific functionality.
 774
 775 It's API looks a lot like L<Moose::Meta::Class>, but internally it
 776 implements many things differently. This may change in the future.
 777
 778 =head1 INHERITANCE
 779
 780 C<Moose::Meta::Role> is a subclass of L<Class::MOP::Module>.
 781
 782 =head1 METHODS
 783
 784 =head2 Construction
 785
 786 =over 4
 787
 788 =item B<< Moose::Meta::Role->initialize($role_name) >>
 789
 790 This method creates a new role object with the provided name.
 791
 792 =item B<< Moose::Meta::Role->combine( [ $role => { ... } ], [ $role ], ... ) >>
 793
 794 This method accepts a list of array references. Each array reference
 795 should contain a role name as its first element. The second element is
 796 an optional hash reference. The hash reference can contain C<exclude>
 797 and C<alias> keys to control how methods are composed from the role.
 798
 799 The return value is a new L<Moose::Meta::Role::Composite> that
 800 represents the combined roles.
 801
 802 =item B<< Moose::Meta::Role->create($name, %options) >>
 803
 804 This method is identical to the L<Moose::Meta::Class> C<create>
 805 method.
 806
 807 =item B<< Moose::Meta::Role->create_anon_role >>
 808
 809 This method is identical to the L<Moose::Meta::Class>
 810 C<create_anon_class> method.
 811
 812 =item B<< $metarole->is_anon_role >>
 813
 814 Returns true if the role is an anonymous role.
 815
 816 =back
 817
 818 =head2 Role application
 819
 820 =over 4
 821
 822 =item B<< $metarole->apply( $thing, @options ) >>
 823
 824 This method applies a role to the given C<$thing>. That can be another
 825 L<Moose::Meta::Role>, object, a L<Moose::Meta::Class> object, or a
 826 (non-meta) object instance.
 827
 828 The options are passed directly to the constructor for the appropriate
 829 L<Moose::Meta::Role::Application> subclass.
 830
 831 Note that this will apply the role even if the C<$thing> in question already
 832 C<does> this role.  L<Moose::Util/does_role> is a convenient wrapper for
 833 finding out if role application is necessary.
 834
 835 =back
 836
 837 =head2 Roles and other roles
 838
 839 =over 4
 840
 841 =item B<< $metarole->get_roles >>
 842
 843 This returns an array reference of roles which this role does. This
 844 list may include duplicates.
 845
 846 =item B<< $metarole->calculate_all_roles >>
 847
 848 This returns a I<unique> list of all roles that this role does, and
 849 all the roles that its roles do.
 850
 851 =item B<< $metarole->does_role($role_name) >>
 852
 853 Given a role I<name>, returns true if this role does the given
 854 role.
 855
 856 =item B<< $metarole->add_role($role) >>
 857
 858 Given a L<Moose::Meta::Role> object, this adds the role to the list of
 859 roles that the role does.
 860
 861 =item B<< $metarole->get_excluded_roles_list >>
 862
 863 Returns a list of role names which this role excludes.
 864
 865 =item B<< $metarole->excludes_role($role_name) >>
 866
 867 Given a role I<name>, returns true if this role excludes the named
 868 role.
 869
 870 =item B<< $metarole->add_excluded_roles(@role_names) >>
 871
 872 Given one or more role names, adds those roles to the list of excluded
 873 roles.
 874
 875 =back
 876
 877 =head2 Methods
 878
 879 The methods for dealing with a role's methods are all identical in API
 880 and behavior to the same methods in L<Class::MOP::Class>.
 881
 882 =over 4
 883
 884 =item B<< $metarole->method_metaclass >>
 885
 886 Returns the method metaclass name for the role. This defaults to
 887 L<Moose::Meta::Role::Method>.
 888
 889 =item B<< $metarole->get_method($name) >>
 890
 891 =item B<< $metarole->has_method($name) >>
 892
 893 =item B<< $metarole->add_method( $name, $body ) >>
 894
 895 =item B<< $metarole->get_method_list >>
 896
 897 =item B<< $metarole->get_method_map >>
 898
 899 =item B<< $metarole->find_method_by_name($name) >>
 900
 901 These methods are all identical to the methods of the same name in
 902 L<Class::MOP::Class>
 903
 904 =back
 905
 906 =head2 Attributes
 907
 908 As with methods, the methods for dealing with a role's attribute are
 909 all identical in API and behavior to the same methods in
 910 L<Class::MOP::Class>.
 911
 912 However, attributes stored in this class are I<not> stored as
 913 objects. Rather, the attribute definition is stored as a hash
 914 reference. When a role is composed into a class, this hash reference
 915 is passed directly to the metaclass's C<add_attribute> method.
 916
 917 This is quite likely to change in the future.
 918
 919 =over 4
 920
 921 =item B<< $metarole->get_attribute($attribute_name) >>
 922
 923 =item B<< $metarole->has_attribute($attribute_name) >>
 924
 925 =item B<< $metarole->get_attribute_map >>
 926
 927 =item B<< $metarole->get_attribute_list >>
 928
 929 =item B<< $metarole->add_attribute($name, %options) >>
 930
 931 =item B<< $metarole->remove_attribute($attribute_name) >>
 932
 933 =back
 934
 935 =head2 Required methods
 936
 937 =over 4
 938
 939 =item B<< $metarole->get_required_method_list >>
 940
 941 Returns the list of methods required by the role.
 942
 943 =item B<< $metarole->requires_method($name) >>
 944
 945 Returns true if the role requires the named method.
 946
 947 =item B<< $metarole->add_required_methods(@names) >>
 948
 949 Adds the named methods to the role's list of required methods.
 950
 951 =item B<< $metarole->remove_required_methods(@names) >>
 952
 953 Removes the named methods from the role's list of required methods.
 954
 955 =item B<< $metarole->add_conflicting_method(%params) >>
 956
 957 Instantiate the parameters as a L<Moose::Meta::Role::Method::Conflicting>
 958 object, then add it to the required method list.
 959
 960 =back
 961
 962 =head2 Method modifiers
 963
 964 These methods act like their counterparts in L<Class::Mop::Class> and
 965 L<Moose::Meta::Class>.
 966
 967 However, method modifiers are simply stored internally, and are not
 968 applied until the role itself is applied to a class.
 969
 970 =over 4
 971
 972 =item B<< $metarole->add_after_method_modifier($method_name, $method) >>
 973
 974 =item B<< $metarole->add_around_method_modifier($method_name, $method) >>
 975
 976 =item B<< $metarole->add_before_method_modifier($method_name, $method) >>
 977
 978 =item B<< $metarole->add_override_method_modifier($method_name, $method) >>
 979
 980 These methods all add an appropriate modifier to the internal list of
 981 modifiers.
 982
 983 =item B<< $metarole->has_after_method_modifiers >>
 984
 985 =item B<< $metarole->has_around_method_modifiers >>
 986
 987 =item B<< $metarole->has_before_method_modifiers >>
 988
 989 =item B<< $metarole->has_override_method_modifier >>
 990
 991 Return true if the role has any modifiers of the given type.
 992
 993 =item B<< $metarole->get_after_method_modifiers($method_name) >>
 994
 995 =item B<< $metarole->get_around_method_modifiers($method_name) >>
 996
 997 =item B<< $metarole->get_before_method_modifiers($method_name) >>
 998
 999 Given a method name, returns a list of the appropriate modifiers for
1000 that method.
1001
1002 =item B<< $metarole->get_override_method_modifier($method_name) >>
1003
1004 Given a method name, returns the override method modifier for that
1005 method, if it has one.
1006
1007 =back
1008
1009 =head2 Introspection
1010
1011 =over 4
1012
1013 =item B<< Moose::Meta::Role->meta >>
1014
1015 This will return a L<Class::MOP::Class> instance for this class.
1016
1017 =back
1018
1019 =head1 BUGS
1020
1021 All complex software has bugs lurking in it, and this module is no
1022 exception. If you find a bug please either email me, or add the bug
1023 to cpan-RT.
1024
1025 =head1 AUTHOR
1026
1027 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1028
1029 =head1 COPYRIGHT AND LICENSE
1030
1031 Copyright 2006-2009 by Infinity Interactive, Inc.
1032
1033 L<http://www.iinteractive.com>
1034
1035 This library is free software; you can redistribute it and/or modify
1036 it under the same terms as Perl itself.
1037
1038 =cut