lib/Moose/Meta/Class.pm

   1
   2 package Moose::Meta::Class;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'weaken';
   9
  10 our $VERSION = '0.04';
  11
  12 use base 'Class::MOP::Class';
  13
  14 sub construct_instance {
  15     my ($class, %params) = @_;
  16     my $instance = $params{'__INSTANCE__'} || {};
  17     foreach my $attr ($class->compute_all_applicable_attributes()) {
  18         my $init_arg = $attr->init_arg();
  19         # try to fetch the init arg from the %params ...
  20         my $val;
  21         if (exists $params{$init_arg}) {
  22             $val = $params{$init_arg};
  23         }
  24         else {
  25             # skip it if it's lazy
  26             next if $attr->is_lazy;
  27             # and die if it is required
  28             confess "Attribute (" . $attr->name . ") is required"
  29                 if $attr->is_required
  30         }
  31         # if nothing was in the %params, we can use the
  32         # attribute's default value (if it has one)
  33         if (!defined $val && $attr->has_default) {
  34             $val = $attr->default($instance);
  35         }
  36                 if (defined $val) {
  37                     if ($attr->has_type_constraint) {
  38                     if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
  39                         $val = $attr->type_constraint->coercion->coerce($val);
  40                     }
  41                 (defined($attr->type_constraint->check($val)))
  42                     || confess "Attribute (" . $attr->name . ") does not pass the type contraint with '$val'";
  43             }
  44                 }
  45         $instance->{$attr->name} = $val;
  46         if (defined $val && $attr->is_weak_ref) {
  47             weaken($instance->{$attr->name});
  48         }
  49     }
  50     return $instance;
  51 }
  52
  53 sub add_override_method_modifier {
  54     my ($self, $name, $method, $_super_package) = @_;
  55     # need this for roles ...
  56     $_super_package ||= $self->name;
  57     my $super = $self->find_next_method_by_name($name);
  58     (defined $super)
  59         || confess "You cannot override '$name' because it has no super method";
  60     $self->add_method($name => sub {
  61         my @args = @_;
  62         no strict   'refs';
  63         no warnings 'redefine';
  64         local *{$_super_package . '::super'} = sub { $super->(@args) };
  65         return $method->(@args);
  66     });
  67 }
  68
  69 sub add_augment_method_modifier {
  70     my ($self, $name, $method) = @_;
  71     my $super = $self->find_next_method_by_name($name);
  72     (defined $super)
  73         || confess "You cannot augment '$name' because it has no super method";
  74     $self->add_method($name => sub {
  75         my @args = @_;
  76         no strict   'refs';
  77         no warnings 'redefine';
  78         local *{$super->package_name . '::inner'} = sub { $method->(@args) };
  79         return $super->(@args);
  80     });
  81 }
  82
  83 1;
  84
  85 __END__
  86
  87 =pod
  88
  89 =head1 NAME
  90
  91 Moose::Meta::Class - The Moose metaclass
  92
  93 =head1 DESCRIPTION
  94
  95 This is a subclass of L<Class::MOP::Class> with Moose specific
  96 extensions.
  97
  98 For the most part, the only time you will ever encounter an
  99 instance of this class is if you are doing some serious deep
 100 introspection. To really understand this class, you need to refer
 101 to the L<Class::MOP::Class> documentation.
 102
 103 =head1 METHODS
 104
 105 =over 4
 106
 107 =item B<construct_instance>
 108
 109 This provides some Moose specific extensions to this method, you
 110 almost never call this method directly unless you really know what
 111 you are doing.
 112
 113 This method makes sure to handle the moose weak-ref, type-constraint
 114 and type coercion features.
 115
 116 =item B<add_override_method_modifier ($name, $method)>
 117
 118 =item B<add_augment_method_modifier ($name, $method)>
 119
 120 =back
 121
 122 =head1 BUGS
 123
 124 All complex software has bugs lurking in it, and this module is no
 125 exception. If you find a bug please either email me, or add the bug
 126 to cpan-RT.
 127
 128 =head1 AUTHOR
 129
 130 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 131
 132 =head1 COPYRIGHT AND LICENSE
 133
 134 Copyright 2006 by Infinity Interactive, Inc.
 135
 136 L<http://www.iinteractive.com>
 137
 138 This library is free software; you can redistribute it and/or modify
 139 it under the same terms as Perl itself.
 140
 141 =cut