lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Scalar::Util 'blessed';
   9 use Carp         'confess';
  10 use Devel::GlobalDestruction 'in_global_destruction';
  11
  12 our $VERSION   = '1.03';
  13 $VERSION = eval $VERSION;
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 use Moose::Meta::Class;
  17 use Moose::Meta::Role::Attribute;
  18 use Moose::Meta::Role::Method;
  19 use Moose::Meta::Role::Method::Required;
  20 use Moose::Meta::Role::Method::Conflicting;
  21 use Moose::Util qw( ensure_all_roles );
  22
  23 use base 'Class::MOP::Module',
  24          'Class::MOP::Mixin::HasAttributes',
  25          'Class::MOP::Mixin::HasMethods';
  26
  27 ## ------------------------------------------------------------------
  28 ## NOTE:
  29 ## I normally don't do this, but I am doing
  30 ## a whole bunch of meta-programmin in this
  31 ## module, so it just makes sense. For a clearer
  32 ## picture of what is going on in the next
  33 ## several lines of code, look at the really
  34 ## big comment at the end of this file (right
  35 ## before the POD).
  36 ## - SL
  37 ## ------------------------------------------------------------------
  38
  39 my $META = __PACKAGE__->meta;
  40
  41 ## ------------------------------------------------------------------
  42 ## attributes ...
  43
  44 # NOTE:
  45 # since roles are lazy, we hold all the attributes
  46 # of the individual role in 'statis' until which
  47 # time when it is applied to a class. This means
  48 # keeping a lot of things in hash maps, so we are
  49 # using a little of that meta-programmin' magic
  50 # here an saving lots of extra typin. And since
  51 # many of these attributes above require similar
  52 # functionality to support them, so we again use
  53 # the wonders of meta-programmin' to deliver a
  54 # very compact solution to this normally verbose
  55 # problem.
  56 # - SL
  57
  58 foreach my $action (
  59     {
  60         name        => 'excluded_roles_map',
  61         attr_reader => 'get_excluded_roles_map' ,
  62         methods     => {
  63             add       => 'add_excluded_roles',
  64             get_keys  => 'get_excluded_roles_list',
  65             existence => 'excludes_role',
  66         }
  67     },
  68     {
  69         name        => 'required_methods',
  70         attr_reader => 'get_required_methods_map',
  71         methods     => {
  72             remove     => 'remove_required_methods',
  73             get_values => 'get_required_method_list',
  74             existence  => 'requires_method',
  75         }
  76     },
  77 ) {
  78
  79     my $attr_reader = $action->{attr_reader};
  80     my $methods     = $action->{methods};
  81
  82     # create the attribute
  83     $META->add_attribute($action->{name} => (
  84         reader  => $attr_reader,
  85         default => sub { {} }
  86     ));
  87
  88     # create some helper methods
  89     $META->add_method($methods->{add} => sub {
  90         my ($self, @values) = @_;
  91         $self->$attr_reader->{$_} = undef foreach @values;
  92     }) if exists $methods->{add};
  93
  94     $META->add_method($methods->{get_keys} => sub {
  95         my ($self) = @_;
  96         keys %{$self->$attr_reader};
  97     }) if exists $methods->{get_keys};
  98
  99     $META->add_method($methods->{get_values} => sub {
 100         my ($self) = @_;
 101         values %{$self->$attr_reader};
 102     }) if exists $methods->{get_values};
 103
 104     $META->add_method($methods->{get} => sub {
 105         my ($self, $name) = @_;
 106         $self->$attr_reader->{$name}
 107     }) if exists $methods->{get};
 108
 109     $META->add_method($methods->{existence} => sub {
 110         my ($self, $name) = @_;
 111         exists $self->$attr_reader->{$name} ? 1 : 0;
 112     }) if exists $methods->{existence};
 113
 114     $META->add_method($methods->{remove} => sub {
 115         my ($self, @values) = @_;
 116         delete $self->$attr_reader->{$_} foreach @values;
 117     }) if exists $methods->{remove};
 118 }
 119
 120 $META->add_attribute(
 121     'method_metaclass',
 122     reader  => 'method_metaclass',
 123     default => 'Moose::Meta::Role::Method',
 124 );
 125
 126 $META->add_attribute(
 127     'required_method_metaclass',
 128     reader  => 'required_method_metaclass',
 129     default => 'Moose::Meta::Role::Method::Required',
 130 );
 131
 132 $META->add_attribute(
 133     'conflicting_method_metaclass',
 134     reader  => 'conflicting_method_metaclass',
 135     default => 'Moose::Meta::Role::Method::Conflicting',
 136 );
 137
 138 $META->add_attribute(
 139     'application_to_class_class',
 140     reader  => 'application_to_class_class',
 141     default => 'Moose::Meta::Role::Application::ToClass',
 142 );
 143
 144 $META->add_attribute(
 145     'application_to_role_class',
 146     reader  => 'application_to_role_class',
 147     default => 'Moose::Meta::Role::Application::ToRole',
 148 );
 149
 150 $META->add_attribute(
 151     'application_to_instance_class',
 152     reader  => 'application_to_instance_class',
 153     default => 'Moose::Meta::Role::Application::ToInstance',
 154 );
 155
 156 # More or less copied from Moose::Meta::Class
 157 sub initialize {
 158     my $class = shift;
 159     my $pkg   = shift;
 160     return Class::MOP::get_metaclass_by_name($pkg)
 161         || $class->SUPER::initialize(
 162         $pkg,
 163         'attribute_metaclass' => 'Moose::Meta::Role::Attribute',
 164         @_
 165         );
 166 }
 167
 168 sub reinitialize {
 169     my $self = shift;
 170     my $pkg  = shift;
 171
 172     my $meta = blessed $pkg ? $pkg : Class::MOP::class_of($pkg);
 173
 174     my %existing_classes;
 175     if ($meta) {
 176         %existing_classes = map { $_ => $meta->$_() } qw(
 177             attribute_metaclass
 178             method_metaclass
 179             wrapped_method_metaclass
 180             required_method_metaclass
 181             conflicting_method_metaclass
 182             application_to_class_class
 183             application_to_role_class
 184             application_to_instance_class
 185         );
 186     }
 187
 188     return $self->SUPER::reinitialize(
 189         $pkg,
 190         %existing_classes,
 191         @_,
 192     );
 193 }
 194
 195 sub add_attribute {
 196     my $self = shift;
 197
 198     if (blessed $_[0] && ! $_[0]->isa('Moose::Meta::Role::Attribute') ) {
 199         my $class = ref $_[0];
 200         Moose->throw_error( "Cannot add a $class as an attribute to a role" );
 201     }
 202     elsif (!blessed($_[0]) && defined($_[0]) && $_[0] =~ /^\+(.*)/) {
 203         Moose->throw_error( "has '+attr' is not supported in roles" );
 204     }
 205
 206     return $self->SUPER::add_attribute(@_);
 207 }
 208
 209 sub _attach_attribute {
 210     my ( $self, $attribute ) = @_;
 211
 212     $attribute->attach_to_role($self);
 213 }
 214
 215 sub add_required_methods {
 216     my $self = shift;
 217
 218     for (@_) {
 219         my $method = $_;
 220         if (!blessed($method)) {
 221             $method = $self->required_method_metaclass->new(
 222                 name => $method,
 223             );
 224         }
 225         $self->get_required_methods_map->{$method->name} = $method;
 226     }
 227 }
 228
 229 sub add_conflicting_method {
 230     my $self = shift;
 231
 232     my $method;
 233     if (@_ == 1 && blessed($_[0])) {
 234         $method = shift;
 235     }
 236     else {
 237         $method = $self->conflicting_method_metaclass->new(@_);
 238     }
 239
 240     $self->add_required_methods($method);
 241 }
 242
 243 ## ------------------------------------------------------------------
 244 ## method modifiers
 245
 246 # NOTE:
 247 # the before/around/after method modifiers are
 248 # stored by name, but there can be many methods
 249 # then associated with that name. So again we have
 250 # lots of similar functionality, so we can do some
 251 # meta-programmin' and save some time.
 252 # - SL
 253
 254 foreach my $modifier_type (qw[ before around after ]) {
 255
 256     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 257
 258     # create the attribute ...
 259     $META->add_attribute("${modifier_type}_method_modifiers" => (
 260         reader  => $attr_reader,
 261         default => sub { {} }
 262     ));
 263
 264     # and some helper methods ...
 265     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 266         my ($self, $method_name) = @_;
 267         #return () unless exists $self->$attr_reader->{$method_name};
 268         my $mm = $self->$attr_reader->{$method_name};
 269         $mm ? @$mm : ();
 270     });
 271
 272     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 273         my ($self, $method_name) = @_;
 274         # NOTE:
 275         # for now we assume that if it exists,..
 276         # it has at least one modifier in it
 277         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 278     });
 279
 280     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 281         my ($self, $method_name, $method) = @_;
 282
 283         $self->$attr_reader->{$method_name} = []
 284             unless exists $self->$attr_reader->{$method_name};
 285
 286         my $modifiers = $self->$attr_reader->{$method_name};
 287
 288         # NOTE:
 289         # check to see that we aren't adding the
 290         # same code twice. We err in favor of the
 291         # first on here, this may not be as expected
 292         foreach my $modifier (@{$modifiers}) {
 293             return if $modifier == $method;
 294         }
 295
 296         push @{$modifiers} => $method;
 297     });
 298
 299 }
 300
 301 ## ------------------------------------------------------------------
 302 ## override method mofidiers
 303
 304 $META->add_attribute('override_method_modifiers' => (
 305     reader  => 'get_override_method_modifiers_map',
 306     default => sub { {} }
 307 ));
 308
 309 # NOTE:
 310 # these are a little different because there
 311 # can only be one per name, whereas the other
 312 # method modifiers can have multiples.
 313 # - SL
 314
 315 sub add_override_method_modifier {
 316     my ($self, $method_name, $method) = @_;
 317     (!$self->has_method($method_name))
 318         || Moose->throw_error("Cannot add an override of method '$method_name' " .
 319                    "because there is a local version of '$method_name'");
 320     $self->get_override_method_modifiers_map->{$method_name} = $method;
 321 }
 322
 323 sub has_override_method_modifier {
 324     my ($self, $method_name) = @_;
 325     # NOTE:
 326     # for now we assume that if it exists,..
 327     # it has at least one modifier in it
 328     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 329 }
 330
 331 sub get_override_method_modifier {
 332     my ($self, $method_name) = @_;
 333     $self->get_override_method_modifiers_map->{$method_name};
 334 }
 335
 336 ## general list accessor ...
 337
 338 sub get_method_modifier_list {
 339     my ($self, $modifier_type) = @_;
 340     my $accessor = "get_${modifier_type}_method_modifiers_map";
 341     keys %{$self->$accessor};
 342 }
 343
 344 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 345 sub update_package_cache_flag {
 346     my $self = shift;
 347     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 348 }
 349
 350
 351
 352 ## ------------------------------------------------------------------
 353 ## subroles
 354
 355 $META->add_attribute('roles' => (
 356     reader  => 'get_roles',
 357     default => sub { [] }
 358 ));
 359
 360 sub add_role {
 361     my ($self, $role) = @_;
 362     (blessed($role) && $role->isa('Moose::Meta::Role'))
 363         || Moose->throw_error("Roles must be instances of Moose::Meta::Role");
 364     push @{$self->get_roles} => $role;
 365     $self->reset_package_cache_flag;
 366 }
 367
 368 sub calculate_all_roles {
 369     my $self = shift;
 370     my %seen;
 371     grep {
 372         !$seen{$_->name}++
 373     } ($self, map {
 374                   $_->calculate_all_roles
 375               } @{ $self->get_roles });
 376 }
 377
 378 sub does_role {
 379     my ($self, $role) = @_;
 380     (defined $role)
 381         || Moose->throw_error("You must supply a role name to look for");
 382     my $role_name = blessed $role ? $role->name : $role;
 383     # if we are it,.. then return true
 384     return 1 if $role_name eq $self->name;
 385     # otherwise.. check our children
 386     foreach my $role (@{$self->get_roles}) {
 387         return 1 if $role->does_role($role_name);
 388     }
 389     return 0;
 390 }
 391
 392 sub find_method_by_name { (shift)->get_method(@_) }
 393
 394 sub alias_method {
 395     Carp::cluck("The alias_method method is deprecated. Use add_method instead.\n");
 396
 397     my $self = shift;
 398
 399     $self->add_method(@_);
 400 }
 401
 402 ## ------------------------------------------------------------------
 403 ## role construction
 404 ## ------------------------------------------------------------------
 405
 406 sub apply {
 407     my ($self, $other, %args) = @_;
 408
 409     (blessed($other))
 410         || Moose->throw_error("You must pass in an blessed instance");
 411
 412     my $application_class;
 413     if ($other->isa('Moose::Meta::Role')) {
 414         $application_class = $self->application_to_role_class;
 415     }
 416     elsif ($other->isa('Moose::Meta::Class')) {
 417         $application_class = $self->application_to_class_class;
 418     }
 419     else {
 420         $application_class = $self->application_to_instance_class;
 421     }
 422
 423     Class::MOP::load_class($application_class);
 424     return $application_class->new(%args)->apply($self, $other, \%args);
 425 }
 426
 427 sub composition_class_roles { }
 428
 429 sub combine {
 430     my ($class, @role_specs) = @_;
 431
 432     require Moose::Meta::Role::Composite;
 433
 434     my (@roles, %role_params);
 435     while (@role_specs) {
 436         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 437         my $requested_role
 438             = blessed $role
 439             ? $role
 440             : Class::MOP::class_of($role);
 441
 442         my $actual_role = $requested_role->_role_for_combination($params);
 443         push @roles => $actual_role;
 444
 445         next unless defined $params;
 446         $role_params{$actual_role->name} = $params;
 447     }
 448
 449     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 450     return $c->apply_params(\%role_params);
 451 }
 452
 453 sub _role_for_combination {
 454     my ($self, $params) = @_;
 455     return $self;
 456 }
 457
 458 sub create {
 459     my ( $role, $package_name, %options ) = @_;
 460
 461     $options{package} = $package_name;
 462
 463     (ref $options{attributes} eq 'HASH')
 464         || confess "You must pass a HASH ref of attributes"
 465             if exists $options{attributes};
 466
 467     (ref $options{methods} eq 'HASH')
 468         || confess "You must pass a HASH ref of methods"
 469             if exists $options{methods};
 470
 471     my (%initialize_options) = %options;
 472     delete @initialize_options{qw(
 473         package
 474         attributes
 475         methods
 476         version
 477         authority
 478     )};
 479
 480     my $meta = $role->initialize( $package_name => %initialize_options );
 481
 482     $meta->_instantiate_module( $options{version}, $options{authority} );
 483
 484     # FIXME totally lame
 485     $meta->add_method('meta' => sub {
 486         $role->initialize(ref($_[0]) || $_[0]);
 487     });
 488
 489     if (exists $options{attributes}) {
 490         foreach my $attribute_name (keys %{$options{attributes}}) {
 491             my $attr = $options{attributes}->{$attribute_name};
 492             $meta->add_attribute(
 493                 $attribute_name => blessed $attr ? $attr : %{$attr} );
 494         }
 495     }
 496
 497     if (exists $options{methods}) {
 498         foreach my $method_name (keys %{$options{methods}}) {
 499             $meta->add_method($method_name, $options{methods}->{$method_name});
 500         }
 501     }
 502
 503     Class::MOP::weaken_metaclass($meta->name)
 504         if $meta->is_anon_role;
 505
 506     return $meta;
 507 }
 508
 509 # anonymous roles. most of it is copied straight out of Class::MOP::Class.
 510 # an intrepid hacker might find great riches if he unifies this code with that
 511 # code in Class::MOP::Module or Class::MOP::Package
 512 {
 513     # NOTE:
 514     # this should be sufficient, if you have a
 515     # use case where it is not, write a test and
 516     # I will change it.
 517     my $ANON_ROLE_SERIAL = 0;
 518
 519     # NOTE:
 520     # we need a sufficiently annoying prefix
 521     # this should suffice for now, this is
 522     # used in a couple of places below, so
 523     # need to put it up here for now.
 524     my $ANON_ROLE_PREFIX = 'Moose::Meta::Role::__ANON__::SERIAL::';
 525
 526     sub is_anon_role {
 527         my $self = shift;
 528         no warnings 'uninitialized';
 529         $self->name =~ /^$ANON_ROLE_PREFIX/;
 530     }
 531
 532     sub create_anon_role {
 533         my ($role, %options) = @_;
 534         my $package_name = $ANON_ROLE_PREFIX . ++$ANON_ROLE_SERIAL;
 535         return $role->create($package_name, %options);
 536     }
 537
 538     # NOTE:
 539     # this will only get called for
 540     # anon-roles, all other calls
 541     # are assumed to occur during
 542     # global destruction and so don't
 543     # really need to be handled explicitly
 544     sub DESTROY {
 545         my $self = shift;
 546
 547         return if in_global_destruction(); # it'll happen soon anyway and this just makes things more complicated
 548
 549         no warnings 'uninitialized';
 550         return unless $self->name =~ /^$ANON_ROLE_PREFIX/;
 551
 552         # XXX: is this necessary for us? I don't understand what it's doing
 553         # -sartak
 554
 555         # Moose does a weird thing where it replaces the metaclass for
 556         # class when fixing metaclass incompatibility. In that case,
 557         # we don't want to clean out the namespace now. We can detect
 558         # that because Moose will explicitly update the singleton
 559         # cache in Class::MOP.
 560         #my $current_meta = Class::MOP::get_metaclass_by_name($self->name);
 561         #return if $current_meta ne $self;
 562
 563         my ($serial_id) = ($self->name =~ /^$ANON_ROLE_PREFIX(\d+)/);
 564         no strict 'refs';
 565         foreach my $key (keys %{$ANON_ROLE_PREFIX . $serial_id}) {
 566             delete ${$ANON_ROLE_PREFIX . $serial_id}{$key};
 567         }
 568         delete ${'main::' . $ANON_ROLE_PREFIX}{$serial_id . '::'};
 569     }
 570 }
 571
 572 #####################################################################
 573 ## NOTE:
 574 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 575 ## MooseX::AttributeHelpers module). It is here as a reference to
 576 ## make it easier to see what is happening above with all the meta
 577 ## programming. - SL
 578 #####################################################################
 579 #
 580 # has 'roles' => (
 581 #     metaclass => 'Array',
 582 #     reader    => 'get_roles',
 583 #     isa       => 'ArrayRef[Moose::Meta::Role]',
 584 #     default   => sub { [] },
 585 #     provides  => {
 586 #         'push' => 'add_role',
 587 #     }
 588 # );
 589 #
 590 # has 'excluded_roles_map' => (
 591 #     metaclass => 'Hash',
 592 #     reader    => 'get_excluded_roles_map',
 593 #     isa       => 'HashRef[Str]',
 594 #     provides  => {
 595 #         # Not exactly set, cause it sets multiple
 596 #         'set'    => 'add_excluded_roles',
 597 #         'keys'   => 'get_excluded_roles_list',
 598 #         'exists' => 'excludes_role',
 599 #     }
 600 # );
 601 #
 602 # has 'required_methods' => (
 603 #     metaclass => 'Hash',
 604 #     reader    => 'get_required_methods_map',
 605 #     isa       => 'HashRef[Moose::Meta::Role::Method::Required]',
 606 #     provides  => {
 607 #         # not exactly set, or delete since it works for multiple
 608 #         'set'    => 'add_required_methods',
 609 #         'delete' => 'remove_required_methods',
 610 #         'keys'   => 'get_required_method_list',
 611 #         'exists' => 'requires_method',
 612 #     }
 613 # );
 614 #
 615 # # the before, around and after modifiers are
 616 # # HASH keyed by method-name, with ARRAY of
 617 # # CODE refs to apply in that order
 618 #
 619 # has 'before_method_modifiers' => (
 620 #     metaclass => 'Hash',
 621 #     reader    => 'get_before_method_modifiers_map',
 622 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 623 #     provides  => {
 624 #         'keys'   => 'get_before_method_modifiers',
 625 #         'exists' => 'has_before_method_modifiers',
 626 #         # This actually makes sure there is an
 627 #         # ARRAY at the given key, and pushed onto
 628 #         # it. It also checks for duplicates as well
 629 #         # 'add'  => 'add_before_method_modifier'
 630 #     }
 631 # );
 632 #
 633 # has 'after_method_modifiers' => (
 634 #     metaclass => 'Hash',
 635 #     reader    =>'get_after_method_modifiers_map',
 636 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 637 #     provides  => {
 638 #         'keys'   => 'get_after_method_modifiers',
 639 #         'exists' => 'has_after_method_modifiers',
 640 #         # This actually makes sure there is an
 641 #         # ARRAY at the given key, and pushed onto
 642 #         # it. It also checks for duplicates as well
 643 #         # 'add'  => 'add_after_method_modifier'
 644 #     }
 645 # );
 646 #
 647 # has 'around_method_modifiers' => (
 648 #     metaclass => 'Hash',
 649 #     reader    =>'get_around_method_modifiers_map',
 650 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 651 #     provides  => {
 652 #         'keys'   => 'get_around_method_modifiers',
 653 #         'exists' => 'has_around_method_modifiers',
 654 #         # This actually makes sure there is an
 655 #         # ARRAY at the given key, and pushed onto
 656 #         # it. It also checks for duplicates as well
 657 #         # 'add'  => 'add_around_method_modifier'
 658 #     }
 659 # );
 660 #
 661 # # override is similar to the other modifiers
 662 # # except that it is not an ARRAY of code refs
 663 # # but instead just a single name->code mapping
 664 #
 665 # has 'override_method_modifiers' => (
 666 #     metaclass => 'Hash',
 667 #     reader    =>'get_override_method_modifiers_map',
 668 #     isa       => 'HashRef[CodeRef]',
 669 #     provides  => {
 670 #         'keys'   => 'get_override_method_modifier',
 671 #         'exists' => 'has_override_method_modifier',
 672 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 673 #     }
 674 # );
 675 #
 676 #####################################################################
 677
 678
 679 1;
 680
 681 __END__
 682
 683 =pod
 684
 685 =head1 NAME
 686
 687 Moose::Meta::Role - The Moose Role metaclass
 688
 689 =head1 DESCRIPTION
 690
 691 This class is a subclass of L<Class::MOP::Module> that provides
 692 additional Moose-specific functionality.
 693
 694 It's API looks a lot like L<Moose::Meta::Class>, but internally it
 695 implements many things differently. This may change in the future.
 696
 697 =head1 INHERITANCE
 698
 699 C<Moose::Meta::Role> is a subclass of L<Class::MOP::Module>.
 700
 701 =head1 METHODS
 702
 703 =head2 Construction
 704
 705 =over 4
 706
 707 =item B<< Moose::Meta::Role->initialize($role_name) >>
 708
 709 This method creates a new role object with the provided name.
 710
 711 =item B<< Moose::Meta::Role->combine( [ $role => { ... } ], [ $role ], ... ) >>
 712
 713 This method accepts a list of array references. Each array reference
 714 should contain a role name or L<Moose::Meta::Role> object as its first element. The second element is
 715 an optional hash reference. The hash reference can contain C<-excludes>
 716 and C<-alias> keys to control how methods are composed from the role.
 717
 718 The return value is a new L<Moose::Meta::Role::Composite> that
 719 represents the combined roles.
 720
 721 =item B<< $metarole->composition_class_roles >>
 722
 723 When combining multiple roles using C<combine>, this method is used to obtain a
 724 list of role names to be applied to the L<Moose::Meta::Role::Composite>
 725 instance returned by C<combine>. The default implementation returns an empty
 726 list. Extensions that need to hook into role combination may wrap this method
 727 to return additional role names.
 728
 729 =item B<< Moose::Meta::Role->create($name, %options) >>
 730
 731 This method is identical to the L<Moose::Meta::Class> C<create>
 732 method.
 733
 734 =item B<< Moose::Meta::Role->create_anon_role >>
 735
 736 This method is identical to the L<Moose::Meta::Class>
 737 C<create_anon_class> method.
 738
 739 =item B<< $metarole->is_anon_role >>
 740
 741 Returns true if the role is an anonymous role.
 742
 743 =back
 744
 745 =head2 Role application
 746
 747 =over 4
 748
 749 =item B<< $metarole->apply( $thing, @options ) >>
 750
 751 This method applies a role to the given C<$thing>. That can be another
 752 L<Moose::Meta::Role>, object, a L<Moose::Meta::Class> object, or a
 753 (non-meta) object instance.
 754
 755 The options are passed directly to the constructor for the appropriate
 756 L<Moose::Meta::Role::Application> subclass.
 757
 758 Note that this will apply the role even if the C<$thing> in question already
 759 C<does> this role.  L<Moose::Util/does_role> is a convenient wrapper for
 760 finding out if role application is necessary.
 761
 762 =back
 763
 764 =head2 Roles and other roles
 765
 766 =over 4
 767
 768 =item B<< $metarole->get_roles >>
 769
 770 This returns an array reference of roles which this role does. This
 771 list may include duplicates.
 772
 773 =item B<< $metarole->calculate_all_roles >>
 774
 775 This returns a I<unique> list of all roles that this role does, and
 776 all the roles that its roles do.
 777
 778 =item B<< $metarole->does_role($role) >>
 779
 780 Given a role I<name> or L<Moose::Meta::Role> object, returns true if this role
 781 does the given role.
 782
 783 =item B<< $metarole->add_role($role) >>
 784
 785 Given a L<Moose::Meta::Role> object, this adds the role to the list of
 786 roles that the role does.
 787
 788 =item B<< $metarole->get_excluded_roles_list >>
 789
 790 Returns a list of role names which this role excludes.
 791
 792 =item B<< $metarole->excludes_role($role_name) >>
 793
 794 Given a role I<name>, returns true if this role excludes the named
 795 role.
 796
 797 =item B<< $metarole->add_excluded_roles(@role_names) >>
 798
 799 Given one or more role names, adds those roles to the list of excluded
 800 roles.
 801
 802 =back
 803
 804 =head2 Methods
 805
 806 The methods for dealing with a role's methods are all identical in API
 807 and behavior to the same methods in L<Class::MOP::Class>.
 808
 809 =over 4
 810
 811 =item B<< $metarole->method_metaclass >>
 812
 813 Returns the method metaclass name for the role. This defaults to
 814 L<Moose::Meta::Role::Method>.
 815
 816 =item B<< $metarole->get_method($name) >>
 817
 818 =item B<< $metarole->has_method($name) >>
 819
 820 =item B<< $metarole->add_method( $name, $body ) >>
 821
 822 =item B<< $metarole->get_method_list >>
 823
 824 =item B<< $metarole->find_method_by_name($name) >>
 825
 826 These methods are all identical to the methods of the same name in
 827 L<Class::MOP::Package>
 828
 829 =back
 830
 831 =head2 Attributes
 832
 833 As with methods, the methods for dealing with a role's attribute are
 834 all identical in API and behavior to the same methods in
 835 L<Class::MOP::Class>.
 836
 837 However, attributes stored in this class are I<not> stored as
 838 objects. Rather, the attribute definition is stored as a hash
 839 reference. When a role is composed into a class, this hash reference
 840 is passed directly to the metaclass's C<add_attribute> method.
 841
 842 This is quite likely to change in the future.
 843
 844 =over 4
 845
 846 =item B<< $metarole->get_attribute($attribute_name) >>
 847
 848 =item B<< $metarole->has_attribute($attribute_name) >>
 849
 850 =item B<< $metarole->get_attribute_list >>
 851
 852 =item B<< $metarole->add_attribute($name, %options) >>
 853
 854 =item B<< $metarole->remove_attribute($attribute_name) >>
 855
 856 =back
 857
 858 =head2 Required methods
 859
 860 =over 4
 861
 862 =item B<< $metarole->get_required_method_list >>
 863
 864 Returns the list of methods required by the role.
 865
 866 =item B<< $metarole->requires_method($name) >>
 867
 868 Returns true if the role requires the named method.
 869
 870 =item B<< $metarole->add_required_methods(@names) >>
 871
 872 Adds the named methods to the role's list of required methods.
 873
 874 =item B<< $metarole->remove_required_methods(@names) >>
 875
 876 Removes the named methods from the role's list of required methods.
 877
 878 =item B<< $metarole->add_conflicting_method(%params) >>
 879
 880 Instantiate the parameters as a L<Moose::Meta::Role::Method::Conflicting>
 881 object, then add it to the required method list.
 882
 883 =back
 884
 885 =head2 Method modifiers
 886
 887 These methods act like their counterparts in L<Class::MOP::Class> and
 888 L<Moose::Meta::Class>.
 889
 890 However, method modifiers are simply stored internally, and are not
 891 applied until the role itself is applied to a class.
 892
 893 =over 4
 894
 895 =item B<< $metarole->add_after_method_modifier($method_name, $method) >>
 896
 897 =item B<< $metarole->add_around_method_modifier($method_name, $method) >>
 898
 899 =item B<< $metarole->add_before_method_modifier($method_name, $method) >>
 900
 901 =item B<< $metarole->add_override_method_modifier($method_name, $method) >>
 902
 903 These methods all add an appropriate modifier to the internal list of
 904 modifiers.
 905
 906 =item B<< $metarole->has_after_method_modifiers >>
 907
 908 =item B<< $metarole->has_around_method_modifiers >>
 909
 910 =item B<< $metarole->has_before_method_modifiers >>
 911
 912 =item B<< $metarole->has_override_method_modifier >>
 913
 914 Return true if the role has any modifiers of the given type.
 915
 916 =item B<< $metarole->get_after_method_modifiers($method_name) >>
 917
 918 =item B<< $metarole->get_around_method_modifiers($method_name) >>
 919
 920 =item B<< $metarole->get_before_method_modifiers($method_name) >>
 921
 922 Given a method name, returns a list of the appropriate modifiers for
 923 that method.
 924
 925 =item B<< $metarole->get_override_method_modifier($method_name) >>
 926
 927 Given a method name, returns the override method modifier for that
 928 method, if it has one.
 929
 930 =back
 931
 932 =head2 Introspection
 933
 934 =over 4
 935
 936 =item B<< Moose::Meta::Role->meta >>
 937
 938 This will return a L<Class::MOP::Class> instance for this class.
 939
 940 =back
 941
 942 =head1 BUGS
 943
 944 See L<Moose/BUGS> for details on reporting bugs.
 945
 946 =head1 AUTHOR
 947
 948 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 949
 950 =head1 COPYRIGHT AND LICENSE
 951
 952 Copyright 2006-2010 by Infinity Interactive, Inc.
 953
 954 L<http://www.iinteractive.com>
 955
 956 This library is free software; you can redistribute it and/or modify
 957 it under the same terms as Perl itself.
 958
 959 =cut