lib/Moose/Meta/Method/Constructor.pm

   1
   2 package Moose::Meta::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed', 'weaken', 'looks_like_number';
   8
   9 our $VERSION   = '0.63';
  10 our $AUTHORITY = 'cpan:STEVAN';
  11
  12 use base 'Moose::Meta::Method',
  13          'Class::MOP::Method::Generated';
  14
  15 sub new {
  16     my $class   = shift;
  17     my %options = @_;
  18
  19     my $meta = $options{metaclass};
  20
  21     (ref $options{options} eq 'HASH')
  22         || $class->throw_error("You must pass a hash of options", data => $options{options});
  23
  24     ($options{package_name} && $options{name})
  25         || $class->throw_error("You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT");
  26
  27     my $self = bless {
  28         # from our superclass
  29         'body'          => undef,
  30         'package_name'  => $options{package_name},
  31         'name'          => $options{name},
  32         # specific to this subclass
  33         'options'       => $options{options},
  34         'meta_instance' => $meta->get_meta_instance,
  35         'attributes'    => [ $meta->compute_all_applicable_attributes ],
  36         # ...
  37         'associated_metaclass' => $meta,
  38     } => $class;
  39
  40     # we don't want this creating
  41     # a cycle in the code, if not
  42     # needed
  43     weaken($self->{'associated_metaclass'});
  44
  45     $self->initialize_body;
  46
  47     return $self;
  48 }
  49
  50 sub can_be_inlined {
  51     my $self      = shift;
  52     my $metaclass = $self->associated_metaclass;
  53
  54     my $expected_class = $self->_expected_constructor_class;
  55
  56     # If any of our parents have been made immutable, we are okay to
  57     # inline our own new method. The assumption is that an inlined new
  58     # method provided by a parent does not actually get used by
  59     # children anyway.
  60     for my $meta (
  61         grep { $_->is_immutable }
  62         map  { ( ref $metaclass )->initialize($_) }
  63         grep { $_ ne $expected_class }
  64         $metaclass->linearized_isa
  65         ) {
  66         my $transformer = $meta->get_immutable_transformer;
  67
  68         # This is actually a false positive if we're in a subclass of
  69         # this class, _and_ the expected class is not overridden (but
  70         # should be), and the real expected class is actually
  71         # immutable itself (see Fey::Object::Table for an example of
  72         # how this can happen). I'm not sure how to actually handle
  73         # that case, since it's effectively a bug in the subclass (for
  74         # not overriding _expected_constructor_class).
  75         return 1 if $transformer->inlined_constructor;
  76     }
  77
  78     if ( my $constructor = $metaclass->find_method_by_name( $self->name ) ) {
  79         my $class = $self->associated_metaclass->name;
  80
  81         if ( $constructor->body != $expected_class->can('new') ) {
  82             my $warning
  83                 = "Not inlining a constructor for $class since it is not"
  84                 . " inheriting the default $expected_class constructor\n";
  85
  86             $warning .= " (constructor has method modifiers which would be lost if it were inlined)\n"
  87                 if $constructor->isa('Class::MOP::Method::Wrapped');
  88
  89             warn $warning;
  90
  91             return 0;
  92         }
  93         else {
  94             return 1;
  95         }
  96     }
  97
  98     # This would be a rather weird case where we have no constructor
  99     # in the inheritance chain.
 100     return 1;
 101 }
 102
 103 # This is here so can_be_inlined can be inherited by MooseX modules.
 104 sub _expected_constructor_class {
 105     return 'Moose::Object';
 106 }
 107
 108 ## accessors
 109
 110 sub options       { (shift)->{'options'}       }
 111 sub meta_instance { (shift)->{'meta_instance'} }
 112 sub attributes    { (shift)->{'attributes'}    }
 113
 114 sub associated_metaclass { (shift)->{'associated_metaclass'} }
 115
 116 ## method
 117
 118 # this was changed in 0.41, but broke MooseX::Singleton, so try to catch
 119 # any other code using the original broken spelling
 120 sub intialize_body { Moose->throw_error("Please correct the spelling of 'intialize_body' to 'initialize_body'") }
 121
 122 sub initialize_body {
 123     my $self = shift;
 124     # TODO:
 125     # the %options should also include a both
 126     # a call 'initializer' and call 'SUPER::'
 127     # options, which should cover approx 90%
 128     # of the possible use cases (even if it
 129     # requires some adaption on the part of
 130     # the author, after all, nothing is free)
 131     my $source = 'sub {';
 132     $source .= "\n" . 'my $class = shift;';
 133
 134     $source .= "\n" . 'return $class->Moose::Object::new(@_)';
 135     $source .= "\n" . '    if $class ne \'' . $self->associated_metaclass->name . '\';';
 136
 137     $source .= "\n" . 'my $params = ' . $self->_generate_BUILDARGS('$class', '@_');
 138
 139     $source .= ";\n" . 'my $instance = ' . $self->meta_instance->inline_create_instance('$class');
 140
 141     $source .= ";\n" . (join ";\n" => map {
 142         $self->_generate_slot_initializer($_)
 143     } 0 .. (@{$self->attributes} - 1));
 144
 145     $source .= ";\n" . $self->_generate_triggers();
 146     $source .= ";\n" . $self->_generate_BUILDALL();
 147
 148     $source .= ";\n" . 'return $instance';
 149     $source .= ";\n" . '}';
 150     warn $source if $self->options->{debug};
 151
 152     my $code;
 153     my $environment = q{
 154         my $meta = $self; # FIXME for _inline_throw_error...
 155
 156         # NOTE:
 157         # create the nessecary lexicals
 158         # to be picked up in the eval
 159         my $attrs = $self->attributes;
 160
 161         # We need to check if the attribute ->can('type_constraint')
 162         # since we may be trying to immutabilize a Moose meta class,
 163         # which in turn has attributes which are Class::MOP::Attribute
 164         # objects, rather than Moose::Meta::Attribute. And
 165         # Class::MOP::Attribute attributes have no type constraints.
 166         # However we need to make sure we leave an undef value there
 167         # because the inlined code is using the index of the attributes
 168         # to determine where to find the type constraint
 169
 170         my @type_constraints = map {
 171             $_->can('type_constraint') ? $_->type_constraint : undef
 172         } @$attrs;
 173
 174         my @type_constraint_bodies = map {
 175             defined $_ ? $_->_compiled_type_constraint : undef;
 176         } @type_constraints;
 177     };
 178     $code = $self->_eval_closure($environment, $source);
 179     $self->throw_error("Could not eval the constructor :\n\n$source\n\nbecause :\n\n$@", error => $@, data => $source ) if $@;
 180     $self->{'body'} = $code;
 181 }
 182
 183 sub _generate_BUILDARGS {
 184     my ( $self, $class, $args ) = @_;
 185
 186     my $buildargs = $self->associated_metaclass->find_method_by_name("BUILDARGS");
 187
 188     if ( $args eq '@_' and ( !$buildargs or $buildargs->body == \&Moose::Object::BUILDARGS ) ) {
 189         return join("\n",
 190             'do {',
 191             $self->_inline_throw_error('"Single parameters to new() must be a HASH ref"', 'data => $_[0]'),
 192             '    if scalar @_ == 1 && defined $_[0] && ref($_[0]) ne q{HASH};',
 193             '(scalar @_ == 1) ? {%{$_[0]}} : {@_};',
 194             '}',
 195         );
 196     } else {
 197         return $class . "->BUILDARGS($args)";
 198     }
 199 }
 200
 201 sub _generate_BUILDALL {
 202     my $self = shift;
 203     my @BUILD_calls;
 204     foreach my $method (reverse $self->associated_metaclass->find_all_methods_by_name('BUILD')) {
 205         push @BUILD_calls => '$instance->' . $method->{class} . '::BUILD($params)';
 206     }
 207     return join ";\n" => @BUILD_calls;
 208 }
 209
 210 sub _generate_triggers {
 211     my $self = shift;
 212     my @trigger_calls;
 213     foreach my $i (0 .. $#{ $self->attributes }) {
 214         my $attr = $self->attributes->[$i];
 215         if ($attr->can('has_trigger') && $attr->has_trigger) {
 216             if (defined(my $init_arg = $attr->init_arg)) {
 217                 push @trigger_calls => (
 218                     '(exists $params->{\'' . $init_arg . '\'}) && do {' . "\n    "
 219                     .   '$attrs->[' . $i . ']->trigger->('
 220                     .       '$instance, '
 221                     .        $self->meta_instance->inline_get_slot_value(
 222                                  '$instance',
 223                                  ("'" . $attr->name . "'")
 224                              )
 225                     .   ');'
 226                     ."\n}"
 227                 );
 228             }
 229         }
 230     }
 231     return join ";\n" => @trigger_calls;
 232 }
 233
 234 sub _generate_slot_initializer {
 235     my $self  = shift;
 236     my $index = shift;
 237
 238     my $attr = $self->attributes->[$index];
 239
 240     my @source = ('## ' . $attr->name);
 241
 242     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 243
 244     if ($is_moose && defined($attr->init_arg) && $attr->is_required && !$attr->has_default && !$attr->has_builder) {
 245         push @source => ('(exists $params->{\'' . $attr->init_arg . '\'}) ' .
 246                         '|| ' . $self->_inline_throw_error('"Attribute (' . $attr->name . ') is required"') .';');
 247     }
 248
 249     if (($attr->has_default || $attr->has_builder) && !($is_moose && $attr->is_lazy)) {
 250
 251         if ( defined( my $init_arg = $attr->init_arg ) ) {
 252             push @source => 'if (exists $params->{\'' . $init_arg . '\'}) {';
 253             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 254             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 255                 if $is_moose;
 256             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 257             push @source => "} else {";
 258         }
 259             my $default;
 260             if ( $attr->has_default ) {
 261                 $default = $self->_generate_default_value($attr, $index);
 262             }
 263             else {
 264                my $builder = $attr->builder;
 265                $default = '$instance->' . $builder;
 266             }
 267
 268             push @source => '{'; # wrap this to avoid my $val overwrite warnings
 269             push @source => ('my $val = ' . $default . ';');
 270             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 271                 if $is_moose;
 272             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 273             push @source => '}'; # close - wrap this to avoid my $val overrite warnings
 274
 275         push @source => "}" if defined $attr->init_arg;
 276     }
 277     elsif ( defined( my $init_arg = $attr->init_arg ) ) {
 278         push @source => '(exists $params->{\'' . $init_arg . '\'}) && do {';
 279
 280             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 281             if ($is_moose && $attr->has_type_constraint) {
 282                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 283                     push @source => $self->_generate_type_coercion(
 284                         $attr,
 285                         '$type_constraints[' . $index . ']',
 286                         '$val',
 287                         '$val'
 288                     );
 289                 }
 290                 push @source => $self->_generate_type_constraint_check(
 291                     $attr,
 292                     '$type_constraint_bodies[' . $index . ']',
 293                     '$type_constraints[' . $index . ']',
 294                     '$val'
 295                 );
 296             }
 297             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 298
 299         push @source => "}";
 300     }
 301
 302     return join "\n" => @source;
 303 }
 304
 305 sub _generate_slot_assignment {
 306     my ($self, $attr, $value, $index) = @_;
 307
 308     my $source;
 309
 310     if ($attr->has_initializer) {
 311         $source = (
 312             '$attrs->[' . $index . ']->set_initial_value($instance, ' . $value . ');'
 313         );
 314     }
 315     else {
 316         $source = (
 317             $self->meta_instance->inline_set_slot_value(
 318                 '$instance',
 319                 ("'" . $attr->name . "'"),
 320                 $value
 321             ) . ';'
 322         );
 323     }
 324
 325     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 326
 327     if ($is_moose && $attr->is_weak_ref) {
 328         $source .= (
 329             "\n" .
 330             $self->meta_instance->inline_weaken_slot_value(
 331                 '$instance',
 332                 ("'" . $attr->name . "'")
 333             ) .
 334             ' if ref ' . $value . ';'
 335         );
 336     }
 337
 338     return $source;
 339 }
 340
 341 sub _generate_type_constraint_and_coercion {
 342     my ($self, $attr, $index) = @_;
 343
 344     return unless $attr->has_type_constraint;
 345
 346     my @source;
 347     if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 348         push @source => $self->_generate_type_coercion(
 349             $attr,
 350             '$type_constraints[' . $index . ']',
 351             '$val',
 352             '$val'
 353         );
 354     }
 355     push @source => $self->_generate_type_constraint_check(
 356         $attr,
 357         ('$type_constraint_bodies[' . $index . ']'),
 358         ('$type_constraints[' . $index . ']'),
 359         '$val'
 360     );
 361     return @source;
 362 }
 363
 364 sub _generate_type_coercion {
 365     my ($self, $attr, $type_constraint_name, $value_name, $return_value_name) = @_;
 366     return ($return_value_name . ' = ' . $type_constraint_name .  '->coerce(' . $value_name . ');');
 367 }
 368
 369 sub _generate_type_constraint_check {
 370     my ($self, $attr, $type_constraint_cv, $type_constraint_obj, $value_name) = @_;
 371     return (
 372         $self->_inline_throw_error('"Attribute (' # FIXME add 'dad'
 373         . $attr->name
 374         . ') does not pass the type constraint because: " . '
 375         . $type_constraint_obj . '->get_message(' . $value_name . ')')
 376         . "\n\t unless " .  $type_constraint_cv . '->(' . $value_name . ');'
 377     );
 378 }
 379
 380 sub _generate_default_value {
 381     my ($self, $attr, $index) = @_;
 382     # NOTE:
 383     # default values can either be CODE refs
 384     # in which case we need to call them. Or
 385     # they can be scalars (strings/numbers)
 386     # in which case we can just deal with them
 387     # in the code we eval.
 388     if ($attr->is_default_a_coderef) {
 389         return '$attrs->[' . $index . ']->default($instance)';
 390     }
 391     else {
 392         return q{"} . quotemeta( $attr->default ) . q{"};
 393     }
 394 }
 395
 396 1;
 397
 398 __END__
 399
 400 =pod
 401
 402 =head1 NAME
 403
 404 Moose::Meta::Method::Constructor - Method Meta Object for constructors
 405
 406 =head1 DESCRIPTION
 407
 408 This is a subclass of L<Class::MOP::Method> which handles
 409 constructing an approprate Constructor methods. This is primarily
 410 used in the making of immutable metaclasses, otherwise it is
 411 not particularly useful.
 412
 413 =head1 METHODS
 414
 415 =over 4
 416
 417 =item B<new>
 418
 419 =item B<can_be_inlined>
 420
 421 =item B<attributes>
 422
 423 =item B<meta_instance>
 424
 425 =item B<options>
 426
 427 =item B<initialize_body>
 428
 429 =item B<associated_metaclass>
 430
 431 =item B<can_be_inlined>
 432
 433 =back
 434
 435 =head1 AUTHORS
 436
 437 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 438
 439 =head1 COPYRIGHT AND LICENSE
 440
 441 Copyright 2006-2008 by Infinity Interactive, Inc.
 442
 443 L<http://www.iinteractive.com>
 444
 445 This library is free software; you can redistribute it and/or modify
 446 it under the same terms as Perl itself.
 447
 448 =cut
 449