lib/Moose/Meta/Class.pm

   1
   2 package Moose::Meta::Class;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Class::MOP;
   8
   9 use Carp         'confess';
  10 use Scalar::Util 'weaken', 'blessed';
  11
  12 our $VERSION   = '0.53';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use Moose::Meta::Method::Overriden;
  16 use Moose::Meta::Method::Augmented;
  17
  18 use base 'Class::MOP::Class';
  19
  20 __PACKAGE__->meta->add_attribute('roles' => (
  21     reader  => 'roles',
  22     default => sub { [] }
  23 ));
  24
  25 sub initialize {
  26     my $class = shift;
  27     my $pkg   = shift;
  28     return Class::MOP::get_metaclass_by_name($pkg)
  29         || $class->SUPER::initialize($pkg,
  30                 'attribute_metaclass' => 'Moose::Meta::Attribute',
  31                 'method_metaclass'    => 'Moose::Meta::Method',
  32                 'instance_metaclass'  => 'Moose::Meta::Instance',
  33                 @_
  34             );
  35 }
  36
  37 sub create {
  38     my ($self, $package_name, %options) = @_;
  39
  40     (ref $options{roles} eq 'ARRAY')
  41         || confess "You must pass an ARRAY ref of roles"
  42             if exists $options{roles};
  43
  44     my $class = $self->SUPER::create($package_name, %options);
  45
  46     if (exists $options{roles}) {
  47         Moose::Util::apply_all_roles($class, @{$options{roles}});
  48     }
  49
  50     return $class;
  51 }
  52
  53 my %ANON_CLASSES;
  54
  55 sub create_anon_class {
  56     my ($self, %options) = @_;
  57
  58     my $cache_ok = delete $options{cache};
  59
  60     # something like Super::Class|Super::Class::2=Role|Role::1
  61     my $cache_key = join '=' => (
  62         join('|', sort @{$options{superclasses} || []}),
  63         join('|', sort @{$options{roles}        || []}),
  64     );
  65
  66     if ($cache_ok && defined $ANON_CLASSES{$cache_key}) {
  67         return $ANON_CLASSES{$cache_key};
  68     }
  69
  70     my $new_class = $self->SUPER::create_anon_class(%options);
  71
  72     $ANON_CLASSES{$cache_key} = $new_class
  73         if $cache_ok;
  74
  75     return $new_class;
  76 }
  77
  78 sub add_role {
  79     my ($self, $role) = @_;
  80     (blessed($role) && $role->isa('Moose::Meta::Role'))
  81         || confess "Roles must be instances of Moose::Meta::Role";
  82     push @{$self->roles} => $role;
  83 }
  84
  85 sub calculate_all_roles {
  86     my $self = shift;
  87     my %seen;
  88     grep { !$seen{$_->name}++ } map { $_->calculate_all_roles } @{ $self->roles };
  89 }
  90
  91 sub does_role {
  92     my ($self, $role_name) = @_;
  93     (defined $role_name)
  94         || confess "You must supply a role name to look for";
  95     foreach my $class ($self->class_precedence_list) {
  96         next unless $class->can('meta') && $class->meta->can('roles');
  97         foreach my $role (@{$class->meta->roles}) {
  98             return 1 if $role->does_role($role_name);
  99         }
 100     }
 101     return 0;
 102 }
 103
 104 sub excludes_role {
 105     my ($self, $role_name) = @_;
 106     (defined $role_name)
 107         || confess "You must supply a role name to look for";
 108     foreach my $class ($self->class_precedence_list) {
 109         next unless $class->can('meta');
 110         # NOTE:
 111         # in the pretty rare instance when a Moose metaclass
 112         # is itself extended with a role, this check needs to
 113         # be done since some items in the class_precedence_list
 114         # might in fact be Class::MOP based still.
 115         next unless $class->meta->can('roles');
 116         foreach my $role (@{$class->meta->roles}) {
 117             return 1 if $role->excludes_role($role_name);
 118         }
 119     }
 120     return 0;
 121 }
 122
 123 sub new_object {
 124     my ($class, %params) = @_;
 125     my $self = $class->SUPER::new_object(%params);
 126     foreach my $attr ($class->compute_all_applicable_attributes()) {
 127         # if we have a trigger, then ...
 128         if ($attr->can('has_trigger') && $attr->has_trigger) {
 129             # make sure we have an init-arg ...
 130             if (defined(my $init_arg = $attr->init_arg)) {
 131                 # now make sure an init-arg was passes ...
 132                 if (exists $params{$init_arg}) {
 133                     # and if get here, fire the trigger
 134                     $attr->trigger->(
 135                         $self,
 136                         # check if there is a coercion
 137                         ($attr->should_coerce
 138                             # and if so, we need to grab the
 139                             # value that is actually been stored
 140                             ? $attr->get_read_method_ref->($self)
 141                             # otherwise, just get the value from
 142                             # the constructor params
 143                             : $params{$init_arg}),
 144                         $attr
 145                     );
 146                 }
 147             }
 148         }
 149     }
 150     return $self;
 151 }
 152
 153 sub construct_instance {
 154     my ($class, %params) = @_;
 155     my $meta_instance = $class->get_meta_instance;
 156     # FIXME:
 157     # the code below is almost certainly incorrect
 158     # but this is foreign inheritence, so we might
 159     # have to kludge it in the end.
 160     my $instance = $params{'__INSTANCE__'} || $meta_instance->create_instance();
 161     foreach my $attr ($class->compute_all_applicable_attributes()) {
 162         $attr->initialize_instance_slot($meta_instance, $instance, \%params);
 163     }
 164     return $instance;
 165 }
 166
 167 # FIXME:
 168 # This is ugly
 169 sub get_method_map {
 170     my $self = shift;
 171
 172     if (defined $self->{'$!_package_cache_flag'} &&
 173                 $self->{'$!_package_cache_flag'} == Class::MOP::check_package_cache_flag($self->meta->name)) {
 174         return $self->{'%!methods'};
 175     }
 176
 177     my $map  = $self->{'%!methods'};
 178
 179     my $class_name       = $self->name;
 180     my $method_metaclass = $self->method_metaclass;
 181
 182     my %all_code = $self->get_all_package_symbols('CODE');
 183
 184     foreach my $symbol (keys %all_code) {
 185         my $code = $all_code{$symbol};
 186
 187         next if exists  $map->{$symbol} &&
 188                 defined $map->{$symbol} &&
 189                         $map->{$symbol}->body == $code;
 190
 191         my ($pkg, $name) = Class::MOP::get_code_info($code);
 192
 193         if ($pkg->can('meta')
 194             # NOTE:
 195             # we don't know what ->meta we are calling
 196             # here, so we need to be careful cause it
 197             # just might blow up at us, or just complain
 198             # loudly (in the case of Curses.pm) so we
 199             # just be a little overly cautious here.
 200             # - SL
 201             && eval { no warnings; blessed($pkg->meta) }
 202             && $pkg->meta->isa('Moose::Meta::Role')) {
 203             #my $role = $pkg->meta->name;
 204             #next unless $self->does_role($role);
 205         }
 206         else {
 207
 208             # NOTE:
 209             # in 5.10 constant.pm the constants show up
 210             # as being in the right package, but in pre-5.10
 211             # they show up as constant::__ANON__ so we
 212             # make an exception here to be sure that things
 213             # work as expected in both.
 214             # - SL
 215             unless ($pkg eq 'constant' && $name eq '__ANON__') {
 216                 next if ($pkg  || '') ne $class_name ||
 217                         (($name || '') ne '__ANON__' && ($pkg  || '') ne $class_name);
 218             }
 219
 220         }
 221
 222         $map->{$symbol} = $method_metaclass->wrap(
 223             $code,
 224             package_name => $class_name,
 225             name         => $symbol
 226         );
 227     }
 228
 229     return $map;
 230 }
 231
 232 ### ---------------------------------------------
 233
 234 sub add_attribute {
 235     my $self = shift;
 236     $self->SUPER::add_attribute(
 237         (blessed $_[0] && $_[0]->isa('Class::MOP::Attribute')
 238             ? $_[0]
 239             : $self->_process_attribute(@_))
 240     );
 241 }
 242
 243 sub add_override_method_modifier {
 244     my ($self, $name, $method, $_super_package) = @_;
 245
 246     (!$self->has_method($name))
 247         || confess "Cannot add an override method if a local method is already present";
 248
 249     $self->add_method($name => Moose::Meta::Method::Overriden->new(
 250         method  => $method,
 251         class   => $self,
 252         package => $_super_package, # need this for roles
 253         name    => $name,
 254     ));
 255 }
 256
 257 sub add_augment_method_modifier {
 258     my ($self, $name, $method) = @_;
 259     (!$self->has_method($name))
 260         || confess "Cannot add an augment method if a local method is already present";
 261
 262     $self->add_method($name => Moose::Meta::Method::Augmented->new(
 263         method  => $method,
 264         class   => $self,
 265         name    => $name,
 266     ));
 267 }
 268
 269 ## Private Utility methods ...
 270
 271 sub _find_next_method_by_name_which_is_not_overridden {
 272     my ($self, $name) = @_;
 273     foreach my $method ($self->find_all_methods_by_name($name)) {
 274         return $method->{code}
 275             if blessed($method->{code}) && !$method->{code}->isa('Moose::Meta::Method::Overriden');
 276     }
 277     return undef;
 278 }
 279
 280 sub _fix_metaclass_incompatability {
 281     my ($self, @superclasses) = @_;
 282     foreach my $super (@superclasses) {
 283         # don't bother if it does not have a meta.
 284         next unless $super->can('meta');
 285         # get the name, make sure we take
 286         # immutable classes into account
 287         my $super_meta_name = ($super->meta->is_immutable
 288                                 ? $super->meta->get_mutable_metaclass_name
 289                                 : blessed($super->meta));
 290         # if it's meta is a vanilla Moose,
 291         # then we can safely ignore it.
 292         next if $super_meta_name eq 'Moose::Meta::Class';
 293         # but if we have anything else,
 294         # we need to check it out ...
 295         unless (# see if of our metaclass is incompatible
 296                 ($self->isa($super_meta_name) &&
 297                  # and see if our instance metaclass is incompatible
 298                  $self->instance_metaclass->isa($super->meta->instance_metaclass)) &&
 299                 # ... and if we are just a vanilla Moose
 300                 $self->isa('Moose::Meta::Class')) {
 301             # re-initialize the meta ...
 302             my $super_meta = $super->meta;
 303             # NOTE:
 304             # We might want to consider actually
 305             # transfering any attributes from the
 306             # original meta into this one, but in
 307             # general you should not have any there
 308             # at this point anyway, so it's very
 309             # much an obscure edge case anyway
 310             $self = $super_meta->reinitialize($self->name => (
 311                 'attribute_metaclass' => $super_meta->attribute_metaclass,
 312                 'method_metaclass'    => $super_meta->method_metaclass,
 313                 'instance_metaclass'  => $super_meta->instance_metaclass,
 314             ));
 315         }
 316     }
 317     return $self;
 318 }
 319
 320 # NOTE:
 321 # this was crap anyway, see
 322 # Moose::Util::apply_all_roles
 323 # instead
 324 sub _apply_all_roles {
 325     Carp::croak 'DEPRECATED: use Moose::Util::apply_all_roles($meta, @roles) instead'
 326 }
 327
 328 sub _process_attribute {
 329     my ( $self, $name, @args ) = @_;
 330
 331     @args = %{$args[0]} if scalar @args == 1 && ref($args[0]) eq 'HASH';
 332
 333     if ($name =~ /^\+(.*)/) {
 334         return $self->_process_inherited_attribute($1, @args);
 335     }
 336     else {
 337         return $self->_process_new_attribute($name, @args);
 338     }
 339 }
 340
 341 sub _process_new_attribute {
 342     my ( $self, $name, @args ) = @_;
 343
 344     $self->attribute_metaclass->interpolate_class_and_new($name, @args);
 345 }
 346
 347 sub _process_inherited_attribute {
 348     my ($self, $attr_name, %options) = @_;
 349     my $inherited_attr = $self->find_attribute_by_name($attr_name);
 350     (defined $inherited_attr)
 351         || confess "Could not find an attribute by the name of '$attr_name' to inherit from";
 352     if ($inherited_attr->isa('Moose::Meta::Attribute')) {
 353         return $inherited_attr->clone_and_inherit_options(%options);
 354     }
 355     else {
 356         # NOTE:
 357         # kind of a kludge to handle Class::MOP::Attributes
 358         return $inherited_attr->Moose::Meta::Attribute::clone_and_inherit_options(%options);
 359     }
 360 }
 361
 362 ## -------------------------------------------------
 363
 364 use Moose::Meta::Method::Constructor;
 365 use Moose::Meta::Method::Destructor;
 366
 367 # This could be done by using SUPER and altering ->options
 368 # I am keeping it this way to make it more explicit.
 369 sub create_immutable_transformer {
 370     my $self = shift;
 371     my $class = Class::MOP::Immutable->new($self, {
 372        read_only   => [qw/superclasses/],
 373        cannot_call => [qw/
 374            add_method
 375            alias_method
 376            remove_method
 377            add_attribute
 378            remove_attribute
 379            remove_package_symbol
 380            add_role
 381        /],
 382        memoize     => {
 383            class_precedence_list             => 'ARRAY',
 384            compute_all_applicable_attributes => 'ARRAY',
 385            get_meta_instance                 => 'SCALAR',
 386            get_method_map                    => 'SCALAR',
 387            # maybe ....
 388            calculate_all_roles               => 'ARRAY',
 389        },
 390        # NOTE:
 391        # this is ugly, but so are typeglobs,
 392        # so whattayahgonnadoboutit
 393        # - SL
 394        wrapped => {
 395            add_package_symbol => sub {
 396                my $original = shift;
 397                confess "Cannot add package symbols to an immutable metaclass"
 398                    unless (caller(2))[3] eq 'Class::MOP::Package::get_package_symbol';
 399                goto $original->body;
 400            },
 401        },
 402     });
 403     return $class;
 404 }
 405
 406 sub make_immutable {
 407     my $self = shift;
 408     $self->SUPER::make_immutable
 409       (
 410        constructor_class => 'Moose::Meta::Method::Constructor',
 411        destructor_class  => 'Moose::Meta::Method::Destructor',
 412        inline_destructor => 1,
 413        # NOTE:
 414        # no need to do this,
 415        # Moose always does it
 416        inline_accessors  => 0,
 417        @_,
 418       );
 419 }
 420
 421 1;
 422
 423 __END__
 424
 425 =pod
 426
 427 =head1 NAME
 428
 429 Moose::Meta::Class - The Moose metaclass
 430
 431 =head1 DESCRIPTION
 432
 433 This is a subclass of L<Class::MOP::Class> with Moose specific
 434 extensions.
 435
 436 For the most part, the only time you will ever encounter an
 437 instance of this class is if you are doing some serious deep
 438 introspection. To really understand this class, you need to refer
 439 to the L<Class::MOP::Class> documentation.
 440
 441 =head1 METHODS
 442
 443 =over 4
 444
 445 =item B<initialize>
 446
 447 =item B<create>
 448
 449 Overrides original to accept a list of roles to apply to
 450 the created class.
 451
 452    my $metaclass = Moose::Meta::Class->create( 'New::Class', roles => [...] );
 453
 454 =item B<create_anon_class>
 455
 456 Overrides original to support roles and caching.
 457
 458    my $metaclass = Moose::Meta::Class->create_anon_class(
 459        superclasses => ['Foo'],
 460        roles        => [qw/Some Roles Go Here/],
 461        cache        => 1,
 462    );
 463
 464 =item B<make_immutable>
 465
 466 Override original to add default options for inlining destructor
 467 and altering the Constructor metaclass.
 468
 469 =item B<create_immutable_transformer>
 470
 471 Override original to lock C<add_role> and memoize C<calculate_all_roles>
 472
 473 =item B<new_object>
 474
 475 We override this method to support the C<trigger> attribute option.
 476
 477 =item B<construct_instance>
 478
 479 This provides some Moose specific extensions to this method, you
 480 almost never call this method directly unless you really know what
 481 you are doing.
 482
 483 This method makes sure to handle the moose weak-ref, type-constraint
 484 and type coercion features.
 485
 486 =item B<get_method_map>
 487
 488 This accommodates Moose::Meta::Role::Method instances, which are
 489 aliased, instead of added, but still need to be counted as valid
 490 methods.
 491
 492 =item B<add_override_method_modifier ($name, $method)>
 493
 494 This will create an C<override> method modifier for you, and install
 495 it in the package.
 496
 497 =item B<add_augment_method_modifier ($name, $method)>
 498
 499 This will create an C<augment> method modifier for you, and install
 500 it in the package.
 501
 502 =item B<calculate_all_roles>
 503
 504 =item B<roles>
 505
 506 This will return an array of C<Moose::Meta::Role> instances which are
 507 attached to this class.
 508
 509 =item B<add_role ($role)>
 510
 511 This takes an instance of C<Moose::Meta::Role> in C<$role>, and adds it
 512 to the list of associated roles.
 513
 514 =item B<does_role ($role_name)>
 515
 516 This will test if this class C<does> a given C<$role_name>. It will
 517 not only check it's local roles, but ask them as well in order to
 518 cascade down the role hierarchy.
 519
 520 =item B<excludes_role ($role_name)>
 521
 522 This will test if this class C<excludes> a given C<$role_name>. It will
 523 not only check it's local roles, but ask them as well in order to
 524 cascade down the role hierarchy.
 525
 526 =item B<add_attribute ($attr_name, %params|$params)>
 527
 528 This method does the same thing as L<Class::MOP::Class::add_attribute>, but adds
 529 support for taking the C<$params> as a HASH ref.
 530
 531 =back
 532
 533 =head1 BUGS
 534
 535 All complex software has bugs lurking in it, and this module is no
 536 exception. If you find a bug please either email me, or add the bug
 537 to cpan-RT.
 538
 539 =head1 AUTHOR
 540
 541 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 542
 543 =head1 COPYRIGHT AND LICENSE
 544
 545 Copyright 2006-2008 by Infinity Interactive, Inc.
 546
 547 L<http://www.iinteractive.com>
 548
 549 This library is free software; you can redistribute it and/or modify
 550 it under the same terms as Perl itself.
 551
 552 =cut
 553