lib/Moose/Meta/Role/Application/RoleSummation.pm

   1 package Moose::Meta::Role::Application::RoleSummation;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8
   9 use Moose::Meta::Role::Composite;
  10
  11 use base 'Moose::Meta::Role::Application';
  12
  13 __PACKAGE__->meta->add_attribute('role_params' => (
  14     reader  => 'role_params',
  15     default => sub { {} }
  16 ));
  17
  18 sub get_exclusions_for_role {
  19     my ($self, $role) = @_;
  20     $role = $role->name if blessed $role;
  21     my $excludes_key = exists $self->role_params->{$role}->{'-excludes'} ?
  22                            '-excludes' : 'excludes';
  23     if ($self->role_params->{$role} && defined $self->role_params->{$role}->{$excludes_key}) {
  24         if (ref $self->role_params->{$role}->{$excludes_key} eq 'ARRAY') {
  25             return $self->role_params->{$role}->{$excludes_key};
  26         }
  27         return [ $self->role_params->{$role}->{$excludes_key} ];
  28     }
  29     return [];
  30 }
  31
  32 sub get_method_aliases_for_role {
  33     my ($self, $role) = @_;
  34     $role = $role->name if blessed $role;
  35     my $alias_key = exists $self->role_params->{$role}->{'-alias'} ?
  36                         '-alias' : 'alias';
  37     if ($self->role_params->{$role} && defined $self->role_params->{$role}->{$alias_key}) {
  38         return $self->role_params->{$role}->{$alias_key};
  39     }
  40     return {};
  41 }
  42
  43 sub is_method_excluded {
  44     my ($self, $role, $method_name) = @_;
  45     foreach ($self->get_exclusions_for_role($role->name)) {
  46         return 1 if $_ eq $method_name;
  47     }
  48     return 0;
  49 }
  50
  51 sub is_method_aliased {
  52     my ($self, $role, $method_name) = @_;
  53     exists $self->get_method_aliases_for_role($role->name)->{$method_name} ? 1 : 0
  54 }
  55
  56 sub is_aliased_method {
  57     my ($self, $role, $method_name) = @_;
  58     my %aliased_names = reverse %{$self->get_method_aliases_for_role($role->name)};
  59     exists $aliased_names{$method_name} ? 1 : 0;
  60 }
  61
  62 sub check_role_exclusions {
  63     my ($self, $c) = @_;
  64
  65     my %excluded_roles;
  66     for my $role (@{ $c->get_roles }) {
  67         my $name = $role->name;
  68
  69         for my $excluded ($role->get_excluded_roles_list) {
  70             push @{ $excluded_roles{$excluded} }, $name;
  71         }
  72     }
  73
  74     foreach my $role (@{$c->get_roles}) {
  75         foreach my $excluded (keys %excluded_roles) {
  76             next unless $role->does_role($excluded);
  77
  78             my @excluding = @{ $excluded_roles{$excluded} };
  79
  80             require Moose;
  81             Moose->throw_error(sprintf "Conflict detected: Role%s %s exclude%s role '%s'", (@excluding == 1 ? '' : 's'), join(', ', @excluding), (@excluding == 1 ? 's' : ''), $excluded);
  82         }
  83     }
  84
  85     $c->add_excluded_roles(keys %excluded_roles);
  86 }
  87
  88 sub check_required_methods {
  89     my ($self, $c) = @_;
  90
  91     my %all_required_methods =
  92         map { $_->name => $_ }
  93         map { $_->get_required_method_list }
  94         @{$c->get_roles};
  95
  96     foreach my $role (@{$c->get_roles}) {
  97         foreach my $required (keys %all_required_methods) {
  98
  99             delete $all_required_methods{$required}
 100                 if $role->has_method($required)
 101                 || $self->is_aliased_method($role, $required);
 102         }
 103     }
 104
 105     $c->add_required_methods(values %all_required_methods);
 106 }
 107
 108 sub check_required_attributes {
 109
 110 }
 111
 112 sub apply_attributes {
 113     my ($self, $c) = @_;
 114
 115     my @all_attributes;
 116
 117     for my $role ( @{ $c->get_roles } ) {
 118         push @all_attributes,
 119             map { $role->get_attribute($_) } $role->get_attribute_list;
 120     }
 121
 122     my %seen;
 123     foreach my $attr (@all_attributes) {
 124         my $name = $attr->name;
 125
 126         if ( exists $seen{$name} ) {
 127             next if $seen{$name}->is_same_as($attr);
 128
 129             my $role1 = $seen{$name}->associated_role->name;
 130             my $role2 = $attr->associated_role->name;
 131
 132             require Moose;
 133             Moose->throw_error(
 134                 "We have encountered an attribute conflict with '$name' "
 135                     . "during role composition. "
 136                     . " This attribute is defined in both $role1 and $role2."
 137                     . " This is fatal error and cannot be disambiguated." );
 138         }
 139
 140         $seen{$name} = $attr;
 141     }
 142
 143     foreach my $attr (@all_attributes) {
 144         $c->add_attribute( $attr->clone );
 145     }
 146 }
 147
 148 sub apply_methods {
 149     my ($self, $c) = @_;
 150
 151     my @all_methods = map {
 152         my $role     = $_;
 153         my $aliases  = $self->get_method_aliases_for_role($role);
 154         my %excludes = map { $_ => undef } @{ $self->get_exclusions_for_role($role) };
 155         (
 156             (map {
 157                 exists $excludes{$_} ? () :
 158                 +{
 159                     role   => $role,
 160                     name   => $_,
 161                     method => $role->get_method($_),
 162                 }
 163             } map { $_->name }
 164               grep { !$_->isa('Class::MOP::Method::Meta') }
 165                    $role->_get_local_methods),
 166             (map {
 167                 +{
 168                     role   => $role,
 169                     name   => $aliases->{$_},
 170                     method => $role->get_method($_),
 171                 }
 172             } keys %$aliases)
 173         );
 174     } @{$c->get_roles};
 175
 176     my (%seen, %method_map);
 177     foreach my $method (@all_methods) {
 178         my $seen = $seen{$method->{name}};
 179
 180         if ($seen) {
 181             if ($seen->{method}->body != $method->{method}->body) {
 182                 $c->add_conflicting_method(
 183                     name  => $method->{name},
 184                     roles => [$method->{role}->name, $seen->{role}->name],
 185                 );
 186
 187                 delete $method_map{$method->{name}};
 188                 next;
 189             }
 190         }
 191
 192         $seen{$method->{name}}       = $method;
 193         $method_map{$method->{name}} = $method->{method};
 194     }
 195
 196     $c->add_method($_ => $method_map{$_}) for keys %method_map;
 197 }
 198
 199 sub apply_override_method_modifiers {
 200     my ($self, $c) = @_;
 201
 202     my @all_overrides = map {
 203         my $role = $_;
 204         map {
 205             +{
 206                 name   => $_,
 207                 method => $role->get_override_method_modifier($_),
 208             }
 209         } $role->get_method_modifier_list('override');
 210     } @{$c->get_roles};
 211
 212     my %seen;
 213     foreach my $override (@all_overrides) {
 214         if ( $c->has_method($override->{name}) ){
 215             require Moose;
 216             Moose->throw_error( "Role '" . $c->name . "' has encountered an 'override' method conflict " .
 217                                 "during composition (A local method of the same name as been found). This " .
 218                                 "is fatal error." )
 219         }
 220         if (exists $seen{$override->{name}}) {
 221             if ( $seen{$override->{name}} != $override->{method} ) {
 222                 require Moose;
 223                 Moose->throw_error( "We have encountered an 'override' method conflict during " .
 224                                     "composition (Two 'override' methods of the same name encountered). " .
 225                                     "This is fatal error.")
 226             }
 227         }
 228         $seen{$override->{name}} = $override->{method};
 229     }
 230
 231     $c->add_override_method_modifier(
 232         $_->{name}, $_->{method}
 233     ) for @all_overrides;
 234
 235 }
 236
 237 sub apply_method_modifiers {
 238     my ($self, $modifier_type, $c) = @_;
 239     my $add = "add_${modifier_type}_method_modifier";
 240     my $get = "get_${modifier_type}_method_modifiers";
 241     foreach my $role (@{$c->get_roles}) {
 242         foreach my $method_name ($role->get_method_modifier_list($modifier_type)) {
 243             $c->$add(
 244                 $method_name,
 245                 $_
 246             ) foreach $role->$get($method_name);
 247         }
 248     }
 249 }
 250
 251 1;
 252
 253 # ABSTRACT: Combine two or more roles
 254
 255 __END__
 256
 257 =pod
 258
 259 =head1 DESCRIPTION
 260
 261 Summation composes two traits, forming the union of non-conflicting
 262 bindings and 'disabling' the conflicting bindings
 263
 264 =head2 METHODS
 265
 266 =over 4
 267
 268 =item B<new>
 269
 270 =item B<meta>
 271
 272 =item B<role_params>
 273
 274 =item B<get_exclusions_for_role>
 275
 276 =item B<get_method_aliases_for_role>
 277
 278 =item B<is_aliased_method>
 279
 280 =item B<is_method_aliased>
 281
 282 =item B<is_method_excluded>
 283
 284 =item B<apply>
 285
 286 =item B<check_role_exclusions>
 287
 288 =item B<check_required_methods>
 289
 290 =item B<check_required_attributes>
 291
 292 =item B<apply_attributes>
 293
 294 =item B<apply_methods>
 295
 296 =item B<apply_method_modifiers>
 297
 298 =item B<apply_override_method_modifiers>
 299
 300 =back
 301
 302 =head1 BUGS
 303
 304 See L<Moose/BUGS> for details on reporting bugs.
 305
 306 =cut
 307