lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Scalar::Util 'blessed';
   9 use Carp         'confess';
  10 use Sub::Name    'subname';
  11 use Devel::GlobalDestruction 'in_global_destruction';
  12
  13 our $VERSION   = '0.81';
  14 $VERSION = eval $VERSION;
  15 our $AUTHORITY = 'cpan:STEVAN';
  16
  17 use Moose::Meta::Class;
  18 use Moose::Meta::Role::Method;
  19 use Moose::Meta::Role::Method::Required;
  20 use Moose::Meta::Role::Method::Conflicting;
  21
  22 use base 'Class::MOP::Module';
  23
  24 ## ------------------------------------------------------------------
  25 ## NOTE:
  26 ## I normally don't do this, but I am doing
  27 ## a whole bunch of meta-programmin in this
  28 ## module, so it just makes sense. For a clearer
  29 ## picture of what is going on in the next
  30 ## several lines of code, look at the really
  31 ## big comment at the end of this file (right
  32 ## before the POD).
  33 ## - SL
  34 ## ------------------------------------------------------------------
  35
  36 my $META = __PACKAGE__->meta;
  37
  38 ## ------------------------------------------------------------------
  39 ## attributes ...
  40
  41 # NOTE:
  42 # since roles are lazy, we hold all the attributes
  43 # of the individual role in 'statis' until which
  44 # time when it is applied to a class. This means
  45 # keeping a lot of things in hash maps, so we are
  46 # using a little of that meta-programmin' magic
  47 # here an saving lots of extra typin. And since
  48 # many of these attributes above require similar
  49 # functionality to support them, so we again use
  50 # the wonders of meta-programmin' to deliver a
  51 # very compact solution to this normally verbose
  52 # problem.
  53 # - SL
  54
  55 foreach my $action (
  56     {
  57         name        => 'excluded_roles_map',
  58         attr_reader => 'get_excluded_roles_map' ,
  59         methods     => {
  60             add       => 'add_excluded_roles',
  61             get_keys  => 'get_excluded_roles_list',
  62             existence => 'excludes_role',
  63         }
  64     },
  65     {
  66         name        => 'required_methods',
  67         attr_reader => 'get_required_methods_map',
  68         methods     => {
  69             remove     => 'remove_required_methods',
  70             get_values => 'get_required_method_list',
  71             existence  => 'requires_method',
  72         }
  73     },
  74     {
  75         name        => 'attribute_map',
  76         attr_reader => 'get_attribute_map',
  77         methods     => {
  78             get       => 'get_attribute',
  79             get_keys  => 'get_attribute_list',
  80             existence => 'has_attribute',
  81             remove    => 'remove_attribute',
  82         }
  83     }
  84 ) {
  85
  86     my $attr_reader = $action->{attr_reader};
  87     my $methods     = $action->{methods};
  88
  89     # create the attribute
  90     $META->add_attribute($action->{name} => (
  91         reader  => $attr_reader,
  92         default => sub { {} }
  93     ));
  94
  95     # create some helper methods
  96     $META->add_method($methods->{add} => sub {
  97         my ($self, @values) = @_;
  98         $self->$attr_reader->{$_} = undef foreach @values;
  99     }) if exists $methods->{add};
 100
 101     $META->add_method($methods->{get_keys} => sub {
 102         my ($self) = @_;
 103         keys %{$self->$attr_reader};
 104     }) if exists $methods->{get_keys};
 105
 106     $META->add_method($methods->{get_values} => sub {
 107         my ($self) = @_;
 108         values %{$self->$attr_reader};
 109     }) if exists $methods->{get_values};
 110
 111     $META->add_method($methods->{get} => sub {
 112         my ($self, $name) = @_;
 113         $self->$attr_reader->{$name}
 114     }) if exists $methods->{get};
 115
 116     $META->add_method($methods->{existence} => sub {
 117         my ($self, $name) = @_;
 118         exists $self->$attr_reader->{$name} ? 1 : 0;
 119     }) if exists $methods->{existence};
 120
 121     $META->add_method($methods->{remove} => sub {
 122         my ($self, @values) = @_;
 123         delete $self->$attr_reader->{$_} foreach @values;
 124     }) if exists $methods->{remove};
 125 }
 126
 127 $META->add_attribute(
 128     'method_metaclass',
 129     reader  => 'method_metaclass',
 130     default => 'Moose::Meta::Role::Method',
 131 );
 132
 133 $META->add_attribute(
 134     'required_method_metaclass',
 135     reader  => 'required_method_metaclass',
 136     default => 'Moose::Meta::Role::Method::Required',
 137 );
 138
 139 $META->add_attribute(
 140     'conflicting_method_metaclass',
 141     reader  => 'conflicting_method_metaclass',
 142     default => 'Moose::Meta::Role::Method::Conflicting',
 143 );
 144
 145 ## some things don't always fit, so they go here ...
 146
 147 sub add_attribute {
 148     my $self = shift;
 149     my $name = shift;
 150     unless ( defined $name && $name ) {
 151         require Moose;
 152         Moose->throw_error("You must provide a name for the attribute");
 153     }
 154     my $attr_desc;
 155     if (scalar @_ == 1 && ref($_[0]) eq 'HASH') {
 156         $attr_desc = $_[0];
 157     }
 158     else {
 159         $attr_desc = { @_ };
 160     }
 161     $self->get_attribute_map->{$name} = $attr_desc;
 162 }
 163
 164 sub add_required_methods {
 165     my $self = shift;
 166
 167     for (@_) {
 168         my $method = $_;
 169         if (!blessed($method)) {
 170             $method = $self->required_method_metaclass->new(
 171                 name => $method,
 172             );
 173         }
 174         $self->get_required_methods_map->{$method->name} = $method;
 175     }
 176 }
 177
 178 sub add_conflicting_method {
 179     my $self = shift;
 180
 181     my $method;
 182     if (@_ == 1 && blessed($_[0])) {
 183         $method = shift;
 184     }
 185     else {
 186         $method = $self->conflicting_method_metaclass->new(@_);
 187     }
 188
 189     $self->add_required_methods($method);
 190 }
 191
 192 ## ------------------------------------------------------------------
 193 ## method modifiers
 194
 195 # NOTE:
 196 # the before/around/after method modifiers are
 197 # stored by name, but there can be many methods
 198 # then associated with that name. So again we have
 199 # lots of similar functionality, so we can do some
 200 # meta-programmin' and save some time.
 201 # - SL
 202
 203 foreach my $modifier_type (qw[ before around after ]) {
 204
 205     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 206
 207     # create the attribute ...
 208     $META->add_attribute("${modifier_type}_method_modifiers" => (
 209         reader  => $attr_reader,
 210         default => sub { {} }
 211     ));
 212
 213     # and some helper methods ...
 214     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 215         my ($self, $method_name) = @_;
 216         #return () unless exists $self->$attr_reader->{$method_name};
 217         @{$self->$attr_reader->{$method_name}};
 218     });
 219
 220     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 221         my ($self, $method_name) = @_;
 222         # NOTE:
 223         # for now we assume that if it exists,..
 224         # it has at least one modifier in it
 225         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 226     });
 227
 228     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 229         my ($self, $method_name, $method) = @_;
 230
 231         $self->$attr_reader->{$method_name} = []
 232             unless exists $self->$attr_reader->{$method_name};
 233
 234         my $modifiers = $self->$attr_reader->{$method_name};
 235
 236         # NOTE:
 237         # check to see that we aren't adding the
 238         # same code twice. We err in favor of the
 239         # first on here, this may not be as expected
 240         foreach my $modifier (@{$modifiers}) {
 241             return if $modifier == $method;
 242         }
 243
 244         push @{$modifiers} => $method;
 245     });
 246
 247 }
 248
 249 ## ------------------------------------------------------------------
 250 ## override method mofidiers
 251
 252 $META->add_attribute('override_method_modifiers' => (
 253     reader  => 'get_override_method_modifiers_map',
 254     default => sub { {} }
 255 ));
 256
 257 # NOTE:
 258 # these are a little different because there
 259 # can only be one per name, whereas the other
 260 # method modifiers can have multiples.
 261 # - SL
 262
 263 sub add_override_method_modifier {
 264     my ($self, $method_name, $method) = @_;
 265     (!$self->has_method($method_name))
 266         || Moose->throw_error("Cannot add an override of method '$method_name' " .
 267                    "because there is a local version of '$method_name'");
 268     $self->get_override_method_modifiers_map->{$method_name} = $method;
 269 }
 270
 271 sub has_override_method_modifier {
 272     my ($self, $method_name) = @_;
 273     # NOTE:
 274     # for now we assume that if it exists,..
 275     # it has at least one modifier in it
 276     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 277 }
 278
 279 sub get_override_method_modifier {
 280     my ($self, $method_name) = @_;
 281     $self->get_override_method_modifiers_map->{$method_name};
 282 }
 283
 284 ## general list accessor ...
 285
 286 sub get_method_modifier_list {
 287     my ($self, $modifier_type) = @_;
 288     my $accessor = "get_${modifier_type}_method_modifiers_map";
 289     keys %{$self->$accessor};
 290 }
 291
 292 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 293 sub update_package_cache_flag {
 294     my $self = shift;
 295     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 296 }
 297
 298
 299
 300 ## ------------------------------------------------------------------
 301 ## subroles
 302
 303 $META->add_attribute('roles' => (
 304     reader  => 'get_roles',
 305     default => sub { [] }
 306 ));
 307
 308 sub add_role {
 309     my ($self, $role) = @_;
 310     (blessed($role) && $role->isa('Moose::Meta::Role'))
 311         || Moose->throw_error("Roles must be instances of Moose::Meta::Role");
 312     push @{$self->get_roles} => $role;
 313     $self->reset_package_cache_flag;
 314 }
 315
 316 sub calculate_all_roles {
 317     my $self = shift;
 318     my %seen;
 319     grep {
 320         !$seen{$_->name}++
 321     } ($self, map {
 322                   $_->calculate_all_roles
 323               } @{ $self->get_roles });
 324 }
 325
 326 sub does_role {
 327     my ($self, $role_name) = @_;
 328     (defined $role_name)
 329         || Moose->throw_error("You must supply a role name to look for");
 330     # if we are it,.. then return true
 331     return 1 if $role_name eq $self->name;
 332     # otherwise.. check our children
 333     foreach my $role (@{$self->get_roles}) {
 334         return 1 if $role->does_role($role_name);
 335     }
 336     return 0;
 337 }
 338
 339 ## ------------------------------------------------------------------
 340 ## methods
 341
 342 sub get_method_map {
 343     my $self = shift;
 344
 345     my $current = Class::MOP::check_package_cache_flag($self->name);
 346
 347     if (defined $self->{'_package_cache_flag'} && $self->{'_package_cache_flag'} == $current) {
 348         return $self->{'methods'} ||= {};
 349     }
 350
 351     $self->{_package_cache_flag} = $current;
 352
 353     my $map  = $self->{'methods'} ||= {};
 354
 355     my $role_name        = $self->name;
 356     my $method_metaclass = $self->method_metaclass;
 357
 358     my $all_code = $self->get_all_package_symbols('CODE');
 359
 360     foreach my $symbol (keys %{ $all_code }) {
 361         my $code = $all_code->{$symbol};
 362
 363         next if exists  $map->{$symbol} &&
 364                 defined $map->{$symbol} &&
 365                         $map->{$symbol}->body == $code;
 366
 367         my ($pkg, $name) = Class::MOP::get_code_info($code);
 368         my $meta = Class::MOP::class_of($pkg);
 369
 370         if ($meta && $meta->isa('Moose::Meta::Role')) {
 371             my $role = $meta->name;
 372             next unless $self->does_role($role);
 373         }
 374         else {
 375             # NOTE:
 376             # in 5.10 constant.pm the constants show up
 377             # as being in the right package, but in pre-5.10
 378             # they show up as constant::__ANON__ so we
 379             # make an exception here to be sure that things
 380             # work as expected in both.
 381             # - SL
 382             unless ($pkg eq 'constant' && $name eq '__ANON__') {
 383                 next if ($pkg  || '') ne $role_name ||
 384                         (($name || '') ne '__ANON__' && ($pkg  || '') ne $role_name);
 385             }
 386         }
 387
 388         $map->{$symbol} = $method_metaclass->wrap(
 389             $code,
 390             package_name => $role_name,
 391             name         => $name
 392         );
 393     }
 394
 395     return $map;
 396 }
 397
 398 sub get_method {
 399     my ($self, $name) = @_;
 400     $self->get_method_map->{$name};
 401 }
 402
 403 sub has_method {
 404     my ($self, $name) = @_;
 405     exists $self->get_method_map->{$name} ? 1 : 0
 406 }
 407
 408 # FIXME this is copy-pasted from Class::MOP::Class
 409 # refactor to inherit from some common base
 410 sub wrap_method_body {
 411     my ( $self, %args ) = @_;
 412
 413     ('CODE' eq ref $args{body})
 414         || Moose->throw_error("Your code block must be a CODE reference");
 415
 416     $self->method_metaclass->wrap(
 417         package_name => $self->name,
 418         %args,
 419     );
 420 }
 421
 422 sub add_method {
 423     my ($self, $method_name, $method) = @_;
 424     (defined $method_name && $method_name)
 425     || Moose->throw_error("You must define a method name");
 426
 427     my $body;
 428     if (blessed($method)) {
 429         $body = $method->body;
 430         if ($method->package_name ne $self->name) {
 431             $method = $method->clone(
 432                 package_name => $self->name,
 433                 name         => $method_name
 434             ) if $method->can('clone');
 435         }
 436     }
 437     else {
 438         $body = $method;
 439         $method = $self->wrap_method_body( body => $body, name => $method_name );
 440     }
 441
 442     $method->attach_to_class($self);
 443
 444     $self->get_method_map->{$method_name} = $method;
 445
 446     my $full_method_name = ($self->name . '::' . $method_name);
 447     $self->add_package_symbol(
 448         { sigil => '&', type => 'CODE', name => $method_name },
 449         subname($full_method_name => $body)
 450     );
 451
 452     $self->update_package_cache_flag; # still valid, since we just added the method to the map, and if it was invalid before that then get_method_map updated it
 453 }
 454
 455 sub find_method_by_name { (shift)->get_method(@_) }
 456
 457 sub get_method_list {
 458     my $self = shift;
 459     grep { !/^meta$/ } keys %{$self->get_method_map};
 460 }
 461
 462 sub alias_method {
 463     Carp::cluck("The alias_method method is deprecated. Use add_method instead.\n");
 464
 465     my $self = shift;
 466
 467     $self->add_method(@_);
 468 }
 469
 470 ## ------------------------------------------------------------------
 471 ## role construction
 472 ## ------------------------------------------------------------------
 473
 474 sub apply {
 475     my ($self, $other, @args) = @_;
 476
 477     (blessed($other))
 478         || Moose->throw_error("You must pass in an blessed instance");
 479
 480     if ($other->isa('Moose::Meta::Role')) {
 481         require Moose::Meta::Role::Application::ToRole;
 482         return Moose::Meta::Role::Application::ToRole->new(@args)->apply($self, $other);
 483     }
 484     elsif ($other->isa('Moose::Meta::Class')) {
 485         require Moose::Meta::Role::Application::ToClass;
 486         return Moose::Meta::Role::Application::ToClass->new(@args)->apply($self, $other);
 487     }
 488     else {
 489         require Moose::Meta::Role::Application::ToInstance;
 490         return Moose::Meta::Role::Application::ToInstance->new(@args)->apply($self, $other);
 491     }
 492 }
 493
 494 sub combine {
 495     my ($class, @role_specs) = @_;
 496
 497     require Moose::Meta::Role::Application::RoleSummation;
 498     require Moose::Meta::Role::Composite;
 499
 500     my (@roles, %role_params);
 501     while (@role_specs) {
 502         my ($role_name, $params) = @{ splice @role_specs, 0, 1 };
 503         my $requested_role = Class::MOP::class_of($role_name);
 504
 505         my $actual_role = $requested_role->_role_for_combination($params);
 506         push @roles => $actual_role;
 507
 508         next unless defined $params;
 509         $role_params{$actual_role->name} = $params;
 510     }
 511
 512     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 513     Moose::Meta::Role::Application::RoleSummation->new(
 514         role_params => \%role_params
 515     )->apply($c);
 516
 517     return $c;
 518 }
 519
 520 sub _role_for_combination {
 521     my ($self, $params) = @_;
 522     return $self;
 523 }
 524
 525 sub create {
 526     my ( $role, $package_name, %options ) = @_;
 527
 528     $options{package} = $package_name;
 529
 530     (ref $options{attributes} eq 'HASH')
 531         || confess "You must pass a HASH ref of attributes"
 532             if exists $options{attributes};
 533
 534     (ref $options{methods} eq 'HASH')
 535         || confess "You must pass a HASH ref of methods"
 536             if exists $options{methods};
 537
 538     my (%initialize_options) = %options;
 539     delete @initialize_options{qw(
 540         package
 541         attributes
 542         methods
 543         version
 544         authority
 545     )};
 546
 547     my $meta = $role->initialize( $package_name => %initialize_options );
 548
 549     $meta->_instantiate_module( $options{version}, $options{authority} );
 550
 551     # FIXME totally lame
 552     $meta->add_method('meta' => sub {
 553         $role->initialize(ref($_[0]) || $_[0]);
 554     });
 555
 556     if (exists $options{attributes}) {
 557         foreach my $attribute_name (keys %{$options{attributes}}) {
 558             my $attr = $options{attributes}->{$attribute_name};
 559             $meta->add_attribute($attribute_name => $attr);
 560         }
 561     }
 562
 563     if (exists $options{methods}) {
 564         foreach my $method_name (keys %{$options{methods}}) {
 565             $meta->add_method($method_name, $options{methods}->{$method_name});
 566         }
 567     }
 568
 569     Class::MOP::weaken_metaclass($meta->name)
 570         if $meta->is_anon_role;
 571
 572     return $meta;
 573 }
 574
 575 # anonymous roles. most of it is copied straight out of Class::MOP::Class.
 576 # an intrepid hacker might find great riches if he unifies this code with that
 577 # code in Class::MOP::Module or Class::MOP::Package
 578 {
 579     # NOTE:
 580     # this should be sufficient, if you have a
 581     # use case where it is not, write a test and
 582     # I will change it.
 583     my $ANON_ROLE_SERIAL = 0;
 584
 585     # NOTE:
 586     # we need a sufficiently annoying prefix
 587     # this should suffice for now, this is
 588     # used in a couple of places below, so
 589     # need to put it up here for now.
 590     my $ANON_ROLE_PREFIX = 'Moose::Meta::Role::__ANON__::SERIAL::';
 591
 592     sub is_anon_role {
 593         my $self = shift;
 594         no warnings 'uninitialized';
 595         $self->name =~ /^$ANON_ROLE_PREFIX/;
 596     }
 597
 598     sub create_anon_role {
 599         my ($role, %options) = @_;
 600         my $package_name = $ANON_ROLE_PREFIX . ++$ANON_ROLE_SERIAL;
 601         return $role->create($package_name, %options);
 602     }
 603
 604     # NOTE:
 605     # this will only get called for
 606     # anon-roles, all other calls
 607     # are assumed to occur during
 608     # global destruction and so don't
 609     # really need to be handled explicitly
 610     sub DESTROY {
 611         my $self = shift;
 612
 613         return if in_global_destruction(); # it'll happen soon anyway and this just makes things more complicated
 614
 615         no warnings 'uninitialized';
 616         return unless $self->name =~ /^$ANON_ROLE_PREFIX/;
 617
 618         # XXX: is this necessary for us? I don't understand what it's doing
 619         # -sartak
 620
 621         # Moose does a weird thing where it replaces the metaclass for
 622         # class when fixing metaclass incompatibility. In that case,
 623         # we don't want to clean out the namespace now. We can detect
 624         # that because Moose will explicitly update the singleton
 625         # cache in Class::MOP.
 626         #my $current_meta = Class::MOP::get_metaclass_by_name($self->name);
 627         #return if $current_meta ne $self;
 628
 629         my ($serial_id) = ($self->name =~ /^$ANON_ROLE_PREFIX(\d+)/);
 630         no strict 'refs';
 631         foreach my $key (keys %{$ANON_ROLE_PREFIX . $serial_id}) {
 632             delete ${$ANON_ROLE_PREFIX . $serial_id}{$key};
 633         }
 634         delete ${'main::' . $ANON_ROLE_PREFIX}{$serial_id . '::'};
 635     }
 636 }
 637
 638 #####################################################################
 639 ## NOTE:
 640 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 641 ## MooseX::AttributeHelpers module). It is here as a reference to
 642 ## make it easier to see what is happening above with all the meta
 643 ## programming. - SL
 644 #####################################################################
 645 #
 646 # has 'roles' => (
 647 #     metaclass => 'Collection::Array',
 648 #     reader    => 'get_roles',
 649 #     isa       => 'ArrayRef[Moose::Meta::Role]',
 650 #     default   => sub { [] },
 651 #     provides  => {
 652 #         'push' => 'add_role',
 653 #     }
 654 # );
 655 #
 656 # has 'excluded_roles_map' => (
 657 #     metaclass => 'Collection::Hash',
 658 #     reader    => 'get_excluded_roles_map',
 659 #     isa       => 'HashRef[Str]',
 660 #     provides  => {
 661 #         # Not exactly set, cause it sets multiple
 662 #         'set'    => 'add_excluded_roles',
 663 #         'keys'   => 'get_excluded_roles_list',
 664 #         'exists' => 'excludes_role',
 665 #     }
 666 # );
 667 #
 668 # has 'attribute_map' => (
 669 #     metaclass => 'Collection::Hash',
 670 #     reader    => 'get_attribute_map',
 671 #     isa       => 'HashRef[Str]',
 672 #     provides => {
 673 #         # 'set'  => 'add_attribute' # has some special crap in it
 674 #         'get'    => 'get_attribute',
 675 #         'keys'   => 'get_attribute_list',
 676 #         'exists' => 'has_attribute',
 677 #         # Not exactly delete, cause it sets multiple
 678 #         'delete' => 'remove_attribute',
 679 #     }
 680 # );
 681 #
 682 # has 'required_methods' => (
 683 #     metaclass => 'Collection::Hash',
 684 #     reader    => 'get_required_methods_map',
 685 #     isa       => 'HashRef[Moose::Meta::Role::Method::Required]',
 686 #     provides  => {
 687 #         # not exactly set, or delete since it works for multiple
 688 #         'set'    => 'add_required_methods',
 689 #         'delete' => 'remove_required_methods',
 690 #         'keys'   => 'get_required_method_list',
 691 #         'exists' => 'requires_method',
 692 #     }
 693 # );
 694 #
 695 # # the before, around and after modifiers are
 696 # # HASH keyed by method-name, with ARRAY of
 697 # # CODE refs to apply in that order
 698 #
 699 # has 'before_method_modifiers' => (
 700 #     metaclass => 'Collection::Hash',
 701 #     reader    => 'get_before_method_modifiers_map',
 702 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 703 #     provides  => {
 704 #         'keys'   => 'get_before_method_modifiers',
 705 #         'exists' => 'has_before_method_modifiers',
 706 #         # This actually makes sure there is an
 707 #         # ARRAY at the given key, and pushed onto
 708 #         # it. It also checks for duplicates as well
 709 #         # 'add'  => 'add_before_method_modifier'
 710 #     }
 711 # );
 712 #
 713 # has 'after_method_modifiers' => (
 714 #     metaclass => 'Collection::Hash',
 715 #     reader    =>'get_after_method_modifiers_map',
 716 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 717 #     provides  => {
 718 #         'keys'   => 'get_after_method_modifiers',
 719 #         'exists' => 'has_after_method_modifiers',
 720 #         # This actually makes sure there is an
 721 #         # ARRAY at the given key, and pushed onto
 722 #         # it. It also checks for duplicates as well
 723 #         # 'add'  => 'add_after_method_modifier'
 724 #     }
 725 # );
 726 #
 727 # has 'around_method_modifiers' => (
 728 #     metaclass => 'Collection::Hash',
 729 #     reader    =>'get_around_method_modifiers_map',
 730 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 731 #     provides  => {
 732 #         'keys'   => 'get_around_method_modifiers',
 733 #         'exists' => 'has_around_method_modifiers',
 734 #         # This actually makes sure there is an
 735 #         # ARRAY at the given key, and pushed onto
 736 #         # it. It also checks for duplicates as well
 737 #         # 'add'  => 'add_around_method_modifier'
 738 #     }
 739 # );
 740 #
 741 # # override is similar to the other modifiers
 742 # # except that it is not an ARRAY of code refs
 743 # # but instead just a single name->code mapping
 744 #
 745 # has 'override_method_modifiers' => (
 746 #     metaclass => 'Collection::Hash',
 747 #     reader    =>'get_override_method_modifiers_map',
 748 #     isa       => 'HashRef[CodeRef]',
 749 #     provides  => {
 750 #         'keys'   => 'get_override_method_modifier',
 751 #         'exists' => 'has_override_method_modifier',
 752 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 753 #     }
 754 # );
 755 #
 756 #####################################################################
 757
 758
 759 1;
 760
 761 __END__
 762
 763 =pod
 764
 765 =head1 NAME
 766
 767 Moose::Meta::Role - The Moose Role metaclass
 768
 769 =head1 DESCRIPTION
 770
 771 This class is a subclass of L<Class::MOP::Module> that provides
 772 additional Moose-specific functionality.
 773
 774 It's API looks a lot like L<Moose::Meta::Class>, but internally it
 775 implements many things differently. This may change in the future.
 776
 777 =head1 INHERITANCE
 778
 779 C<Moose::Meta::Role> is a subclass of L<Class::MOP::Module>.
 780
 781 =head1 METHODS
 782
 783 =head2 Construction
 784
 785 =over 4
 786
 787 =item B<< Moose::Meta::Role->initialize($role_name) >>
 788
 789 This method creates a new role object with the provided name.
 790
 791 =item B<< Moose::Meta::Role->combine( [ $role => { ... } ], [ $role ], ... ) >>
 792
 793 This method accepts a list of array references. Each array reference
 794 should contain a role name as its first element. The second element is
 795 an optional hash reference. The hash reference can contain C<exclude>
 796 and C<alias> keys to control how methods are composed from the role.
 797
 798 The return value is a new L<Moose::Meta::Role::Composite> that
 799 represents the combined roles.
 800
 801 =item B<< Moose::Meta::Role->create($name, %options) >>
 802
 803 This method is identical to the L<Moose::Meta::Class> C<create>
 804 method.
 805
 806 =item B<< Moose::Meta::Role->create_anon_role >>
 807
 808 This method is identical to the L<Moose::Meta::Class>
 809 C<create_anon_class> method.
 810
 811 =item B<< $metarole->is_anon_role >>
 812
 813 Returns true if the role is an anonymous role.
 814
 815 =back
 816
 817 =head2 Role application
 818
 819 =over 4
 820
 821 =item B<< $metarole->apply( $thing, @options ) >>
 822
 823 This method applies a role to the given C<$thing>. That can be another
 824 L<Moose::Meta::Role>, object, a L<Moose::Meta::Class> object, or a
 825 (non-meta) object instance.
 826
 827 The options are passed directly to the constructor for the appropriate
 828 L<Moose::Meta::Role::Application> subclass.
 829
 830 Note that this will apply the role even if the C<$thing> in question already
 831 C<does> this role.  L<Moose::Util/does_role> is a convenient wrapper for
 832 finding out if role application is necessary.
 833
 834 =back
 835
 836 =head2 Roles and other roles
 837
 838 =over 4
 839
 840 =item B<< $metarole->get_roles >>
 841
 842 This returns an array reference of roles which this role does. This
 843 list may include duplicates.
 844
 845 =item B<< $metarole->calculate_all_roles >>
 846
 847 This returns a I<unique> list of all roles that this role does, and
 848 all the roles that its roles do.
 849
 850 =item B<< $metarole->does_role($role_name) >>
 851
 852 Given a role I<name>, returns true if this role does the given
 853 role.
 854
 855 =item B<< $metarole->add_role($role) >>
 856
 857 Given a L<Moose::Meta::Role> object, this adds the role to the list of
 858 roles that the role does.
 859
 860 =item B<< $metarole->get_excluded_roles_list >>
 861
 862 Returns a list of role names which this role excludes.
 863
 864 =item B<< $metarole->excludes_role($role_name) >>
 865
 866 Given a role I<name>, returns true if this role excludes the named
 867 role.
 868
 869 =item B<< $metarole->add_excluded_roles(@role_names) >>
 870
 871 Given one or more role names, adds those roles to the list of excluded
 872 roles.
 873
 874 =back
 875
 876 =head2 Methods
 877
 878 The methods for dealing with a role's methods are all identical in API
 879 and behavior to the same methods in L<Class::MOP::Class>.
 880
 881 =over 4
 882
 883 =item B<< $metarole->method_metaclass >>
 884
 885 Returns the method metaclass name for the role. This defaults to
 886 L<Moose::Meta::Role::Method>.
 887
 888 =item B<< $metarole->get_method($name) >>
 889
 890 =item B<< $metarole->has_method($name) >>
 891
 892 =item B<< $metarole->add_method( $name, $body ) >>
 893
 894 =item B<< $metarole->get_method_list >>
 895
 896 =item B<< $metarole->get_method_map >>
 897
 898 =item B<< $metarole->find_method_by_name($name) >>
 899
 900 These methods are all identical to the methods of the same name in
 901 L<Class::MOP::Class>
 902
 903 =back
 904
 905 =head2 Attributes
 906
 907 As with methods, the methods for dealing with a role's attribute are
 908 all identical in API and behavior to the same methods in
 909 L<Class::MOP::Class>.
 910
 911 However, attributes stored in this class are I<not> stored as
 912 objects. Rather, the attribute definition is stored as a hash
 913 reference. When a role is composed into a class, this hash reference
 914 is passed directly to the metaclass's C<add_attribute> method.
 915
 916 This is quite likely to change in the future.
 917
 918 =over 4
 919
 920 =item B<< $metarole->get_attribute($attribute_name) >>
 921
 922 =item B<< $metarole->has_attribute($attribute_name) >>
 923
 924 =item B<< $metarole->get_attribute_map >>
 925
 926 =item B<< $metarole->get_attribute_list >>
 927
 928 =item B<< $metarole->add_attribute($name, %options) >>
 929
 930 =item B<< $metarole->remove_attribute($attribute_name) >>
 931
 932 =back
 933
 934 =head2 Required methods
 935
 936 =over 4
 937
 938 =item B<< $metarole->get_required_method_list >>
 939
 940 Returns the list of methods required by the role.
 941
 942 =item B<< $metarole->requires_method($name) >>
 943
 944 Returns true if the role requires the named method.
 945
 946 =item B<< $metarole->add_required_methods(@names) >>
 947
 948 Adds the named methods to the role's list of required methods.
 949
 950 =item B<< $metarole->remove_required_methods(@names) >>
 951
 952 Removes the named methods from the role's list of required methods.
 953
 954 =item B<< $metarole->add_conflicting_method(%params) >>
 955
 956 Instantiate the parameters as a L<Moose::Meta::Role::Method::Conflicting>
 957 object, then add it to the required method list.
 958
 959 =back
 960
 961 =head2 Method modifiers
 962
 963 These methods act like their counterparts in L<Class::Mop::Class> and
 964 L<Moose::Meta::Class>.
 965
 966 However, method modifiers are simply stored internally, and are not
 967 applied until the role itself is applied to a class.
 968
 969 =over 4
 970
 971 =item B<< $metarole->add_after_method_modifier($method_name, $method) >>
 972
 973 =item B<< $metarole->add_around_method_modifier($method_name, $method) >>
 974
 975 =item B<< $metarole->add_before_method_modifier($method_name, $method) >>
 976
 977 =item B<< $metarole->add_override_method_modifier($method_name, $method) >>
 978
 979 These methods all add an appropriate modifier to the internal list of
 980 modifiers.
 981
 982 =item B<< $metarole->has_after_method_modifiers >>
 983
 984 =item B<< $metarole->has_around_method_modifiers >>
 985
 986 =item B<< $metarole->has_before_method_modifiers >>
 987
 988 =item B<< $metarole->has_override_method_modifier >>
 989
 990 Return true if the role has any modifiers of the given type.
 991
 992 =item B<< $metarole->get_after_method_modifiers($method_name) >>
 993
 994 =item B<< $metarole->get_around_method_modifiers($method_name) >>
 995
 996 =item B<< $metarole->get_before_method_modifiers($method_name) >>
 997
 998 Given a method name, returns a list of the appropriate modifiers for
 999 that method.
1000
1001 =item B<< $metarole->get_override_method_modifier($method_name) >>
1002
1003 Given a method name, returns the override method modifier for that
1004 method, if it has one.
1005
1006 =back
1007
1008 =head2 Introspection
1009
1010 =over 4
1011
1012 =item B<< Moose::Meta::Role->meta >>
1013
1014 This will return a L<Class::MOP::Class> instance for this class.
1015
1016 =back
1017
1018 =head1 BUGS
1019
1020 All complex software has bugs lurking in it, and this module is no
1021 exception. If you find a bug please either email me, or add the bug
1022 to cpan-RT.
1023
1024 =head1 AUTHOR
1025
1026 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1027
1028 =head1 COPYRIGHT AND LICENSE
1029
1030 Copyright 2006-2009 by Infinity Interactive, Inc.
1031
1032 L<http://www.iinteractive.com>
1033
1034 This library is free software; you can redistribute it and/or modify
1035 it under the same terms as Perl itself.
1036
1037 =cut