lib/Moose/Meta/Attribute.pm

   1
   2 package Moose::Meta::Attribute;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed', 'weaken';
   8 use List::MoreUtils 'any';
   9 use Try::Tiny;
  10 use overload     ();
  11
  12 our $VERSION   = '1.08';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use Moose::Meta::Method::Accessor;
  16 use Moose::Meta::Method::Delegation;
  17 use Moose::Util ();
  18 use Moose::Util::TypeConstraints ();
  19
  20 use base 'Class::MOP::Attribute', 'Moose::Meta::Mixin::AttributeCore';
  21
  22 __PACKAGE__->meta->add_attribute('traits' => (
  23     reader    => 'applied_traits',
  24     predicate => 'has_applied_traits',
  25 ));
  26
  27 # we need to have a ->does method in here to
  28 # more easily support traits, and the introspection
  29 # of those traits. We extend the does check to look
  30 # for metatrait aliases.
  31 sub does {
  32     my ($self, $role_name) = @_;
  33     my $name = try {
  34         Moose::Util::resolve_metatrait_alias(Attribute => $role_name)
  35     };
  36     return 0 if !defined($name); # failed to load class
  37     return $self->Moose::Object::does($name);
  38 }
  39
  40 sub throw_error {
  41     my $self = shift;
  42     my $class = ( ref $self && $self->associated_class ) || "Moose::Meta::Class";
  43     unshift @_, "message" if @_ % 2 == 1;
  44     unshift @_, attr => $self if ref $self;
  45     unshift @_, $class;
  46     my $handler = $class->can("throw_error"); # to avoid incrementing depth by 1
  47     goto $handler;
  48 }
  49
  50 sub new {
  51     my ($class, $name, %options) = @_;
  52     $class->_process_options($name, \%options) unless $options{__hack_no_process_options}; # used from clone()... YECHKKK FIXME ICKY YUCK GROSS
  53
  54     delete $options{__hack_no_process_options};
  55
  56     my %attrs =
  57         ( map { $_ => 1 }
  58           grep { defined }
  59           map { $_->init_arg() }
  60           $class->meta()->get_all_attributes()
  61         );
  62
  63     my @bad = sort grep { ! $attrs{$_} }  keys %options;
  64
  65     if (@bad)
  66     {
  67         Carp::cluck "Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad";
  68     }
  69
  70     return $class->SUPER::new($name, %options);
  71 }
  72
  73 sub interpolate_class_and_new {
  74     my ($class, $name, %args) = @_;
  75
  76     my ( $new_class, @traits ) = $class->interpolate_class(\%args);
  77
  78     $new_class->new($name, %args, ( scalar(@traits) ? ( traits => \@traits ) : () ) );
  79 }
  80
  81 sub interpolate_class {
  82     my ($class, $options) = @_;
  83
  84     $class = ref($class) || $class;
  85
  86     if ( my $metaclass_name = delete $options->{metaclass} ) {
  87         my $new_class = Moose::Util::resolve_metaclass_alias( Attribute => $metaclass_name );
  88
  89         if ( $class ne $new_class ) {
  90             if ( $new_class->can("interpolate_class") ) {
  91                 return $new_class->interpolate_class($options);
  92             } else {
  93                 $class = $new_class;
  94             }
  95         }
  96     }
  97
  98     my @traits;
  99
 100     if (my $traits = $options->{traits}) {
 101         my $i = 0;
 102         while ($i < @$traits) {
 103             my $trait = $traits->[$i++];
 104             next if ref($trait); # options to a trait we discarded
 105
 106             $trait = Moose::Util::resolve_metatrait_alias(Attribute => $trait)
 107                   || $trait;
 108
 109             next if $class->does($trait);
 110
 111             push @traits, $trait;
 112
 113             # are there options?
 114             push @traits, $traits->[$i++]
 115                 if $traits->[$i] && ref($traits->[$i]);
 116         }
 117
 118         if (@traits) {
 119             my $anon_class = Moose::Meta::Class->create_anon_class(
 120                 superclasses => [ $class ],
 121                 roles        => [ @traits ],
 122                 cache        => 1,
 123             );
 124
 125             $class = $anon_class->name;
 126         }
 127     }
 128
 129     return ( wantarray ? ( $class, @traits ) : $class );
 130 }
 131
 132 # ...
 133
 134 my @legal_options_for_inheritance = qw(
 135     default coerce required
 136     documentation lazy handles
 137     builder type_constraint
 138     definition_context
 139     lazy_build weak_ref
 140 );
 141
 142 sub legal_options_for_inheritance { @legal_options_for_inheritance }
 143
 144 # NOTE/TODO
 145 # This method *must* be able to handle
 146 # Class::MOP::Attribute instances as
 147 # well. Yes, I know that is wrong, but
 148 # apparently we didn't realize it was
 149 # doing that and now we have some code
 150 # which is dependent on it. The real
 151 # solution of course is to push this
 152 # feature back up into Class::MOP::Attribute
 153 # but I not right now, I am too lazy.
 154 # However if you are reading this and
 155 # looking for something to do,.. please
 156 # be my guest.
 157 # - stevan
 158 sub clone_and_inherit_options {
 159     my ($self, %options) = @_;
 160
 161     my %copy = %options;
 162
 163     my %actual_options;
 164
 165     # NOTE:
 166     # we may want to extends a Class::MOP::Attribute
 167     # in which case we need to be able to use the
 168     # core set of legal options that have always
 169     # been here. But we allows Moose::Meta::Attribute
 170     # instances to changes them.
 171     # - SL
 172     my @legal_options = $self->can('legal_options_for_inheritance')
 173         ? $self->legal_options_for_inheritance
 174         : @legal_options_for_inheritance;
 175
 176     foreach my $legal_option (@legal_options) {
 177         if (exists $options{$legal_option}) {
 178             $actual_options{$legal_option} = $options{$legal_option};
 179             delete $options{$legal_option};
 180         }
 181     }
 182
 183     if ($options{isa}) {
 184         my $type_constraint;
 185         if (blessed($options{isa}) && $options{isa}->isa('Moose::Meta::TypeConstraint')) {
 186             $type_constraint = $options{isa};
 187         }
 188         else {
 189             $type_constraint = Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($options{isa});
 190             (defined $type_constraint)
 191                 || $self->throw_error("Could not find the type constraint '" . $options{isa} . "'", data => $options{isa});
 192         }
 193
 194         $actual_options{type_constraint} = $type_constraint;
 195         delete $options{isa};
 196     }
 197
 198     if ($options{does}) {
 199         my $type_constraint;
 200         if (blessed($options{does}) && $options{does}->isa('Moose::Meta::TypeConstraint')) {
 201             $type_constraint = $options{does};
 202         }
 203         else {
 204             $type_constraint = Moose::Util::TypeConstraints::find_or_create_does_type_constraint($options{does});
 205             (defined $type_constraint)
 206                 || $self->throw_error("Could not find the type constraint '" . $options{does} . "'", data => $options{does});
 207         }
 208
 209         $actual_options{type_constraint} = $type_constraint;
 210         delete $options{does};
 211     }
 212
 213     # NOTE:
 214     # this doesn't apply to Class::MOP::Attributes,
 215     # so we can ignore it for them.
 216     # - SL
 217     if ($self->can('interpolate_class')) {
 218         ( $actual_options{metaclass}, my @traits ) = $self->interpolate_class(\%options);
 219
 220         my %seen;
 221         my @all_traits = grep { $seen{$_}++ } @{ $self->applied_traits || [] }, @traits;
 222         $actual_options{traits} = \@all_traits if @all_traits;
 223
 224         delete @options{qw(metaclass traits)};
 225     }
 226
 227     (scalar keys %options == 0)
 228         || $self->throw_error("Illegal inherited options => (" . (join ', ' => keys %options) . ")", data => \%options);
 229
 230
 231     $self->clone(%actual_options);
 232 }
 233
 234 sub clone {
 235     my ( $self, %params ) = @_;
 236
 237     my $class = delete $params{metaclass} || ref $self;
 238
 239     my ( @init, @non_init );
 240
 241     foreach my $attr ( grep { $_->has_value($self) } Class::MOP::class_of($self)->get_all_attributes ) {
 242         push @{ $attr->has_init_arg ? \@init : \@non_init }, $attr;
 243     }
 244
 245     my %new_params = ( ( map { $_->init_arg => $_->get_value($self) } @init ), %params );
 246
 247     my $name = delete $new_params{name};
 248
 249     my $clone = $class->new($name, %new_params, __hack_no_process_options => 1 );
 250
 251     foreach my $attr ( @non_init ) {
 252         $attr->set_value($clone, $attr->get_value($self));
 253     }
 254
 255     return $clone;
 256 }
 257
 258 sub _process_options {
 259     my ($class, $name, $options) = @_;
 260
 261     if (exists $options->{is}) {
 262
 263         ### -------------------------
 264         ## is => ro, writer => _foo    # turns into (reader => foo, writer => _foo) as before
 265         ## is => rw, writer => _foo    # turns into (reader => foo, writer => _foo)
 266         ## is => rw, accessor => _foo  # turns into (accessor => _foo)
 267         ## is => ro, accessor => _foo  # error, accesor is rw
 268         ### -------------------------
 269
 270         if ($options->{is} eq 'ro') {
 271             $class->throw_error("Cannot define an accessor name on a read-only attribute, accessors are read/write", data => $options)
 272                 if exists $options->{accessor};
 273             $options->{reader} ||= $name;
 274         }
 275         elsif ($options->{is} eq 'rw') {
 276             if ($options->{writer}) {
 277                 $options->{reader} ||= $name;
 278             }
 279             else {
 280                 $options->{accessor} ||= $name;
 281             }
 282         }
 283         elsif ($options->{is} eq 'bare') {
 284             # do nothing, but don't complain (later) about missing methods
 285         }
 286         else {
 287             $class->throw_error("I do not understand this option (is => " . $options->{is} . ") on attribute ($name)", data => $options->{is});
 288         }
 289     }
 290
 291     if (exists $options->{isa}) {
 292         if (exists $options->{does}) {
 293             if (try { $options->{isa}->can('does') }) {
 294                 ($options->{isa}->does($options->{does}))
 295                     || $class->throw_error("Cannot have an isa option and a does option if the isa does not do the does on attribute ($name)", data => $options);
 296             }
 297             else {
 298                 $class->throw_error("Cannot have an isa option which cannot ->does() on attribute ($name)", data => $options);
 299             }
 300         }
 301
 302         # allow for anon-subtypes here ...
 303         if (blessed($options->{isa}) && $options->{isa}->isa('Moose::Meta::TypeConstraint')) {
 304             $options->{type_constraint} = $options->{isa};
 305         }
 306         else {
 307             $options->{type_constraint} = Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($options->{isa});
 308         }
 309     }
 310     elsif (exists $options->{does}) {
 311         # allow for anon-subtypes here ...
 312         if (blessed($options->{does}) && $options->{does}->isa('Moose::Meta::TypeConstraint')) {
 313                 $options->{type_constraint} = $options->{does};
 314         }
 315         else {
 316             $options->{type_constraint} = Moose::Util::TypeConstraints::find_or_create_does_type_constraint($options->{does});
 317         }
 318     }
 319
 320     if (exists $options->{coerce} && $options->{coerce}) {
 321         (exists $options->{type_constraint})
 322             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)", data => $options);
 323         $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)", data => $options)
 324             if $options->{weak_ref};
 325     }
 326
 327     if (exists $options->{trigger}) {
 328         ('CODE' eq ref $options->{trigger})
 329             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)", data => $options->{trigger});
 330     }
 331
 332     if (exists $options->{auto_deref} && $options->{auto_deref}) {
 333         (exists $options->{type_constraint})
 334             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)", data => $options);
 335         ($options->{type_constraint}->is_a_type_of('ArrayRef') ||
 336          $options->{type_constraint}->is_a_type_of('HashRef'))
 337             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)", data => $options);
 338     }
 339
 340     if (exists $options->{lazy_build} && $options->{lazy_build} == 1) {
 341         $class->throw_error("You can not use lazy_build and default for the same attribute ($name)", data => $options)
 342             if exists $options->{default};
 343         $options->{lazy}      = 1;
 344         $options->{builder} ||= "_build_${name}";
 345         if ($name =~ /^_/) {
 346             $options->{clearer}   ||= "_clear${name}";
 347             $options->{predicate} ||= "_has${name}";
 348         }
 349         else {
 350             $options->{clearer}   ||= "clear_${name}";
 351             $options->{predicate} ||= "has_${name}";
 352         }
 353     }
 354
 355     if (exists $options->{lazy} && $options->{lazy}) {
 356         (exists $options->{default} || defined $options->{builder} )
 357             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it", data => $options);
 358     }
 359
 360     if ( $options->{required} && !( ( !exists $options->{init_arg} || defined $options->{init_arg} ) || exists $options->{default} || defined $options->{builder} ) ) {
 361         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg", data => $options);
 362     }
 363
 364 }
 365
 366 sub initialize_instance_slot {
 367     my ($self, $meta_instance, $instance, $params) = @_;
 368     my $init_arg = $self->init_arg();
 369     # try to fetch the init arg from the %params ...
 370
 371     my $val;
 372     my $value_is_set;
 373     if ( defined($init_arg) and exists $params->{$init_arg}) {
 374         $val = $params->{$init_arg};
 375         $value_is_set = 1;
 376     }
 377     else {
 378         # skip it if it's lazy
 379         return if $self->is_lazy;
 380         # and die if it's required and doesn't have a default value
 381         $self->throw_error("Attribute (" . $self->name . ") is required", object => $instance, data => $params)
 382             if $self->is_required && !$self->has_default && !$self->has_builder;
 383
 384         # if nothing was in the %params, we can use the
 385         # attribute's default value (if it has one)
 386         if ($self->has_default) {
 387             $val = $self->default($instance);
 388             $value_is_set = 1;
 389         }
 390         elsif ($self->has_builder) {
 391             $val = $self->_call_builder($instance);
 392             $value_is_set = 1;
 393         }
 394     }
 395
 396     return unless $value_is_set;
 397
 398     $val = $self->_coerce_and_verify( $val, $instance );
 399
 400     $self->set_initial_value($instance, $val);
 401
 402     if ( ref $val && $self->is_weak_ref ) {
 403         $self->_weaken_value($instance);
 404     }
 405 }
 406
 407 sub _call_builder {
 408     my ( $self, $instance ) = @_;
 409
 410     my $builder = $self->builder();
 411
 412     return $instance->$builder()
 413         if $instance->can( $self->builder );
 414
 415     $self->throw_error(  blessed($instance)
 416             . " does not support builder method '"
 417             . $self->builder
 418             . "' for attribute '"
 419             . $self->name
 420             . "'",
 421             object => $instance,
 422      );
 423 }
 424
 425 ## Slot management
 426
 427 # FIXME:
 428 # this duplicates too much code from
 429 # Class::MOP::Attribute, we need to
 430 # refactor these bits eventually.
 431 # - SL
 432 sub _set_initial_slot_value {
 433     my ($self, $meta_instance, $instance, $value) = @_;
 434
 435     my $slot_name = $self->name;
 436
 437     return $meta_instance->set_slot_value($instance, $slot_name, $value)
 438         unless $self->has_initializer;
 439
 440     my $callback = sub {
 441         my $val = $self->_coerce_and_verify( shift, $instance );;
 442
 443         $meta_instance->set_slot_value($instance, $slot_name, $val);
 444     };
 445
 446     my $initializer = $self->initializer;
 447
 448     # most things will just want to set a value, so make it first arg
 449     $instance->$initializer($value, $callback, $self);
 450 }
 451
 452 sub set_value {
 453     my ($self, $instance, @args) = @_;
 454     my $value = $args[0];
 455
 456     my $attr_name = $self->name;
 457
 458     if ($self->is_required and not @args) {
 459         $self->throw_error("Attribute ($attr_name) is required", object => $instance);
 460     }
 461
 462     $value = $self->_coerce_and_verify( $value, $instance );
 463
 464     my @old;
 465     if ( $self->has_trigger && $self->has_value($instance) ) {
 466         @old = $self->get_value($instance, 'for trigger');
 467     }
 468
 469     $self->SUPER::set_value($instance, $value);
 470
 471     if ( ref $value && $self->is_weak_ref ) {
 472         $self->_weaken_value($instance);
 473     }
 474
 475     if ($self->has_trigger) {
 476         $self->trigger->($instance, $value, @old);
 477     }
 478 }
 479
 480 sub _weaken_value {
 481     my ( $self, $instance ) = @_;
 482
 483     my $meta_instance = Class::MOP::Class->initialize( blessed($instance) )
 484         ->get_meta_instance;
 485
 486     $meta_instance->weaken_slot_value( $instance, $self->name );
 487 }
 488
 489 sub get_value {
 490     my ($self, $instance, $for_trigger) = @_;
 491
 492     if ($self->is_lazy) {
 493         unless ($self->has_value($instance)) {
 494             my $value;
 495             if ($self->has_default) {
 496                 $value = $self->default($instance);
 497             } elsif ( $self->has_builder ) {
 498                 $value = $self->_call_builder($instance);
 499             }
 500
 501             $value = $self->_coerce_and_verify( $value, $instance );
 502
 503             $self->set_initial_value($instance, $value);
 504         }
 505     }
 506
 507     if ( $self->should_auto_deref && ! $for_trigger ) {
 508
 509         my $type_constraint = $self->type_constraint;
 510
 511         if ($type_constraint->is_a_type_of('ArrayRef')) {
 512             my $rv = $self->SUPER::get_value($instance);
 513             return unless defined $rv;
 514             return wantarray ? @{ $rv } : $rv;
 515         }
 516         elsif ($type_constraint->is_a_type_of('HashRef')) {
 517             my $rv = $self->SUPER::get_value($instance);
 518             return unless defined $rv;
 519             return wantarray ? %{ $rv } : $rv;
 520         }
 521         else {
 522             $self->throw_error("Can not auto de-reference the type constraint '" . $type_constraint->name . "'", object => $instance, type_constraint => $type_constraint);
 523         }
 524
 525     }
 526     else {
 527
 528         return $self->SUPER::get_value($instance);
 529     }
 530 }
 531
 532 ## installing accessors
 533
 534 sub accessor_metaclass { 'Moose::Meta::Method::Accessor' }
 535
 536 sub install_accessors {
 537     my $self = shift;
 538     $self->SUPER::install_accessors(@_);
 539     $self->install_delegation if $self->has_handles;
 540     return;
 541 }
 542
 543 sub _check_associated_methods {
 544     my $self = shift;
 545     unless (
 546         @{ $self->associated_methods }
 547         || ($self->_is_metadata || '') eq 'bare'
 548     ) {
 549         Carp::cluck(
 550             'Attribute (' . $self->name . ') of class '
 551             . $self->associated_class->name
 552             . ' has no associated methods'
 553             . ' (did you mean to provide an "is" argument?)'
 554             . "\n"
 555         )
 556     }
 557 }
 558
 559 sub _process_accessors {
 560     my $self = shift;
 561     my ($type, $accessor, $generate_as_inline_methods) = @_;
 562     $accessor = (keys %$accessor)[0] if (ref($accessor)||'') eq 'HASH';
 563     my $method = $self->associated_class->get_method($accessor);
 564     if ($method && !$method->isa('Class::MOP::Method::Accessor')
 565      && (!$self->definition_context
 566       || $method->package_name eq $self->definition_context->{package})) {
 567         Carp::cluck(
 568             "You are overwriting a locally defined method ($accessor) with "
 569           . "an accessor"
 570         );
 571     }
 572     $self->SUPER::_process_accessors(@_);
 573 }
 574
 575 sub remove_accessors {
 576     my $self = shift;
 577     $self->SUPER::remove_accessors(@_);
 578     $self->remove_delegation if $self->has_handles;
 579     return;
 580 }
 581
 582 sub install_delegation {
 583     my $self = shift;
 584
 585     # NOTE:
 586     # Here we canonicalize the 'handles' option
 587     # this will sort out any details and always
 588     # return an hash of methods which we want
 589     # to delagate to, see that method for details
 590     my %handles = $self->_canonicalize_handles;
 591
 592
 593     # install the delegation ...
 594     my $associated_class = $self->associated_class;
 595     foreach my $handle (keys %handles) {
 596         my $method_to_call = $handles{$handle};
 597         my $class_name = $associated_class->name;
 598         my $name = "${class_name}::${handle}";
 599
 600             (!$associated_class->has_method($handle))
 601                 || $self->throw_error("You cannot overwrite a locally defined method ($handle) with a delegation", method_name => $handle);
 602
 603         # NOTE:
 604         # handles is not allowed to delegate
 605         # any of these methods, as they will
 606         # override the ones in your class, which
 607         # is almost certainly not what you want.
 608
 609         # FIXME warn when $handle was explicitly specified, but not if the source is a regex or something
 610         #cluck("Not delegating method '$handle' because it is a core method") and
 611         next if $class_name->isa("Moose::Object") and $handle =~ /^BUILD|DEMOLISH$/ || Moose::Object->can($handle);
 612
 613         my $method = $self->_make_delegation_method($handle, $method_to_call);
 614
 615         $self->associated_class->add_method($method->name, $method);
 616         $self->associate_method($method);
 617     }
 618 }
 619
 620 sub remove_delegation {
 621     my $self = shift;
 622     my %handles = $self->_canonicalize_handles;
 623     my $associated_class = $self->associated_class;
 624     foreach my $handle (keys %handles) {
 625         next unless any { $handle eq $_ }
 626                     map { $_->name }
 627                     @{ $self->associated_methods };
 628         $self->associated_class->remove_method($handle);
 629     }
 630 }
 631
 632 # private methods to help delegation ...
 633
 634 sub _canonicalize_handles {
 635     my $self    = shift;
 636     my $handles = $self->handles;
 637     if (my $handle_type = ref($handles)) {
 638         if ($handle_type eq 'HASH') {
 639             return %{$handles};
 640         }
 641         elsif ($handle_type eq 'ARRAY') {
 642             return map { $_ => $_ } @{$handles};
 643         }
 644         elsif ($handle_type eq 'Regexp') {
 645             ($self->has_type_constraint)
 646                 || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)", data => $handles);
 647             return map  { ($_ => $_) }
 648                    grep { /$handles/ } $self->_get_delegate_method_list;
 649         }
 650         elsif ($handle_type eq 'CODE') {
 651             return $handles->($self, $self->_find_delegate_metaclass);
 652         }
 653         elsif (blessed($handles) && $handles->isa('Moose::Meta::TypeConstraint::DuckType')) {
 654             return map { $_ => $_ } @{ $handles->methods };
 655         }
 656         elsif (blessed($handles) && $handles->isa('Moose::Meta::TypeConstraint::Role')) {
 657             $handles = $handles->role;
 658         }
 659         else {
 660             $self->throw_error("Unable to canonicalize the 'handles' option with $handles", data => $handles);
 661         }
 662     }
 663
 664     Class::MOP::load_class($handles);
 665     my $role_meta = Class::MOP::class_of($handles);
 666
 667     (blessed $role_meta && $role_meta->isa('Moose::Meta::Role'))
 668         || $self->throw_error("Unable to canonicalize the 'handles' option with $handles because its metaclass is not a Moose::Meta::Role", data => $handles);
 669
 670     return map { $_ => $_ }
 671         grep { $_ ne 'meta' } (
 672         $role_meta->get_method_list,
 673         map { $_->name } $role_meta->get_required_method_list,
 674         );
 675 }
 676
 677 sub _find_delegate_metaclass {
 678     my $self = shift;
 679     if (my $class = $self->_isa_metadata) {
 680         # we might be dealing with a non-Moose class,
 681         # and need to make our own metaclass. if there's
 682         # already a metaclass, it will be returned
 683         return Class::MOP::Class->initialize($class);
 684     }
 685     elsif (my $role = $self->_does_metadata) {
 686         return Class::MOP::class_of($role);
 687     }
 688     else {
 689         $self->throw_error("Cannot find delegate metaclass for attribute " . $self->name);
 690     }
 691 }
 692
 693 sub _get_delegate_method_list {
 694     my $self = shift;
 695     my $meta = $self->_find_delegate_metaclass;
 696     if ($meta->isa('Class::MOP::Class')) {
 697         return map  { $_->name }  # NOTE: !never! delegate &meta
 698                grep { $_->package_name ne 'Moose::Object' && $_->name ne 'meta' }
 699                     $meta->get_all_methods;
 700     }
 701     elsif ($meta->isa('Moose::Meta::Role')) {
 702         return $meta->get_method_list;
 703     }
 704     else {
 705         $self->throw_error("Unable to recognize the delegate metaclass '$meta'", data => $meta);
 706     }
 707 }
 708
 709 sub delegation_metaclass { 'Moose::Meta::Method::Delegation' }
 710
 711 sub _make_delegation_method {
 712     my ( $self, $handle_name, $method_to_call ) = @_;
 713
 714     my @curried_arguments;
 715
 716     ($method_to_call, @curried_arguments) = @$method_to_call
 717         if 'ARRAY' eq ref($method_to_call);
 718
 719     return $self->delegation_metaclass->new(
 720         name               => $handle_name,
 721         package_name       => $self->associated_class->name,
 722         attribute          => $self,
 723         delegate_to_method => $method_to_call,
 724         curried_arguments  => \@curried_arguments,
 725     );
 726 }
 727
 728 sub _coerce_and_verify {
 729     my $self     = shift;
 730     my $val      = shift;
 731     my $instance = shift;
 732
 733     return $val unless $self->has_type_constraint;
 734
 735     my $type_constraint = $self->type_constraint;
 736     if ($self->should_coerce && $type_constraint->has_coercion) {
 737         $val = $type_constraint->coerce($val);
 738     }
 739
 740     $self->verify_against_type_constraint($val, instance => $instance);
 741
 742     return $val;
 743 }
 744
 745 sub verify_against_type_constraint {
 746     my $self = shift;
 747     my $val  = shift;
 748
 749     return 1 if !$self->has_type_constraint;
 750
 751     my $type_constraint = $self->type_constraint;
 752
 753     $type_constraint->check($val)
 754         || $self->throw_error("Attribute ("
 755                  . $self->name
 756                  . ") does not pass the type constraint because: "
 757                  . $type_constraint->get_message($val), data => $val, @_);
 758 }
 759
 760 package Moose::Meta::Attribute::Custom::Moose;
 761 sub register_implementation { 'Moose::Meta::Attribute' }
 762
 763 1;
 764
 765 __END__
 766
 767 =pod
 768
 769 =head1 NAME
 770
 771 Moose::Meta::Attribute - The Moose attribute metaclass
 772
 773 =head1 DESCRIPTION
 774
 775 This class is a subclass of L<Class::MOP::Attribute> that provides
 776 additional Moose-specific functionality.
 777
 778 To really understand this class, you will need to start with the
 779 L<Class::MOP::Attribute> documentation. This class can be understood
 780 as a set of additional features on top of the basic feature provided
 781 by that parent class.
 782
 783 =head1 INHERITANCE
 784
 785 C<Moose::Meta::Attribute> is a subclass of L<Class::MOP::Attribute>.
 786
 787 =head1 METHODS
 788
 789 Many of the documented below override methods in
 790 L<Class::MOP::Attribute> and add Moose specific features.
 791
 792 =head2 Creation
 793
 794 =over 4
 795
 796 =item B<< Moose::Meta::Attribute->new(%options) >>
 797
 798 This method overrides the L<Class::MOP::Attribute> constructor.
 799
 800 Many of the options below are described in more detail in the
 801 L<Moose::Manual::Attributes> document.
 802
 803 It adds the following options to the constructor:
 804
 805 =over 8
 806
 807 =item * is => 'ro', 'rw', 'bare'
 808
 809 This provides a shorthand for specifying the C<reader>, C<writer>, or
 810 C<accessor> names. If the attribute is read-only ('ro') then it will
 811 have a C<reader> method with the same attribute as the name.
 812
 813 If it is read-write ('rw') then it will have an C<accessor> method
 814 with the same name. If you provide an explicit C<writer> for a
 815 read-write attribute, then you will have a C<reader> with the same
 816 name as the attribute, and a C<writer> with the name you provided.
 817
 818 Use 'bare' when you are deliberately not installing any methods
 819 (accessor, reader, etc.) associated with this attribute; otherwise,
 820 Moose will issue a deprecation warning when this attribute is added to a
 821 metaclass.
 822
 823 =item * isa => $type
 824
 825 This option accepts a type. The type can be a string, which should be
 826 a type name. If the type name is unknown, it is assumed to be a class
 827 name.
 828
 829 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 830
 831 If you I<also> provide a C<does> option, then your C<isa> option must
 832 be a class name, and that class must do the role specified with
 833 C<does>.
 834
 835 =item * does => $role
 836
 837 This is short-hand for saying that the attribute's type must be an
 838 object which does the named role.
 839
 840 =item * coerce => $bool
 841
 842 This option is only valid for objects with a type constraint
 843 (C<isa>). If this is true, then coercions will be applied whenever
 844 this attribute is set.
 845
 846 You can make both this and the C<weak_ref> option true.
 847
 848 =item * trigger => $sub
 849
 850 This option accepts a subroutine reference, which will be called after
 851 the attribute is set.
 852
 853 =item * required => $bool
 854
 855 An attribute which is required must be provided to the constructor. An
 856 attribute which is required can also have a C<default> or C<builder>,
 857 which will satisfy its required-ness.
 858
 859 A required attribute must have a C<default>, C<builder> or a
 860 non-C<undef> C<init_arg>
 861
 862 =item * lazy => $bool
 863
 864 A lazy attribute must have a C<default> or C<builder>. When an
 865 attribute is lazy, the default value will not be calculated until the
 866 attribute is read.
 867
 868 =item * weak_ref => $bool
 869
 870 If this is true, the attribute's value will be stored as a weak
 871 reference.
 872
 873 =item * auto_deref => $bool
 874
 875 If this is true, then the reader will dereference the value when it is
 876 called. The attribute must have a type constraint which defines the
 877 attribute as an array or hash reference.
 878
 879 =item * lazy_build => $bool
 880
 881 Setting this to true makes the attribute lazy and provides a number of
 882 default methods.
 883
 884   has 'size' => (
 885       is         => 'ro',
 886       lazy_build => 1,
 887   );
 888
 889 is equivalent to this:
 890
 891   has 'size' => (
 892       is        => 'ro',
 893       lazy      => 1,
 894       builder   => '_build_size',
 895       clearer   => 'clear_size',
 896       predicate => 'has_size',
 897   );
 898
 899 =item * documentation
 900
 901 An arbitrary string that can be retrieved later by calling C<<
 902 $attr->documentation >>.
 903
 904 =back
 905
 906 =item B<< $attr->clone(%options) >>
 907
 908 This creates a new attribute based on attribute being cloned. You must
 909 supply a C<name> option to provide a new name for the attribute.
 910
 911 The C<%options> can only specify options handled by
 912 L<Class::MOP::Attribute>.
 913
 914 =back
 915
 916 =head2 Value management
 917
 918 =over 4
 919
 920 =item B<< $attr->initialize_instance_slot($meta_instance, $instance, $params) >>
 921
 922 This method is used internally to initialize the attribute's slot in
 923 the object C<$instance>.
 924
 925 This overrides the L<Class::MOP::Attribute> method to handle lazy
 926 attributes, weak references, and type constraints.
 927
 928 =item B<get_value>
 929
 930 =item B<set_value>
 931
 932   eval { $point->meta->get_attribute('x')->set_value($point, 'forty-two') };
 933   if($@) {
 934     print "Oops: $@\n";
 935   }
 936
 937 I<Attribute (x) does not pass the type constraint (Int) with 'forty-two'>
 938
 939 Before setting the value, a check is made on the type constraint of
 940 the attribute, if it has one, to see if the value passes it. If the
 941 value fails to pass, the set operation dies with a L</throw_error>.
 942
 943 Any coercion to convert values is done before checking the type constraint.
 944
 945 To check a value against a type constraint before setting it, fetch the
 946 attribute instance using L<Class::MOP::Class/find_attribute_by_name>,
 947 fetch the type_constraint from the attribute using L<Moose::Meta::Attribute/type_constraint>
 948 and call L<Moose::Meta::TypeConstraint/check>. See L<Moose::Cookbook::Basics::Recipe4>
 949 for an example.
 950
 951 =back
 952
 953 =head2 Attribute Accessor generation
 954
 955 =over 4
 956
 957 =item B<< $attr->install_accessors >>
 958
 959 This method overrides the parent to also install delegation methods.
 960
 961 If, after installing all methods, the attribute object has no associated
 962 methods, it throws an error unless C<< is => 'bare' >> was passed to the
 963 attribute constructor.  (Trying to add an attribute that has no associated
 964 methods is almost always an error.)
 965
 966 =item B<< $attr->remove_accessors >>
 967
 968 This method overrides the parent to also remove delegation methods.
 969
 970 =item B<< $attr->install_delegation >>
 971
 972 This method adds its delegation methods to the attribute's associated
 973 class, if it has any to add.
 974
 975 =item B<< $attr->remove_delegation >>
 976
 977 This method remove its delegation methods from the attribute's
 978 associated class.
 979
 980 =item B<< $attr->accessor_metaclass >>
 981
 982 Returns the accessor metaclass name, which defaults to
 983 L<Moose::Meta::Method::Accessor>.
 984
 985 =item B<< $attr->delegation_metaclass >>
 986
 987 Returns the delegation metaclass name, which defaults to
 988 L<Moose::Meta::Method::Delegation>.
 989
 990 =back
 991
 992 =head2 Additional Moose features
 993
 994 These methods are not found in the superclass. They support features
 995 provided by Moose.
 996
 997 =over 4
 998
 999 =item B<< $attr->does($role) >>
1000
1001 This indicates whether the I<attribute itself> does the given
1002 role. The role can be given as a full class name, or as a resolvable
1003 trait name.
1004
1005 Note that this checks the attribute itself, not its type constraint,
1006 so it is checking the attribute's metaclass and any traits applied to
1007 the attribute.
1008
1009 =item B<< Moose::Meta::Class->interpolate_class_and_new($name, %options) >>
1010
1011 This is an alternate constructor that handles the C<metaclass> and
1012 C<traits> options.
1013
1014 Effectively, this method is a factory that finds or creates the
1015 appropriate class for the given C<metaclass> and/or C<traits>.
1016
1017 Once it has the appropriate class, it will call C<< $class->new($name,
1018 %options) >> on that class.
1019
1020 =item B<< $attr->clone_and_inherit_options(%options) >>
1021
1022 This method supports the C<has '+foo'> feature. It does various bits
1023 of processing on the supplied C<%options> before ultimately calling
1024 the C<clone> method.
1025
1026 One of its main tasks is to make sure that the C<%options> provided
1027 only includes the options returned by the
1028 C<legal_options_for_inheritance> method.
1029
1030 =item B<< $attr->legal_options_for_inheritance >>
1031
1032 This returns a whitelist of options that can be overridden in a
1033 subclass's attribute definition.
1034
1035 This exists to allow a custom metaclass to change or add to the list
1036 of options which can be changed.
1037
1038 =item B<< $attr->type_constraint >>
1039
1040 Returns the L<Moose::Meta::TypeConstraint> object for this attribute,
1041 if it has one.
1042
1043 =item B<< $attr->has_type_constraint >>
1044
1045 Returns true if this attribute has a type constraint.
1046
1047 =item B<< $attr->verify_against_type_constraint($value) >>
1048
1049 Given a value, this method returns true if the value is valid for the
1050 attribute's type constraint. If the value is not valid, it throws an
1051 error.
1052
1053 =item B<< $attr->handles >>
1054
1055 This returns the value of the C<handles> option passed to the
1056 constructor.
1057
1058 =item B<< $attr->has_handles >>
1059
1060 Returns true if this attribute performs delegation.
1061
1062 =item B<< $attr->is_weak_ref >>
1063
1064 Returns true if this attribute stores its value as a weak reference.
1065
1066 =item B<< $attr->is_required >>
1067
1068 Returns true if this attribute is required to have a value.
1069
1070 =item B<< $attr->is_lazy >>
1071
1072 Returns true if this attribute is lazy.
1073
1074 =item B<< $attr->is_lazy_build >>
1075
1076 Returns true if the C<lazy_build> option was true when passed to the
1077 constructor.
1078
1079 =item B<< $attr->should_coerce >>
1080
1081 Returns true if the C<coerce> option passed to the constructor was
1082 true.
1083
1084 =item B<< $attr->should_auto_deref >>
1085
1086 Returns true if the C<auto_deref> option passed to the constructor was
1087 true.
1088
1089 =item B<< $attr->trigger >>
1090
1091 This is the subroutine reference that was in the C<trigger> option
1092 passed to the constructor, if any.
1093
1094 =item B<< $attr->has_trigger >>
1095
1096 Returns true if this attribute has a trigger set.
1097
1098 =item B<< $attr->documentation >>
1099
1100 Returns the value that was in the C<documentation> option passed to
1101 the constructor, if any.
1102
1103 =item B<< $attr->has_documentation >>
1104
1105 Returns true if this attribute has any documentation.
1106
1107 =item B<< $attr->applied_traits >>
1108
1109 This returns an array reference of all the traits which were applied
1110 to this attribute. If none were applied, this returns C<undef>.
1111
1112 =item B<< $attr->has_applied_traits >>
1113
1114 Returns true if this attribute has any traits applied.
1115
1116 =back
1117
1118 =head1 BUGS
1119
1120 See L<Moose/BUGS> for details on reporting bugs.
1121
1122 =head1 AUTHOR
1123
1124 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1125
1126 Yuval Kogman E<lt>nothingmuch@woobling.comE<gt>
1127
1128 =head1 COPYRIGHT AND LICENSE
1129
1130 Copyright 2006-2010 by Infinity Interactive, Inc.
1131
1132 L<http://www.iinteractive.com>
1133
1134 This library is free software; you can redistribute it and/or modify
1135 it under the same terms as Perl itself.
1136
1137 =cut