lib/Moose/Meta/Class.pm

   1
   2 package Moose::Meta::Class;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Class::MOP;
   8
   9 use Carp         'confess';
  10 use Scalar::Util 'weaken', 'blessed', 'reftype';
  11
  12 our $VERSION   = '0.21';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use Moose::Meta::Method::Overriden;
  16
  17 use base 'Class::MOP::Class';
  18
  19 __PACKAGE__->meta->add_attribute('roles' => (
  20     reader  => 'roles',
  21     default => sub { [] }
  22 ));
  23
  24 sub initialize {
  25     my $class = shift;
  26     my $pkg   = shift;
  27     $class->SUPER::initialize($pkg,
  28         'attribute_metaclass' => 'Moose::Meta::Attribute',
  29         'method_metaclass'    => 'Moose::Meta::Method',
  30         'instance_metaclass'  => 'Moose::Meta::Instance',
  31         @_);
  32 }
  33
  34 sub create {
  35     my ($self, $package_name, %options) = @_;
  36
  37     (ref $options{roles} eq 'ARRAY')
  38         || confess "You must pass an ARRAY ref of roles"
  39             if exists $options{roles};
  40
  41     my $class = $self->SUPER::create($package_name, %options);
  42
  43     if (exists $options{roles}) {
  44         Moose::Util::apply_all_roles($class, @{$options{roles}});
  45     }
  46
  47     return $class;
  48 }
  49
  50 my %ANON_CLASSES;
  51
  52 sub create_anon_class {
  53     my ($self, %options) = @_;
  54
  55     my $cache_ok = delete $options{cache};
  56
  57     # something like Super::Class|Super::Class::2=Role|Role::1
  58     my $cache_key = join '=' => (
  59         join('|', sort @{$options{superclasses} || []}),
  60         join('|', sort @{$options{roles}        || []}),
  61     );
  62
  63     if ($cache_ok && defined $ANON_CLASSES{$cache_key}) {
  64         return $ANON_CLASSES{$cache_key};
  65     }
  66
  67     my $new_class = $self->SUPER::create_anon_class(%options);
  68
  69     $ANON_CLASSES{$cache_key} = $new_class
  70         if $cache_ok;
  71
  72     return $new_class;
  73 }
  74
  75 sub add_role {
  76     my ($self, $role) = @_;
  77     (blessed($role) && $role->isa('Moose::Meta::Role'))
  78         || confess "Roles must be instances of Moose::Meta::Role";
  79     push @{$self->roles} => $role;
  80 }
  81
  82 sub calculate_all_roles {
  83     my $self = shift;
  84     my %seen;
  85     grep { !$seen{$_->name}++ } map { $_->calculate_all_roles } @{ $self->roles };
  86 }
  87
  88 sub does_role {
  89     my ($self, $role_name) = @_;
  90     (defined $role_name)
  91         || confess "You must supply a role name to look for";
  92     foreach my $class ($self->class_precedence_list) {
  93         next unless $class->can('meta') && $class->meta->can('roles');
  94         foreach my $role (@{$class->meta->roles}) {
  95             return 1 if $role->does_role($role_name);
  96         }
  97     }
  98     return 0;
  99 }
 100
 101 sub excludes_role {
 102     my ($self, $role_name) = @_;
 103     (defined $role_name)
 104         || confess "You must supply a role name to look for";
 105     foreach my $class ($self->class_precedence_list) {
 106         next unless $class->can('meta');
 107         # NOTE:
 108         # in the pretty rare instance when a Moose metaclass
 109         # is itself extended with a role, this check needs to
 110         # be done since some items in the class_precedence_list
 111         # might in fact be Class::MOP based still.
 112         next unless $class->meta->can('roles');
 113         foreach my $role (@{$class->meta->roles}) {
 114             return 1 if $role->excludes_role($role_name);
 115         }
 116     }
 117     return 0;
 118 }
 119
 120 sub new_object {
 121     my ($class, %params) = @_;
 122     my $self = $class->SUPER::new_object(%params);
 123     foreach my $attr ($class->compute_all_applicable_attributes()) {
 124         # if we have a trigger, then ...
 125         if ($attr->can('has_trigger') && $attr->has_trigger) {
 126             # make sure we have an init-arg ...
 127             if (defined(my $init_arg = $attr->init_arg)) {
 128                 # now make sure an init-arg was passes ...
 129                 if (exists $params{$init_arg}) {
 130                     # and if get here, fire the trigger
 131                     $attr->trigger->(
 132                         $self,
 133                         # check if there is a coercion
 134                         ($attr->should_coerce
 135                             # and if so, we need to grab the
 136                             # value that is actually been stored
 137                             ? $attr->get_read_method_ref->($self)
 138                             # otherwise, just get the value from
 139                             # the constructor params
 140                             : $params{$init_arg}),
 141                         $attr
 142                     );
 143                 }
 144             }
 145         }
 146     }
 147     return $self;
 148 }
 149
 150 sub construct_instance {
 151     my ($class, %params) = @_;
 152     my $meta_instance = $class->get_meta_instance;
 153     # FIXME:
 154     # the code below is almost certainly incorrect
 155     # but this is foreign inheritence, so we might
 156     # have to kludge it in the end.
 157     my $instance = $params{'__INSTANCE__'} || $meta_instance->create_instance();
 158     foreach my $attr ($class->compute_all_applicable_attributes()) {
 159         $attr->initialize_instance_slot($meta_instance, $instance, \%params)
 160     }
 161     return $instance;
 162 }
 163
 164 # FIXME:
 165 # This is ugly
 166 sub get_method_map {
 167     my $self = shift;
 168
 169     if (defined $self->{'$!_package_cache_flag'} &&
 170                 $self->{'$!_package_cache_flag'} == Class::MOP::check_package_cache_flag($self->meta->name)) {
 171         return $self->{'%!methods'};
 172     }
 173
 174     my $map  = $self->{'%!methods'};
 175
 176     my $class_name       = $self->name;
 177     my $method_metaclass = $self->method_metaclass;
 178
 179     foreach my $symbol ($self->list_all_package_symbols('CODE')) {
 180
 181         my $code = $self->get_package_symbol('&' . $symbol);
 182
 183         next if exists  $map->{$symbol} &&
 184                 defined $map->{$symbol} &&
 185                         $map->{$symbol}->body == $code;
 186
 187         my ($pkg, $name) = Class::MOP::get_code_info($code);
 188
 189         if ($pkg->can('meta')
 190             # NOTE:
 191             # we don't know what ->meta we are calling
 192             # here, so we need to be careful cause it
 193             # just might blow up at us, or just complain
 194             # loudly (in the case of Curses.pm) so we
 195             # just be a little overly cautious here.
 196             # - SL
 197             && eval { no warnings; blessed($pkg->meta) }
 198             && $pkg->meta->isa('Moose::Meta::Role')) {
 199             #my $role = $pkg->meta->name;
 200             #next unless $self->does_role($role);
 201         }
 202         else {
 203             next if ($pkg  || '') ne $class_name &&
 204                     ($name || '') ne '__ANON__';
 205
 206         }
 207
 208         $map->{$symbol} = $method_metaclass->wrap($code);
 209     }
 210
 211     return $map;
 212 }
 213
 214 ### ---------------------------------------------
 215
 216 sub add_attribute {
 217     my $self = shift;
 218     $self->SUPER::add_attribute(
 219         (blessed $_[0] && $_[0]->isa('Class::MOP::Attribute')
 220             ? $_[0]
 221             : $self->_process_attribute(@_))
 222     );
 223 }
 224
 225 sub add_override_method_modifier {
 226     my ($self, $name, $method, $_super_package) = @_;
 227     (!$self->has_method($name))
 228         || confess "Cannot add an override method if a local method is already present";
 229     # need this for roles ...
 230     $_super_package ||= $self->name;
 231     my $super = $self->find_next_method_by_name($name);
 232     (defined $super)
 233         || confess "You cannot override '$name' because it has no super method";
 234     $self->add_method($name => Moose::Meta::Method::Overriden->wrap(sub {
 235         my @args = @_;
 236         no warnings 'redefine';
 237         if ($Moose::SUPER_SLOT{$_super_package}) {
 238             local *{$Moose::SUPER_SLOT{$_super_package}} = sub { $super->body->(@args) };
 239             return $method->(@args);
 240         } else {
 241             confess "Trying to call override modifier'd method without super()";
 242         }
 243     }));
 244 }
 245
 246 sub add_augment_method_modifier {
 247     my ($self, $name, $method) = @_;
 248     (!$self->has_method($name))
 249         || confess "Cannot add an augment method if a local method is already present";
 250     my $super = $self->find_next_method_by_name($name);
 251     (defined $super)
 252         || confess "You cannot augment '$name' because it has no super method";
 253     my $_super_package = $super->package_name;
 254     # BUT!,... if this is an overriden method ....
 255     if ($super->isa('Moose::Meta::Method::Overriden')) {
 256         # we need to be sure that we actually
 257         # find the next method, which is not
 258         # an 'override' method, the reason is
 259         # that an 'override' method will not
 260         # be the one calling inner()
 261         my $real_super = $self->_find_next_method_by_name_which_is_not_overridden($name);
 262         $_super_package = $real_super->package_name;
 263     }
 264     $self->add_method($name => sub {
 265         my @args = @_;
 266         no warnings 'redefine';
 267         if ($Moose::INNER_SLOT{$_super_package}) {
 268             local *{$Moose::INNER_SLOT{$_super_package}} = sub {
 269                 local *{$Moose::INNER_SLOT{$_super_package}} = sub {};
 270                 $method->(@args);
 271             };
 272             return $super->body->(@args);
 273         }
 274         else {
 275             return $super->body->(@args);
 276         }
 277     });
 278 }
 279
 280 ## Private Utility methods ...
 281
 282 sub _find_next_method_by_name_which_is_not_overridden {
 283     my ($self, $name) = @_;
 284     foreach my $method ($self->find_all_methods_by_name($name)) {
 285         return $method->{code}
 286             if blessed($method->{code}) && !$method->{code}->isa('Moose::Meta::Method::Overriden');
 287     }
 288     return undef;
 289 }
 290
 291 sub _fix_metaclass_incompatability {
 292     my ($self, @superclasses) = @_;
 293     foreach my $super (@superclasses) {
 294         # don't bother if it does not have a meta.
 295         next unless $super->can('meta');
 296         # get the name, make sure we take
 297         # immutable classes into account
 298         my $super_meta_name = ($super->meta->is_immutable
 299                                 ? $super->meta->get_mutable_metaclass_name
 300                                 : blessed($super->meta));
 301         # if it's meta is a vanilla Moose,
 302         # then we can safely ignore it.
 303         next if $super_meta_name eq 'Moose::Meta::Class';
 304         # but if we have anything else,
 305         # we need to check it out ...
 306         unless (# see if of our metaclass is incompatible
 307                 ($self->isa($super_meta_name) &&
 308                  # and see if our instance metaclass is incompatible
 309                  $self->instance_metaclass->isa($super->meta->instance_metaclass)) &&
 310                 # ... and if we are just a vanilla Moose
 311                 $self->isa('Moose::Meta::Class')) {
 312             # re-initialize the meta ...
 313             my $super_meta = $super->meta;
 314             # NOTE:
 315             # We might want to consider actually
 316             # transfering any attributes from the
 317             # original meta into this one, but in
 318             # general you should not have any there
 319             # at this point anyway, so it's very
 320             # much an obscure edge case anyway
 321             $self = $super_meta->reinitialize($self->name => (
 322                 'attribute_metaclass' => $super_meta->attribute_metaclass,
 323                 'method_metaclass'    => $super_meta->method_metaclass,
 324                 'instance_metaclass'  => $super_meta->instance_metaclass,
 325             ));
 326         }
 327     }
 328     return $self;
 329 }
 330
 331 # NOTE:
 332 # this was crap anyway, see
 333 # Moose::Util::apply_all_roles
 334 # instead
 335 sub _apply_all_roles {
 336     Carp::croak 'DEPRECATED: use Moose::Util::apply_all_roles($meta, @roles) instead'
 337 }
 338
 339 sub _process_attribute {
 340     my $self    = shift;
 341     my $name    = shift;
 342     my %options = ((scalar @_ == 1 && ref($_[0]) eq 'HASH') ? %{$_[0]} : @_);
 343
 344     if ($name =~ /^\+(.*)/) {
 345         return $self->_process_inherited_attribute($1, %options);
 346     }
 347     else {
 348         my $attr_metaclass_name;
 349         if ($options{metaclass}) {
 350             my $metaclass_name = $options{metaclass};
 351             eval {
 352                 my $possible_full_name = 'Moose::Meta::Attribute::Custom::' . $metaclass_name;
 353                 Class::MOP::load_class($possible_full_name);
 354                 $metaclass_name = $possible_full_name->can('register_implementation')
 355                     ? $possible_full_name->register_implementation
 356                     : $possible_full_name;
 357             };
 358             if ($@) {
 359                 Class::MOP::load_class($metaclass_name);
 360             }
 361             $attr_metaclass_name = $metaclass_name;
 362         }
 363         else {
 364             $attr_metaclass_name = $self->attribute_metaclass;
 365         }
 366
 367         if ($options{traits}) {
 368             my @traits;
 369             foreach my $trait (@{$options{traits}}) {
 370                 eval {
 371                     my $possible_full_name = 'Moose::Meta::Attribute::Custom::Trait::' . $trait;
 372                     Class::MOP::load_class($possible_full_name);
 373                     push @traits => $possible_full_name->can('register_implementation')
 374                       ? $possible_full_name->register_implementation
 375                         : $possible_full_name;
 376                 };
 377                 if ($@) {
 378                     push @traits => $trait;
 379                 }
 380             }
 381
 382             my $class = Moose::Meta::Class->create_anon_class(
 383                 superclasses => [ $attr_metaclass_name ],
 384                 roles        => [ @traits ],
 385                 cache        => 1,
 386             );
 387
 388             $attr_metaclass_name = $class->name;
 389         }
 390
 391         return $attr_metaclass_name->new($name, %options);
 392     }
 393 }
 394
 395 sub _process_inherited_attribute {
 396     my ($self, $attr_name, %options) = @_;
 397     my $inherited_attr = $self->find_attribute_by_name($attr_name);
 398     (defined $inherited_attr)
 399         || confess "Could not find an attribute by the name of '$attr_name' to inherit from";
 400     if ($inherited_attr->isa('Moose::Meta::Attribute')) {
 401         return $inherited_attr->clone_and_inherit_options(%options);
 402     }
 403     else {
 404         # NOTE:
 405         # kind of a kludge to handle Class::MOP::Attributes
 406         return $inherited_attr->Moose::Meta::Attribute::clone_and_inherit_options(%options);
 407     }
 408 }
 409
 410 ## -------------------------------------------------
 411
 412 use Moose::Meta::Method::Constructor;
 413 use Moose::Meta::Method::Destructor;
 414
 415 # This could be done by using SUPER and altering ->options
 416 # I am keeping it this way to make it more explicit.
 417 sub create_immutable_transformer {
 418     my $self = shift;
 419     my $class = Class::MOP::Immutable->new($self, {
 420        read_only   => [qw/superclasses/],
 421        cannot_call => [qw/
 422            add_method
 423            alias_method
 424            remove_method
 425            add_attribute
 426            remove_attribute
 427            add_package_symbol
 428            remove_package_symbol
 429            add_role
 430        /],
 431        memoize     => {
 432            class_precedence_list             => 'ARRAY',
 433            compute_all_applicable_attributes => 'ARRAY',
 434            get_meta_instance                 => 'SCALAR',
 435            get_method_map                    => 'SCALAR',
 436            # maybe ....
 437            calculate_all_roles               => 'ARRAY',
 438        }
 439     });
 440     return $class;
 441 }
 442
 443 sub make_immutable {
 444     my $self = shift;
 445     $self->SUPER::make_immutable
 446       (
 447        constructor_class => 'Moose::Meta::Method::Constructor',
 448        destructor_class  => 'Moose::Meta::Method::Destructor',
 449        inline_destructor => 1,
 450        # NOTE:
 451        # no need to do this,
 452        # Moose always does it
 453        inline_accessors  => 0,
 454        @_,
 455       );
 456 }
 457
 458 1;
 459
 460 __END__
 461
 462 =pod
 463
 464 =head1 NAME
 465
 466 Moose::Meta::Class - The Moose metaclass
 467
 468 =head1 DESCRIPTION
 469
 470 This is a subclass of L<Class::MOP::Class> with Moose specific
 471 extensions.
 472
 473 For the most part, the only time you will ever encounter an
 474 instance of this class is if you are doing some serious deep
 475 introspection. To really understand this class, you need to refer
 476 to the L<Class::MOP::Class> documentation.
 477
 478 =head1 METHODS
 479
 480 =over 4
 481
 482 =item B<initialize>
 483
 484 =item B<create>
 485
 486 Overrides original to accept a list of roles to apply to
 487 the created class.
 488
 489    my $metaclass = Moose::Meta::Class->create( 'New::Class', roles => [...] );
 490
 491 =item B<create_anon_class>
 492
 493 Overrides original to support roles and caching.
 494
 495    my $metaclass = Moose::Meta::Class->create_anon_class(
 496        superclasses => ['Foo'],
 497        roles        => [qw/Some Roles Go Here/],
 498        cache        => 1,
 499    );
 500
 501 =item B<make_immutable>
 502
 503 Override original to add default options for inlining destructor
 504 and altering the Constructor metaclass.
 505
 506 =item B<create_immutable_transformer>
 507
 508 Override original to lock C<add_role> and memoize C<calculate_all_roles>
 509
 510 =item B<new_object>
 511
 512 We override this method to support the C<trigger> attribute option.
 513
 514 =item B<construct_instance>
 515
 516 This provides some Moose specific extensions to this method, you
 517 almost never call this method directly unless you really know what
 518 you are doing.
 519
 520 This method makes sure to handle the moose weak-ref, type-constraint
 521 and type coercion features.
 522
 523 =item B<get_method_map>
 524
 525 This accommodates Moose::Meta::Role::Method instances, which are
 526 aliased, instead of added, but still need to be counted as valid
 527 methods.
 528
 529 =item B<add_override_method_modifier ($name, $method)>
 530
 531 This will create an C<override> method modifier for you, and install
 532 it in the package.
 533
 534 =item B<add_augment_method_modifier ($name, $method)>
 535
 536 This will create an C<augment> method modifier for you, and install
 537 it in the package.
 538
 539 =item B<calculate_all_roles>
 540
 541 =item B<roles>
 542
 543 This will return an array of C<Moose::Meta::Role> instances which are
 544 attached to this class.
 545
 546 =item B<add_role ($role)>
 547
 548 This takes an instance of C<Moose::Meta::Role> in C<$role>, and adds it
 549 to the list of associated roles.
 550
 551 =item B<does_role ($role_name)>
 552
 553 This will test if this class C<does> a given C<$role_name>. It will
 554 not only check it's local roles, but ask them as well in order to
 555 cascade down the role hierarchy.
 556
 557 =item B<excludes_role ($role_name)>
 558
 559 This will test if this class C<excludes> a given C<$role_name>. It will
 560 not only check it's local roles, but ask them as well in order to
 561 cascade down the role hierarchy.
 562
 563 =item B<add_attribute ($attr_name, %params|$params)>
 564
 565 This method does the same thing as L<Class::MOP::Class::add_attribute>, but adds
 566 support for taking the C<$params> as a HASH ref.
 567
 568 =back
 569
 570 =head1 BUGS
 571
 572 All complex software has bugs lurking in it, and this module is no
 573 exception. If you find a bug please either email me, or add the bug
 574 to cpan-RT.
 575
 576 =head1 AUTHOR
 577
 578 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 579
 580 =head1 COPYRIGHT AND LICENSE
 581
 582 Copyright 2006-2008 by Infinity Interactive, Inc.
 583
 584 L<http://www.iinteractive.com>
 585
 586 This library is free software; you can redistribute it and/or modify
 587 it under the same terms as Perl itself.
 588
 589 =cut
 590