lib/Moose/Meta/Method/Constructor.pm

   1
   2 package Moose::Meta::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp ();
   8 use Scalar::Util 'blessed', 'weaken', 'looks_like_number', 'refaddr';
   9
  10 our $VERSION   = '1.15';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::Method',
  14          'Class::MOP::Method::Constructor';
  15
  16 sub new {
  17     my $class   = shift;
  18     my %options = @_;
  19
  20     my $meta = $options{metaclass};
  21
  22     (ref $options{options} eq 'HASH')
  23         || $class->throw_error("You must pass a hash of options", data => $options{options});
  24
  25     ($options{package_name} && $options{name})
  26         || $class->throw_error("You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT");
  27
  28     my $self = bless {
  29         'body'          => undef,
  30         'package_name'  => $options{package_name},
  31         'name'          => $options{name},
  32         'options'       => $options{options},
  33         'associated_metaclass' => $meta,
  34         '_expected_method_class' => $options{_expected_method_class} || 'Moose::Object',
  35     } => $class;
  36
  37     # we don't want this creating
  38     # a cycle in the code, if not
  39     # needed
  40     weaken($self->{'associated_metaclass'});
  41
  42     $self->_initialize_body;
  43
  44     return $self;
  45 }
  46
  47 ## method
  48
  49 sub _initialize_body {
  50     my $self = shift;
  51     # TODO:
  52     # the %options should also include a both
  53     # a call 'initializer' and call 'SUPER::'
  54     # options, which should cover approx 90%
  55     # of the possible use cases (even if it
  56     # requires some adaption on the part of
  57     # the author, after all, nothing is free)
  58     my $source = 'sub {';
  59     $source .= "\n" . 'my $_instance = shift;';
  60
  61     $source .= "\n" . 'my $class = Scalar::Util::blessed($_instance) || $_instance;';
  62
  63     $source .= "\n" . "if (\$class ne '" . $self->associated_metaclass->name
  64             .  "') {";
  65     $source .= "\n    return "
  66             .  $self->_generate_fallback_constructor('$class') . ";";
  67     $source .= "\n}\n";
  68
  69     $source .= $self->_generate_params('$params', '$class');
  70     $source .= $self->_generate_instance('$instance', '$class');
  71     $source .= $self->_generate_slot_initializers;
  72
  73     $source .= $self->_generate_triggers();
  74     $source .= ";\n" . $self->_generate_BUILDALL();
  75
  76     $source .= ";\nreturn \$instance";
  77     $source .= ";\n" . '}';
  78     warn $source if $self->options->{debug};
  79
  80     # We need to check if the attribute ->can('type_constraint')
  81     # since we may be trying to immutabilize a Moose meta class,
  82     # which in turn has attributes which are Class::MOP::Attribute
  83     # objects, rather than Moose::Meta::Attribute. And
  84     # Class::MOP::Attribute attributes have no type constraints.
  85     # However we need to make sure we leave an undef value there
  86     # because the inlined code is using the index of the attributes
  87     # to determine where to find the type constraint
  88
  89     my $attrs = $self->_attributes;
  90
  91     my @type_constraints = map {
  92         $_->can('type_constraint') ? $_->type_constraint : undef
  93     } @$attrs;
  94
  95     my @type_constraint_bodies = map {
  96         defined $_ ? $_->_compiled_type_constraint : undef;
  97     } @type_constraints;
  98
  99     my $defaults = [map { $_->default } @$attrs];
 100
 101     my ( $code, $e ) = $self->_compile_code(
 102         code => $source,
 103         environment => {
 104             '$meta'  => \$self,
 105             '$attrs' => \$attrs,
 106             '$defaults' => \$defaults,
 107             '@type_constraints' => \@type_constraints,
 108             '@type_constraint_bodies' => \@type_constraint_bodies,
 109         },
 110     );
 111
 112     $self->throw_error(
 113         "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$e",
 114         error => $e, data => $source )
 115         if $e;
 116
 117     $self->{'body'} = $code;
 118 }
 119
 120 sub _generate_fallback_constructor {
 121     my ( $self, $class_var ) = @_;
 122     "${class_var}->Moose::Object::new(\@_)";
 123 }
 124
 125 sub _generate_params {
 126     my ( $self, $var, $class_var ) = @_;
 127     "my $var = " . $self->_generate_BUILDARGS( $class_var, '@_' ) . ";\n";
 128 }
 129
 130 sub _generate_instance {
 131     my ( $self, $var, $class_var ) = @_;
 132     "my $var = "
 133         . $self->associated_metaclass->inline_create_instance($class_var) . ";\n";
 134 }
 135
 136 sub _generate_slot_initializers {
 137     my ($self) = @_;
 138     return (join ";\n" => map {
 139         $self->_generate_slot_initializer($_)
 140     } 0 .. (@{$self->_attributes} - 1)) . ";\n";
 141 }
 142
 143 sub _generate_BUILDARGS {
 144     my ( $self, $class, $args ) = @_;
 145
 146     my $buildargs = $self->associated_metaclass->find_method_by_name("BUILDARGS");
 147
 148     if ( $args eq '@_'
 149         and ( !$buildargs or $buildargs->body == \&Moose::Object::BUILDARGS )
 150         ) {
 151
 152         # This is basically a copy of Moose::Object::BUILDARGS wrapped in a do
 153         # {} block.
 154         return sprintf( <<'EOF', $self->_inline_throw_error( q{'Single parameters to new() must be a HASH ref'}, 'data => $_[0]' ) );
 155 do {
 156     my $params;
 157     if ( scalar @_ == 1 ) {
 158         unless ( defined $_[0] && ref $_[0] eq 'HASH' ) {
 159             %s
 160         }
 161         $params = { %%{ $_[0] } };
 162     }
 163     elsif ( @_ %% 2 ) {
 164         Carp::carp(
 165             "The new() method for $class expects a hash reference or a key/value list."
 166                 . " You passed an odd number of arguments" );
 167         $params = { @_, undef };
 168     }
 169     else {
 170         $params = {@_};
 171     }
 172     $params
 173 };
 174 EOF
 175             ;
 176     }
 177     else {
 178         return $class . "->BUILDARGS($args)";
 179     }
 180 }
 181
 182 sub _generate_BUILDALL {
 183     my $self = shift;
 184     my @BUILD_calls;
 185     foreach my $method (reverse $self->associated_metaclass->find_all_methods_by_name('BUILD')) {
 186         push @BUILD_calls => '$instance->' . $method->{class} . '::BUILD($params)';
 187     }
 188     return join ";\n" => @BUILD_calls;
 189 }
 190
 191 sub _generate_triggers {
 192     my $self = shift;
 193     my @trigger_calls;
 194     foreach my $i ( 0 .. $#{ $self->_attributes } ) {
 195         my $attr = $self->_attributes->[$i];
 196
 197         next unless $attr->can('has_trigger') && $attr->has_trigger;
 198
 199         my $init_arg = $attr->init_arg;
 200
 201         next unless defined $init_arg;
 202
 203         push @trigger_calls => '(exists $params->{\''
 204             . $init_arg
 205             . '\'}) && do {'
 206             . "\n    "
 207             . '$attrs->['
 208             . $i
 209             . ']->trigger->('
 210             . '$instance, '
 211             . $attr->inline_get('$instance')
 212             . ', '
 213             . ');' . "\n}";
 214     }
 215
 216     return join ";\n" => @trigger_calls;
 217 }
 218
 219 sub _generate_slot_initializer {
 220     my $self  = shift;
 221     my $index = shift;
 222
 223     my $attr = $self->_attributes->[$index];
 224
 225     my @source = ('## ' . $attr->name);
 226
 227     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 228
 229     if ($is_moose && defined($attr->init_arg) && $attr->is_required && !$attr->has_default && !$attr->has_builder) {
 230         push @source => ('(exists $params->{\'' . $attr->init_arg . '\'}) ' .
 231                         '|| ' . $self->_inline_throw_error('"Attribute (' . quotemeta($attr->name) . ') is required"') .';');
 232     }
 233
 234     if (($attr->has_default || $attr->has_builder) && !($is_moose && $attr->is_lazy)) {
 235
 236         if ( defined( my $init_arg = $attr->init_arg ) ) {
 237             push @source => 'if (exists $params->{\'' . $init_arg . '\'}) {';
 238             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 239             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 240                 if $is_moose;
 241             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 242             push @source => "} else {";
 243         }
 244             my $default;
 245             if ( $attr->has_default ) {
 246                 $default = $self->_generate_default_value($attr, $index);
 247             }
 248             else {
 249                my $builder = $attr->builder;
 250                $default = '$instance->' . $builder;
 251             }
 252
 253             push @source => '{'; # wrap this to avoid my $val overwrite warnings
 254             push @source => ('my $val = ' . $default . ';');
 255             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 256                 if $is_moose;
 257             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 258             push @source => '}'; # close - wrap this to avoid my $val overrite warnings
 259
 260         push @source => "}" if defined $attr->init_arg;
 261     }
 262     elsif ( defined( my $init_arg = $attr->init_arg ) ) {
 263         push @source => '(exists $params->{\'' . $init_arg . '\'}) && do {';
 264
 265             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 266             if ($is_moose && $attr->has_type_constraint) {
 267                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 268                     push @source => $self->_generate_type_coercion(
 269                         $attr,
 270                         '$type_constraints[' . $index . ']',
 271                         '$val',
 272                         '$val'
 273                     );
 274                 }
 275                 push @source => $self->_generate_type_constraint_check(
 276                     $attr,
 277                     '$type_constraint_bodies[' . $index . ']',
 278                     '$type_constraints[' . $index . ']',
 279                     '$val'
 280                 );
 281             }
 282             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 283
 284         push @source => "}";
 285     }
 286
 287     return join "\n" => @source;
 288 }
 289
 290 sub _generate_slot_assignment {
 291     my ($self, $attr, $value, $index) = @_;
 292
 293     my $source;
 294
 295     if ( $attr->has_initializer ) {
 296         return
 297               '$attrs->['
 298             . $index
 299             . ']->set_initial_value($instance, '
 300             . $value . ');';
 301     }
 302     else {
 303         return $attr->inline_set(
 304             '$instance',
 305             $value
 306         ) . ';';
 307     }
 308
 309     return $source;
 310 }
 311
 312 sub _generate_type_constraint_and_coercion {
 313     my ($self, $attr, $index) = @_;
 314
 315     return unless $attr->has_type_constraint;
 316
 317     my @source;
 318     if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 319         push @source => $self->_generate_type_coercion(
 320             $attr,
 321             '$type_constraints[' . $index . ']',
 322             '$val',
 323             '$val'
 324         );
 325     }
 326     push @source => $self->_generate_type_constraint_check(
 327         $attr,
 328         ('$type_constraint_bodies[' . $index . ']'),
 329         ('$type_constraints[' . $index . ']'),
 330         '$val'
 331     );
 332     return @source;
 333 }
 334
 335 sub _generate_type_coercion {
 336     my ($self, $attr, $type_constraint_name, $value_name, $return_value_name) = @_;
 337     return ($return_value_name . ' = ' . $type_constraint_name .  '->coerce(' . $value_name . ');');
 338 }
 339
 340 sub _generate_type_constraint_check {
 341     my ($self, $attr, $type_constraint_cv, $type_constraint_obj, $value_name) = @_;
 342     return (
 343         $self->_inline_throw_error('"Attribute (' # FIXME add 'dad'
 344         . quotemeta( $attr->name )
 345         . ') does not pass the type constraint because: " . '
 346         . $type_constraint_obj . '->get_message(' . $value_name . ')')
 347         . "\n\t unless " .  $type_constraint_cv . '->(' . $value_name . ');'
 348     );
 349 }
 350
 351 1;
 352
 353 __END__
 354
 355 =pod
 356
 357 =head1 NAME
 358
 359 Moose::Meta::Method::Constructor - Method Meta Object for constructors
 360
 361 =head1 DESCRIPTION
 362
 363 This class is a subclass of L<Class::MOP::Method::Constructor> that
 364 provides additional Moose-specific functionality
 365
 366 To understand this class, you should read the the
 367 L<Class::MOP::Method::Constructor> documentation as well.
 368
 369 =head1 INHERITANCE
 370
 371 C<Moose::Meta::Method::Constructor> is a subclass of
 372 L<Moose::Meta::Method> I<and> L<Class::MOP::Method::Constructor>.
 373
 374 =head1 BUGS
 375
 376 See L<Moose/BUGS> for details on reporting bugs.
 377
 378 =head1 AUTHORS
 379
 380 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 381
 382 =head1 COPYRIGHT AND LICENSE
 383
 384 Copyright 2006-2010 by Infinity Interactive, Inc.
 385
 386 L<http://www.iinteractive.com>
 387
 388 This library is free software; you can redistribute it and/or modify
 389 it under the same terms as Perl itself.
 390
 391 =cut
 392