lib/Moose/Meta/Role/Application/ToClass.pm

   1 package Moose::Meta::Role::Application::ToClass;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Carp            'confess';
   8 use Scalar::Util    'blessed';
   9
  10 use Data::Dumper;
  11
  12 our $VERSION   = '0.51';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use base 'Moose::Meta::Role::Application';
  16
  17 sub apply {
  18     my ($self, $role, $class) = @_;
  19     $self->SUPER::apply($role, $class);
  20     $class->add_role($role);
  21 }
  22
  23 sub check_role_exclusions {
  24     my ($self, $role, $class) = @_;
  25     if ($class->excludes_role($role->name)) {
  26         confess "Conflict detected: " . $class->name . " excludes role '" . $role->name . "'";
  27     }
  28     foreach my $excluded_role_name ($role->get_excluded_roles_list) {
  29         if ($class->does_role($excluded_role_name)) {
  30             confess "The class " . $class->name . " does the excluded role '$excluded_role_name'";
  31         }
  32     }
  33 }
  34
  35 sub check_required_methods {
  36     my ($self, $role, $class) = @_;
  37     # NOTE:
  38     # we might need to move this down below the
  39     # the attributes so that we can require any
  40     # attribute accessors. However I am thinking
  41     # that maybe those are somehow exempt from
  42     # the require methods stuff.
  43     foreach my $required_method_name ($role->get_required_method_list) {
  44
  45         if (!$class->find_method_by_name($required_method_name)) {
  46
  47             next if $self->is_aliased_method($required_method_name);
  48
  49             confess "'" . $role->name . "' requires the method '$required_method_name' " .
  50                     "to be implemented by '" . $class->name . "'";
  51         }
  52         else {
  53             # NOTE:
  54             # we need to make sure that the method is
  55             # not a method modifier, because those do
  56             # not satisfy the requirements ...
  57             my $method = $class->find_method_by_name($required_method_name);
  58
  59             # check if it is a generated accessor ...
  60             (!$method->isa('Class::MOP::Method::Accessor'))
  61                 || confess "'" . $role->name . "' requires the method '$required_method_name' " .
  62                            "to be implemented by '" . $class->name . "', the method is only an attribute accessor";
  63
  64             # NOTE:
  65             # All other tests here have been removed, they were tests
  66             # for overriden methods and before/after/around modifiers.
  67             # But we realized that for classes any overriden or modified
  68             # methods would be backed by a real method of that name
  69             # (and therefore meet the requirement). And for roles, the
  70             # overriden and modified methods are "in statis" and so would
  71             # not show up in this test anyway (and as a side-effect they
  72             # would not fufill the requirement, which is exactly what we
  73             # want them to do anyway).
  74             # - SL
  75         }
  76     }
  77 }
  78
  79 sub check_required_attributes {
  80
  81 }
  82
  83 sub apply_attributes {
  84     my ($self, $role, $class) = @_;
  85     foreach my $attribute_name ($role->get_attribute_list) {
  86         # it if it has one already
  87         if ($class->has_attribute($attribute_name) &&
  88             # make sure we haven't seen this one already too
  89             $class->get_attribute($attribute_name) != $role->get_attribute($attribute_name)) {
  90             next;
  91         }
  92         else {
  93             $class->add_attribute(
  94                 $attribute_name,
  95                 $role->get_attribute($attribute_name)
  96             );
  97         }
  98     }
  99 }
 100
 101 sub apply_methods {
 102     my ($self, $role, $class) = @_;
 103     foreach my $method_name ($role->get_method_list) {
 104
 105         next if $self->is_method_excluded($method_name);
 106
 107         # it if it has one already
 108         if ($class->has_method($method_name) &&
 109             # and if they are not the same thing ...
 110             $class->get_method($method_name)->body != $role->get_method($method_name)->body) {
 111             next;
 112         }
 113         else {
 114             # add it, although it could be overriden
 115             $class->alias_method(
 116                 $method_name,
 117                 $role->get_method($method_name)
 118             );
 119         }
 120
 121         if ($self->is_method_aliased($method_name)) {
 122             my $aliased_method_name = $self->get_method_aliases->{$method_name};
 123             # it if it has one already
 124             if ($class->has_method($aliased_method_name) &&
 125                 # and if they are not the same thing ...
 126                 $class->get_method($aliased_method_name)->body != $role->get_method($method_name)->body) {
 127                 confess "Cannot create a method alias if a local method of the same name exists";
 128             }
 129             $class->alias_method(
 130                 $aliased_method_name,
 131                 $role->get_method($method_name)
 132             );
 133         }
 134     }
 135     # we must reset the cache here since
 136     # we are just aliasing methods, otherwise
 137     # the modifiers go wonky.
 138     $class->reset_package_cache_flag;
 139 }
 140
 141 sub apply_override_method_modifiers {
 142     my ($self, $role, $class) = @_;
 143     foreach my $method_name ($role->get_method_modifier_list('override')) {
 144         # it if it has one already then ...
 145         if ($class->has_method($method_name)) {
 146             next;
 147         }
 148         else {
 149             # if this is not a role, then we need to
 150             # find the original package of the method
 151             # so that we can tell the class were to
 152             # find the right super() method
 153             my $method = $role->get_override_method_modifier($method_name);
 154             my ($package) = Class::MOP::get_code_info($method);
 155             # if it is a class, we just add it
 156             $class->add_override_method_modifier($method_name, $method, $package);
 157         }
 158     }
 159 }
 160
 161 sub apply_method_modifiers {
 162     my ($self, $modifier_type, $role, $class) = @_;
 163     my $add = "add_${modifier_type}_method_modifier";
 164     my $get = "get_${modifier_type}_method_modifiers";
 165     foreach my $method_name ($role->get_method_modifier_list($modifier_type)) {
 166         $class->$add(
 167             $method_name,
 168             $_
 169         ) foreach $role->$get($method_name);
 170     }
 171 }
 172
 173 1;
 174
 175 __END__
 176
 177 =pod
 178
 179 =head1 NAME
 180
 181 Moose::Meta::Role::Application::ToClass - Compose a role into a class
 182
 183 =head1 DESCRIPTION
 184
 185 =head2 METHODS
 186
 187 =over 4
 188
 189 =item B<new>
 190
 191 =item B<meta>
 192
 193 =item B<apply>
 194
 195 =item B<check_role_exclusions>
 196
 197 =item B<check_required_methods>
 198
 199 =item B<check_required_attributes>
 200
 201 =item B<apply_attributes>
 202
 203 =item B<apply_methods>
 204
 205 =item B<apply_method_modifiers>
 206
 207 =item B<apply_override_method_modifiers>
 208
 209 =back
 210
 211 =head1 BUGS
 212
 213 All complex software has bugs lurking in it, and this module is no
 214 exception. If you find a bug please either email me, or add the bug
 215 to cpan-RT.
 216
 217 =head1 AUTHOR
 218
 219 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 220
 221 =head1 COPYRIGHT AND LICENSE
 222
 223 Copyright 2006-2008 by Infinity Interactive, Inc.
 224
 225 L<http://www.iinteractive.com>
 226
 227 This library is free software; you can redistribute it and/or modify
 228 it under the same terms as Perl itself.
 229
 230 =cut
 231