lib/Moose/Meta/Method/Constructor.pm

   1
   2 package Moose::Meta::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed', 'weaken', 'looks_like_number';
   8
   9 our $VERSION   = '0.72';
  10 our $AUTHORITY = 'cpan:STEVAN';
  11
  12 use base 'Moose::Meta::Method',
  13          'Class::MOP::Method::Generated';
  14
  15 sub new {
  16     my $class   = shift;
  17     my %options = @_;
  18
  19     my $meta = $options{metaclass};
  20
  21     (ref $options{options} eq 'HASH')
  22         || $class->throw_error("You must pass a hash of options", data => $options{options});
  23
  24     ($options{package_name} && $options{name})
  25         || $class->throw_error("You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT");
  26
  27     my $self = bless {
  28         # from our superclass
  29         'body'          => undef,
  30         'package_name'  => $options{package_name},
  31         'name'          => $options{name},
  32         # specific to this subclass
  33         'options'       => $options{options},
  34         'meta_instance' => $meta->get_meta_instance,
  35         'attributes'    => [ $meta->compute_all_applicable_attributes ],
  36         # ...
  37         'associated_metaclass' => $meta,
  38     } => $class;
  39
  40     # we don't want this creating
  41     # a cycle in the code, if not
  42     # needed
  43     weaken($self->{'associated_metaclass'});
  44
  45     $self->initialize_body;
  46
  47     return $self;
  48 }
  49
  50 sub can_be_inlined {
  51     my $self      = shift;
  52     my $metaclass = $self->associated_metaclass;
  53
  54     my $expected_class = $self->_expected_constructor_class;
  55
  56     # If any of our parents have been made immutable, we are okay to
  57     # inline our own new method. The assumption is that an inlined new
  58     # method provided by a parent does not actually get used by
  59     # children anyway.
  60     for my $meta (
  61         grep { $_->is_immutable }
  62         map  { ( ref $metaclass )->initialize($_) }
  63         grep { $_ ne $expected_class }
  64         $metaclass->linearized_isa
  65         ) {
  66         my $transformer = $meta->get_immutable_transformer;
  67
  68         # This is actually a false positive if we're in a subclass of
  69         # this class, _and_ the expected class is not overridden (but
  70         # should be), and the real expected class is actually
  71         # immutable itself (see Fey::Object::Table for an example of
  72         # how this can happen). I'm not sure how to actually handle
  73         # that case, since it's effectively a bug in the subclass (for
  74         # not overriding _expected_constructor_class).
  75         return 1 if $transformer->inlined_constructor;
  76     }
  77
  78     if ( my $constructor = $metaclass->find_method_by_name( $self->name ) ) {
  79         my $class = $self->associated_metaclass->name;
  80
  81         if ( $constructor->body != $expected_class->can('new') ) {
  82             my $warning
  83                 = "Not inlining a constructor for $class since it is not"
  84                 . " inheriting the default $expected_class constructor\n"
  85                 . "If you are certain you don't need to inline your"
  86                 . " constructor, specify inline_constructor => 0 in your"
  87                 . " call to $class->meta->make_immutable\n";
  88
  89             $warning .= " (constructor has method modifiers which would be lost if it were inlined)\n"
  90                 if $constructor->isa('Class::MOP::Method::Wrapped');
  91
  92             warn $warning;
  93
  94             return 0;
  95         }
  96         else {
  97             return 1;
  98         }
  99     }
 100
 101     # This would be a rather weird case where we have no constructor
 102     # in the inheritance chain.
 103     return 1;
 104 }
 105
 106 # This is here so can_be_inlined can be inherited by MooseX modules.
 107 sub _expected_constructor_class {
 108     return 'Moose::Object';
 109 }
 110
 111 ## accessors
 112
 113 sub options       { (shift)->{'options'}       }
 114 sub meta_instance { (shift)->{'meta_instance'} }
 115 sub attributes    { (shift)->{'attributes'}    }
 116
 117 sub associated_metaclass { (shift)->{'associated_metaclass'} }
 118
 119 ## method
 120
 121 # this was changed in 0.41, but broke MooseX::Singleton, so try to catch
 122 # any other code using the original broken spelling
 123 sub intialize_body { $_[0]->throw_error("Please correct the spelling of 'intialize_body' to 'initialize_body'") }
 124
 125 sub _generate_params {
 126   my ($self, $var, $class_var) = @_;
 127   "my $var = " . $self->_generate_BUILDARGS($class_var, '@_') . ";\n";
 128 }
 129
 130 sub _generate_instance {
 131   my ($self, $var, $class_var) = @_;
 132   "my $var = " . $self->meta_instance->inline_create_instance($class_var)
 133                . ";\n";
 134 }
 135
 136 sub _generate_slot_initializers {
 137     my ($self) = @_;
 138     return (join ";\n" => map {
 139         $self->_generate_slot_initializer($_)
 140     } 0 .. (@{$self->attributes} - 1)) . ";\n";
 141 }
 142
 143 sub initialize_body {
 144     my $self = shift;
 145     # TODO:
 146     # the %options should also include a both
 147     # a call 'initializer' and call 'SUPER::'
 148     # options, which should cover approx 90%
 149     # of the possible use cases (even if it
 150     # requires some adaption on the part of
 151     # the author, after all, nothing is free)
 152     my $source = 'sub {';
 153     $source .= "\n" . 'my $class = shift;';
 154
 155     $source .= "\n" . 'return $class->Moose::Object::new(@_)';
 156     $source .= "\n    if \$class ne '" . $self->associated_metaclass->name
 157             .  "';\n";
 158
 159     $source .= $self->_generate_params('$params', '$class');
 160     $source .= $self->_generate_instance('$instance', '$class');
 161     $source .= $self->_generate_slot_initializers;
 162
 163     $source .= $self->_generate_triggers();
 164     $source .= ";\n" . $self->_generate_BUILDALL();
 165
 166     $source .= ";\nreturn \$instance";
 167     $source .= ";\n" . '}';
 168     warn $source if $self->options->{debug};
 169
 170     # We need to check if the attribute ->can('type_constraint')
 171     # since we may be trying to immutabilize a Moose meta class,
 172     # which in turn has attributes which are Class::MOP::Attribute
 173     # objects, rather than Moose::Meta::Attribute. And
 174     # Class::MOP::Attribute attributes have no type constraints.
 175     # However we need to make sure we leave an undef value there
 176     # because the inlined code is using the index of the attributes
 177     # to determine where to find the type constraint
 178
 179     my $attrs = $self->attributes;
 180
 181     my @type_constraints = map {
 182         $_->can('type_constraint') ? $_->type_constraint : undef
 183     } @$attrs;
 184
 185     my @type_constraint_bodies = map {
 186         defined $_ ? $_->_compiled_type_constraint : undef;
 187     } @type_constraints;
 188
 189     my $code = $self->_compile_code(
 190         code => $source,
 191         environment => {
 192             '$meta'  => \$self,
 193             '$attrs' => \$attrs,
 194             '@type_constraints' => \@type_constraints,
 195             '@type_constraint_bodies' => \@type_constraint_bodies,
 196         },
 197     ) or $self->throw_error("Could not eval the constructor :\n\n$source\n\nbecause :\n\n$@", error => $@, data => $source );
 198
 199     $self->{'body'} = $code;
 200 }
 201
 202 sub _generate_BUILDARGS {
 203     my ( $self, $class, $args ) = @_;
 204
 205     my $buildargs = $self->associated_metaclass->find_method_by_name("BUILDARGS");
 206
 207     if ( $args eq '@_' and ( !$buildargs or $buildargs->body == \&Moose::Object::BUILDARGS ) ) {
 208         return join("\n",
 209             'do {',
 210             $self->_inline_throw_error('"Single parameters to new() must be a HASH ref"', 'data => $_[0]'),
 211             '    if scalar @_ == 1 && !( defined $_[0] && ref $_[0] eq q{HASH} );',
 212             '(scalar @_ == 1) ? {%{$_[0]}} : {@_};',
 213             '}',
 214         );
 215     } else {
 216         return $class . "->BUILDARGS($args)";
 217     }
 218 }
 219
 220 sub _generate_BUILDALL {
 221     my $self = shift;
 222     my @BUILD_calls;
 223     foreach my $method (reverse $self->associated_metaclass->find_all_methods_by_name('BUILD')) {
 224         push @BUILD_calls => '$instance->' . $method->{class} . '::BUILD($params)';
 225     }
 226     return join ";\n" => @BUILD_calls;
 227 }
 228
 229 sub _generate_triggers {
 230     my $self = shift;
 231     my @trigger_calls;
 232     foreach my $i ( 0 .. $#{ $self->attributes } ) {
 233         my $attr = $self->attributes->[$i];
 234
 235         next unless $attr->can('has_trigger') && $attr->has_trigger;
 236
 237         my $init_arg = $attr->init_arg;
 238
 239         next unless defined $init_arg;
 240
 241         push @trigger_calls => '(exists $params->{\''
 242             . $init_arg
 243             . '\'}) && do {'
 244             . "\n    "
 245             . '$attrs->['
 246             . $i
 247             . ']->trigger->('
 248             . '$instance, '
 249             . $self->meta_instance->inline_get_slot_value(
 250                   '$instance',
 251                   $attr->name,
 252               )
 253             . ', '
 254             . '$attrs->['
 255             . $i . ']' . ');' . "\n}";
 256     }
 257
 258     return join ";\n" => @trigger_calls;
 259 }
 260
 261 sub _generate_slot_initializer {
 262     my $self  = shift;
 263     my $index = shift;
 264
 265     my $attr = $self->attributes->[$index];
 266
 267     my @source = ('## ' . $attr->name);
 268
 269     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 270
 271     if ($is_moose && defined($attr->init_arg) && $attr->is_required && !$attr->has_default && !$attr->has_builder) {
 272         push @source => ('(exists $params->{\'' . $attr->init_arg . '\'}) ' .
 273                         '|| ' . $self->_inline_throw_error('"Attribute (' . $attr->name . ') is required"') .';');
 274     }
 275
 276     if (($attr->has_default || $attr->has_builder) && !($is_moose && $attr->is_lazy)) {
 277
 278         if ( defined( my $init_arg = $attr->init_arg ) ) {
 279             push @source => 'if (exists $params->{\'' . $init_arg . '\'}) {';
 280             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 281             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 282                 if $is_moose;
 283             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 284             push @source => "} else {";
 285         }
 286             my $default;
 287             if ( $attr->has_default ) {
 288                 $default = $self->_generate_default_value($attr, $index);
 289             }
 290             else {
 291                my $builder = $attr->builder;
 292                $default = '$instance->' . $builder;
 293             }
 294
 295             push @source => '{'; # wrap this to avoid my $val overwrite warnings
 296             push @source => ('my $val = ' . $default . ';');
 297             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 298                 if $is_moose;
 299             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 300             push @source => '}'; # close - wrap this to avoid my $val overrite warnings
 301
 302         push @source => "}" if defined $attr->init_arg;
 303     }
 304     elsif ( defined( my $init_arg = $attr->init_arg ) ) {
 305         push @source => '(exists $params->{\'' . $init_arg . '\'}) && do {';
 306
 307             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 308             if ($is_moose && $attr->has_type_constraint) {
 309                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 310                     push @source => $self->_generate_type_coercion(
 311                         $attr,
 312                         '$type_constraints[' . $index . ']',
 313                         '$val',
 314                         '$val'
 315                     );
 316                 }
 317                 push @source => $self->_generate_type_constraint_check(
 318                     $attr,
 319                     '$type_constraint_bodies[' . $index . ']',
 320                     '$type_constraints[' . $index . ']',
 321                     '$val'
 322                 );
 323             }
 324             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 325
 326         push @source => "}";
 327     }
 328
 329     return join "\n" => @source;
 330 }
 331
 332 sub _generate_slot_assignment {
 333     my ($self, $attr, $value, $index) = @_;
 334
 335     my $source;
 336
 337     if ($attr->has_initializer) {
 338         $source = (
 339             '$attrs->[' . $index . ']->set_initial_value($instance, ' . $value . ');'
 340         );
 341     }
 342     else {
 343         $source = (
 344             $self->meta_instance->inline_set_slot_value(
 345                 '$instance',
 346                 $attr->name,
 347                 $value
 348             ) . ';'
 349         );
 350     }
 351
 352     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 353
 354     if ($is_moose && $attr->is_weak_ref) {
 355         $source .= (
 356             "\n" .
 357             $self->meta_instance->inline_weaken_slot_value(
 358                 '$instance',
 359                 $attr->name
 360             ) .
 361             ' if ref ' . $value . ';'
 362         );
 363     }
 364
 365     return $source;
 366 }
 367
 368 sub _generate_type_constraint_and_coercion {
 369     my ($self, $attr, $index) = @_;
 370
 371     return unless $attr->has_type_constraint;
 372
 373     my @source;
 374     if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 375         push @source => $self->_generate_type_coercion(
 376             $attr,
 377             '$type_constraints[' . $index . ']',
 378             '$val',
 379             '$val'
 380         );
 381     }
 382     push @source => $self->_generate_type_constraint_check(
 383         $attr,
 384         ('$type_constraint_bodies[' . $index . ']'),
 385         ('$type_constraints[' . $index . ']'),
 386         '$val'
 387     );
 388     return @source;
 389 }
 390
 391 sub _generate_type_coercion {
 392     my ($self, $attr, $type_constraint_name, $value_name, $return_value_name) = @_;
 393     return ($return_value_name . ' = ' . $type_constraint_name .  '->coerce(' . $value_name . ');');
 394 }
 395
 396 sub _generate_type_constraint_check {
 397     my ($self, $attr, $type_constraint_cv, $type_constraint_obj, $value_name) = @_;
 398     return (
 399         $self->_inline_throw_error('"Attribute (' # FIXME add 'dad'
 400         . $attr->name
 401         . ') does not pass the type constraint because: " . '
 402         . $type_constraint_obj . '->get_message(' . $value_name . ')')
 403         . "\n\t unless " .  $type_constraint_cv . '->(' . $value_name . ');'
 404     );
 405 }
 406
 407 sub _generate_default_value {
 408     my ($self, $attr, $index) = @_;
 409     # NOTE:
 410     # default values can either be CODE refs
 411     # in which case we need to call them. Or
 412     # they can be scalars (strings/numbers)
 413     # in which case we can just deal with them
 414     # in the code we eval.
 415     if ($attr->is_default_a_coderef) {
 416         return '$attrs->[' . $index . ']->default($instance)';
 417     }
 418     else {
 419         return q{"} . quotemeta( $attr->default ) . q{"};
 420     }
 421 }
 422
 423 1;
 424
 425 __END__
 426
 427 =pod
 428
 429 =head1 NAME
 430
 431 Moose::Meta::Method::Constructor - Method Meta Object for constructors
 432
 433 =head1 DESCRIPTION
 434
 435 This is a subclass of L<Class::MOP::Method> which handles
 436 constructing an appropriate Constructor methods. This is primarily
 437 used in the making of immutable metaclasses, otherwise it is
 438 not particularly useful.
 439
 440 =head1 METHODS
 441
 442 =over 4
 443
 444 =item B<new>
 445
 446 =item B<can_be_inlined>
 447
 448 =item B<attributes>
 449
 450 =item B<meta_instance>
 451
 452 =item B<options>
 453
 454 =item B<initialize_body>
 455
 456 =item B<associated_metaclass>
 457
 458 =back
 459
 460 =head1 AUTHORS
 461
 462 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 463
 464 =head1 COPYRIGHT AND LICENSE
 465
 466 Copyright 2006-2009 by Infinity Interactive, Inc.
 467
 468 L<http://www.iinteractive.com>
 469
 470 This library is free software; you can redistribute it and/or modify
 471 it under the same terms as Perl itself.
 472
 473 =cut
 474