lib/Moose/Meta/Method/Accessor/Native/Writer.pm

   1 package Moose::Meta::Method::Accessor::Native::Writer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use List::MoreUtils qw( any );
   7
   8 our $VERSION = '1.13';
   9 $VERSION = eval $VERSION;
  10 our $AUTHORITY = 'cpan:STEVAN';
  11
  12 use base 'Moose::Meta::Method::Accessor::Native';
  13
  14 sub _generate_method {
  15     my $self = shift;
  16
  17     my $inv = '$self';
  18
  19     my $slot_access = $self->_inline_get($inv);
  20
  21     my $code = 'sub {';
  22
  23     $code .= "\n" . $self->_inline_pre_body(@_);
  24
  25     $code .= "\n" . 'my $self = shift;';
  26
  27     $code .= "\n" . $self->_inline_curried_arguments;
  28
  29     $code .= $self->_writer_core( $inv, $slot_access );
  30
  31     $code .= "\n" . $self->_inline_post_body(@_);
  32
  33     $code .= "\n}";
  34
  35     return $code;
  36 }
  37
  38 sub _writer_core {
  39     my ( $self, $inv, $slot_access ) = @_;
  40
  41     my $code = q{};
  42
  43     $code .= "\n" . $self->_inline_check_argument_count;
  44     $code .= "\n" . $self->_inline_process_arguments( $inv, $slot_access );
  45     $code .= "\n" . $self->_inline_check_arguments('for writer');
  46
  47     $code .= "\n" . $self->_inline_check_lazy($inv);
  48
  49     my $new_value       = $self->_new_value($slot_access);
  50     my $potential_value = $self->_potential_value($slot_access);
  51
  52     $code .= "\n" . $self->_inline_copy_value( \$potential_value );
  53     $code .= "\n"
  54         . $self->_inline_tc_code(
  55         $new_value,
  56         $potential_value
  57         );
  58
  59     $code .= "\n" . $self->_inline_get_old_value_for_trigger($inv);
  60     $code .= "\n" . $self->_inline_capture_return_value($slot_access);
  61     $code .= "\n"
  62         . $self->_inline_set_new_value(
  63         $inv,
  64         $potential_value,
  65         $slot_access,
  66         );
  67     $code .= "\n" . $self->_inline_trigger( $inv, $slot_access, '@old' );
  68     $code .= "\n" . $self->_return_value( $slot_access, 'for writer' );
  69
  70     return $code;
  71 }
  72
  73 sub _inline_process_arguments {q{}}
  74
  75 sub _inline_check_arguments {q{}}
  76
  77 sub _new_value {'$_[0]'}
  78
  79 sub _value_needs_copy {
  80     my $self = shift;
  81
  82     return $self->_constraint_must_be_checked;
  83 }
  84
  85 sub _constraint_must_be_checked {
  86     my $self = shift;
  87
  88     my $attr = $self->associated_attribute;
  89
  90     return $attr->has_type_constraint
  91         && ( !$self->_is_root_type( $attr->type_constraint )
  92         || ( $attr->should_coerce && $attr->type_constraint->has_coercion ) );
  93 }
  94
  95 sub _is_root_type {
  96     my ($self, $type) = @_;
  97
  98     my $name = $type->name();
  99
 100     return any { $name eq $_ } @{ $self->root_types };
 101 }
 102
 103 sub _inline_copy_value {
 104     my ( $self, $potential_ref ) = @_;
 105
 106     return q{} unless $self->_value_needs_copy;
 107
 108     my $code = "my \$potential = ${$potential_ref};";
 109
 110     ${$potential_ref} = '$potential';
 111
 112     return $code;
 113 }
 114
 115 sub _inline_tc_code {
 116     my ( $self, $new_value, $potential_value ) = @_;
 117
 118     return q{} unless $self->_constraint_must_be_checked;
 119
 120     return $self->_inline_check_coercion($potential_value) . "\n"
 121         . $self->_inline_check_constraint($potential_value);
 122 }
 123
 124 sub _inline_check_coercion {
 125     my ( $self, $value ) = @_;
 126
 127     my $attr = $self->associated_attribute;
 128
 129     return ''
 130         unless $attr->should_coerce && $attr->type_constraint->has_coercion;
 131
 132     # We want to break the aliasing in @_ in case the coercion tries to make a
 133     # destructive change to an array member.
 134     return "$value = \$type_constraint_obj->coerce($value);";
 135 }
 136
 137 sub _inline_check_constraint {
 138     my $self = shift;
 139
 140     return q{} unless $self->_constraint_must_be_checked;
 141
 142     return $self->SUPER::_inline_check_constraint( $_[0] );
 143 }
 144
 145 sub _inline_capture_return_value { return q{} }
 146
 147 sub _inline_set_new_value {
 148     my $self = shift;
 149
 150     return $self->SUPER::_inline_store(@_)
 151         if $self->_value_needs_copy;
 152
 153     return $self->_inline_optimized_set_new_value(@_);
 154 }
 155
 156 sub _inline_optimized_set_new_value {
 157     my $self = shift;
 158
 159     return $self->SUPER::_inline_store(@_)
 160 }
 161
 162 sub _return_value { return q{} }
 163
 164 1;