lib/Moose/Meta/Method/Accessor.pm

   1
   2 package Moose::Meta::Method::Accessor;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION   = '1.14';
   8 $VERSION = eval $VERSION;
   9 our $AUTHORITY = 'cpan:STEVAN';
  10
  11 use base 'Moose::Meta::Method',
  12          'Class::MOP::Method::Accessor';
  13
  14 sub _error_thrower {
  15     my $self = shift;
  16     ( ref $self && $self->associated_attribute ) || $self->SUPER::_error_thrower();
  17 }
  18
  19 sub _eval_code {
  20     my ( $self, $source ) = @_;
  21
  22     my $environment = $self->_eval_environment;
  23
  24     my ( $code, $e ) = $self->_compile_code( environment => $environment, code => $source );
  25
  26     $self->throw_error(
  27         "Could not create writer for '${\$self->associated_attribute->name}' because $e \n code: $source",
  28         error => $e, data => $source )
  29         if $e;
  30
  31     return $code;
  32 }
  33
  34 sub _eval_environment {
  35     my $self = shift;
  36
  37     my $attr                = $self->associated_attribute;
  38     my $type_constraint_obj = $attr->type_constraint;
  39
  40     return {
  41         '$attr'                => \$attr,
  42         '$meta'                => \$self,
  43         '$type_constraint_obj' => \$type_constraint_obj,
  44         '$type_constraint'     => \(
  45               $type_constraint_obj
  46             ? $type_constraint_obj->_compiled_type_constraint
  47             : undef
  48         ),
  49     };
  50 }
  51
  52 sub _generate_accessor_method_inline {
  53     my $self        = $_[0];
  54     my $attr        = $self->associated_attribute;
  55     my $inv         = '$_[0]';
  56     my $value_name  = $self->_value_needs_copy ? '$val' : '$_[1]';
  57
  58     $self->_eval_code('sub { ' . "\n"
  59     . $self->_inline_pre_body(@_) . "\n"
  60     . 'if (scalar(@_) >= 2) {' . "\n"
  61         . $self->_inline_copy_value . "\n"
  62         . $self->_inline_check_required . "\n"
  63         . $self->_inline_check_coercion($value_name) . "\n"
  64         . $self->_inline_check_constraint($value_name) . "\n"
  65         . $self->_inline_get_old_value_for_trigger($inv, $value_name) . "\n"
  66         . $self->_inline_store($inv, $value_name) . "\n"
  67         . $self->_inline_trigger($inv, $value_name, '@old') . "\n"
  68     . ' }' . "\n"
  69     . $self->_inline_check_lazy($inv) . "\n"
  70     . $self->_inline_post_body(@_) . "\n"
  71     . 'return ' . $self->_inline_auto_deref($self->_inline_get($inv)) . "\n"
  72     . ' }');
  73 }
  74
  75 sub _generate_writer_method_inline {
  76     my $self        = $_[0];
  77     my $attr        = $self->associated_attribute;
  78     my $inv         = '$_[0]';
  79     my $slot_access = $self->_inline_get($inv);
  80     my $value_name  = $self->_value_needs_copy ? '$val' : '$_[1]';
  81
  82     $self->_eval_code('sub { '
  83     . $self->_inline_pre_body(@_)
  84     . $self->_inline_copy_value
  85     . $self->_inline_check_required
  86     . $self->_inline_check_coercion($value_name)
  87     . $self->_inline_check_constraint($value_name)
  88     . $self->_inline_get_old_value_for_trigger($inv, $value_name) . "\n"
  89     . $self->_inline_store($inv, $value_name)
  90     . $self->_inline_post_body(@_)
  91     . $self->_inline_trigger($inv, $value_name, '@old')
  92     . ' }');
  93 }
  94
  95 sub _generate_reader_method_inline {
  96     my $self        = $_[0];
  97     my $attr        = $self->associated_attribute;
  98     my $inv         = '$_[0]';
  99     my $slot_access = $self->_inline_get($inv);
 100
 101     $self->_eval_code('sub {'
 102     . $self->_inline_pre_body(@_)
 103     . $self->_inline_throw_error('"Cannot assign a value to a read-only accessor"', 'data => \@_') . ' if @_ > 1;'
 104     . $self->_inline_check_lazy($inv)
 105     . $self->_inline_post_body(@_)
 106     . 'return ' . $self->_inline_auto_deref( $slot_access ) . ';'
 107     . '}');
 108 }
 109
 110 sub _inline_copy_value {
 111     return '' unless shift->_value_needs_copy;
 112     return 'my $val = $_[1];'
 113 }
 114
 115 sub _value_needs_copy {
 116     my $attr = (shift)->associated_attribute;
 117     return $attr->should_coerce;
 118 }
 119
 120 sub _instance_is_inlinable {
 121     my $self = shift;
 122     return $self->associated_attribute->associated_class->instance_metaclass->is_inlinable;
 123 }
 124
 125 sub _generate_reader_method {
 126     my $self = shift;
 127     $self->_instance_is_inlinable ? $self->_generate_reader_method_inline(@_)
 128                                   : $self->SUPER::_generate_reader_method(@_);
 129 }
 130
 131 sub _generate_writer_method {
 132     my $self = shift;
 133     $self->_instance_is_inlinable ? $self->_generate_writer_method_inline(@_)
 134                                   : $self->SUPER::_generate_writer_method(@_);
 135 }
 136
 137 sub _generate_accessor_method {
 138     my $self = shift;
 139     $self->_instance_is_inlinable ? $self->_generate_accessor_method_inline(@_)
 140                                   : $self->SUPER::_generate_accessor_method(@_);
 141 }
 142
 143 sub _generate_predicate_method {
 144     my $self = shift;
 145     $self->_instance_is_inlinable ? $self->_generate_predicate_method_inline(@_)
 146                                   : $self->SUPER::_generate_predicate_method(@_);
 147 }
 148
 149 sub _generate_clearer_method {
 150     my $self = shift;
 151     $self->_instance_is_inlinable ? $self->_generate_clearer_method_inline(@_)
 152                                   : $self->SUPER::_generate_clearer_method(@_);
 153 }
 154
 155 sub _inline_pre_body  { '' }
 156 sub _inline_post_body { '' }
 157
 158 sub _inline_check_constraint {
 159     my ($self, $value) = @_;
 160
 161     my $attr = $self->associated_attribute;
 162
 163     return '' unless $attr->has_type_constraint;
 164
 165     my $attr_name = quotemeta( $attr->name );
 166
 167     qq{\$type_constraint->($value) || } . $self->_inline_throw_error(qq{"Attribute ($attr_name) does not pass the type constraint because: " . \$type_constraint_obj->get_message($value)}, "data => $value") . ";";
 168 }
 169
 170 sub _inline_check_coercion {
 171     my ($self, $value) = @_;
 172
 173     my $attr = $self->associated_attribute;
 174
 175     return '' unless $attr->should_coerce && $attr->type_constraint->has_coercion;
 176     return "$value = \$attr->type_constraint->coerce($value);";
 177 }
 178
 179 sub _inline_check_required {
 180     my $self = shift;
 181     my $attr = $self->associated_attribute;
 182
 183     return '' unless $attr->is_required;
 184
 185     my $attr_name = quotemeta( $attr->name );
 186
 187     return qq{(\@_ >= 2) || } . $self->_inline_throw_error(qq{"Attribute ($attr_name) is required, so cannot be set to undef"}) . ';' # defined $_[1] is not good enough
 188 }
 189
 190 sub _inline_check_lazy {
 191     my ($self, $instance) = @_;
 192
 193     my $attr = $self->associated_attribute;
 194
 195     return '' unless $attr->is_lazy;
 196
 197     my $slot_exists = $self->_inline_has($instance);
 198
 199     my $code = 'unless (' . $slot_exists . ') {' . "\n";
 200     if ($attr->has_type_constraint) {
 201         if ($attr->has_default || $attr->has_builder) {
 202             if ($attr->has_default) {
 203                 $code .= '    my $default = $attr->default(' . $instance . ');'."\n";
 204             }
 205             elsif ($attr->has_builder) {
 206                 $code .= '    my $default;'."\n".
 207                          '    if(my $builder = '.$instance.'->can($attr->builder)){ '."\n".
 208                          '        $default = '.$instance.'->$builder; '. "\n    } else {\n" .
 209                          '        ' . $self->_inline_throw_error(q{sprintf "%s does not support builder method '%s' for attribute '%s'", ref(} . $instance . ') || '.$instance.', $attr->builder, $attr->name') .
 210                          ';'. "\n    }";
 211             }
 212             $code .= $self->_inline_check_coercion('$default') . "\n";
 213             $code .= $self->_inline_check_constraint('$default') . "\n";
 214             $code .= '    ' . $self->_inline_init_slot($attr, $instance, '$default') . "\n";
 215         }
 216         else {
 217             $code .= '    ' . $self->_inline_init_slot($attr, $instance, 'undef') . "\n";
 218         }
 219
 220     } else {
 221         if ($attr->has_default) {
 222             $code .= '    ' . $self->_inline_init_slot($attr, $instance, ('$attr->default(' . $instance . ')')) . "\n";
 223         }
 224         elsif ($attr->has_builder) {
 225             $code .= '    if (my $builder = '.$instance.'->can($attr->builder)) { ' . "\n"
 226                   .  '       ' . $self->_inline_init_slot($attr, $instance, ($instance . '->$builder'))
 227                   .  "\n    } else {\n"
 228                   .  '        ' . $self->_inline_throw_error(q{sprintf "%s does not support builder method '%s' for attribute '%s'", ref(} . $instance . ') || '.$instance.', $attr->builder, $attr->name')
 229                   .  ';'. "\n    }";
 230         }
 231         else {
 232             $code .= '    ' . $self->_inline_init_slot($attr, $instance, 'undef') . "\n";
 233         }
 234     }
 235     $code .= "}\n";
 236     return $code;
 237 }
 238
 239 sub _inline_init_slot {
 240     my ($self, $attr, $inv, $value) = @_;
 241     if ($attr->has_initializer) {
 242         return ('$attr->set_initial_value(' . $inv . ', ' . $value . ');');
 243     }
 244     else {
 245         return $self->_inline_store($inv, $value);
 246     }
 247 }
 248
 249 sub _inline_store {
 250     my ($self, $instance, $value) = @_;
 251     my $attr = $self->associated_attribute;
 252
 253     my $mi = $attr->associated_class->get_meta_instance;
 254
 255     my $code = $mi->inline_set_slot_value($instance, $attr->slots, $value)    . ";";
 256     $code   .= $mi->inline_weaken_slot_value($instance, $attr->slots, $value) . ";"
 257         if $attr->is_weak_ref;
 258     return $code;
 259 }
 260
 261 sub _inline_get_old_value_for_trigger {
 262     my ( $self, $instance ) = @_;
 263
 264     my $attr = $self->associated_attribute;
 265     return '' unless $attr->has_trigger;
 266
 267     my $mi = $attr->associated_class->get_meta_instance;
 268     my $pred = $mi->inline_is_slot_initialized($instance, $attr->name);
 269
 270     return
 271           'my @old = '
 272         . $pred . q{ ? }
 273         . $self->_inline_get($instance) . q{ : ()} . ";\n";
 274 }
 275
 276 sub _inline_trigger {
 277     my ($self, $instance, $value, $old_value) = @_;
 278     my $attr = $self->associated_attribute;
 279     return '' unless $attr->has_trigger;
 280     return sprintf('$attr->trigger->(%s, %s, %s);', $instance, $value, $old_value);
 281 }
 282
 283 sub _inline_get {
 284     my ($self, $instance) = @_;
 285     my $attr = $self->associated_attribute;
 286
 287     my $mi = $attr->associated_class->get_meta_instance;
 288
 289     return $mi->inline_get_slot_value($instance, $attr->slots);
 290 }
 291
 292 sub _inline_access {
 293     my ($self, $instance) = @_;
 294     my $attr = $self->associated_attribute;
 295
 296     my $mi = $attr->associated_class->get_meta_instance;
 297
 298     return $mi->inline_slot_access($instance, $attr->slots);
 299 }
 300
 301 sub _inline_has {
 302     my ($self, $instance) = @_;
 303     my $attr = $self->associated_attribute;
 304
 305     my $mi = $attr->associated_class->get_meta_instance;
 306
 307     return $mi->inline_is_slot_initialized($instance, $attr->slots);
 308 }
 309
 310 sub _inline_auto_deref {
 311     my ( $self, $ref_value ) = @_;
 312         my $attr = $self->associated_attribute;
 313
 314     return $ref_value unless $attr->should_auto_deref;
 315
 316     my $type_constraint = $attr->type_constraint;
 317
 318     my $sigil;
 319     if ($type_constraint->is_a_type_of('ArrayRef')) {
 320         $sigil = '@';
 321     }
 322     elsif ($type_constraint->is_a_type_of('HashRef')) {
 323         $sigil = '%';
 324     }
 325     else {
 326         $self->throw_error( "Can not auto de-reference the type constraint '"
 327                 . quotemeta( $type_constraint->name )
 328                 . "'", type_constraint => $type_constraint );
 329     }
 330
 331     "(wantarray() ? $sigil\{ ( $ref_value ) || return } : ( $ref_value ) )";
 332 }
 333
 334 1;
 335
 336 __END__
 337
 338 =pod
 339
 340 =head1 NAME
 341
 342 Moose::Meta::Method::Accessor - A Moose Method metaclass for accessors
 343
 344 =head1 DESCRIPTION
 345
 346 This class is a subclass of L<Class::MOP::Method::Accessor> that
 347 provides additional Moose-specific functionality, all of which is
 348 private.
 349
 350 To understand this class, you should read the the
 351 L<Class::MOP::Method::Accessor> documentation.
 352
 353 =head1 BUGS
 354
 355 See L<Moose/BUGS> for details on reporting bugs.
 356
 357 =head1 AUTHOR
 358
 359 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 360
 361 Yuval Kogman E<lt>nothingmuch@woobling.comE<gt>
 362
 363 =head1 COPYRIGHT AND LICENSE
 364
 365 Copyright 2006-2010 by Infinity Interactive, Inc.
 366
 367 L<http://www.iinteractive.com>
 368
 369 This library is free software; you can redistribute it and/or modify
 370 it under the same terms as Perl itself.
 371
 372 =cut