lib/Moose/Meta/Attribute.pm

   1
   2 package Moose::Meta::Attribute;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed', 'weaken';
   8 use overload     ();
   9
  10 our $VERSION   = '0.88';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use Moose::Meta::Method::Accessor;
  14 use Moose::Meta::Method::Delegation;
  15 use Moose::Util ();
  16 use Moose::Util::TypeConstraints ();
  17
  18 use base 'Class::MOP::Attribute';
  19
  20 # options which are not directly used
  21 # but we store them for metadata purposes
  22 __PACKAGE__->meta->add_attribute('isa'  => (reader    => '_isa_metadata'));
  23 __PACKAGE__->meta->add_attribute('does' => (reader    => '_does_metadata'));
  24 __PACKAGE__->meta->add_attribute('is'   => (reader    => '_is_metadata'));
  25
  26 # these are actual options for the attrs
  27 __PACKAGE__->meta->add_attribute('required'   => (reader => 'is_required'      ));
  28 __PACKAGE__->meta->add_attribute('lazy'       => (reader => 'is_lazy'          ));
  29 __PACKAGE__->meta->add_attribute('lazy_build' => (reader => 'is_lazy_build'    ));
  30 __PACKAGE__->meta->add_attribute('coerce'     => (reader => 'should_coerce'    ));
  31 __PACKAGE__->meta->add_attribute('weak_ref'   => (reader => 'is_weak_ref'      ));
  32 __PACKAGE__->meta->add_attribute('auto_deref' => (reader => 'should_auto_deref'));
  33 __PACKAGE__->meta->add_attribute('type_constraint' => (
  34     reader    => 'type_constraint',
  35     predicate => 'has_type_constraint',
  36 ));
  37 __PACKAGE__->meta->add_attribute('trigger' => (
  38     reader    => 'trigger',
  39     predicate => 'has_trigger',
  40 ));
  41 __PACKAGE__->meta->add_attribute('handles' => (
  42     reader    => 'handles',
  43     writer    => '_set_handles',
  44     predicate => 'has_handles',
  45 ));
  46 __PACKAGE__->meta->add_attribute('documentation' => (
  47     reader    => 'documentation',
  48     predicate => 'has_documentation',
  49 ));
  50 __PACKAGE__->meta->add_attribute('traits' => (
  51     reader    => 'applied_traits',
  52     predicate => 'has_applied_traits',
  53 ));
  54
  55 # we need to have a ->does method in here to
  56 # more easily support traits, and the introspection
  57 # of those traits. We extend the does check to look
  58 # for metatrait aliases.
  59 sub does {
  60     my ($self, $role_name) = @_;
  61     my $name = eval {
  62         Moose::Util::resolve_metatrait_alias(Attribute => $role_name)
  63     };
  64     return 0 if !defined($name); # failed to load class
  65     return $self->Moose::Object::does($name);
  66 }
  67
  68 sub throw_error {
  69     my $self = shift;
  70     my $class = ( ref $self && $self->associated_class ) || "Moose::Meta::Class";
  71     unshift @_, "message" if @_ % 2 == 1;
  72     unshift @_, attr => $self if ref $self;
  73     unshift @_, $class;
  74     my $handler = $class->can("throw_error"); # to avoid incrementing depth by 1
  75     goto $handler;
  76 }
  77
  78 sub new {
  79     my ($class, $name, %options) = @_;
  80     $class->_process_options($name, \%options) unless $options{__hack_no_process_options}; # used from clone()... YECHKKK FIXME ICKY YUCK GROSS
  81
  82     delete $options{__hack_no_process_options};
  83
  84     my %attrs =
  85         ( map { $_ => 1 }
  86           grep { defined }
  87           map { $_->init_arg() }
  88           $class->meta()->get_all_attributes()
  89         );
  90
  91     my @bad = sort grep { ! $attrs{$_} }  keys %options;
  92
  93     if (@bad)
  94     {
  95         Carp::cluck "Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad";
  96     }
  97
  98     return $class->SUPER::new($name, %options);
  99 }
 100
 101 sub interpolate_class_and_new {
 102     my ($class, $name, %args) = @_;
 103
 104     my ( $new_class, @traits ) = $class->interpolate_class(\%args);
 105
 106     $new_class->new($name, %args, ( scalar(@traits) ? ( traits => \@traits ) : () ) );
 107 }
 108
 109 sub interpolate_class {
 110     my ($class, $options) = @_;
 111
 112     $class = ref($class) || $class;
 113
 114     if ( my $metaclass_name = delete $options->{metaclass} ) {
 115         my $new_class = Moose::Util::resolve_metaclass_alias( Attribute => $metaclass_name );
 116
 117         if ( $class ne $new_class ) {
 118             if ( $new_class->can("interpolate_class") ) {
 119                 return $new_class->interpolate_class($options);
 120             } else {
 121                 $class = $new_class;
 122             }
 123         }
 124     }
 125
 126     my @traits;
 127
 128     if (my $traits = $options->{traits}) {
 129         my $i = 0;
 130         while ($i < @$traits) {
 131             my $trait = $traits->[$i++];
 132             next if ref($trait); # options to a trait we discarded
 133
 134             $trait = Moose::Util::resolve_metatrait_alias(Attribute => $trait)
 135                   || $trait;
 136
 137             next if $class->does($trait);
 138
 139             push @traits, $trait;
 140
 141             # are there options?
 142             push @traits, $traits->[$i++]
 143                 if $traits->[$i] && ref($traits->[$i]);
 144         }
 145
 146         if (@traits) {
 147             my $anon_class = Moose::Meta::Class->create_anon_class(
 148                 superclasses => [ $class ],
 149                 roles        => [ @traits ],
 150                 cache        => 1,
 151             );
 152
 153             $class = $anon_class->name;
 154         }
 155     }
 156
 157     return ( wantarray ? ( $class, @traits ) : $class );
 158 }
 159
 160 # ...
 161
 162 my @legal_options_for_inheritance = qw(
 163     default coerce required
 164     documentation lazy handles
 165     builder type_constraint
 166     definition_context
 167     lazy_build weak_ref
 168 );
 169
 170 sub legal_options_for_inheritance { @legal_options_for_inheritance }
 171
 172 # NOTE/TODO
 173 # This method *must* be able to handle
 174 # Class::MOP::Attribute instances as
 175 # well. Yes, I know that is wrong, but
 176 # apparently we didn't realize it was
 177 # doing that and now we have some code
 178 # which is dependent on it. The real
 179 # solution of course is to push this
 180 # feature back up into Class::MOP::Attribute
 181 # but I not right now, I am too lazy.
 182 # However if you are reading this and
 183 # looking for something to do,.. please
 184 # be my guest.
 185 # - stevan
 186 sub clone_and_inherit_options {
 187     my ($self, %options) = @_;
 188
 189     my %copy = %options;
 190
 191     my %actual_options;
 192
 193     # NOTE:
 194     # we may want to extends a Class::MOP::Attribute
 195     # in which case we need to be able to use the
 196     # core set of legal options that have always
 197     # been here. But we allows Moose::Meta::Attribute
 198     # instances to changes them.
 199     # - SL
 200     my @legal_options = $self->can('legal_options_for_inheritance')
 201         ? $self->legal_options_for_inheritance
 202         : @legal_options_for_inheritance;
 203
 204     foreach my $legal_option (@legal_options) {
 205         if (exists $options{$legal_option}) {
 206             $actual_options{$legal_option} = $options{$legal_option};
 207             delete $options{$legal_option};
 208         }
 209     }
 210
 211     if ($options{isa}) {
 212         my $type_constraint;
 213         if (blessed($options{isa}) && $options{isa}->isa('Moose::Meta::TypeConstraint')) {
 214             $type_constraint = $options{isa};
 215         }
 216         else {
 217             $type_constraint = Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($options{isa});
 218             (defined $type_constraint)
 219                 || $self->throw_error("Could not find the type constraint '" . $options{isa} . "'", data => $options{isa});
 220         }
 221
 222         $actual_options{type_constraint} = $type_constraint;
 223         delete $options{isa};
 224     }
 225
 226     if ($options{does}) {
 227         my $type_constraint;
 228         if (blessed($options{does}) && $options{does}->isa('Moose::Meta::TypeConstraint')) {
 229             $type_constraint = $options{does};
 230         }
 231         else {
 232             $type_constraint = Moose::Util::TypeConstraints::find_or_create_does_type_constraint($options{does});
 233             (defined $type_constraint)
 234                 || $self->throw_error("Could not find the type constraint '" . $options{does} . "'", data => $options{does});
 235         }
 236
 237         $actual_options{type_constraint} = $type_constraint;
 238         delete $options{does};
 239     }
 240
 241     # NOTE:
 242     # this doesn't apply to Class::MOP::Attributes,
 243     # so we can ignore it for them.
 244     # - SL
 245     if ($self->can('interpolate_class')) {
 246         ( $actual_options{metaclass}, my @traits ) = $self->interpolate_class(\%options);
 247
 248         my %seen;
 249         my @all_traits = grep { $seen{$_}++ } @{ $self->applied_traits || [] }, @traits;
 250         $actual_options{traits} = \@all_traits if @all_traits;
 251
 252         delete @options{qw(metaclass traits)};
 253     }
 254
 255     (scalar keys %options == 0)
 256         || $self->throw_error("Illegal inherited options => (" . (join ', ' => keys %options) . ")", data => \%options);
 257
 258
 259     $self->clone(%actual_options);
 260 }
 261
 262 sub clone {
 263     my ( $self, %params ) = @_;
 264
 265     my $class = delete $params{metaclass} || ref $self;
 266
 267     my ( @init, @non_init );
 268
 269     foreach my $attr ( grep { $_->has_value($self) } Class::MOP::class_of($self)->get_all_attributes ) {
 270         push @{ $attr->has_init_arg ? \@init : \@non_init }, $attr;
 271     }
 272
 273     my %new_params = ( ( map { $_->init_arg => $_->get_value($self) } @init ), %params );
 274
 275     my $name = delete $new_params{name};
 276
 277     my $clone = $class->new($name, %new_params, __hack_no_process_options => 1 );
 278
 279     foreach my $attr ( @non_init ) {
 280         $attr->set_value($clone, $attr->get_value($self));
 281     }
 282
 283     return $clone;
 284 }
 285
 286 sub _process_options {
 287     my ($class, $name, $options) = @_;
 288
 289     if (exists $options->{is}) {
 290
 291         ### -------------------------
 292         ## is => ro, writer => _foo    # turns into (reader => foo, writer => _foo) as before
 293         ## is => rw, writer => _foo    # turns into (reader => foo, writer => _foo)
 294         ## is => rw, accessor => _foo  # turns into (accessor => _foo)
 295         ## is => ro, accessor => _foo  # error, accesor is rw
 296         ### -------------------------
 297
 298         if ($options->{is} eq 'ro') {
 299             $class->throw_error("Cannot define an accessor name on a read-only attribute, accessors are read/write", data => $options)
 300                 if exists $options->{accessor};
 301             $options->{reader} ||= $name;
 302         }
 303         elsif ($options->{is} eq 'rw') {
 304             if ($options->{writer}) {
 305                 $options->{reader} ||= $name;
 306             }
 307             else {
 308                 $options->{accessor} ||= $name;
 309             }
 310         }
 311         elsif ($options->{is} eq 'bare') {
 312             # do nothing, but don't complain (later) about missing methods
 313         }
 314         else {
 315             $class->throw_error("I do not understand this option (is => " . $options->{is} . ") on attribute ($name)", data => $options->{is});
 316         }
 317     }
 318
 319     if (exists $options->{isa}) {
 320         if (exists $options->{does}) {
 321             if (eval { $options->{isa}->can('does') }) {
 322                 ($options->{isa}->does($options->{does}))
 323                     || $class->throw_error("Cannot have an isa option and a does option if the isa does not do the does on attribute ($name)", data => $options);
 324             }
 325             else {
 326                 $class->throw_error("Cannot have an isa option which cannot ->does() on attribute ($name)", data => $options);
 327             }
 328         }
 329
 330         # allow for anon-subtypes here ...
 331         if (blessed($options->{isa}) && $options->{isa}->isa('Moose::Meta::TypeConstraint')) {
 332             $options->{type_constraint} = $options->{isa};
 333         }
 334         else {
 335             $options->{type_constraint} = Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($options->{isa});
 336         }
 337     }
 338     elsif (exists $options->{does}) {
 339         # allow for anon-subtypes here ...
 340         if (blessed($options->{does}) && $options->{does}->isa('Moose::Meta::TypeConstraint')) {
 341                 $options->{type_constraint} = $options->{does};
 342         }
 343         else {
 344             $options->{type_constraint} = Moose::Util::TypeConstraints::find_or_create_does_type_constraint($options->{does});
 345         }
 346     }
 347
 348     if (exists $options->{coerce} && $options->{coerce}) {
 349         (exists $options->{type_constraint})
 350             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)", data => $options);
 351         $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)", data => $options)
 352             if $options->{weak_ref};
 353     }
 354
 355     if (exists $options->{trigger}) {
 356         ('CODE' eq ref $options->{trigger})
 357             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)", data => $options->{trigger});
 358     }
 359
 360     if (exists $options->{auto_deref} && $options->{auto_deref}) {
 361         (exists $options->{type_constraint})
 362             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)", data => $options);
 363         ($options->{type_constraint}->is_a_type_of('ArrayRef') ||
 364          $options->{type_constraint}->is_a_type_of('HashRef'))
 365             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)", data => $options);
 366     }
 367
 368     if (exists $options->{lazy_build} && $options->{lazy_build} == 1) {
 369         $class->throw_error("You can not use lazy_build and default for the same attribute ($name)", data => $options)
 370             if exists $options->{default};
 371         $options->{lazy}      = 1;
 372         $options->{builder} ||= "_build_${name}";
 373         if ($name =~ /^_/) {
 374             $options->{clearer}   ||= "_clear${name}";
 375             $options->{predicate} ||= "_has${name}";
 376         }
 377         else {
 378             $options->{clearer}   ||= "clear_${name}";
 379             $options->{predicate} ||= "has_${name}";
 380         }
 381     }
 382
 383     if (exists $options->{lazy} && $options->{lazy}) {
 384         (exists $options->{default} || defined $options->{builder} )
 385             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it", data => $options);
 386     }
 387
 388     if ( $options->{required} && !( ( !exists $options->{init_arg} || defined $options->{init_arg} ) || exists $options->{default} || defined $options->{builder} ) ) {
 389         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg", data => $options);
 390     }
 391
 392 }
 393
 394 sub initialize_instance_slot {
 395     my ($self, $meta_instance, $instance, $params) = @_;
 396     my $init_arg = $self->init_arg();
 397     # try to fetch the init arg from the %params ...
 398
 399     my $val;
 400     my $value_is_set;
 401     if ( defined($init_arg) and exists $params->{$init_arg}) {
 402         $val = $params->{$init_arg};
 403         $value_is_set = 1;
 404     }
 405     else {
 406         # skip it if it's lazy
 407         return if $self->is_lazy;
 408         # and die if it's required and doesn't have a default value
 409         $self->throw_error("Attribute (" . $self->name . ") is required", object => $instance, data => $params)
 410             if $self->is_required && !$self->has_default && !$self->has_builder;
 411
 412         # if nothing was in the %params, we can use the
 413         # attribute's default value (if it has one)
 414         if ($self->has_default) {
 415             $val = $self->default($instance);
 416             $value_is_set = 1;
 417         }
 418         elsif ($self->has_builder) {
 419             $val = $self->_call_builder($instance);
 420             $value_is_set = 1;
 421         }
 422     }
 423
 424     return unless $value_is_set;
 425
 426     $val = $self->_coerce_and_verify( $val, $instance );
 427
 428     $self->set_initial_value($instance, $val);
 429     $meta_instance->weaken_slot_value($instance, $self->name)
 430         if ref $val && $self->is_weak_ref;
 431 }
 432
 433 sub _call_builder {
 434     my ( $self, $instance ) = @_;
 435
 436     my $builder = $self->builder();
 437
 438     return $instance->$builder()
 439         if $instance->can( $self->builder );
 440
 441     $self->throw_error(  blessed($instance)
 442             . " does not support builder method '"
 443             . $self->builder
 444             . "' for attribute '"
 445             . $self->name
 446             . "'",
 447             object => $instance,
 448      );
 449 }
 450
 451 ## Slot management
 452
 453 # FIXME:
 454 # this duplicates too much code from
 455 # Class::MOP::Attribute, we need to
 456 # refactor these bits eventually.
 457 # - SL
 458 sub _set_initial_slot_value {
 459     my ($self, $meta_instance, $instance, $value) = @_;
 460
 461     my $slot_name = $self->name;
 462
 463     return $meta_instance->set_slot_value($instance, $slot_name, $value)
 464         unless $self->has_initializer;
 465
 466     my ($type_constraint, $can_coerce);
 467     if ($self->has_type_constraint) {
 468         $type_constraint = $self->type_constraint;
 469         $can_coerce      = ($self->should_coerce && $type_constraint->has_coercion);
 470     }
 471
 472     my $callback = sub {
 473         my $val = $self->_coerce_and_verify( shift, $instance );;
 474
 475         $meta_instance->set_slot_value($instance, $slot_name, $val);
 476     };
 477
 478     my $initializer = $self->initializer;
 479
 480     # most things will just want to set a value, so make it first arg
 481     $instance->$initializer($value, $callback, $self);
 482 }
 483
 484 sub set_value {
 485     my ($self, $instance, @args) = @_;
 486     my $value = $args[0];
 487
 488     my $attr_name = $self->name;
 489
 490     if ($self->is_required and not @args) {
 491         $self->throw_error("Attribute ($attr_name) is required", object => $instance);
 492     }
 493
 494     $value = $self->_coerce_and_verify( $value, $instance );
 495
 496     my $meta_instance = Class::MOP::Class->initialize(blessed($instance))
 497                                          ->get_meta_instance;
 498
 499     $meta_instance->set_slot_value($instance, $attr_name, $value);
 500
 501     if (ref $value && $self->is_weak_ref) {
 502         $meta_instance->weaken_slot_value($instance, $attr_name);
 503     }
 504
 505     if ($self->has_trigger) {
 506         $self->trigger->($instance, $value);
 507     }
 508 }
 509
 510 sub get_value {
 511     my ($self, $instance) = @_;
 512
 513     if ($self->is_lazy) {
 514         unless ($self->has_value($instance)) {
 515             my $value;
 516             if ($self->has_default) {
 517                 $value = $self->default($instance);
 518             } elsif ( $self->has_builder ) {
 519                 $value = $self->_call_builder($instance);
 520             }
 521
 522             $value = $self->_coerce_and_verify( $value, $instance );
 523
 524             $self->set_initial_value($instance, $value);
 525         }
 526     }
 527
 528     if ($self->should_auto_deref) {
 529
 530         my $type_constraint = $self->type_constraint;
 531
 532         if ($type_constraint->is_a_type_of('ArrayRef')) {
 533             my $rv = $self->SUPER::get_value($instance);
 534             return unless defined $rv;
 535             return wantarray ? @{ $rv } : $rv;
 536         }
 537         elsif ($type_constraint->is_a_type_of('HashRef')) {
 538             my $rv = $self->SUPER::get_value($instance);
 539             return unless defined $rv;
 540             return wantarray ? %{ $rv } : $rv;
 541         }
 542         else {
 543             $self->throw_error("Can not auto de-reference the type constraint '" . $type_constraint->name . "'", object => $instance, type_constraint => $type_constraint);
 544         }
 545
 546     }
 547     else {
 548
 549         return $self->SUPER::get_value($instance);
 550     }
 551 }
 552
 553 ## installing accessors
 554
 555 sub accessor_metaclass { 'Moose::Meta::Method::Accessor' }
 556
 557 sub install_accessors {
 558     my $self = shift;
 559     $self->SUPER::install_accessors(@_);
 560     $self->install_delegation if $self->has_handles;
 561     return;
 562 }
 563
 564 sub _check_associated_methods {
 565     my $self = shift;
 566     unless (
 567         @{ $self->associated_methods }
 568         || ($self->_is_metadata || '') eq 'bare'
 569     ) {
 570         Carp::cluck(
 571             'Attribute (' . $self->name . ') of class '
 572             . $self->associated_class->name
 573             . ' has no associated methods'
 574             . ' (did you mean to provide an "is" argument?)'
 575             . "\n"
 576         )
 577     }
 578 }
 579
 580 sub _process_accessors {
 581     my $self = shift;
 582     my ($type, $accessor, $generate_as_inline_methods) = @_;
 583     $accessor = (keys %$accessor)[0] if (ref($accessor)||'') eq 'HASH';
 584     my $method = $self->associated_class->get_method($accessor);
 585     if ($method && !$method->isa('Class::MOP::Method::Accessor')
 586      && (!$self->definition_context
 587       || $method->package_name eq $self->definition_context->{package})) {
 588         Carp::cluck(
 589             "You are overwriting a locally defined method ($accessor) with "
 590           . "an accessor"
 591         );
 592     }
 593     $self->SUPER::_process_accessors(@_);
 594 }
 595
 596 sub remove_accessors {
 597     my $self = shift;
 598     $self->SUPER::remove_accessors(@_);
 599     $self->remove_delegation if $self->has_handles;
 600     return;
 601 }
 602
 603 sub install_delegation {
 604     my $self = shift;
 605
 606     # NOTE:
 607     # Here we canonicalize the 'handles' option
 608     # this will sort out any details and always
 609     # return an hash of methods which we want
 610     # to delagate to, see that method for details
 611     my %handles = $self->_canonicalize_handles;
 612
 613
 614     # install the delegation ...
 615     my $associated_class = $self->associated_class;
 616     foreach my $handle (keys %handles) {
 617         my $method_to_call = $handles{$handle};
 618         my $class_name = $associated_class->name;
 619         my $name = "${class_name}::${handle}";
 620
 621             (!$associated_class->has_method($handle))
 622                 || $self->throw_error("You cannot overwrite a locally defined method ($handle) with a delegation", method_name => $handle);
 623
 624         # NOTE:
 625         # handles is not allowed to delegate
 626         # any of these methods, as they will
 627         # override the ones in your class, which
 628         # is almost certainly not what you want.
 629
 630         # FIXME warn when $handle was explicitly specified, but not if the source is a regex or something
 631         #cluck("Not delegating method '$handle' because it is a core method") and
 632         next if $class_name->isa("Moose::Object") and $handle =~ /^BUILD|DEMOLISH$/ || Moose::Object->can($handle);
 633
 634         my $method = $self->_make_delegation_method($handle, $method_to_call);
 635
 636         $self->associated_class->add_method($method->name, $method);
 637         $self->associate_method($method);
 638     }
 639 }
 640
 641 sub remove_delegation {
 642     my $self = shift;
 643     my %handles = $self->_canonicalize_handles;
 644     my $associated_class = $self->associated_class;
 645     foreach my $handle (keys %handles) {
 646         $self->associated_class->remove_method($handle);
 647     }
 648 }
 649
 650 # private methods to help delegation ...
 651
 652 sub _canonicalize_handles {
 653     my $self    = shift;
 654     my $handles = $self->handles;
 655     if (my $handle_type = ref($handles)) {
 656         if ($handle_type eq 'HASH') {
 657             return %{$handles};
 658         }
 659         elsif ($handle_type eq 'ARRAY') {
 660             return map { $_ => $_ } @{$handles};
 661         }
 662         elsif ($handle_type eq 'Regexp') {
 663             ($self->has_type_constraint)
 664                 || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)", data => $handles);
 665             return map  { ($_ => $_) }
 666                    grep { /$handles/ } $self->_get_delegate_method_list;
 667         }
 668         elsif ($handle_type eq 'CODE') {
 669             return $handles->($self, $self->_find_delegate_metaclass);
 670         }
 671         elsif (blessed($handles) && $handles->isa('Moose::Meta::TypeConstraint::DuckType')) {
 672             return map { $_ => $_ } @{ $handles->methods };
 673         }
 674         else {
 675             $self->throw_error("Unable to canonicalize the 'handles' option with $handles", data => $handles);
 676         }
 677     }
 678     else {
 679         Class::MOP::load_class($handles);
 680         my $role_meta = Class::MOP::class_of($handles);
 681
 682         (blessed $role_meta && $role_meta->isa('Moose::Meta::Role'))
 683             || $self->throw_error("Unable to canonicalize the 'handles' option with $handles because its metaclass is not a Moose::Meta::Role", data => $handles);
 684
 685         return map { $_ => $_ } (
 686             $role_meta->get_method_list,
 687             map { $_->name } $role_meta->get_required_method_list,
 688         );
 689     }
 690 }
 691
 692 sub _find_delegate_metaclass {
 693     my $self = shift;
 694     if (my $class = $self->_isa_metadata) {
 695         # we might be dealing with a non-Moose class,
 696         # and need to make our own metaclass. if there's
 697         # already a metaclass, it will be returned
 698         return Moose::Meta::Class->initialize($class);
 699     }
 700     elsif (my $role = $self->_does_metadata) {
 701         return Class::MOP::class_of($role);
 702     }
 703     else {
 704         $self->throw_error("Cannot find delegate metaclass for attribute " . $self->name);
 705     }
 706 }
 707
 708 sub _get_delegate_method_list {
 709     my $self = shift;
 710     my $meta = $self->_find_delegate_metaclass;
 711     if ($meta->isa('Class::MOP::Class')) {
 712         return map  { $_->name }  # NOTE: !never! delegate &meta
 713                grep { $_->package_name ne 'Moose::Object' && $_->name ne 'meta' }
 714                     $meta->get_all_methods;
 715     }
 716     elsif ($meta->isa('Moose::Meta::Role')) {
 717         return $meta->get_method_list;
 718     }
 719     else {
 720         $self->throw_error("Unable to recognize the delegate metaclass '$meta'", data => $meta);
 721     }
 722 }
 723
 724 sub delegation_metaclass { 'Moose::Meta::Method::Delegation' }
 725
 726 sub _make_delegation_method {
 727     my ( $self, $handle_name, $method_to_call ) = @_;
 728
 729     my $method_body;
 730
 731     $method_body = $method_to_call
 732         if 'CODE' eq ref($method_to_call);
 733
 734     my $curried_arguments = [];
 735
 736     ($method_to_call, $curried_arguments) = @$method_to_call
 737         if 'ARRAY' eq ref($method_to_call);
 738
 739     return $self->delegation_metaclass->new(
 740         name               => $handle_name,
 741         package_name       => $self->associated_class->name,
 742         attribute          => $self,
 743         delegate_to_method => $method_to_call,
 744         curried_arguments  => $curried_arguments || [],
 745     );
 746 }
 747
 748 sub _coerce_and_verify {
 749     my $self     = shift;
 750     my $val      = shift;
 751     my $instance = shift;
 752
 753     return $val unless $self->has_type_constraint;
 754
 755     my $type_constraint = $self->type_constraint;
 756     if ($self->should_coerce && $type_constraint->has_coercion) {
 757         $val = $type_constraint->coerce($val);
 758     }
 759
 760     $self->verify_against_type_constraint($val, instance => $instance);
 761
 762     return $val;
 763 }
 764
 765 sub verify_against_type_constraint {
 766     my $self = shift;
 767     my $val  = shift;
 768
 769     return 1 if !$self->has_type_constraint;
 770
 771     my $type_constraint = $self->type_constraint;
 772
 773     $type_constraint->check($val)
 774         || $self->throw_error("Attribute ("
 775                  . $self->name
 776                  . ") does not pass the type constraint because: "
 777                  . $type_constraint->get_message($val), data => $val, @_);
 778 }
 779
 780 package Moose::Meta::Attribute::Custom::Moose;
 781 sub register_implementation { 'Moose::Meta::Attribute' }
 782
 783 1;
 784
 785 __END__
 786
 787 =pod
 788
 789 =head1 NAME
 790
 791 Moose::Meta::Attribute - The Moose attribute metaclass
 792
 793 =head1 DESCRIPTION
 794
 795 This class is a subclass of L<Class::MOP::Attribute> that provides
 796 additional Moose-specific functionality.
 797
 798 To really understand this class, you will need to start with the
 799 L<Class::MOP::Attribute> documentation. This class can be understood
 800 as a set of additional features on top of the basic feature provided
 801 by that parent class.
 802
 803 =head1 INHERITANCE
 804
 805 C<Moose::Meta::Attribute> is a subclass of L<Class::MOP::Attribute>.
 806
 807 =head1 METHODS
 808
 809 Many of the documented below override methods in
 810 L<Class::MOP::Attribute> and add Moose specific features.
 811
 812 =head2 Creation
 813
 814 =over 4
 815
 816 =item B<< Moose::Meta::Attribute->new(%options) >>
 817
 818 This method overrides the L<Class::MOP::Attribute> constructor.
 819
 820 Many of the options below are described in more detail in the
 821 L<Moose::Manual::Attributes> document.
 822
 823 It adds the following options to the constructor:
 824
 825 =over 8
 826
 827 =item * is => 'ro', 'rw', 'bare'
 828
 829 This provides a shorthand for specifying the C<reader>, C<writer>, or
 830 C<accessor> names. If the attribute is read-only ('ro') then it will
 831 have a C<reader> method with the same attribute as the name.
 832
 833 If it is read-write ('rw') then it will have an C<accessor> method
 834 with the same name. If you provide an explicit C<writer> for a
 835 read-write attribute, then you will have a C<reader> with the same
 836 name as the attribute, and a C<writer> with the name you provided.
 837
 838 Use 'bare' when you are deliberately not installing any methods
 839 (accessor, reader, etc.) associated with this attribute; otherwise,
 840 Moose will issue a deprecation warning when this attribute is added to a
 841 metaclass.
 842
 843 =item * isa => $type
 844
 845 This option accepts a type. The type can be a string, which should be
 846 a type name. If the type name is unknown, it is assumed to be a class
 847 name.
 848
 849 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 850
 851 If you I<also> provide a C<does> option, then your C<isa> option must
 852 be a class name, and that class must do the role specified with
 853 C<does>.
 854
 855 =item * does => $role
 856
 857 This is short-hand for saying that the attribute's type must be an
 858 object which does the named role.
 859
 860 =item * coerce => $bool
 861
 862 This option is only valid for objects with a type constraint
 863 (C<isa>). If this is true, then coercions will be applied whenever
 864 this attribute is set.
 865
 866 You can make both this and the C<weak_ref> option true.
 867
 868 =item * trigger => $sub
 869
 870 This option accepts a subroutine reference, which will be called after
 871 the attribute is set.
 872
 873 =item * required => $bool
 874
 875 An attribute which is required must be provided to the constructor. An
 876 attribute which is required can also have a C<default> or C<builder>,
 877 which will satisfy its required-ness.
 878
 879 A required attribute must have a C<default>, C<builder> or a
 880 non-C<undef> C<init_arg>
 881
 882 =item * lazy => $bool
 883
 884 A lazy attribute must have a C<default> or C<builder>. When an
 885 attribute is lazy, the default value will not be calculated until the
 886 attribute is read.
 887
 888 =item * weak_ref => $bool
 889
 890 If this is true, the attribute's value will be stored as a weak
 891 reference.
 892
 893 =item * auto_deref => $bool
 894
 895 If this is true, then the reader will dereference the value when it is
 896 called. The attribute must have a type constraint which defines the
 897 attribute as an array or hash reference.
 898
 899 =item * lazy_build => $bool
 900
 901 Setting this to true makes the attribute lazy and provides a number of
 902 default methods.
 903
 904   has 'size' => (
 905       is         => 'ro',
 906       lazy_build => 1,
 907   );
 908
 909 is equivalent to this:
 910
 911   has 'size' => (
 912       is        => 'ro',
 913       lazy      => 1,
 914       builder   => '_build_size',
 915       clearer   => 'clear_size',
 916       predicate => 'has_size',
 917   );
 918
 919 =item * documentation
 920
 921 An arbitrary string that can be retrieved later by calling C<<
 922 $attr->documentation >>.
 923
 924 =back
 925
 926 =item B<< $attr->clone(%options) >>
 927
 928 This creates a new attribute based on attribute being cloned. You must
 929 supply a C<name> option to provide a new name for the attribute.
 930
 931 The C<%options> can only specify options handled by
 932 L<Class::MOP::Attribute>.
 933
 934 =back
 935
 936 =head2 Value management
 937
 938 =over 4
 939
 940 =item B<< $attr->initialize_instance_slot($meta_instance, $instance, $params) >>
 941
 942 This method is used internally to initialize the attribute's slot in
 943 the object C<$instance>.
 944
 945 This overrides the L<Class::MOP::Attribute> method to handle lazy
 946 attributes, weak references, and type constraints.
 947
 948 =item B<get_value>
 949
 950 =item B<set_value>
 951
 952   eval { $point->meta->get_attribute('x')->set_value($point, 'forty-two') };
 953   if($@) {
 954     print "Oops: $@\n";
 955   }
 956
 957 I<Attribute (x) does not pass the type constraint (Int) with 'forty-two'>
 958
 959 Before setting the value, a check is made on the type constraint of
 960 the attribute, if it has one, to see if the value passes it. If the
 961 value fails to pass, the set operation dies with a L<throw_error>.
 962
 963 Any coercion to convert values is done before checking the type constraint.
 964
 965 To check a value against a type constraint before setting it, fetch the
 966 attribute instance using L<Class::MOP::Class/find_attribute_by_name>,
 967 fetch the type_constraint from the attribute using L<Moose::Meta::Attribute/type_constraint>
 968 and call L<Moose::Meta::TypeConstraint/check>. See L<Moose::Cookbook::Basics::Recipe4>
 969 for an example.
 970
 971 =back
 972
 973 =head2 Attribute Accessor generation
 974
 975 =over 4
 976
 977 =item B<< $attr->install_accessors >>
 978
 979 This method overrides the parent to also install delegation methods.
 980
 981 If, after installing all methods, the attribute object has no associated
 982 methods, it throws an error unless C<< is => 'bare' >> was passed to the
 983 attribute constructor.  (Trying to add an attribute that has no associated
 984 methods is almost always an error.)
 985
 986 =item B<< $attr->remove_accessors >>
 987
 988 This method overrides the parent to also remove delegation methods.
 989
 990 =item B<< $attr->install_delegation >>
 991
 992 This method adds its delegation methods to the attribute's associated
 993 class, if it has any to add.
 994
 995 =item B<< $attr->remove_delegation >>
 996
 997 This method remove its delegation methods from the attribute's
 998 associated class.
 999
1000 =item B<< $attr->accessor_metaclass >>
1001
1002 Returns the accessor metaclass name, which defaults to
1003 L<Moose::Meta::Method::Accessor>.
1004
1005 =item B<< $attr->delegation_metaclass >>
1006
1007 Returns the delegation metaclass name, which defaults to
1008 L<Moose::Meta::Method::Delegation>.
1009
1010 =back
1011
1012 =head2 Additional Moose features
1013
1014 These methods are not found in the superclass. They support features
1015 provided by Moose.
1016
1017 =over 4
1018
1019 =item B<< $attr->does($role) >>
1020
1021 This indicates whether the I<attribute itself> does the given
1022 role. The role can be given as a full class name, or as a resolvable
1023 trait name.
1024
1025 Note that this checks the attribute itself, not its type constraint,
1026 so it is checking the attribute's metaclass and any traits applied to
1027 the attribute.
1028
1029 =item B<< Moose::Meta::Class->interpolate_class_and_new($name, %options) >>
1030
1031 This is an alternate constructor that handles the C<metaclass> and
1032 C<traits> options.
1033
1034 Effectively, this method is a factory that finds or creates the
1035 appropriate class for the given C<metaclass> and/or C<traits>.
1036
1037 Once it has the appropriate class, it will call C<< $class->new($name,
1038 %options) >> on that class.
1039
1040 =item B<< $attr->clone_and_inherit_options(%options) >>
1041
1042 This method supports the C<has '+foo'> feature. It does various bits
1043 of processing on the supplied C<%options> before ultimately calling
1044 the C<clone> method.
1045
1046 One of its main tasks is to make sure that the C<%options> provided
1047 only includes the options returned by the
1048 C<legal_options_for_inheritance> method.
1049
1050 =item B<< $attr->legal_options_for_inheritance >>
1051
1052 This returns a whitelist of options that can be overridden in a
1053 subclass's attribute definition.
1054
1055 This exists to allow a custom metaclass to change or add to the list
1056 of options which can be changed.
1057
1058 =item B<< $attr->type_constraint >>
1059
1060 Returns the L<Moose::Meta::TypeConstraint> object for this attribute,
1061 if it has one.
1062
1063 =item B<< $attr->has_type_constraint >>
1064
1065 Returns true if this attribute has a type constraint.
1066
1067 =item B<< $attr->verify_against_type_constraint($value) >>
1068
1069 Given a value, this method returns true if the value is valid for the
1070 attribute's type constraint. If the value is not valid, it throws an
1071 error.
1072
1073 =item B<< $attr->handles >>
1074
1075 This returns the value of the C<handles> option passed to the
1076 constructor.
1077
1078 =item B<< $attr->has_handles >>
1079
1080 Returns true if this attribute performs delegation.
1081
1082 =item B<< $attr->is_weak_ref >>
1083
1084 Returns true if this attribute stores its value as a weak reference.
1085
1086 =item B<< $attr->is_required >>
1087
1088 Returns true if this attribute is required to have a value.
1089
1090 =item B<< $attr->is_lazy >>
1091
1092 Returns true if this attribute is lazy.
1093
1094 =item B<< $attr->is_lazy_build >>
1095
1096 Returns true if the C<lazy_build> option was true when passed to the
1097 constructor.
1098
1099 =item B<< $attr->should_coerce >>
1100
1101 Returns true if the C<coerce> option passed to the constructor was
1102 true.
1103
1104 =item B<< $attr->should_auto_deref >>
1105
1106 Returns true if the C<auto_deref> option passed to the constructor was
1107 true.
1108
1109 =item B<< $attr->trigger >>
1110
1111 This is the subroutine reference that was in the C<trigger> option
1112 passed to the constructor, if any.
1113
1114 =item B<< $attr->has_trigger >>
1115
1116 Returns true if this attribute has a trigger set.
1117
1118 =item B<< $attr->documentation >>
1119
1120 Returns the value that was in the C<documentation> option passed to
1121 the constructor, if any.
1122
1123 =item B<< $attr->has_documentation >>
1124
1125 Returns true if this attribute has any documentation.
1126
1127 =item B<< $attr->applied_traits >>
1128
1129 This returns an array reference of all the traits which were applied
1130 to this attribute. If none were applied, this returns C<undef>.
1131
1132 =item B<< $attr->has_applied_traits >>
1133
1134 Returns true if this attribute has any traits applied.
1135
1136 =back
1137
1138 =head1 BUGS
1139
1140 All complex software has bugs lurking in it, and this module is no
1141 exception. If you find a bug please either email me, or add the bug
1142 to cpan-RT.
1143
1144 =head1 AUTHOR
1145
1146 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1147
1148 Yuval Kogman E<lt>nothingmuch@woobling.comE<gt>
1149
1150 =head1 COPYRIGHT AND LICENSE
1151
1152 Copyright 2006-2009 by Infinity Interactive, Inc.
1153
1154 L<http://www.iinteractive.com>
1155
1156 This library is free software; you can redistribute it and/or modify
1157 it under the same terms as Perl itself.
1158
1159 =cut