lib/Moose/Meta/Method/Accessor/Native/Array/accessor.pm

   1 package Moose::Meta::Method::Accessor::Native::Array::accessor;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION = '1.14';
   7 $VERSION = eval $VERSION;
   8 our $AUTHORITY = 'cpan:STEVAN';
   9
  10 use base qw(
  11     Moose::Meta::Method::Accessor::Native::Array::set
  12     Moose::Meta::Method::Accessor::Native::Array::get
  13 );
  14
  15 sub _generate_method {
  16     my $self = shift;
  17
  18     my $inv = '$self';
  19
  20     my $code = 'sub {';
  21     $code .= "\n" . $self->_inline_pre_body(@_);
  22
  23     $code .= "\n" . 'my $self = shift;';
  24
  25     $code .= "\n" . $self->_inline_curried_arguments;
  26
  27     $code .= "\n" . $self->_inline_check_lazy($inv);
  28
  29     my $slot_access = $self->_inline_get($inv);
  30
  31     # get
  32     $code .= "\n" . 'if ( @_ == 1 ) {';
  33
  34     $code .= "\n" . $self->_inline_check_var_is_valid_index('$_[0]');
  35
  36     $code
  37         .= "\n"
  38         . 'return '
  39         . $self
  40         ->Moose::Meta::Method::Accessor::Native::Array::get::_return_value(
  41         $slot_access)
  42         . ';';
  43
  44     # set
  45     $code .= "\n" . '} else {';
  46
  47     $code .= "\n" . $self->_inline_check_argument_count;
  48
  49     $code
  50         .= "\n"
  51         . $self
  52         ->Moose::Meta::Method::Accessor::Native::Array::set::_inline_check_arguments;
  53
  54     my $potential_value = $self->_potential_value($slot_access);
  55
  56     $code .= "\n"
  57         . $self->_inline_tc_code(
  58         $potential_value,
  59         $slot_access,
  60         );
  61
  62     $code .= "\n" . $self->_inline_get_old_value_for_trigger($inv);
  63     $code .= "\n" . $self->_inline_capture_return_value($slot_access);
  64
  65     $code .= "\n"
  66         . $self->_inline_set_new_value(
  67         $inv,
  68         $potential_value,
  69         $slot_access,
  70         );
  71
  72     $code .= "\n" . $self->_inline_trigger( $inv, $slot_access, '@old' );
  73     $code .= "\n" . $self->_inline_post_body(@_);
  74
  75     $code .= "\n}";
  76     $code .= "\n}";
  77
  78     return $code;
  79 }
  80
  81 # If we get one argument we won't check the argument count
  82 sub _minimum_arguments {2}
  83 sub _maximum_arguments {2}
  84
  85 sub _adds_members {1}
  86
  87 sub _potential_value {
  88     my ( $self, $slot_access ) = @_;
  89
  90     return
  91         "( do { my \@potential = \@{ $slot_access }; \$potential[ \$_[0] ] = \$_[1]; \@potential } )";
  92 }
  93
  94 sub _new_members {'$_[1]'}
  95
  96 1;