lib/Moose/Meta/Method/Accessor/Native/Array/accessor.pm

   1 package Moose::Meta::Method::Accessor::Native::Array::accessor;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION = '1.14';
   7 $VERSION = eval $VERSION;
   8 our $AUTHORITY = 'cpan:STEVAN';
   9
  10 use base qw(
  11     Moose::Meta::Method::Accessor::Native::Array::set
  12     Moose::Meta::Method::Accessor::Native::Array::get
  13 );
  14
  15 sub _generate_method {
  16     my $self = shift;
  17
  18     my $inv = '$self';
  19
  20     my $code = 'sub {';
  21     $code .= "\n" . $self->_inline_pre_body(@_);
  22
  23     $code .= "\n" . 'my $self = shift;';
  24
  25     $code .= "\n" . $self->_inline_curried_arguments;
  26
  27     $code .= "\n" . $self->_inline_check_lazy($inv);
  28
  29     my $slot_access = $self->_inline_get($inv);
  30
  31     # get
  32     $code .= "\n" . 'if ( @_ == 1 ) {';
  33
  34     $code .= "\n" . $self->_inline_check_var_is_valid_index('$_[0]');
  35
  36     $code
  37         .= "\n"
  38         . 'return '
  39         . $self
  40         ->Moose::Meta::Method::Accessor::Native::Array::get::_return_value(
  41         $slot_access)
  42         . ';';
  43
  44     # set
  45     $code .= "\n" . '} else {';
  46
  47     $code .= "\n" . $self->_inline_check_argument_count;
  48     $code .= "\n" . $self->_inline_process_arguments( $inv, $slot_access );
  49     $code
  50         .= "\n"
  51         . $self
  52         ->Moose::Meta::Method::Accessor::Native::Array::set::_inline_check_arguments;
  53
  54     my $potential_value = $self->_potential_value($slot_access);
  55
  56     $code .= "\n" . $self->_inline_copy_value( \$potential_value );
  57     $code .= "\n"
  58         . $self->_inline_tc_code(
  59         $potential_value,
  60         $slot_access,
  61         );
  62
  63     $code .= "\n" . $self->_inline_get_old_value_for_trigger($inv);
  64     $code .= "\n" . $self->_inline_capture_return_value($slot_access);
  65
  66     $code .= "\n"
  67         . $self->_inline_set_new_value(
  68         $inv,
  69         $potential_value,
  70         $slot_access,
  71         );
  72
  73     $code .= "\n" . $self->_inline_trigger( $inv, $slot_access, '@old' );
  74     $code .= "\n" . $self->_inline_post_body(@_);
  75
  76     $code .= "\n}";
  77     $code .= "\n}";
  78
  79     return $code;
  80 }
  81
  82 # If we get one argument we won't check the argument count
  83 sub _minimum_arguments {2}
  84 sub _maximum_arguments {2}
  85
  86 sub _adds_members {1}
  87
  88 sub _potential_value {
  89     my ( $self, $slot_access ) = @_;
  90
  91     return
  92         "( do { my \@potential = \@{ $slot_access }; \$potential[ \$_[0] ] = \$_[1]; \@potential } )";
  93 }
  94
  95 sub _new_members {'$_[1]'}
  96
  97 1;