lib/Moose/Meta/Class.pm

   1
   2 package Moose::Meta::Class;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Class::MOP;
   8
   9 use Carp         'confess';
  10 use Scalar::Util 'weaken', 'blessed';
  11
  12 our $VERSION = '0.05';
  13
  14 use base 'Class::MOP::Class';
  15
  16 __PACKAGE__->meta->add_attribute('roles' => (
  17     reader  => 'roles',
  18     default => sub { [] }
  19 ));
  20
  21 sub initialize {
  22     my $class = shift;
  23     my $pkg   = shift;
  24     $class->SUPER::initialize($pkg,
  25         ':attribute_metaclass' => 'Moose::Meta::Attribute',
  26         @_);
  27 }
  28
  29 sub add_role {
  30     my ($self, $role) = @_;
  31     (blessed($role) && $role->isa('Moose::Meta::Role'))
  32         || confess "Roles must be instances of Moose::Meta::Role";
  33     push @{$self->roles} => $role;
  34 }
  35
  36 sub does_role {
  37     my ($self, $role_name) = @_;
  38     (defined $role_name)
  39         || confess "You must supply a role name to look for";
  40     foreach my $role (@{$self->roles}) {
  41         return 1 if $role->does_role($role_name);
  42     }
  43     return 0;
  44 }
  45
  46 sub new_object {
  47     my ($class, %params) = @_;
  48     my $self = $class->SUPER::new_object(%params);
  49     foreach my $attr ($class->compute_all_applicable_attributes()) {
  50         next unless $params{$attr->init_arg} && $attr->can('has_trigger') && $attr->has_trigger;
  51         $attr->trigger->($self, $params{$attr->init_arg}, $attr);
  52     }
  53     return $self;
  54 }
  55
  56 sub construct_instance {
  57     my ($class, %params) = @_;
  58     my $instance = $params{'__INSTANCE__'} || {};
  59     foreach my $attr ($class->compute_all_applicable_attributes()) {
  60         $attr->initialize_instance_slot($class, $instance, \%params)
  61     }
  62     return $instance;
  63 }
  64
  65 sub has_method {
  66     my ($self, $method_name) = @_;
  67     (defined $method_name && $method_name)
  68         || confess "You must define a method name";
  69
  70     my $sub_name = ($self->name . '::' . $method_name);
  71
  72     no strict 'refs';
  73     return 0 if !defined(&{$sub_name});
  74         my $method = \&{$sub_name};
  75
  76         return 1 if blessed($method) && $method->isa('Moose::Meta::Role::Method');
  77     return $self->SUPER::has_method($method_name);
  78 }
  79
  80
  81 sub add_override_method_modifier {
  82     my ($self, $name, $method, $_super_package) = @_;
  83     # need this for roles ...
  84     $_super_package ||= $self->name;
  85     my $super = $self->find_next_method_by_name($name);
  86     (defined $super)
  87         || confess "You cannot override '$name' because it has no super method";
  88     $self->add_method($name => bless sub {
  89         my @args = @_;
  90         no strict   'refs';
  91         no warnings 'redefine';
  92         local *{$_super_package . '::super'} = sub { $super->(@args) };
  93         return $method->(@args);
  94     } => 'Moose::Meta::Method::Overriden');
  95 }
  96
  97 sub add_augment_method_modifier {
  98     my ($self, $name, $method) = @_;
  99     my $super = $self->find_next_method_by_name($name);
 100     (defined $super)
 101         || confess "You cannot augment '$name' because it has no super method";
 102     my $_super_package = $super->package_name;
 103     # BUT!,... if this is an overriden method ....
 104     if ($super->isa('Moose::Meta::Method::Overriden')) {
 105         # we need to be sure that we actually
 106         # find the next method, which is not
 107         # an 'override' method, the reason is
 108         # that an 'override' method will not
 109         # be the one calling inner()
 110         my $real_super = $self->_find_next_method_by_name_which_is_not_overridden($name);
 111         $_super_package = $real_super->package_name;
 112     }
 113     $self->add_method($name => sub {
 114         my @args = @_;
 115         no strict   'refs';
 116         no warnings 'redefine';
 117         local *{$_super_package . '::inner'} = sub { $method->(@args) };
 118         return $super->(@args);
 119     });
 120 }
 121
 122 sub _find_next_method_by_name_which_is_not_overridden {
 123     my ($self, $name) = @_;
 124     my @methods = $self->find_all_methods_by_name($name);
 125     foreach my $method (@methods) {
 126         return $method->{code}
 127             if blessed($method->{code}) && !$method->{code}->isa('Moose::Meta::Method::Overriden');
 128     }
 129     return undef;
 130 }
 131
 132 package Moose::Meta::Method::Overriden;
 133
 134 use strict;
 135 use warnings;
 136
 137 our $VERSION = '0.01';
 138
 139 use base 'Class::MOP::Method';
 140
 141 1;
 142
 143 __END__
 144
 145 =pod
 146
 147 =head1 NAME
 148
 149 Moose::Meta::Class - The Moose metaclass
 150
 151 =head1 DESCRIPTION
 152
 153 This is a subclass of L<Class::MOP::Class> with Moose specific
 154 extensions.
 155
 156 For the most part, the only time you will ever encounter an
 157 instance of this class is if you are doing some serious deep
 158 introspection. To really understand this class, you need to refer
 159 to the L<Class::MOP::Class> documentation.
 160
 161 =head1 METHODS
 162
 163 =over 4
 164
 165 =item B<initialize>
 166
 167 =item B<new_object>
 168
 169 We override this method to support the C<trigger> attribute option.
 170
 171 =item B<construct_instance>
 172
 173 This provides some Moose specific extensions to this method, you
 174 almost never call this method directly unless you really know what
 175 you are doing.
 176
 177 This method makes sure to handle the moose weak-ref, type-constraint
 178 and type coercion features.
 179
 180 =item B<has_method ($name)>
 181
 182 This accomidates Moose::Meta::Role::Method instances, which are
 183 aliased, instead of added, but still need to be counted as valid
 184 methods.
 185
 186 =item B<add_override_method_modifier ($name, $method)>
 187
 188 This will create an C<override> method modifier for you, and install
 189 it in the package.
 190
 191 =item B<add_augment_method_modifier ($name, $method)>
 192
 193 This will create an C<augment> method modifier for you, and install
 194 it in the package.
 195
 196 =item B<roles>
 197
 198 This will return an array of C<Moose::Meta::Role> instances which are
 199 attached to this class.
 200
 201 =item B<add_role ($role)>
 202
 203 This takes an instance of C<Moose::Meta::Role> in C<$role>, and adds it
 204 to the list of associated roles.
 205
 206 =item B<does_role ($role_name)>
 207
 208 This will test if this class C<does> a given C<$role_name>. It will
 209 not only check it's local roles, but ask them as well in order to
 210 cascade down the role hierarchy.
 211
 212 =back
 213
 214 =head1 BUGS
 215
 216 All complex software has bugs lurking in it, and this module is no
 217 exception. If you find a bug please either email me, or add the bug
 218 to cpan-RT.
 219
 220 =head1 AUTHOR
 221
 222 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 223
 224 =head1 COPYRIGHT AND LICENSE
 225
 226 Copyright 2006 by Infinity Interactive, Inc.
 227
 228 L<http://www.iinteractive.com>
 229
 230 This library is free software; you can redistribute it and/or modify
 231 it under the same terms as Perl itself.
 232
 233 =cut