lib/Moose/Meta/Method/Constructor.pm

   1
   2 package Moose::Meta::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed', 'weaken', 'looks_like_number';
   9
  10 our $VERSION   = '0.01';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::Method';
  14
  15 sub new {
  16     my $class   = shift;
  17     my %options = @_;
  18
  19     (exists $options{options} && ref $options{options} eq 'HASH')
  20         || confess "You must pass a hash of options";
  21
  22     my $self = bless {
  23         # from our superclass
  24         '&!body'          => undef,
  25         # specific to this subclass
  26         '%!options'       => $options{options},
  27         '$!meta_instance' => $options{metaclass}->get_meta_instance,
  28         '@!attributes'    => [ $options{metaclass}->compute_all_applicable_attributes ],
  29         # ...
  30         '$!associated_metaclass' => $options{metaclass},
  31     } => $class;
  32
  33     # we don't want this creating
  34     # a cycle in the code, if not
  35     # needed
  36     weaken($self->{'$!associated_metaclass'});
  37
  38     $self->intialize_body;
  39
  40     return $self;
  41 }
  42
  43 ## accessors
  44
  45 sub options       { (shift)->{'%!options'}       }
  46 sub meta_instance { (shift)->{'$!meta_instance'} }
  47 sub attributes    { (shift)->{'@!attributes'}    }
  48
  49 sub associated_metaclass { (shift)->{'$!associated_metaclass'} }
  50
  51 ## method
  52
  53 sub intialize_body {
  54     my $self = shift;
  55     # TODO:
  56     # the %options should also include a both
  57     # a call 'initializer' and call 'SUPER::'
  58     # options, which should cover approx 90%
  59     # of the possible use cases (even if it
  60     # requires some adaption on the part of
  61     # the author, after all, nothing is free)
  62     my $source = 'sub {';
  63     $source .= "\n" . 'my $class = shift;';
  64
  65     $source .= "\n" . 'return $class->Moose::Object::new(@_)';
  66     $source .= "\n" . '    if $class ne \'' . $self->associated_metaclass->name . '\';';
  67
  68     $source .= "\n" . 'my %params = (scalar @_ == 1) ? %{$_[0]} : @_;';
  69
  70     $source .= "\n" . 'my $instance = ' . $self->meta_instance->inline_create_instance('$class');
  71
  72     $source .= ";\n" . (join ";\n" => map {
  73         $self->_generate_slot_initializer($_)
  74     } 0 .. (@{$self->attributes} - 1));
  75
  76     $source .= ";\n" . $self->_generate_BUILDALL();
  77
  78     $source .= ";\n" . 'return $instance';
  79     $source .= ";\n" . '}';
  80     warn $source if $self->options->{debug};
  81
  82     my $code;
  83     {
  84         # NOTE:
  85         # create the nessecary lexicals
  86         # to be picked up in the eval
  87         my $attrs = $self->attributes;
  88
  89         $code = eval $source;
  90         confess "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$@" if $@;
  91     }
  92     $self->{'&!body'} = $code;
  93 }
  94
  95 sub _generate_BUILDALL {
  96     my $self = shift;
  97     my @BUILD_calls;
  98     foreach my $method (reverse $self->associated_metaclass->find_all_methods_by_name('BUILD')) {
  99         push @BUILD_calls => '$instance->' . $method->{class} . '::BUILD(\%params)';
 100     }
 101     return join "\n" => @BUILD_calls;
 102 }
 103
 104 sub _generate_slot_initializer {
 105     my $self  = shift;
 106     my $index = shift;
 107
 108     my $attr = $self->attributes->[$index];
 109
 110     my @source = ('## ' . $attr->name);
 111
 112     if ($attr->is_required && !$attr->has_default) {
 113         push @source => ('(exists $params{\'' . $attr->init_arg . '\'}) ' .
 114                         '|| confess "Attribute (' . $attr->name . ') is required";');
 115     }
 116
 117     if ($attr->has_default && !$attr->is_lazy) {
 118
 119         push @source => 'if (exists $params{\'' . $attr->init_arg . '\'}) {';
 120
 121             push @source => ('my $val = $params{\'' . $attr->init_arg . '\'};');
 122             if ($attr->has_type_constraint) {
 123                 push @source => ('my $type_constraint = $attrs->[' . $index . ']->type_constraint;');
 124
 125                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 126                     push @source => $self->_generate_type_coercion($attr, '$type_constraint', '$val', '$val');
 127                 }
 128                 push @source => $self->_generate_type_constraint_check($attr, '$type_constraint', '$val');
 129             }
 130             push @source => $self->_generate_slot_assignment($attr, '$val');
 131
 132
 133         push @source => "} else {";
 134
 135             my $default = $self->_generate_default_value($attr, $index);
 136
 137             push @source => ('my $val = ' . $default . ';');
 138             push @source => $self->_generate_type_constraint_check(
 139                 $attr,
 140                 ('$attrs->[' . $index . ']->type_constraint'),
 141                 '$val'
 142             ) if $attr->has_type_constraint;
 143             push @source => $self->_generate_slot_assignment($attr, $default);
 144
 145         push @source => "}";
 146     }
 147     else {
 148         push @source => '(exists $params{\'' . $attr->init_arg . '\'}) && do {';
 149
 150             push @source => ('my $val = $params{\'' . $attr->init_arg . '\'};');
 151             if ($attr->has_type_constraint) {
 152                 push @source => ('my $type_constraint = $attrs->[' . $index . ']->type_constraint;');
 153
 154                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 155                     push @source => $self->_generate_type_coercion($attr, '$type_constraint', '$val', '$val');
 156                 }
 157                 push @source => $self->_generate_type_constraint_check($attr, '$type_constraint', '$val');
 158             }
 159             push @source => $self->_generate_slot_assignment($attr, '$val');
 160
 161         push @source => "}";
 162     }
 163
 164     return join "\n" => @source;
 165 }
 166
 167 sub _generate_slot_assignment {
 168     my ($self, $attr, $value) = @_;
 169     my $source = (
 170         $self->meta_instance->inline_set_slot_value(
 171             '$instance',
 172             ("'" . $attr->name . "'"),
 173             $value
 174         ) . ';'
 175     );
 176
 177     if ($attr->is_weak_ref) {
 178         $source .= (
 179             "\n" .
 180             $self->meta_instance->inline_weaken_slot_value(
 181                 '$instance',
 182                 ("'" . $attr->name . "'")
 183             ) .
 184             ' if ref ' . $value . ';'
 185         );
 186     }
 187
 188     return $source;
 189 }
 190
 191 sub _generate_type_coercion {
 192     my ($self, $attr, $type_constraint_name, $value_name, $return_value_name) = @_;
 193     return ($return_value_name . ' = ' . $type_constraint_name .  '->coerce(' . $value_name . ');');
 194 }
 195
 196 sub _generate_type_constraint_check {
 197     my ($self, $attr, $type_constraint_name, $value_name) = @_;
 198     return (
 199         'defined(' . $type_constraint_name . '->_compiled_type_constraint->(' . $value_name . '))'
 200         . "\n\t" . '|| confess "Attribute (' . $attr->name . ') does not pass the type constraint ('
 201         . $attr->type_constraint->name . ') with " . (defined() ? "' . $value_name . '" : "undef");'
 202     );
 203 }
 204
 205 sub _generate_default_value {
 206     my ($self, $attr, $index) = @_;
 207     # NOTE:
 208     # default values can either be CODE refs
 209     # in which case we need to call them. Or
 210     # they can be scalars (strings/numbers)
 211     # in which case we can just deal with them
 212     # in the code we eval.
 213     if ($attr->is_default_a_coderef) {
 214         return '$attrs->[' . $index . ']->default($instance)';
 215     }
 216     else {
 217         my $default = $attr->default;
 218         # make sure to quote strings ...
 219         unless (looks_like_number($default)) {
 220             $default = "'$default'";
 221         }
 222
 223         return $default;
 224     }
 225 }
 226
 227 1;
 228
 229 1;
 230
 231 __END__
 232
 233 =pod
 234
 235 =head1 NAME
 236
 237 Moose::Meta::Method::Constructor - Method Meta Object for constructors
 238
 239 =head1 SYNOPSIS
 240
 241 =head1 DESCRIPTION
 242
 243 =head1 METHODS
 244
 245 =over 4
 246
 247 =item B<new>
 248
 249 =item B<attributes>
 250
 251 =item B<meta_instance>
 252
 253 =item B<options>
 254
 255 =item B<intialize_body>
 256
 257 =item B<associated_metaclass>
 258
 259 =back
 260
 261 =head1 AUTHORS
 262
 263 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 264
 265 =head1 COPYRIGHT AND LICENSE
 266
 267 Copyright 2006 by Infinity Interactive, Inc.
 268
 269 L<http://www.iinteractive.com>
 270
 271 This library is free software; you can redistribute it and/or modify
 272 it under the same terms as Perl itself.
 273
 274 =cut
 275