lib/Moose/Meta/Method/Delegation.pm

   1
   2 package Moose::Meta::Method::Delegation;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed', 'weaken';
   9
  10 our $VERSION   = '0.85';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Moose::Meta::Method',
  15          'Class::MOP::Method::Generated';
  16
  17
  18 sub new {
  19     my $class   = shift;
  20     my %options = @_;
  21
  22     ( exists $options{attribute} )
  23         || confess "You must supply an attribute to construct with";
  24
  25     ( blessed( $options{attribute} )
  26             && $options{attribute}->isa('Moose::Meta::Attribute') )
  27         || confess
  28         "You must supply an attribute which is a 'Moose::Meta::Attribute' instance";
  29
  30     ( $options{package_name} && $options{name} )
  31         || confess
  32         "You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT";
  33
  34     ( $options{delegate_to_method} && ( !ref $options{delegate_to_method} )
  35             || ( 'CODE' eq ref $options{delegate_to_method} ) )
  36         || confess
  37         'You must supply a delegate_to_method which is a method name or a CODE reference';
  38
  39     exists $options{curried_arguments}
  40         || ( $options{curried_arguments} = [] );
  41
  42     ( $options{curried_arguments} &&
  43         ( 'ARRAY' eq ref $options{curried_arguments} ) )
  44         || confess 'You must supply a curried_arguments which is an ARRAY reference';
  45
  46     my $self = $class->_new( \%options );
  47
  48     weaken( $self->{'attribute'} );
  49
  50     $self->_initialize_body;
  51
  52     return $self;
  53 }
  54
  55 sub _new {
  56     my $class = shift;
  57     my $options = @_ == 1 ? $_[0] : {@_};
  58
  59     return bless $options, $class;
  60 }
  61
  62 sub curried_arguments { (shift)->{'curried_arguments'} }
  63
  64 sub associated_attribute { (shift)->{'attribute'} }
  65
  66 sub delegate_to_method { (shift)->{'delegate_to_method'} }
  67
  68 sub _initialize_body {
  69     my $self = shift;
  70
  71     my $method_to_call = $self->delegate_to_method;
  72     return $self->{body} = $method_to_call
  73         if ref $method_to_call;
  74
  75     my $accessor = $self->_get_delegate_accessor;
  76
  77     my $handle_name = $self->name;
  78
  79     # NOTE: we used to do a goto here, but the goto didn't handle
  80     # failure correctly (it just returned nothing), so I took that
  81     # out. However, the more I thought about it, the less I liked it
  82     # doing the goto, and I preferred the act of delegation being
  83     # actually represented in the stack trace.  - SL
  84     # not inlining this, since it won't really speed things up at
  85     # all... the only thing that would end up different would be
  86     # interpolating in $method_to_call, and a bunch of things in the
  87     # error handling that mostly never gets called - doy
  88     $self->{body} = sub {
  89         my $instance = shift;
  90         my $proxy    = $instance->$accessor();
  91         ( defined $proxy )
  92             || $self->throw_error(
  93             "Cannot delegate $handle_name to $method_to_call because "
  94                 . "the value of "
  95                 . $self->associated_attribute->name
  96                 . " is not defined",
  97             method_name => $method_to_call,
  98             object      => $instance
  99             );
 100         my @args = (@{ $self->curried_arguments }, @_);
 101         $proxy->$method_to_call(@args);
 102     };
 103 }
 104
 105 sub _get_delegate_accessor {
 106     my $self = shift;
 107
 108     my $accessor = $self->associated_attribute->get_read_method_ref;
 109
 110     $accessor = $accessor->body if blessed $accessor;
 111
 112     return $accessor;
 113 }
 114
 115 1;
 116
 117 __END__
 118
 119 =pod
 120
 121 =head1 NAME
 122
 123 Moose::Meta::Method::Delegation - A Moose Method metaclass for delegation methods
 124
 125 =head1 DESCRIPTION
 126
 127 This is a subclass of L<Moose::Meta::Method> for delegation
 128 methods.
 129
 130 =head1 METHODS
 131
 132 =over 4
 133
 134 =item B<< Moose::Meta::Method::Delegation->new(%options) >>
 135
 136 This creates the delegation methods based on the provided C<%options>.
 137
 138 =over 4
 139
 140 =item I<attribute>
 141
 142 This must be an instance of C<Moose::Meta::Attribute> which this
 143 accessor is being generated for. This options is B<required>.
 144
 145 =item I<delegate_to_method>
 146
 147 The method in the associated attribute's value to which we
 148 delegate. This can be either a method name or a code reference.
 149
 150 =item I<curried_arguments>
 151
 152 An array reference of arguments that will be prepended to the argument list for
 153 any call to the delegating method.
 154
 155 =back
 156
 157 =item B<< $metamethod->associated_attribute >>
 158
 159 Returns the attribute associated with this method.
 160
 161 =item B<< $metamethod->curried_arguments >>
 162
 163 Return any curried arguments that will be passed to the delegated method.
 164
 165 =item B<< $metamethod->delegate_to_method >>
 166
 167 Returns the method to which this method delegates, as passed to the
 168 constructor.
 169
 170 =back
 171
 172 =head1 BUGS
 173
 174 All complex software has bugs lurking in it, and this module is no
 175 exception. If you find a bug please either email me, or add the bug
 176 to cpan-RT.
 177
 178 =head1 AUTHOR
 179
 180 Dave Rolsky E<lt>autarch@urth.orgE<gt>
 181
 182 =head1 COPYRIGHT AND LICENSE
 183
 184 Copyright 2009 by Infinity Interactive, Inc.
 185
 186 L<http://www.iinteractive.com>
 187
 188 This library is free software; you can redistribute it and/or modify
 189 it under the same terms as Perl itself.
 190
 191 =cut