lib/Moose/Meta/Method/Delegation.pm

   1
   2 package Moose::Meta::Method::Delegation;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed', 'weaken';
   9
  10 our $VERSION   = '0.89';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Moose::Meta::Method',
  15          'Class::MOP::Method::Generated';
  16
  17
  18 sub new {
  19     my $class   = shift;
  20     my %options = @_;
  21
  22     ( exists $options{attribute} )
  23         || confess "You must supply an attribute to construct with";
  24
  25     ( blessed( $options{attribute} )
  26             && $options{attribute}->isa('Moose::Meta::Attribute') )
  27         || confess
  28         "You must supply an attribute which is a 'Moose::Meta::Attribute' instance";
  29
  30     ( $options{package_name} && $options{name} )
  31         || confess
  32         "You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT";
  33
  34     ( $options{delegate_to_method} && ( !ref $options{delegate_to_method} )
  35             || ( 'CODE' eq ref $options{delegate_to_method} ) )
  36         || confess
  37         'You must supply a delegate_to_method which is a method name or a CODE reference';
  38
  39     exists $options{curried_arguments}
  40         || ( $options{curried_arguments} = [] );
  41
  42     ( $options{curried_arguments} &&
  43         ( 'ARRAY' eq ref $options{curried_arguments} ) )
  44         || confess 'You must supply a curried_arguments which is an ARRAY reference';
  45
  46     my $self = $class->_new( \%options );
  47
  48     weaken( $self->{'attribute'} );
  49
  50     $self->_initialize_body;
  51
  52     return $self;
  53 }
  54
  55 sub _new {
  56     my $class = shift;
  57     my $options = @_ == 1 ? $_[0] : {@_};
  58
  59     return bless $options, $class;
  60 }
  61
  62 sub curried_arguments { (shift)->{'curried_arguments'} }
  63
  64 sub associated_attribute { (shift)->{'attribute'} }
  65
  66 sub delegate_to_method { (shift)->{'delegate_to_method'} }
  67
  68 sub _initialize_body {
  69     my $self = shift;
  70
  71     my $method_to_call = $self->delegate_to_method;
  72     return $self->{body} = $method_to_call
  73         if ref $method_to_call;
  74
  75     my $accessor = $self->_get_delegate_accessor;
  76
  77     my $handle_name = $self->name;
  78
  79     # NOTE: we used to do a goto here, but the goto didn't handle
  80     # failure correctly (it just returned nothing), so I took that
  81     # out. However, the more I thought about it, the less I liked it
  82     # doing the goto, and I preferred the act of delegation being
  83     # actually represented in the stack trace.  - SL
  84     # not inlining this, since it won't really speed things up at
  85     # all... the only thing that would end up different would be
  86     # interpolating in $method_to_call, and a bunch of things in the
  87     # error handling that mostly never gets called - doy
  88     $self->{body} = sub {
  89         my $instance = shift;
  90         my $proxy    = $instance->$accessor();
  91
  92         my $error
  93             = !defined $proxy                 ? ' is not defined'
  94             : ref($proxy) && !blessed($proxy) ? qq{ is not an object (got '$proxy')}
  95             : undef;
  96
  97         if ($error) {
  98             $self->throw_error(
  99                 "Cannot delegate $handle_name to $method_to_call because "
 100                     . "the value of "
 101                     . $self->associated_attribute->name
 102                     . $error,
 103                 method_name => $method_to_call,
 104                 object      => $instance
 105             );
 106         }
 107         my @args = (@{ $self->curried_arguments }, @_);
 108         $proxy->$method_to_call(@args);
 109     };
 110 }
 111
 112 sub _get_delegate_accessor {
 113     my $self = shift;
 114
 115     my $accessor = $self->associated_attribute->get_read_method_ref;
 116
 117     $accessor = $accessor->body if blessed $accessor;
 118
 119     return $accessor;
 120 }
 121
 122 1;
 123
 124 __END__
 125
 126 =pod
 127
 128 =head1 NAME
 129
 130 Moose::Meta::Method::Delegation - A Moose Method metaclass for delegation methods
 131
 132 =head1 DESCRIPTION
 133
 134 This is a subclass of L<Moose::Meta::Method> for delegation
 135 methods.
 136
 137 =head1 METHODS
 138
 139 =over 4
 140
 141 =item B<< Moose::Meta::Method::Delegation->new(%options) >>
 142
 143 This creates the delegation methods based on the provided C<%options>.
 144
 145 =over 4
 146
 147 =item I<attribute>
 148
 149 This must be an instance of C<Moose::Meta::Attribute> which this
 150 accessor is being generated for. This options is B<required>.
 151
 152 =item I<delegate_to_method>
 153
 154 The method in the associated attribute's value to which we
 155 delegate. This can be either a method name or a code reference.
 156
 157 =item I<curried_arguments>
 158
 159 An array reference of arguments that will be prepended to the argument list for
 160 any call to the delegating method.
 161
 162 =back
 163
 164 =item B<< $metamethod->associated_attribute >>
 165
 166 Returns the attribute associated with this method.
 167
 168 =item B<< $metamethod->curried_arguments >>
 169
 170 Return any curried arguments that will be passed to the delegated method.
 171
 172 =item B<< $metamethod->delegate_to_method >>
 173
 174 Returns the method to which this method delegates, as passed to the
 175 constructor.
 176
 177 =back
 178
 179 =head1 BUGS
 180
 181 All complex software has bugs lurking in it, and this module is no
 182 exception. If you find a bug please either email me, or add the bug
 183 to cpan-RT.
 184
 185 =head1 AUTHOR
 186
 187 Dave Rolsky E<lt>autarch@urth.orgE<gt>
 188
 189 =head1 COPYRIGHT AND LICENSE
 190
 191 Copyright 2009 by Infinity Interactive, Inc.
 192
 193 L<http://www.iinteractive.com>
 194
 195 This library is free software; you can redistribute it and/or modify
 196 it under the same terms as Perl itself.
 197
 198 =cut