lib/Moose/Meta/Class.pm

   1
   2 package Moose::Meta::Class;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Class::MOP;
   8
   9 use Carp         'confess';
  10 use Scalar::Util 'weaken', 'blessed', 'reftype';
  11
  12 our $VERSION   = '0.17';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use Moose::Meta::Method::Overriden;
  16
  17 use base 'Class::MOP::Class';
  18
  19 __PACKAGE__->meta->add_attribute('roles' => (
  20     reader  => 'roles',
  21     default => sub { [] }
  22 ));
  23
  24 sub initialize {
  25     my $class = shift;
  26     my $pkg   = shift;
  27     $class->SUPER::initialize($pkg,
  28         'attribute_metaclass' => 'Moose::Meta::Attribute',
  29         'method_metaclass'    => 'Moose::Meta::Method',
  30         'instance_metaclass'  => 'Moose::Meta::Instance',
  31         @_);
  32 }
  33
  34 sub add_role {
  35     my ($self, $role) = @_;
  36     (blessed($role) && $role->isa('Moose::Meta::Role'))
  37         || confess "Roles must be instances of Moose::Meta::Role";
  38     push @{$self->roles} => $role;
  39 }
  40
  41 sub calculate_all_roles {
  42     my $self = shift;
  43     my %seen;
  44     grep { !$seen{$_->name}++ } map { $_->calculate_all_roles } @{ $self->roles };
  45 }
  46
  47 sub does_role {
  48     my ($self, $role_name) = @_;
  49     (defined $role_name)
  50         || confess "You must supply a role name to look for";
  51     foreach my $class ($self->class_precedence_list) {
  52         next unless $class->can('meta');
  53         foreach my $role (@{$class->meta->roles}) {
  54             return 1 if $role->does_role($role_name);
  55         }
  56     }
  57     return 0;
  58 }
  59
  60 sub excludes_role {
  61     my ($self, $role_name) = @_;
  62     (defined $role_name)
  63         || confess "You must supply a role name to look for";
  64     foreach my $class ($self->class_precedence_list) {
  65         next unless $class->can('meta');
  66         # NOTE:
  67         # in the pretty rare instance when a Moose metaclass
  68         # is itself extended with a role, this check needs to
  69         # be done since some items in the class_precedence_list
  70         # might in fact be Class::MOP based still.
  71         next unless $class->meta->can('roles');
  72         foreach my $role (@{$class->meta->roles}) {
  73             return 1 if $role->excludes_role($role_name);
  74         }
  75     }
  76     return 0;
  77 }
  78
  79 sub new_object {
  80     my ($class, %params) = @_;
  81     my $self = $class->SUPER::new_object(%params);
  82     foreach my $attr ($class->compute_all_applicable_attributes()) {
  83         # FIXME:
  84         # this does not accept undefined
  85         # values, nor does it accept false
  86         # values to be passed into the init-arg
  87         next unless $params{$attr->init_arg} && $attr->can('has_trigger') && $attr->has_trigger;
  88         $attr->trigger->($self, $params{$attr->init_arg}, $attr);
  89     }
  90     return $self;
  91 }
  92
  93 sub construct_instance {
  94     my ($class, %params) = @_;
  95     my $meta_instance = $class->get_meta_instance;
  96     # FIXME:
  97     # the code below is almost certainly incorrect
  98     # but this is foreign inheritence, so we might
  99     # have to kludge it in the end.
 100     my $instance = $params{'__INSTANCE__'} || $meta_instance->create_instance();
 101     foreach my $attr ($class->compute_all_applicable_attributes()) {
 102         $attr->initialize_instance_slot($meta_instance, $instance, \%params)
 103     }
 104     return $instance;
 105 }
 106
 107 # FIXME:
 108 # This is ugly
 109 sub get_method_map {
 110     my $self = shift;
 111
 112     if (defined $self->{'$!_package_cache_flag'} &&
 113                 $self->{'$!_package_cache_flag'} == Class::MOP::check_package_cache_flag($self->meta->name)) {
 114         return $self->{'%!methods'};
 115     }
 116
 117     my $map  = $self->{'%!methods'};
 118
 119     my $class_name       = $self->name;
 120     my $method_metaclass = $self->method_metaclass;
 121
 122     foreach my $symbol ($self->list_all_package_symbols('CODE')) {
 123
 124         my $code = $self->get_package_symbol('&' . $symbol);
 125
 126         next if exists  $map->{$symbol} &&
 127                 defined $map->{$symbol} &&
 128                         $map->{$symbol}->body == $code;
 129
 130         my ($pkg, $name) = Class::MOP::get_code_info($code);
 131
 132         if ($pkg->can('meta')
 133             # NOTE:
 134             # we don't know what ->meta we are calling
 135             # here, so we need to be careful cause it
 136             # just might blow up at us, or just complain
 137             # loudly (in the case of Curses.pm) so we
 138             # just be a little overly cautious here.
 139             # - SL
 140             && eval { no warnings; blessed($pkg->meta) }
 141             && $pkg->meta->isa('Moose::Meta::Role')) {
 142             #my $role = $pkg->meta->name;
 143             #next unless $self->does_role($role);
 144         }
 145         else {
 146             next if ($pkg  || '') ne $class_name &&
 147                     ($name || '') ne '__ANON__';
 148
 149         }
 150
 151         $map->{$symbol} = $method_metaclass->wrap($code);
 152     }
 153
 154     return $map;
 155 }
 156
 157 ### ---------------------------------------------
 158
 159 sub add_attribute {
 160     my $self = shift;
 161     $self->SUPER::add_attribute($self->_process_attribute(@_));
 162 }
 163
 164 sub add_override_method_modifier {
 165     my ($self, $name, $method, $_super_package) = @_;
 166     (!$self->has_method($name))
 167         || confess "Cannot add an override method if a local method is already present";
 168     # need this for roles ...
 169     $_super_package ||= $self->name;
 170     my $super = $self->find_next_method_by_name($name);
 171     (defined $super)
 172         || confess "You cannot override '$name' because it has no super method";
 173     $self->add_method($name => Moose::Meta::Method::Overriden->wrap(sub {
 174         my @args = @_;
 175         no warnings 'redefine';
 176         if ($Moose::SUPER_SLOT{$_super_package}) {
 177             local *{$Moose::SUPER_SLOT{$_super_package}} = sub { $super->body->(@args) };
 178             return $method->(@args);
 179         } else {
 180             confess "Trying to call override modifier'd method without super()";
 181         }
 182     }));
 183 }
 184
 185 sub add_augment_method_modifier {
 186     my ($self, $name, $method) = @_;
 187     (!$self->has_method($name))
 188         || confess "Cannot add an augment method if a local method is already present";
 189     my $super = $self->find_next_method_by_name($name);
 190     (defined $super)
 191         || confess "You cannot augment '$name' because it has no super method";
 192     my $_super_package = $super->package_name;
 193     # BUT!,... if this is an overriden method ....
 194     if ($super->isa('Moose::Meta::Method::Overriden')) {
 195         # we need to be sure that we actually
 196         # find the next method, which is not
 197         # an 'override' method, the reason is
 198         # that an 'override' method will not
 199         # be the one calling inner()
 200         my $real_super = $self->_find_next_method_by_name_which_is_not_overridden($name);
 201         $_super_package = $real_super->package_name;
 202     }
 203     $self->add_method($name => sub {
 204         my @args = @_;
 205         no warnings 'redefine';
 206         if ($Moose::INNER_SLOT{$_super_package}) {
 207             local *{$Moose::INNER_SLOT{$_super_package}} = sub {
 208                 local *{$Moose::INNER_SLOT{$_super_package}} = sub {};
 209                 $method->(@args);
 210             };
 211             return $super->body->(@args);
 212         }
 213         else {
 214             return $super->body->(@args);
 215         }
 216     });
 217 }
 218
 219 ## Private Utility methods ...
 220
 221 sub _find_next_method_by_name_which_is_not_overridden {
 222     my ($self, $name) = @_;
 223     foreach my $method ($self->find_all_methods_by_name($name)) {
 224         return $method->{code}
 225             if blessed($method->{code}) && !$method->{code}->isa('Moose::Meta::Method::Overriden');
 226     }
 227     return undef;
 228 }
 229
 230 sub _fix_metaclass_incompatability {
 231     my ($self, @superclasses) = @_;
 232     foreach my $super (@superclasses) {
 233         # don't bother if it does not have a meta.
 234         next unless $super->can('meta');
 235         # get the name, make sure we take
 236         # immutable classes into account
 237         my $super_meta_name = ($super->meta->is_immutable
 238                                 ? $super->meta->get_mutable_metaclass_name
 239                                 : blessed($super->meta));
 240         # if it's meta is a vanilla Moose,
 241         # then we can safely ignore it.
 242         next if $super_meta_name eq 'Moose::Meta::Class';
 243         # but if we have anything else,
 244         # we need to check it out ...
 245         unless (# see if of our metaclass is incompatible
 246                 ($self->isa($super_meta_name) &&
 247                  # and see if our instance metaclass is incompatible
 248                  $self->instance_metaclass->isa($super->meta->instance_metaclass)) &&
 249                 # ... and if we are just a vanilla Moose
 250                 $self->isa('Moose::Meta::Class')) {
 251             # re-initialize the meta ...
 252             my $super_meta = $super->meta;
 253             # NOTE:
 254             # We might want to consider actually
 255             # transfering any attributes from the
 256             # original meta into this one, but in
 257             # general you should not have any there
 258             # at this point anyway, so it's very
 259             # much an obscure edge case anyway
 260             $self = $super_meta->reinitialize($self->name => (
 261                 'attribute_metaclass' => $super_meta->attribute_metaclass,
 262                 'method_metaclass'    => $super_meta->method_metaclass,
 263                 'instance_metaclass'  => $super_meta->instance_metaclass,
 264             ));
 265         }
 266     }
 267     return $self;
 268 }
 269
 270 # NOTE:
 271 # this was crap anyway, see
 272 # Moose::Util::apply_all_roles
 273 # instead
 274 sub _apply_all_roles { die "DEPRECATED" }
 275
 276 my %ANON_CLASSES;
 277
 278 sub _process_attribute {
 279     my $self    = shift;
 280     my $name    = shift;
 281     my %options = ((scalar @_ == 1 && ref($_[0]) eq 'HASH') ? %{$_[0]} : @_);
 282
 283     if ($name =~ /^\+(.*)/) {
 284         return $self->_process_inherited_attribute($1, %options);
 285     }
 286     else {
 287         my $attr_metaclass_name;
 288         if ($options{metaclass}) {
 289             my $metaclass_name = $options{metaclass};
 290             eval {
 291                 my $possible_full_name = 'Moose::Meta::Attribute::Custom::' . $metaclass_name;
 292                 Class::MOP::load_class($possible_full_name);
 293                 $metaclass_name = $possible_full_name->can('register_implementation')
 294                     ? $possible_full_name->register_implementation
 295                     : $possible_full_name;
 296             };
 297             if ($@) {
 298                 Class::MOP::load_class($metaclass_name);
 299             }
 300             $attr_metaclass_name = $metaclass_name;
 301         }
 302         else {
 303             $attr_metaclass_name = $self->attribute_metaclass;
 304         }
 305
 306         if ($options{traits}) {
 307
 308             my $anon_role_key = join "|" => @{$options{traits}};
 309
 310             my $class;
 311             if (exists $ANON_CLASSES{$anon_role_key} && defined $ANON_CLASSES{$anon_role_key}) {
 312                 $class = $ANON_CLASSES{$anon_role_key};
 313             }
 314             else {
 315                 $class = Moose::Meta::Class->create_anon_class(
 316                     superclasses => [ $attr_metaclass_name ]
 317                 );
 318                 $ANON_CLASSES{$anon_role_key} = $class;
 319
 320                 my @traits;
 321                 foreach my $trait (@{$options{traits}}) {
 322                     eval {
 323                         my $possible_full_name = 'Moose::Meta::Attribute::Custom::Trait::' . $trait;
 324                         Class::MOP::load_class($possible_full_name);
 325                         push @traits => $possible_full_name->can('register_implementation')
 326                             ? $possible_full_name->register_implementation
 327                             : $possible_full_name;
 328                     };
 329                     if ($@) {
 330                         push @traits => $trait;
 331                     }
 332                 }
 333
 334                 Moose::Util::apply_all_roles($class, @traits);
 335             }
 336
 337             $attr_metaclass_name = $class->name;
 338         }
 339
 340         return $attr_metaclass_name->new($name, %options);
 341     }
 342 }
 343
 344 sub _process_inherited_attribute {
 345     my ($self, $attr_name, %options) = @_;
 346     my $inherited_attr = $self->find_attribute_by_name($attr_name);
 347     (defined $inherited_attr)
 348         || confess "Could not find an attribute by the name of '$attr_name' to inherit from";
 349     if ($inherited_attr->isa('Moose::Meta::Attribute')) {
 350         return $inherited_attr->clone_and_inherit_options(%options);
 351     }
 352     else {
 353         # NOTE:
 354         # kind of a kludge to handle Class::MOP::Attributes
 355         return $inherited_attr->Moose::Meta::Attribute::clone_and_inherit_options(%options);
 356     }
 357 }
 358
 359 ## -------------------------------------------------
 360
 361 use Moose::Meta::Method::Constructor;
 362 use Moose::Meta::Method::Destructor;
 363
 364 # This could be done by using SUPER and altering ->options
 365 # I am keeping it this way to make it more explicit.
 366 sub create_immutable_transformer {
 367     my $self = shift;
 368     my $class = Class::MOP::Immutable->new($self, {
 369        read_only   => [qw/superclasses/],
 370        cannot_call => [qw/
 371            add_method
 372            alias_method
 373            remove_method
 374            add_attribute
 375            remove_attribute
 376            add_package_symbol
 377            remove_package_symbol
 378            add_role
 379        /],
 380        memoize     => {
 381            class_precedence_list             => 'ARRAY',
 382            compute_all_applicable_attributes => 'ARRAY',
 383            get_meta_instance                 => 'SCALAR',
 384            get_method_map                    => 'SCALAR',
 385            # maybe ....
 386            calculate_all_roles               => 'ARRAY',
 387        }
 388     });
 389     return $class;
 390 }
 391
 392 sub make_immutable {
 393     my $self = shift;
 394     $self->SUPER::make_immutable
 395       (
 396        constructor_class => 'Moose::Meta::Method::Constructor',
 397        destructor_class  => 'Moose::Meta::Method::Destructor',
 398        inline_destructor => 1,
 399        # NOTE:
 400        # no need to do this,
 401        # Moose always does it
 402        inline_accessors  => 0,
 403        @_,
 404       );
 405 }
 406
 407 1;
 408
 409 __END__
 410
 411 =pod
 412
 413 =head1 NAME
 414
 415 Moose::Meta::Class - The Moose metaclass
 416
 417 =head1 DESCRIPTION
 418
 419 This is a subclass of L<Class::MOP::Class> with Moose specific
 420 extensions.
 421
 422 For the most part, the only time you will ever encounter an
 423 instance of this class is if you are doing some serious deep
 424 introspection. To really understand this class, you need to refer
 425 to the L<Class::MOP::Class> documentation.
 426
 427 =head1 METHODS
 428
 429 =over 4
 430
 431 =item B<initialize>
 432
 433 =item B<make_immutable>
 434
 435 Override original to add default options for inlining destructor
 436 and altering the Constructor metaclass.
 437
 438 =item B<create_immutable_transformer>
 439
 440 Override original to lock C<add_role> and memoize C<calculate_all_roles>
 441
 442 =item B<new_object>
 443
 444 We override this method to support the C<trigger> attribute option.
 445
 446 =item B<construct_instance>
 447
 448 This provides some Moose specific extensions to this method, you
 449 almost never call this method directly unless you really know what
 450 you are doing.
 451
 452 This method makes sure to handle the moose weak-ref, type-constraint
 453 and type coercion features.
 454
 455 =item B<get_method_map>
 456
 457 This accommodates Moose::Meta::Role::Method instances, which are
 458 aliased, instead of added, but still need to be counted as valid
 459 methods.
 460
 461 =item B<add_override_method_modifier ($name, $method)>
 462
 463 This will create an C<override> method modifier for you, and install
 464 it in the package.
 465
 466 =item B<add_augment_method_modifier ($name, $method)>
 467
 468 This will create an C<augment> method modifier for you, and install
 469 it in the package.
 470
 471 =item B<calculate_all_roles>
 472
 473 =item B<roles>
 474
 475 This will return an array of C<Moose::Meta::Role> instances which are
 476 attached to this class.
 477
 478 =item B<add_role ($role)>
 479
 480 This takes an instance of C<Moose::Meta::Role> in C<$role>, and adds it
 481 to the list of associated roles.
 482
 483 =item B<does_role ($role_name)>
 484
 485 This will test if this class C<does> a given C<$role_name>. It will
 486 not only check it's local roles, but ask them as well in order to
 487 cascade down the role hierarchy.
 488
 489 =item B<excludes_role ($role_name)>
 490
 491 This will test if this class C<excludes> a given C<$role_name>. It will
 492 not only check it's local roles, but ask them as well in order to
 493 cascade down the role hierarchy.
 494
 495 =item B<add_attribute ($attr_name, %params|$params)>
 496
 497 This method does the same thing as L<Class::MOP::Class::add_attribute>, but adds
 498 support for taking the C<$params> as a HASH ref.
 499
 500 =back
 501
 502 =head1 BUGS
 503
 504 All complex software has bugs lurking in it, and this module is no
 505 exception. If you find a bug please either email me, or add the bug
 506 to cpan-RT.
 507
 508 =head1 AUTHOR
 509
 510 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 511
 512 =head1 COPYRIGHT AND LICENSE
 513
 514 Copyright 2006-2008 by Infinity Interactive, Inc.
 515
 516 L<http://www.iinteractive.com>
 517
 518 This library is free software; you can redistribute it and/or modify
 519 it under the same terms as Perl itself.
 520
 521 =cut
 522