lib/Moose/Meta/Method/Constructor.pm

   1
   2 package Moose::Meta::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed', 'weaken', 'looks_like_number';
   8
   9 our $VERSION   = '0.64';
  10 our $AUTHORITY = 'cpan:STEVAN';
  11
  12 use base 'Moose::Meta::Method',
  13          'Class::MOP::Method::Generated';
  14
  15 sub new {
  16     my $class   = shift;
  17     my %options = @_;
  18
  19     my $meta = $options{metaclass};
  20
  21     (ref $options{options} eq 'HASH')
  22         || $class->throw_error("You must pass a hash of options", data => $options{options});
  23
  24     ($options{package_name} && $options{name})
  25         || $class->throw_error("You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT");
  26
  27     my $self = bless {
  28         # from our superclass
  29         'body'          => undef,
  30         'package_name'  => $options{package_name},
  31         'name'          => $options{name},
  32         # specific to this subclass
  33         'options'       => $options{options},
  34         'meta_instance' => $meta->get_meta_instance,
  35         'attributes'    => [ $meta->compute_all_applicable_attributes ],
  36         # ...
  37         'associated_metaclass' => $meta,
  38     } => $class;
  39
  40     # we don't want this creating
  41     # a cycle in the code, if not
  42     # needed
  43     weaken($self->{'associated_metaclass'});
  44
  45     $self->initialize_body;
  46
  47     return $self;
  48 }
  49
  50 sub can_be_inlined {
  51     my $self      = shift;
  52     my $metaclass = $self->associated_metaclass;
  53
  54     my $expected_class = $self->_expected_constructor_class;
  55
  56     # If any of our parents have been made immutable, we are okay to
  57     # inline our own new method. The assumption is that an inlined new
  58     # method provided by a parent does not actually get used by
  59     # children anyway.
  60     for my $meta (
  61         grep { $_->is_immutable }
  62         map  { ( ref $metaclass )->initialize($_) }
  63         grep { $_ ne $expected_class }
  64         $metaclass->linearized_isa
  65         ) {
  66         my $transformer = $meta->get_immutable_transformer;
  67
  68         # This is actually a false positive if we're in a subclass of
  69         # this class, _and_ the expected class is not overridden (but
  70         # should be), and the real expected class is actually
  71         # immutable itself (see Fey::Object::Table for an example of
  72         # how this can happen). I'm not sure how to actually handle
  73         # that case, since it's effectively a bug in the subclass (for
  74         # not overriding _expected_constructor_class).
  75         return 1 if $transformer->inlined_constructor;
  76     }
  77
  78     if ( my $constructor = $metaclass->find_method_by_name( $self->name ) ) {
  79         my $class = $self->associated_metaclass->name;
  80
  81         if ( $constructor->body != $expected_class->can('new') ) {
  82             my $warning
  83                 = "Not inlining a constructor for $class since it is not"
  84                 . " inheriting the default $expected_class constructor\n";
  85
  86             $warning .= " (constructor has method modifiers which would be lost if it were inlined)\n"
  87                 if $constructor->isa('Class::MOP::Method::Wrapped');
  88
  89             warn $warning;
  90
  91             return 0;
  92         }
  93         else {
  94             return 1;
  95         }
  96     }
  97
  98     # This would be a rather weird case where we have no constructor
  99     # in the inheritance chain.
 100     return 1;
 101 }
 102
 103 # This is here so can_be_inlined can be inherited by MooseX modules.
 104 sub _expected_constructor_class {
 105     return 'Moose::Object';
 106 }
 107
 108 ## accessors
 109
 110 sub options       { (shift)->{'options'}       }
 111 sub meta_instance { (shift)->{'meta_instance'} }
 112 sub attributes    { (shift)->{'attributes'}    }
 113
 114 sub associated_metaclass { (shift)->{'associated_metaclass'} }
 115
 116 ## method
 117
 118 # this was changed in 0.41, but broke MooseX::Singleton, so try to catch
 119 # any other code using the original broken spelling
 120 sub intialize_body { Moose->throw_error("Please correct the spelling of 'intialize_body' to 'initialize_body'") }
 121
 122 sub initialize_body {
 123     my $self = shift;
 124     # TODO:
 125     # the %options should also include a both
 126     # a call 'initializer' and call 'SUPER::'
 127     # options, which should cover approx 90%
 128     # of the possible use cases (even if it
 129     # requires some adaption on the part of
 130     # the author, after all, nothing is free)
 131     my $source = 'sub {';
 132     $source .= "\n" . 'my $class = shift;';
 133
 134     $source .= "\n" . 'return $class->Moose::Object::new(@_)';
 135     $source .= "\n" . '    if $class ne \'' . $self->associated_metaclass->name . '\';';
 136
 137     $source .= "\n" . 'my $params = ' . $self->_generate_BUILDARGS('$class', '@_');
 138
 139     $source .= ";\n" . 'my $instance = ' . $self->meta_instance->inline_create_instance('$class');
 140
 141     $source .= ";\n" . (join ";\n" => map {
 142         $self->_generate_slot_initializer($_)
 143     } 0 .. (@{$self->attributes} - 1));
 144
 145     $source .= ";\n" . $self->_generate_triggers();
 146     $source .= ";\n" . $self->_generate_BUILDALL();
 147
 148     $source .= ";\n" . 'return $instance';
 149     $source .= ";\n" . '}';
 150     warn $source if $self->options->{debug};
 151
 152     my $code;
 153     {
 154         my $meta = $self; # FIXME for _inline_throw_error...
 155
 156         # NOTE:
 157         # create the nessecary lexicals
 158         # to be picked up in the eval
 159         my $attrs = $self->attributes;
 160
 161         # We need to check if the attribute ->can('type_constraint')
 162         # since we may be trying to immutabilize a Moose meta class,
 163         # which in turn has attributes which are Class::MOP::Attribute
 164         # objects, rather than Moose::Meta::Attribute. And
 165         # Class::MOP::Attribute attributes have no type constraints.
 166         # However we need to make sure we leave an undef value there
 167         # because the inlined code is using the index of the attributes
 168         # to determine where to find the type constraint
 169
 170         my @type_constraints = map {
 171             $_->can('type_constraint') ? $_->type_constraint : undef
 172         } @$attrs;
 173
 174         my @type_constraint_bodies = map {
 175             defined $_ ? $_->_compiled_type_constraint : undef;
 176         } @type_constraints;
 177
 178         $code = eval $source;
 179         $self->throw_error("Could not eval the constructor :\n\n$source\n\nbecause :\n\n$@", error => $@, data => $source ) if $@;
 180     }
 181     $self->{'body'} = $code;
 182 }
 183
 184 sub _generate_BUILDARGS {
 185     my ( $self, $class, $args ) = @_;
 186
 187     my $buildargs = $self->associated_metaclass->find_method_by_name("BUILDARGS");
 188
 189     if ( $args eq '@_' and ( !$buildargs or $buildargs->body == \&Moose::Object::BUILDARGS ) ) {
 190         return join("\n",
 191             'do {',
 192             $self->_inline_throw_error('"Single parameters to new() must be a HASH ref"', 'data => $_[0]'),
 193             '    if scalar @_ == 1 && defined $_[0] && ref($_[0]) ne q{HASH};',
 194             '(scalar @_ == 1) ? {%{$_[0]}} : {@_};',
 195             '}',
 196         );
 197     } else {
 198         return $class . "->BUILDARGS($args)";
 199     }
 200 }
 201
 202 sub _generate_BUILDALL {
 203     my $self = shift;
 204     my @BUILD_calls;
 205     foreach my $method (reverse $self->associated_metaclass->find_all_methods_by_name('BUILD')) {
 206         push @BUILD_calls => '$instance->' . $method->{class} . '::BUILD($params)';
 207     }
 208     return join ";\n" => @BUILD_calls;
 209 }
 210
 211 sub _generate_triggers {
 212     my $self = shift;
 213     my @trigger_calls;
 214     foreach my $i (0 .. $#{ $self->attributes }) {
 215         my $attr = $self->attributes->[$i];
 216         if ($attr->can('has_trigger') && $attr->has_trigger) {
 217             if (defined(my $init_arg = $attr->init_arg)) {
 218                 push @trigger_calls => (
 219                     '(exists $params->{\'' . $init_arg . '\'}) && do {' . "\n    "
 220                     .   '$attrs->[' . $i . ']->trigger->('
 221                     .       '$instance, '
 222                     .        $self->meta_instance->inline_get_slot_value(
 223                                  '$instance',
 224                                  ("'" . $attr->name . "'")
 225                              )
 226                              . ', '
 227                     .        '$attrs->[' . $i . ']'
 228                     .   ');'
 229                     ."\n}"
 230                 );
 231             }
 232         }
 233     }
 234     return join ";\n" => @trigger_calls;
 235 }
 236
 237 sub _generate_slot_initializer {
 238     my $self  = shift;
 239     my $index = shift;
 240
 241     my $attr = $self->attributes->[$index];
 242
 243     my @source = ('## ' . $attr->name);
 244
 245     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 246
 247     if ($is_moose && defined($attr->init_arg) && $attr->is_required && !$attr->has_default && !$attr->has_builder) {
 248         push @source => ('(exists $params->{\'' . $attr->init_arg . '\'}) ' .
 249                         '|| ' . $self->_inline_throw_error('"Attribute (' . $attr->name . ') is required"') .';');
 250     }
 251
 252     if (($attr->has_default || $attr->has_builder) && !($is_moose && $attr->is_lazy)) {
 253
 254         if ( defined( my $init_arg = $attr->init_arg ) ) {
 255             push @source => 'if (exists $params->{\'' . $init_arg . '\'}) {';
 256             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 257             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 258                 if $is_moose;
 259             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 260             push @source => "} else {";
 261         }
 262             my $default;
 263             if ( $attr->has_default ) {
 264                 $default = $self->_generate_default_value($attr, $index);
 265             }
 266             else {
 267                my $builder = $attr->builder;
 268                $default = '$instance->' . $builder;
 269             }
 270
 271             push @source => '{'; # wrap this to avoid my $val overwrite warnings
 272             push @source => ('my $val = ' . $default . ';');
 273             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 274                 if $is_moose;
 275             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 276             push @source => '}'; # close - wrap this to avoid my $val overrite warnings
 277
 278         push @source => "}" if defined $attr->init_arg;
 279     }
 280     elsif ( defined( my $init_arg = $attr->init_arg ) ) {
 281         push @source => '(exists $params->{\'' . $init_arg . '\'}) && do {';
 282
 283             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 284             if ($is_moose && $attr->has_type_constraint) {
 285                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 286                     push @source => $self->_generate_type_coercion(
 287                         $attr,
 288                         '$type_constraints[' . $index . ']',
 289                         '$val',
 290                         '$val'
 291                     );
 292                 }
 293                 push @source => $self->_generate_type_constraint_check(
 294                     $attr,
 295                     '$type_constraint_bodies[' . $index . ']',
 296                     '$type_constraints[' . $index . ']',
 297                     '$val'
 298                 );
 299             }
 300             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 301
 302         push @source => "}";
 303     }
 304
 305     return join "\n" => @source;
 306 }
 307
 308 sub _generate_slot_assignment {
 309     my ($self, $attr, $value, $index) = @_;
 310
 311     my $source;
 312
 313     if ($attr->has_initializer) {
 314         $source = (
 315             '$attrs->[' . $index . ']->set_initial_value($instance, ' . $value . ');'
 316         );
 317     }
 318     else {
 319         $source = (
 320             $self->meta_instance->inline_set_slot_value(
 321                 '$instance',
 322                 ("'" . $attr->name . "'"),
 323                 $value
 324             ) . ';'
 325         );
 326     }
 327
 328     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 329
 330     if ($is_moose && $attr->is_weak_ref) {
 331         $source .= (
 332             "\n" .
 333             $self->meta_instance->inline_weaken_slot_value(
 334                 '$instance',
 335                 ("'" . $attr->name . "'")
 336             ) .
 337             ' if ref ' . $value . ';'
 338         );
 339     }
 340
 341     return $source;
 342 }
 343
 344 sub _generate_type_constraint_and_coercion {
 345     my ($self, $attr, $index) = @_;
 346
 347     return unless $attr->has_type_constraint;
 348
 349     my @source;
 350     if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 351         push @source => $self->_generate_type_coercion(
 352             $attr,
 353             '$type_constraints[' . $index . ']',
 354             '$val',
 355             '$val'
 356         );
 357     }
 358     push @source => $self->_generate_type_constraint_check(
 359         $attr,
 360         ('$type_constraint_bodies[' . $index . ']'),
 361         ('$type_constraints[' . $index . ']'),
 362         '$val'
 363     );
 364     return @source;
 365 }
 366
 367 sub _generate_type_coercion {
 368     my ($self, $attr, $type_constraint_name, $value_name, $return_value_name) = @_;
 369     return ($return_value_name . ' = ' . $type_constraint_name .  '->coerce(' . $value_name . ');');
 370 }
 371
 372 sub _generate_type_constraint_check {
 373     my ($self, $attr, $type_constraint_cv, $type_constraint_obj, $value_name) = @_;
 374     return (
 375         $self->_inline_throw_error('"Attribute (' # FIXME add 'dad'
 376         . $attr->name
 377         . ') does not pass the type constraint because: " . '
 378         . $type_constraint_obj . '->get_message(' . $value_name . ')')
 379         . "\n\t unless " .  $type_constraint_cv . '->(' . $value_name . ');'
 380     );
 381 }
 382
 383 sub _generate_default_value {
 384     my ($self, $attr, $index) = @_;
 385     # NOTE:
 386     # default values can either be CODE refs
 387     # in which case we need to call them. Or
 388     # they can be scalars (strings/numbers)
 389     # in which case we can just deal with them
 390     # in the code we eval.
 391     if ($attr->is_default_a_coderef) {
 392         return '$attrs->[' . $index . ']->default($instance)';
 393     }
 394     else {
 395         return q{"} . quotemeta( $attr->default ) . q{"};
 396     }
 397 }
 398
 399 1;
 400
 401 __END__
 402
 403 =pod
 404
 405 =head1 NAME
 406
 407 Moose::Meta::Method::Constructor - Method Meta Object for constructors
 408
 409 =head1 DESCRIPTION
 410
 411 This is a subclass of L<Class::MOP::Method> which handles
 412 constructing an approprate Constructor methods. This is primarily
 413 used in the making of immutable metaclasses, otherwise it is
 414 not particularly useful.
 415
 416 =head1 METHODS
 417
 418 =over 4
 419
 420 =item B<new>
 421
 422 =item B<can_be_inlined>
 423
 424 =item B<attributes>
 425
 426 =item B<meta_instance>
 427
 428 =item B<options>
 429
 430 =item B<initialize_body>
 431
 432 =item B<associated_metaclass>
 433
 434 =item B<can_be_inlined>
 435
 436 =back
 437
 438 =head1 AUTHORS
 439
 440 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 441
 442 =head1 COPYRIGHT AND LICENSE
 443
 444 Copyright 2006-2008 by Infinity Interactive, Inc.
 445
 446 L<http://www.iinteractive.com>
 447
 448 This library is free software; you can redistribute it and/or modify
 449 it under the same terms as Perl itself.
 450
 451 =cut
 452