lib/Moose/Meta/Role/Application/ToClass.pm

   1 package Moose::Meta::Role::Application::ToClass;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Moose::Util  'english_list';
   8 use Scalar::Util 'weaken', 'blessed';
   9
  10 our $VERSION   = '0.89_02';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Moose::Meta::Role::Application';
  15
  16 __PACKAGE__->meta->add_attribute('role' => (
  17     reader => 'role',
  18 ));
  19
  20 __PACKAGE__->meta->add_attribute('class' => (
  21     reader => 'class',
  22 ));
  23
  24 sub apply {
  25     my ($self, $role, $class) = @_;
  26
  27     # We need weak_ref in CMOP :(
  28     weaken($self->{role}  = $role);
  29     weaken($self->{class} = $class);
  30
  31     $self->SUPER::apply($role, $class);
  32
  33     $class->add_role($role);
  34     $class->add_role_application($self);
  35 }
  36
  37 sub check_role_exclusions {
  38     my ($self, $role, $class) = @_;
  39     if ($class->excludes_role($role->name)) {
  40         $class->throw_error("Conflict detected: " . $class->name . " excludes role '" . $role->name . "'");
  41     }
  42     foreach my $excluded_role_name ($role->get_excluded_roles_list) {
  43         if ($class->does_role($excluded_role_name)) {
  44             $class->throw_error("The class " . $class->name . " does the excluded role '$excluded_role_name'");
  45         }
  46     }
  47 }
  48
  49 sub check_required_methods {
  50     my ($self, $role, $class) = @_;
  51
  52     my @missing;
  53     my @is_attr;
  54
  55     # NOTE:
  56     # we might need to move this down below the
  57     # the attributes so that we can require any
  58     # attribute accessors. However I am thinking
  59     # that maybe those are somehow exempt from
  60     # the require methods stuff.
  61     foreach my $required_method ($role->get_required_method_list) {
  62         my $required_method_name = $required_method->name;
  63
  64         if (!$class->find_method_by_name($required_method_name)) {
  65
  66             next if $self->is_aliased_method($required_method_name);
  67
  68             push @missing, $required_method;
  69         }
  70     }
  71
  72     return unless @missing;
  73
  74     my $error = '';
  75
  76     @missing = sort { $a->name cmp $b->name } @missing;
  77     my @conflicts = grep { $_->isa('Moose::Meta::Role::Method::Conflicting') } @missing;
  78
  79     if (@conflicts) {
  80         my $conflict = $conflicts[0];
  81         my $roles = $conflict->roles_as_english_list;
  82
  83         my @same_role_conflicts = grep { $_->roles_as_english_list eq $roles } @conflicts;
  84
  85         if (@same_role_conflicts == 1) {
  86             $error
  87                 .= "Due to a method name conflict in roles "
  88                 .  $roles
  89                 . ", the method '"
  90                 . $conflict->name
  91                 . "' must be implemented or excluded by '"
  92                 . $class->name
  93                 . q{'};
  94         }
  95         else {
  96             my $methods
  97                 = Moose::Util::english_list( map { q{'} . $_->name . q{'} } @same_role_conflicts );
  98
  99             $error
 100                 .= "Due to method name conflicts in roles "
 101                 .  $roles
 102                 . ", the methods "
 103                 . $methods
 104                 . " must be implemented or excluded by '"
 105                 . $class->name
 106                 . q{'};
 107         }
 108     }
 109     elsif (@missing) {
 110         my $noun = @missing == 1 ? 'method' : 'methods';
 111
 112         my $list
 113             = Moose::Util::english_list( map { q{'} . $_ . q{'} } @missing );
 114
 115         $error
 116             .= q{'}
 117             . $role->name
 118             . "' requires the $noun $list "
 119             . "to be implemented by '"
 120             . $class->name . q{'};
 121     }
 122
 123     $class->throw_error($error);
 124 }
 125
 126 sub check_required_attributes {
 127
 128 }
 129
 130 sub apply_attributes {
 131     my ($self, $role, $class) = @_;
 132     foreach my $attribute_name ($role->get_attribute_list) {
 133         # it if it has one already
 134         if ($class->has_attribute($attribute_name) &&
 135             # make sure we haven't seen this one already too
 136             $class->get_attribute($attribute_name) != $role->get_attribute($attribute_name)) {
 137             next;
 138         }
 139         else {
 140             $class->add_attribute(
 141                 $attribute_name,
 142                 $role->get_attribute($attribute_name)
 143             );
 144         }
 145     }
 146 }
 147
 148 sub apply_methods {
 149     my ($self, $role, $class) = @_;
 150     foreach my $method_name ($role->get_method_list) {
 151
 152         unless ($self->is_method_excluded($method_name)) {
 153             # it if it has one already
 154             if ($class->has_method($method_name) &&
 155                 # and if they are not the same thing ...
 156                 $class->get_method($method_name)->body != $role->get_method($method_name)->body) {
 157                 next;
 158             }
 159             else {
 160                 # add it, although it could be overridden
 161                 $class->add_method(
 162                     $method_name,
 163                     $role->get_method($method_name)
 164                 );
 165             }
 166         }
 167
 168         if ($self->is_method_aliased($method_name)) {
 169             my $aliased_method_name = $self->get_method_aliases->{$method_name};
 170             # it if it has one already
 171             if ($class->has_method($aliased_method_name) &&
 172                 # and if they are not the same thing ...
 173                 $class->get_method($aliased_method_name)->body != $role->get_method($method_name)->body) {
 174                 $class->throw_error("Cannot create a method alias if a local method of the same name exists");
 175             }
 176             $class->add_method(
 177                 $aliased_method_name,
 178                 $role->get_method($method_name)
 179             );
 180         }
 181     }
 182     # we must reset the cache here since
 183     # we are just aliasing methods, otherwise
 184     # the modifiers go wonky.
 185     $class->reset_package_cache_flag;
 186 }
 187
 188 sub apply_override_method_modifiers {
 189     my ($self, $role, $class) = @_;
 190     foreach my $method_name ($role->get_method_modifier_list('override')) {
 191         # it if it has one already then ...
 192         if ($class->has_method($method_name)) {
 193             next;
 194         }
 195         else {
 196             # if this is not a role, then we need to
 197             # find the original package of the method
 198             # so that we can tell the class were to
 199             # find the right super() method
 200             my $method = $role->get_override_method_modifier($method_name);
 201             my ($package) = Class::MOP::get_code_info($method);
 202             # if it is a class, we just add it
 203             $class->add_override_method_modifier($method_name, $method, $package);
 204         }
 205     }
 206 }
 207
 208 sub apply_method_modifiers {
 209     my ($self, $modifier_type, $role, $class) = @_;
 210     my $add = "add_${modifier_type}_method_modifier";
 211     my $get = "get_${modifier_type}_method_modifiers";
 212     foreach my $method_name ($role->get_method_modifier_list($modifier_type)) {
 213         $class->$add(
 214             $method_name,
 215             $_
 216         ) foreach $role->$get($method_name);
 217     }
 218 }
 219
 220 1;
 221
 222 __END__
 223
 224 =pod
 225
 226 =head1 NAME
 227
 228 Moose::Meta::Role::Application::ToClass - Compose a role into a class
 229
 230 =head1 DESCRIPTION
 231
 232 =head2 METHODS
 233
 234 =over 4
 235
 236 =item B<new>
 237
 238 =item B<meta>
 239
 240 =item B<apply>
 241
 242 =item B<check_role_exclusions>
 243
 244 =item B<check_required_methods>
 245
 246 =item B<check_required_attributes>
 247
 248 =item B<apply_attributes>
 249
 250 =item B<apply_methods>
 251
 252 =item B<apply_method_modifiers>
 253
 254 =item B<apply_override_method_modifiers>
 255
 256 =back
 257
 258 =head1 BUGS
 259
 260 All complex software has bugs lurking in it, and this module is no
 261 exception. If you find a bug please either email me, or add the bug
 262 to cpan-RT.
 263
 264 =head1 AUTHOR
 265
 266 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 267
 268 =head1 COPYRIGHT AND LICENSE
 269
 270 Copyright 2006-2009 by Infinity Interactive, Inc.
 271
 272 L<http://www.iinteractive.com>
 273
 274 This library is free software; you can redistribute it and/or modify
 275 it under the same terms as Perl itself.
 276
 277 =cut
 278