lib/Moose/Meta/Method/Accessor/Native/Writer.pm

   1 package Moose::Meta::Method::Accessor::Native::Writer;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION = '1.13';
   7 $VERSION = eval $VERSION;
   8 our $AUTHORITY = 'cpan:STEVAN';
   9
  10 use base 'Moose::Meta::Method::Accessor::Native';
  11
  12 sub _generate_method {
  13     my $self = shift;
  14
  15     my $inv = '$self';
  16
  17     my $slot_access = $self->_inline_get($inv);
  18
  19     my $code = 'sub {';
  20
  21     $code .= "\n" . $self->_inline_pre_body(@_);
  22
  23     $code .= "\n" . 'my $self = shift;';
  24
  25     $code .= "\n" . $self->_inline_curried_arguments;
  26
  27     $code .= $self->_writer_core( $inv, $slot_access );
  28
  29     $code .= "\n" . $self->_inline_post_body(@_);
  30
  31     $code .= "\n}";
  32
  33     return $code;
  34 }
  35
  36 sub _writer_core {
  37     my ( $self, $inv, $slot_access ) = @_;
  38
  39     my $code = q{};
  40
  41     $code .= "\n" . $self->_inline_check_argument_count;
  42     $code .= "\n" . $self->_inline_process_arguments( $inv, $slot_access );
  43     $code .= "\n" . $self->_inline_check_arguments('for writer');
  44
  45     $code .= "\n" . $self->_inline_check_lazy($inv);
  46
  47     my $new_value       = $self->_new_value($slot_access);
  48     my $potential_value = $self->_potential_value($slot_access);
  49
  50     $code .= "\n" . $self->_inline_copy_value( \$potential_value );
  51     $code .= "\n"
  52         . $self->_inline_tc_code(
  53         $new_value,
  54         $potential_value
  55         );
  56
  57     $code .= "\n" . $self->_inline_get_old_value_for_trigger($inv);
  58     $code .= "\n" . $self->_inline_capture_return_value($slot_access);
  59     $code .= "\n"
  60         . $self->_inline_set_new_value(
  61         $inv,
  62         $potential_value,
  63         $slot_access,
  64         );
  65     $code .= "\n" . $self->_inline_trigger( $inv, $slot_access, '@old' );
  66     $code .= "\n" . $self->_return_value( $slot_access, 'for writer' );
  67
  68     return $code;
  69 }
  70
  71 sub _inline_process_arguments {q{}}
  72
  73 sub _inline_check_arguments {q{}}
  74
  75 sub _value_needs_copy {0}
  76
  77 sub _inline_tc_code {
  78     die '_inline_tc_code must be overridden by ' . ref $_[0];
  79 }
  80
  81 sub _inline_check_coercion {
  82     die '_inline_check_coercion must be overridden by ' . ref $_[0];
  83 }
  84
  85 sub _inline_check_constraint {
  86     my $self = shift;
  87
  88     return q{} unless $self->_constraint_must_be_checked;
  89
  90     return $self->SUPER::_inline_check_constraint( $_[0] );
  91 }
  92
  93 sub _constraint_must_be_checked {
  94     die '_constraint_must_be_checked must be overridden by ' . ref $_[0];
  95 }
  96
  97 sub _inline_capture_return_value { return q{} }
  98
  99 sub _inline_set_new_value {
 100     my $self = shift;
 101
 102     return $self->SUPER::_inline_store(@_)
 103         if $self->_value_needs_copy;
 104
 105     return $self->_inline_optimized_set_new_value(@_);
 106 }
 107
 108 sub _inline_optimized_set_new_value {
 109     my $self = shift;
 110
 111     return $self->SUPER::_inline_store(@_)
 112 }
 113
 114 sub _return_value { return q{} }
 115
 116 1;