lib/Moose/Meta/Role/Application/ToRole.pm

   1 package Moose::Meta::Role::Application::ToRole;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util    'blessed';
   8
   9 our $VERSION   = '0.90';
  10 $VERSION = eval $VERSION;
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::Role::Application';
  14
  15 sub apply {
  16     my ($self, $role1, $role2) = @_;
  17     $self->SUPER::apply($role1, $role2);
  18     $role2->add_role($role1);
  19 }
  20
  21 sub check_role_exclusions {
  22     my ($self, $role1, $role2) = @_;
  23     if ( $role2->excludes_role($role1->name) ) {
  24         require Moose;
  25         Moose->throw_error("Conflict detected: " . $role2->name . " excludes role '" . $role1->name . "'");
  26     }
  27     foreach my $excluded_role_name ($role1->get_excluded_roles_list) {
  28         if ( $role2->does_role($excluded_role_name) ) {
  29             require Moose;
  30             Moose->throw_error("The class " . $role2->name . " does the excluded role '$excluded_role_name'");
  31         }
  32         $role2->add_excluded_roles($excluded_role_name);
  33     }
  34 }
  35
  36 sub check_required_methods {
  37     my ($self, $role1, $role2) = @_;
  38     foreach my $required_method ($role1->get_required_method_list) {
  39         my $required_method_name = $required_method->name;
  40
  41         next if $self->is_aliased_method($required_method_name);
  42
  43         $role2->add_required_methods($required_method)
  44             unless $role2->find_method_by_name($required_method_name);
  45     }
  46 }
  47
  48 sub check_required_attributes {
  49
  50 }
  51
  52 sub apply_attributes {
  53     my ($self, $role1, $role2) = @_;
  54     foreach my $attribute_name ($role1->get_attribute_list) {
  55         # it if it has one already
  56         if ($role2->has_attribute($attribute_name) &&
  57             # make sure we haven't seen this one already too
  58             $role2->get_attribute($attribute_name) != $role1->get_attribute($attribute_name)) {
  59
  60             require Moose;
  61             Moose->throw_error("Role '" . $role1->name . "' has encountered an attribute conflict " .
  62                     "during composition. This is fatal error and cannot be disambiguated.");
  63         }
  64         else {
  65             $role2->add_attribute(
  66                 $attribute_name,
  67                 $role1->get_attribute($attribute_name)
  68             );
  69         }
  70     }
  71 }
  72
  73 sub apply_methods {
  74     my ($self, $role1, $role2) = @_;
  75     foreach my $method_name ($role1->get_method_list) {
  76         next if $method_name eq 'meta';
  77
  78         unless ( $self->is_method_excluded($method_name) ) {
  79             if (   $role2->has_method($method_name)
  80                 && $role2->get_method($method_name)->body
  81                 != $role1->get_method($method_name)->body ) {
  82
  83                 # method conflicts between roles result in the method becoming
  84                 # a requirement
  85                 $role2->add_conflicting_method(
  86                     name  => $method_name,
  87                     roles => [ $role1->name, $role2->name ],
  88                 );
  89             }
  90             else {
  91                 $role2->add_method(
  92                     $method_name,
  93                     $role1->get_method($method_name)
  94                 );
  95             }
  96         }
  97
  98         if ($self->is_method_aliased($method_name)) {
  99             my $aliased_method_name = $self->get_method_aliases->{$method_name};
 100
 101             if ($role2->has_method($aliased_method_name) &&
 102                 $role2->get_method($aliased_method_name)->body != $role1->get_method($method_name)->body) {
 103
 104                 require Moose;
 105                 Moose->throw_error("Cannot create a method alias if a local method of the same name exists");
 106             }
 107
 108             $role2->add_method(
 109                 $aliased_method_name,
 110                 $role1->get_method($method_name)
 111             );
 112
 113             if (!$role2->has_method($method_name)) {
 114                 $role2->add_required_methods($method_name)
 115                     unless $self->is_method_excluded($method_name);
 116             }
 117         }
 118     }
 119 }
 120
 121 sub apply_override_method_modifiers {
 122     my ($self, $role1, $role2) = @_;
 123     foreach my $method_name ($role1->get_method_modifier_list('override')) {
 124         # it if it has one already then ...
 125         if ($role2->has_method($method_name)) {
 126             # if it is being composed into another role
 127             # we have a conflict here, because you cannot
 128             # combine an overridden method with a locally
 129             # defined one
 130             require Moose;
 131             Moose->throw_error("Role '" . $role1->name . "' has encountered an 'override' method conflict " .
 132                     "during composition (A local method of the same name as been found). This " .
 133                     "is fatal error.");
 134         }
 135         else {
 136             # if we are a role, we need to make sure
 137             # we dont have a conflict with the role
 138             # we are composing into
 139             if ($role2->has_override_method_modifier($method_name) &&
 140                 $role2->get_override_method_modifier($method_name) != $role2->get_override_method_modifier($method_name)) {
 141
 142                 require Moose;
 143                 Moose->throw_error("Role '" . $role1->name . "' has encountered an 'override' method conflict " .
 144                         "during composition (Two 'override' methods of the same name encountered). " .
 145                         "This is fatal error.");
 146             }
 147             else {
 148                 # if there is no conflict,
 149                 # just add it to the role
 150                 $role2->add_override_method_modifier(
 151                     $method_name,
 152                     $role1->get_override_method_modifier($method_name)
 153                 );
 154             }
 155         }
 156     }
 157 }
 158
 159 sub apply_method_modifiers {
 160     my ($self, $modifier_type, $role1, $role2) = @_;
 161     my $add = "add_${modifier_type}_method_modifier";
 162     my $get = "get_${modifier_type}_method_modifiers";
 163     foreach my $method_name ($role1->get_method_modifier_list($modifier_type)) {
 164         $role2->$add(
 165             $method_name,
 166             $_
 167         ) foreach $role1->$get($method_name);
 168     }
 169 }
 170
 171
 172 1;
 173
 174 __END__
 175
 176 =pod
 177
 178 =head1 NAME
 179
 180 Moose::Meta::Role::Application::ToRole - Compose a role into another role
 181
 182 =head1 DESCRIPTION
 183
 184 =head2 METHODS
 185
 186 =over 4
 187
 188 =item B<new>
 189
 190 =item B<meta>
 191
 192 =item B<apply>
 193
 194 =item B<check_role_exclusions>
 195
 196 =item B<check_required_methods>
 197
 198 =item B<check_required_attributes>
 199
 200 =item B<apply_attributes>
 201
 202 =item B<apply_methods>
 203
 204 =item B<apply_method_modifiers>
 205
 206 =item B<apply_override_method_modifiers>
 207
 208 =back
 209
 210 =head1 BUGS
 211
 212 All complex software has bugs lurking in it, and this module is no
 213 exception. If you find a bug please either email me, or add the bug
 214 to cpan-RT.
 215
 216 =head1 AUTHOR
 217
 218 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 219
 220 =head1 COPYRIGHT AND LICENSE
 221
 222 Copyright 2006-2009 by Infinity Interactive, Inc.
 223
 224 L<http://www.iinteractive.com>
 225
 226 This library is free software; you can redistribute it and/or modify
 227 it under the same terms as Perl itself.
 228
 229 =cut
 230