lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Scalar::Util 'blessed';
   9 use Carp         'confess';
  10 use Devel::GlobalDestruction 'in_global_destruction';
  11
  12 our $VERSION   = '1.16';
  13 $VERSION = eval $VERSION;
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 use Moose::Meta::Class;
  17 use Moose::Meta::Role::Attribute;
  18 use Moose::Meta::Role::Method;
  19 use Moose::Meta::Role::Method::Required;
  20 use Moose::Meta::Role::Method::Conflicting;
  21 use Moose::Meta::Method::Meta;
  22 use Moose::Util qw( ensure_all_roles );
  23 use Class::MOP::MiniTrait;
  24
  25 use base 'Class::MOP::Module',
  26          'Class::MOP::Mixin::HasAttributes',
  27          'Class::MOP::Mixin::HasMethods';
  28
  29 Class::MOP::MiniTrait::apply(__PACKAGE__, 'Moose::Meta::Object::Trait');
  30
  31 ## ------------------------------------------------------------------
  32 ## NOTE:
  33 ## I normally don't do this, but I am doing
  34 ## a whole bunch of meta-programmin in this
  35 ## module, so it just makes sense. For a clearer
  36 ## picture of what is going on in the next
  37 ## several lines of code, look at the really
  38 ## big comment at the end of this file (right
  39 ## before the POD).
  40 ## - SL
  41 ## ------------------------------------------------------------------
  42
  43 my $META = __PACKAGE__->meta;
  44
  45 ## ------------------------------------------------------------------
  46 ## attributes ...
  47
  48 # NOTE:
  49 # since roles are lazy, we hold all the attributes
  50 # of the individual role in 'statis' until which
  51 # time when it is applied to a class. This means
  52 # keeping a lot of things in hash maps, so we are
  53 # using a little of that meta-programmin' magic
  54 # here an saving lots of extra typin. And since
  55 # many of these attributes above require similar
  56 # functionality to support them, so we again use
  57 # the wonders of meta-programmin' to deliver a
  58 # very compact solution to this normally verbose
  59 # problem.
  60 # - SL
  61
  62 foreach my $action (
  63     {
  64         name        => 'excluded_roles_map',
  65         attr_reader => 'get_excluded_roles_map' ,
  66         methods     => {
  67             add       => 'add_excluded_roles',
  68             get_keys  => 'get_excluded_roles_list',
  69             existence => 'excludes_role',
  70         }
  71     },
  72     {
  73         name        => 'required_methods',
  74         attr_reader => 'get_required_methods_map',
  75         methods     => {
  76             remove     => 'remove_required_methods',
  77             get_values => 'get_required_method_list',
  78             existence  => 'requires_method',
  79         }
  80     },
  81 ) {
  82
  83     my $attr_reader = $action->{attr_reader};
  84     my $methods     = $action->{methods};
  85
  86     # create the attribute
  87     $META->add_attribute($action->{name} => (
  88         reader  => $attr_reader,
  89         default => sub { {} }
  90     ));
  91
  92     # create some helper methods
  93     $META->add_method($methods->{add} => sub {
  94         my ($self, @values) = @_;
  95         $self->$attr_reader->{$_} = undef foreach @values;
  96     }) if exists $methods->{add};
  97
  98     $META->add_method($methods->{get_keys} => sub {
  99         my ($self) = @_;
 100         keys %{$self->$attr_reader};
 101     }) if exists $methods->{get_keys};
 102
 103     $META->add_method($methods->{get_values} => sub {
 104         my ($self) = @_;
 105         values %{$self->$attr_reader};
 106     }) if exists $methods->{get_values};
 107
 108     $META->add_method($methods->{get} => sub {
 109         my ($self, $name) = @_;
 110         $self->$attr_reader->{$name}
 111     }) if exists $methods->{get};
 112
 113     $META->add_method($methods->{existence} => sub {
 114         my ($self, $name) = @_;
 115         exists $self->$attr_reader->{$name} ? 1 : 0;
 116     }) if exists $methods->{existence};
 117
 118     $META->add_method($methods->{remove} => sub {
 119         my ($self, @values) = @_;
 120         delete $self->$attr_reader->{$_} foreach @values;
 121     }) if exists $methods->{remove};
 122 }
 123
 124 $META->add_attribute(
 125     'method_metaclass',
 126     reader  => 'method_metaclass',
 127     default => 'Moose::Meta::Role::Method',
 128 );
 129
 130 $META->add_attribute(
 131     'required_method_metaclass',
 132     reader  => 'required_method_metaclass',
 133     default => 'Moose::Meta::Role::Method::Required',
 134 );
 135
 136 $META->add_attribute(
 137     'conflicting_method_metaclass',
 138     reader  => 'conflicting_method_metaclass',
 139     default => 'Moose::Meta::Role::Method::Conflicting',
 140 );
 141
 142 $META->add_attribute(
 143     'application_to_class_class',
 144     reader  => 'application_to_class_class',
 145     default => 'Moose::Meta::Role::Application::ToClass',
 146 );
 147
 148 $META->add_attribute(
 149     'application_to_role_class',
 150     reader  => 'application_to_role_class',
 151     default => 'Moose::Meta::Role::Application::ToRole',
 152 );
 153
 154 $META->add_attribute(
 155     'application_to_instance_class',
 156     reader  => 'application_to_instance_class',
 157     default => 'Moose::Meta::Role::Application::ToInstance',
 158 );
 159
 160 # More or less copied from Moose::Meta::Class
 161 sub initialize {
 162     my $class = shift;
 163     my $pkg   = shift;
 164
 165     if (defined(my $meta = Class::MOP::get_metaclass_by_name($pkg))) {
 166         return $meta;
 167     }
 168
 169     my %options = @_;
 170
 171     my $meta = $class->SUPER::initialize(
 172         $pkg,
 173         'attribute_metaclass' => 'Moose::Meta::Role::Attribute',
 174         %options,
 175     );
 176
 177     Class::MOP::weaken_metaclass($pkg) if $options{weaken};
 178
 179     return $meta;
 180 }
 181
 182 sub reinitialize {
 183     my $self = shift;
 184     my $pkg  = shift;
 185
 186     my $meta = blessed $pkg ? $pkg : Class::MOP::class_of($pkg);
 187
 188     my %existing_classes;
 189     if ($meta) {
 190         %existing_classes = map { $_ => $meta->$_() } qw(
 191             attribute_metaclass
 192             method_metaclass
 193             wrapped_method_metaclass
 194             required_method_metaclass
 195             conflicting_method_metaclass
 196             application_to_class_class
 197             application_to_role_class
 198             application_to_instance_class
 199         );
 200     }
 201
 202     my %options = @_;
 203     $options{weaken} = Class::MOP::metaclass_is_weak($meta->name)
 204         if !exists $options{weaken}
 205         && blessed($meta)
 206         && $meta->isa('Moose::Meta::Role');
 207
 208     # don't need to remove generated metaobjects here yet, since we don't
 209     # yet generate anything in roles. this may change in the future though...
 210     # keep an eye on that
 211     my $new_meta = $self->SUPER::reinitialize(
 212         $pkg,
 213         %existing_classes,
 214         %options,
 215     );
 216     $new_meta->_restore_metaobjects_from($meta)
 217         if $meta && $meta->isa('Moose::Meta::Role');
 218     return $new_meta;
 219 }
 220
 221 sub _restore_metaobjects_from {
 222     my $self = shift;
 223     my ($old_meta) = @_;
 224
 225     $self->_restore_metamethods_from($old_meta);
 226     $self->_restore_metaattributes_from($old_meta);
 227 }
 228
 229 sub add_attribute {
 230     my $self = shift;
 231
 232     if (blessed $_[0] && ! $_[0]->isa('Moose::Meta::Role::Attribute') ) {
 233         my $class = ref $_[0];
 234         Moose->throw_error( "Cannot add a $class as an attribute to a role" );
 235     }
 236     elsif (!blessed($_[0]) && defined($_[0]) && $_[0] =~ /^\+(.*)/) {
 237         Moose->throw_error( "has '+attr' is not supported in roles" );
 238     }
 239
 240     return $self->SUPER::add_attribute(@_);
 241 }
 242
 243 sub _attach_attribute {
 244     my ( $self, $attribute ) = @_;
 245
 246     $attribute->attach_to_role($self);
 247 }
 248
 249 sub add_required_methods {
 250     my $self = shift;
 251
 252     for (@_) {
 253         my $method = $_;
 254         if (!blessed($method)) {
 255             $method = $self->required_method_metaclass->new(
 256                 name => $method,
 257             );
 258         }
 259         $self->get_required_methods_map->{$method->name} = $method;
 260     }
 261 }
 262
 263 sub add_conflicting_method {
 264     my $self = shift;
 265
 266     my $method;
 267     if (@_ == 1 && blessed($_[0])) {
 268         $method = shift;
 269     }
 270     else {
 271         $method = $self->conflicting_method_metaclass->new(@_);
 272     }
 273
 274     $self->add_required_methods($method);
 275 }
 276
 277 ## ------------------------------------------------------------------
 278 ## method modifiers
 279
 280 # NOTE:
 281 # the before/around/after method modifiers are
 282 # stored by name, but there can be many methods
 283 # then associated with that name. So again we have
 284 # lots of similar functionality, so we can do some
 285 # meta-programmin' and save some time.
 286 # - SL
 287
 288 foreach my $modifier_type (qw[ before around after ]) {
 289
 290     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 291
 292     # create the attribute ...
 293     $META->add_attribute("${modifier_type}_method_modifiers" => (
 294         reader  => $attr_reader,
 295         default => sub { {} }
 296     ));
 297
 298     # and some helper methods ...
 299     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 300         my ($self, $method_name) = @_;
 301         #return () unless exists $self->$attr_reader->{$method_name};
 302         my $mm = $self->$attr_reader->{$method_name};
 303         $mm ? @$mm : ();
 304     });
 305
 306     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 307         my ($self, $method_name) = @_;
 308         # NOTE:
 309         # for now we assume that if it exists,..
 310         # it has at least one modifier in it
 311         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 312     });
 313
 314     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 315         my ($self, $method_name, $method) = @_;
 316
 317         $self->$attr_reader->{$method_name} = []
 318             unless exists $self->$attr_reader->{$method_name};
 319
 320         my $modifiers = $self->$attr_reader->{$method_name};
 321
 322         # NOTE:
 323         # check to see that we aren't adding the
 324         # same code twice. We err in favor of the
 325         # first on here, this may not be as expected
 326         foreach my $modifier (@{$modifiers}) {
 327             return if $modifier == $method;
 328         }
 329
 330         push @{$modifiers} => $method;
 331     });
 332
 333 }
 334
 335 ## ------------------------------------------------------------------
 336 ## override method mofidiers
 337
 338 $META->add_attribute('override_method_modifiers' => (
 339     reader  => 'get_override_method_modifiers_map',
 340     default => sub { {} }
 341 ));
 342
 343 # NOTE:
 344 # these are a little different because there
 345 # can only be one per name, whereas the other
 346 # method modifiers can have multiples.
 347 # - SL
 348
 349 sub add_override_method_modifier {
 350     my ($self, $method_name, $method) = @_;
 351     (!$self->has_method($method_name))
 352         || Moose->throw_error("Cannot add an override of method '$method_name' " .
 353                    "because there is a local version of '$method_name'");
 354     $self->get_override_method_modifiers_map->{$method_name} = $method;
 355 }
 356
 357 sub has_override_method_modifier {
 358     my ($self, $method_name) = @_;
 359     # NOTE:
 360     # for now we assume that if it exists,..
 361     # it has at least one modifier in it
 362     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 363 }
 364
 365 sub get_override_method_modifier {
 366     my ($self, $method_name) = @_;
 367     $self->get_override_method_modifiers_map->{$method_name};
 368 }
 369
 370 ## general list accessor ...
 371
 372 sub get_method_modifier_list {
 373     my ($self, $modifier_type) = @_;
 374     my $accessor = "get_${modifier_type}_method_modifiers_map";
 375     keys %{$self->$accessor};
 376 }
 377
 378 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 379 sub update_package_cache_flag {
 380     my $self = shift;
 381     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 382 }
 383
 384
 385 sub _meta_method_class { 'Moose::Meta::Method::Meta' }
 386
 387 ## ------------------------------------------------------------------
 388 ## subroles
 389
 390 $META->add_attribute('roles' => (
 391     reader  => 'get_roles',
 392     default => sub { [] }
 393 ));
 394
 395 sub add_role {
 396     my ($self, $role) = @_;
 397     (blessed($role) && $role->isa('Moose::Meta::Role'))
 398         || Moose->throw_error("Roles must be instances of Moose::Meta::Role");
 399     push @{$self->get_roles} => $role;
 400     $self->reset_package_cache_flag;
 401 }
 402
 403 sub calculate_all_roles {
 404     my $self = shift;
 405     my %seen;
 406     grep {
 407         !$seen{$_->name}++
 408     } ($self, map {
 409                   $_->calculate_all_roles
 410               } @{ $self->get_roles });
 411 }
 412
 413 sub does_role {
 414     my ($self, $role) = @_;
 415     (defined $role)
 416         || Moose->throw_error("You must supply a role name to look for");
 417     my $role_name = blessed $role ? $role->name : $role;
 418     # if we are it,.. then return true
 419     return 1 if $role_name eq $self->name;
 420     # otherwise.. check our children
 421     foreach my $role (@{$self->get_roles}) {
 422         return 1 if $role->does_role($role_name);
 423     }
 424     return 0;
 425 }
 426
 427 sub find_method_by_name { (shift)->get_method(@_) }
 428
 429 ## ------------------------------------------------------------------
 430 ## role construction
 431 ## ------------------------------------------------------------------
 432
 433 sub apply {
 434     my ($self, $other, %args) = @_;
 435
 436     (blessed($other))
 437         || Moose->throw_error("You must pass in an blessed instance");
 438
 439     my $application_class;
 440     if ($other->isa('Moose::Meta::Role')) {
 441         $application_class = $self->application_to_role_class;
 442     }
 443     elsif ($other->isa('Moose::Meta::Class')) {
 444         $application_class = $self->application_to_class_class;
 445     }
 446     else {
 447         $application_class = $self->application_to_instance_class;
 448     }
 449
 450     Class::MOP::load_class($application_class);
 451     return $application_class->new(%args)->apply($self, $other, \%args);
 452 }
 453
 454 sub composition_class_roles { }
 455
 456 sub combine {
 457     my ($class, @role_specs) = @_;
 458
 459     require Moose::Meta::Role::Composite;
 460
 461     my (@roles, %role_params);
 462     while (@role_specs) {
 463         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 464         my $requested_role
 465             = blessed $role
 466             ? $role
 467             : Class::MOP::class_of($role);
 468
 469         my $actual_role = $requested_role->_role_for_combination($params);
 470         push @roles => $actual_role;
 471
 472         next unless defined $params;
 473         $role_params{$actual_role->name} = $params;
 474     }
 475
 476     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 477     return $c->apply_params(\%role_params);
 478 }
 479
 480 sub _role_for_combination {
 481     my ($self, $params) = @_;
 482     return $self;
 483 }
 484
 485 sub create {
 486     my ( $role, $package_name, %options ) = @_;
 487
 488     $options{package} = $package_name;
 489
 490     (ref $options{attributes} eq 'HASH')
 491         || confess "You must pass a HASH ref of attributes"
 492             if exists $options{attributes};
 493
 494     (ref $options{methods} eq 'HASH')
 495         || confess "You must pass a HASH ref of methods"
 496             if exists $options{methods};
 497
 498     $options{meta_name} = 'meta'
 499         unless exists $options{meta_name};
 500
 501     my (%initialize_options) = %options;
 502     delete @initialize_options{qw(
 503         package
 504         attributes
 505         methods
 506         meta_name
 507         version
 508         authority
 509     )};
 510
 511     my $meta = $role->initialize( $package_name => %initialize_options );
 512
 513     $meta->_instantiate_module( $options{version}, $options{authority} );
 514
 515     $meta->_add_meta_method($options{meta_name})
 516         if defined $options{meta_name};
 517
 518     if (exists $options{attributes}) {
 519         foreach my $attribute_name (keys %{$options{attributes}}) {
 520             my $attr = $options{attributes}->{$attribute_name};
 521             $meta->add_attribute(
 522                 $attribute_name => blessed $attr ? $attr : %{$attr} );
 523         }
 524     }
 525
 526     if (exists $options{methods}) {
 527         foreach my $method_name (keys %{$options{methods}}) {
 528             $meta->add_method($method_name, $options{methods}->{$method_name});
 529         }
 530     }
 531
 532     return $meta;
 533 }
 534
 535 sub consumers {
 536     my $self = shift;
 537     my @consumers;
 538     for my $meta (Class::MOP::get_all_metaclass_instances) {
 539         next if $meta->name eq $self->name;
 540         next unless $meta->isa('Moose::Meta::Class')
 541                  || $meta->isa('Moose::Meta::Role');
 542         push @consumers, $meta->name
 543             if $meta->does_role($self->name);
 544     }
 545     return @consumers;
 546 }
 547
 548 # anonymous roles. most of it is copied straight out of Class::MOP::Class.
 549 # an intrepid hacker might find great riches if he unifies this code with that
 550 # code in Class::MOP::Module or Class::MOP::Package
 551 {
 552     # NOTE:
 553     # this should be sufficient, if you have a
 554     # use case where it is not, write a test and
 555     # I will change it.
 556     my $ANON_ROLE_SERIAL = 0;
 557
 558     # NOTE:
 559     # we need a sufficiently annoying prefix
 560     # this should suffice for now, this is
 561     # used in a couple of places below, so
 562     # need to put it up here for now.
 563     my $ANON_ROLE_PREFIX = 'Moose::Meta::Role::__ANON__::SERIAL::';
 564
 565     sub is_anon_role {
 566         my $self = shift;
 567         no warnings 'uninitialized';
 568         $self->name =~ /^$ANON_ROLE_PREFIX/;
 569     }
 570
 571     sub create_anon_role {
 572         my ($role, %options) = @_;
 573         $options{weaken} = 1 unless exists $options{weaken};
 574         my $package_name = $ANON_ROLE_PREFIX . ++$ANON_ROLE_SERIAL;
 575         return $role->create($package_name, %options);
 576     }
 577
 578     # NOTE:
 579     # this will only get called for
 580     # anon-roles, all other calls
 581     # are assumed to occur during
 582     # global destruction and so don't
 583     # really need to be handled explicitly
 584     sub DESTROY {
 585         my $self = shift;
 586
 587         return if in_global_destruction(); # it'll happen soon anyway and this just makes things more complicated
 588
 589         no warnings 'uninitialized';
 590         return unless $self->name =~ /^$ANON_ROLE_PREFIX/;
 591
 592         # XXX: is this necessary for us? I don't understand what it's doing
 593         # -sartak
 594
 595         # Moose does a weird thing where it replaces the metaclass for
 596         # class when fixing metaclass incompatibility. In that case,
 597         # we don't want to clean out the namespace now. We can detect
 598         # that because Moose will explicitly update the singleton
 599         # cache in Class::MOP.
 600         #my $current_meta = Class::MOP::get_metaclass_by_name($self->name);
 601         #return if $current_meta ne $self;
 602
 603         my ($serial_id) = ($self->name =~ /^$ANON_ROLE_PREFIX(\d+)/);
 604         no strict 'refs';
 605         foreach my $key (keys %{$ANON_ROLE_PREFIX . $serial_id}) {
 606             delete ${$ANON_ROLE_PREFIX . $serial_id}{$key};
 607         }
 608         delete ${'main::' . $ANON_ROLE_PREFIX}{$serial_id . '::'};
 609     }
 610 }
 611
 612 #####################################################################
 613 ## NOTE:
 614 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 615 ## MooseX::AttributeHelpers module). It is here as a reference to
 616 ## make it easier to see what is happening above with all the meta
 617 ## programming. - SL
 618 #####################################################################
 619 #
 620 # has 'roles' => (
 621 #     metaclass => 'Array',
 622 #     reader    => 'get_roles',
 623 #     isa       => 'ArrayRef[Moose::Meta::Role]',
 624 #     default   => sub { [] },
 625 #     provides  => {
 626 #         'push' => 'add_role',
 627 #     }
 628 # );
 629 #
 630 # has 'excluded_roles_map' => (
 631 #     metaclass => 'Hash',
 632 #     reader    => 'get_excluded_roles_map',
 633 #     isa       => 'HashRef[Str]',
 634 #     provides  => {
 635 #         # Not exactly set, cause it sets multiple
 636 #         'set'    => 'add_excluded_roles',
 637 #         'keys'   => 'get_excluded_roles_list',
 638 #         'exists' => 'excludes_role',
 639 #     }
 640 # );
 641 #
 642 # has 'required_methods' => (
 643 #     metaclass => 'Hash',
 644 #     reader    => 'get_required_methods_map',
 645 #     isa       => 'HashRef[Moose::Meta::Role::Method::Required]',
 646 #     provides  => {
 647 #         # not exactly set, or delete since it works for multiple
 648 #         'set'    => 'add_required_methods',
 649 #         'delete' => 'remove_required_methods',
 650 #         'keys'   => 'get_required_method_list',
 651 #         'exists' => 'requires_method',
 652 #     }
 653 # );
 654 #
 655 # # the before, around and after modifiers are
 656 # # HASH keyed by method-name, with ARRAY of
 657 # # CODE refs to apply in that order
 658 #
 659 # has 'before_method_modifiers' => (
 660 #     metaclass => 'Hash',
 661 #     reader    => 'get_before_method_modifiers_map',
 662 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 663 #     provides  => {
 664 #         'keys'   => 'get_before_method_modifiers',
 665 #         'exists' => 'has_before_method_modifiers',
 666 #         # This actually makes sure there is an
 667 #         # ARRAY at the given key, and pushed onto
 668 #         # it. It also checks for duplicates as well
 669 #         # 'add'  => 'add_before_method_modifier'
 670 #     }
 671 # );
 672 #
 673 # has 'after_method_modifiers' => (
 674 #     metaclass => 'Hash',
 675 #     reader    =>'get_after_method_modifiers_map',
 676 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 677 #     provides  => {
 678 #         'keys'   => 'get_after_method_modifiers',
 679 #         'exists' => 'has_after_method_modifiers',
 680 #         # This actually makes sure there is an
 681 #         # ARRAY at the given key, and pushed onto
 682 #         # it. It also checks for duplicates as well
 683 #         # 'add'  => 'add_after_method_modifier'
 684 #     }
 685 # );
 686 #
 687 # has 'around_method_modifiers' => (
 688 #     metaclass => 'Hash',
 689 #     reader    =>'get_around_method_modifiers_map',
 690 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 691 #     provides  => {
 692 #         'keys'   => 'get_around_method_modifiers',
 693 #         'exists' => 'has_around_method_modifiers',
 694 #         # This actually makes sure there is an
 695 #         # ARRAY at the given key, and pushed onto
 696 #         # it. It also checks for duplicates as well
 697 #         # 'add'  => 'add_around_method_modifier'
 698 #     }
 699 # );
 700 #
 701 # # override is similar to the other modifiers
 702 # # except that it is not an ARRAY of code refs
 703 # # but instead just a single name->code mapping
 704 #
 705 # has 'override_method_modifiers' => (
 706 #     metaclass => 'Hash',
 707 #     reader    =>'get_override_method_modifiers_map',
 708 #     isa       => 'HashRef[CodeRef]',
 709 #     provides  => {
 710 #         'keys'   => 'get_override_method_modifier',
 711 #         'exists' => 'has_override_method_modifier',
 712 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 713 #     }
 714 # );
 715 #
 716 #####################################################################
 717
 718
 719 1;
 720
 721 __END__
 722
 723 =pod
 724
 725 =head1 NAME
 726
 727 Moose::Meta::Role - The Moose Role metaclass
 728
 729 =head1 DESCRIPTION
 730
 731 This class is a subclass of L<Class::MOP::Module> that provides
 732 additional Moose-specific functionality.
 733
 734 It's API looks a lot like L<Moose::Meta::Class>, but internally it
 735 implements many things differently. This may change in the future.
 736
 737 =head1 INHERITANCE
 738
 739 C<Moose::Meta::Role> is a subclass of L<Class::MOP::Module>.
 740
 741 =head1 METHODS
 742
 743 =head2 Construction
 744
 745 =over 4
 746
 747 =item B<< Moose::Meta::Role->initialize($role_name) >>
 748
 749 This method creates a new role object with the provided name.
 750
 751 =item B<< Moose::Meta::Role->combine( [ $role => { ... } ], [ $role ], ... ) >>
 752
 753 This method accepts a list of array references. Each array reference
 754 should contain a role name or L<Moose::Meta::Role> object as its first element. The second element is
 755 an optional hash reference. The hash reference can contain C<-excludes>
 756 and C<-alias> keys to control how methods are composed from the role.
 757
 758 The return value is a new L<Moose::Meta::Role::Composite> that
 759 represents the combined roles.
 760
 761 =item B<< $metarole->composition_class_roles >>
 762
 763 When combining multiple roles using C<combine>, this method is used to obtain a
 764 list of role names to be applied to the L<Moose::Meta::Role::Composite>
 765 instance returned by C<combine>. The default implementation returns an empty
 766 list. Extensions that need to hook into role combination may wrap this method
 767 to return additional role names.
 768
 769 =item B<< Moose::Meta::Role->create($name, %options) >>
 770
 771 This method is identical to the L<Moose::Meta::Class> C<create>
 772 method.
 773
 774 =item B<< Moose::Meta::Role->create_anon_role >>
 775
 776 This method is identical to the L<Moose::Meta::Class>
 777 C<create_anon_class> method.
 778
 779 =item B<< $metarole->is_anon_role >>
 780
 781 Returns true if the role is an anonymous role.
 782
 783 =item B<< $metarole->consumers >>
 784
 785 Returns a list of names of classes and roles which consume this role.
 786
 787 =back
 788
 789 =head2 Role application
 790
 791 =over 4
 792
 793 =item B<< $metarole->apply( $thing, @options ) >>
 794
 795 This method applies a role to the given C<$thing>. That can be another
 796 L<Moose::Meta::Role>, object, a L<Moose::Meta::Class> object, or a
 797 (non-meta) object instance.
 798
 799 The options are passed directly to the constructor for the appropriate
 800 L<Moose::Meta::Role::Application> subclass.
 801
 802 Note that this will apply the role even if the C<$thing> in question already
 803 C<does> this role.  L<Moose::Util/does_role> is a convenient wrapper for
 804 finding out if role application is necessary.
 805
 806 =back
 807
 808 =head2 Roles and other roles
 809
 810 =over 4
 811
 812 =item B<< $metarole->get_roles >>
 813
 814 This returns an array reference of roles which this role does. This
 815 list may include duplicates.
 816
 817 =item B<< $metarole->calculate_all_roles >>
 818
 819 This returns a I<unique> list of all roles that this role does, and
 820 all the roles that its roles do.
 821
 822 =item B<< $metarole->does_role($role) >>
 823
 824 Given a role I<name> or L<Moose::Meta::Role> object, returns true if this role
 825 does the given role.
 826
 827 =item B<< $metarole->add_role($role) >>
 828
 829 Given a L<Moose::Meta::Role> object, this adds the role to the list of
 830 roles that the role does.
 831
 832 =item B<< $metarole->get_excluded_roles_list >>
 833
 834 Returns a list of role names which this role excludes.
 835
 836 =item B<< $metarole->excludes_role($role_name) >>
 837
 838 Given a role I<name>, returns true if this role excludes the named
 839 role.
 840
 841 =item B<< $metarole->add_excluded_roles(@role_names) >>
 842
 843 Given one or more role names, adds those roles to the list of excluded
 844 roles.
 845
 846 =back
 847
 848 =head2 Methods
 849
 850 The methods for dealing with a role's methods are all identical in API
 851 and behavior to the same methods in L<Class::MOP::Class>.
 852
 853 =over 4
 854
 855 =item B<< $metarole->method_metaclass >>
 856
 857 Returns the method metaclass name for the role. This defaults to
 858 L<Moose::Meta::Role::Method>.
 859
 860 =item B<< $metarole->get_method($name) >>
 861
 862 =item B<< $metarole->has_method($name) >>
 863
 864 =item B<< $metarole->add_method( $name, $body ) >>
 865
 866 =item B<< $metarole->get_method_list >>
 867
 868 =item B<< $metarole->find_method_by_name($name) >>
 869
 870 These methods are all identical to the methods of the same name in
 871 L<Class::MOP::Package>
 872
 873 =back
 874
 875 =head2 Attributes
 876
 877 As with methods, the methods for dealing with a role's attribute are
 878 all identical in API and behavior to the same methods in
 879 L<Class::MOP::Class>.
 880
 881 However, attributes stored in this class are I<not> stored as
 882 objects. Rather, the attribute definition is stored as a hash
 883 reference. When a role is composed into a class, this hash reference
 884 is passed directly to the metaclass's C<add_attribute> method.
 885
 886 This is quite likely to change in the future.
 887
 888 =over 4
 889
 890 =item B<< $metarole->get_attribute($attribute_name) >>
 891
 892 =item B<< $metarole->has_attribute($attribute_name) >>
 893
 894 =item B<< $metarole->get_attribute_list >>
 895
 896 =item B<< $metarole->add_attribute($name, %options) >>
 897
 898 =item B<< $metarole->remove_attribute($attribute_name) >>
 899
 900 =back
 901
 902 =head2 Required methods
 903
 904 =over 4
 905
 906 =item B<< $metarole->get_required_method_list >>
 907
 908 Returns the list of methods required by the role.
 909
 910 =item B<< $metarole->requires_method($name) >>
 911
 912 Returns true if the role requires the named method.
 913
 914 =item B<< $metarole->add_required_methods(@names) >>
 915
 916 Adds the named methods to the role's list of required methods.
 917
 918 =item B<< $metarole->remove_required_methods(@names) >>
 919
 920 Removes the named methods from the role's list of required methods.
 921
 922 =item B<< $metarole->add_conflicting_method(%params) >>
 923
 924 Instantiate the parameters as a L<Moose::Meta::Role::Method::Conflicting>
 925 object, then add it to the required method list.
 926
 927 =back
 928
 929 =head2 Method modifiers
 930
 931 These methods act like their counterparts in L<Class::MOP::Class> and
 932 L<Moose::Meta::Class>.
 933
 934 However, method modifiers are simply stored internally, and are not
 935 applied until the role itself is applied to a class.
 936
 937 =over 4
 938
 939 =item B<< $metarole->add_after_method_modifier($method_name, $method) >>
 940
 941 =item B<< $metarole->add_around_method_modifier($method_name, $method) >>
 942
 943 =item B<< $metarole->add_before_method_modifier($method_name, $method) >>
 944
 945 =item B<< $metarole->add_override_method_modifier($method_name, $method) >>
 946
 947 These methods all add an appropriate modifier to the internal list of
 948 modifiers.
 949
 950 =item B<< $metarole->has_after_method_modifiers >>
 951
 952 =item B<< $metarole->has_around_method_modifiers >>
 953
 954 =item B<< $metarole->has_before_method_modifiers >>
 955
 956 =item B<< $metarole->has_override_method_modifier >>
 957
 958 Return true if the role has any modifiers of the given type.
 959
 960 =item B<< $metarole->get_after_method_modifiers($method_name) >>
 961
 962 =item B<< $metarole->get_around_method_modifiers($method_name) >>
 963
 964 =item B<< $metarole->get_before_method_modifiers($method_name) >>
 965
 966 Given a method name, returns a list of the appropriate modifiers for
 967 that method.
 968
 969 =item B<< $metarole->get_override_method_modifier($method_name) >>
 970
 971 Given a method name, returns the override method modifier for that
 972 method, if it has one.
 973
 974 =back
 975
 976 =head2 Introspection
 977
 978 =over 4
 979
 980 =item B<< Moose::Meta::Role->meta >>
 981
 982 This will return a L<Class::MOP::Class> instance for this class.
 983
 984 =back
 985
 986 =head1 BUGS
 987
 988 See L<Moose/BUGS> for details on reporting bugs.
 989
 990 =head1 AUTHOR
 991
 992 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 993
 994 =head1 COPYRIGHT AND LICENSE
 995
 996 Copyright 2006-2010 by Infinity Interactive, Inc.
 997
 998 L<http://www.iinteractive.com>
 999
1000 This library is free software; you can redistribute it and/or modify
1001 it under the same terms as Perl itself.
1002
1003 =cut