lib/Moose/Meta/Attribute.pm

   1
   2 package Moose::Meta::Attribute;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed', 'weaken';
   8 use overload     ();
   9
  10 our $VERSION   = '0.57';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use Moose::Meta::Method::Accessor;
  14 use Moose::Meta::Method::Delegation;
  15 use Moose::Util ();
  16 use Moose::Util::TypeConstraints ();
  17
  18 use base 'Class::MOP::Attribute';
  19
  20 # options which are not directly used
  21 # but we store them for metadata purposes
  22 __PACKAGE__->meta->add_attribute('isa'  => (reader    => '_isa_metadata'));
  23 __PACKAGE__->meta->add_attribute('does' => (reader    => '_does_metadata'));
  24 __PACKAGE__->meta->add_attribute('is'   => (reader    => '_is_metadata'));
  25
  26 # these are actual options for the attrs
  27 __PACKAGE__->meta->add_attribute('required'   => (reader => 'is_required'      ));
  28 __PACKAGE__->meta->add_attribute('lazy'       => (reader => 'is_lazy'          ));
  29 __PACKAGE__->meta->add_attribute('lazy_build' => (reader => 'is_lazy_build'    ));
  30 __PACKAGE__->meta->add_attribute('coerce'     => (reader => 'should_coerce'    ));
  31 __PACKAGE__->meta->add_attribute('weak_ref'   => (reader => 'is_weak_ref'      ));
  32 __PACKAGE__->meta->add_attribute('auto_deref' => (reader => 'should_auto_deref'));
  33 __PACKAGE__->meta->add_attribute('type_constraint' => (
  34     reader    => 'type_constraint',
  35     predicate => 'has_type_constraint',
  36 ));
  37 __PACKAGE__->meta->add_attribute('trigger' => (
  38     reader    => 'trigger',
  39     predicate => 'has_trigger',
  40 ));
  41 __PACKAGE__->meta->add_attribute('handles' => (
  42     reader    => 'handles',
  43     predicate => 'has_handles',
  44 ));
  45 __PACKAGE__->meta->add_attribute('documentation' => (
  46     reader    => 'documentation',
  47     predicate => 'has_documentation',
  48 ));
  49 __PACKAGE__->meta->add_attribute('traits' => (
  50     reader    => 'applied_traits',
  51     predicate => 'has_applied_traits',
  52 ));
  53
  54 # we need to have a ->does method in here to
  55 # more easily support traits, and the introspection
  56 # of those traits. We extend the does check to look
  57 # for metatrait aliases.
  58 sub does {
  59     my ($self, $role_name) = @_;
  60     my $name = eval {
  61         Moose::Util::resolve_metatrait_alias(Attribute => $role_name)
  62     };
  63     return 0 if !defined($name); # failed to load class
  64     return Moose::Object::does($self, $name);
  65 }
  66
  67 sub throw_error {
  68     my $self = shift;
  69     my $class = ( ref $self && $self->associated_class ) || "Moose::Meta::Class";
  70     unshift @_, "message" if @_ % 2 == 1;
  71     unshift @_, attr => $self if ref $self;
  72     unshift @_, $class;
  73     my $handler = $class->can("throw_error"); # to avoid incrementing depth by 1
  74     goto $handler;
  75 }
  76
  77 sub new {
  78     my ($class, $name, %options) = @_;
  79     $class->_process_options($name, \%options) unless $options{__hack_no_process_options}; # used from clone()... YECHKKK FIXME ICKY YUCK GROSS
  80     return $class->SUPER::new($name, %options);
  81 }
  82
  83 sub interpolate_class_and_new {
  84     my ($class, $name, @args) = @_;
  85
  86     my ( $new_class, @traits ) = $class->interpolate_class(@args);
  87
  88     $new_class->new($name, @args, ( scalar(@traits) ? ( traits => \@traits ) : () ) );
  89 }
  90
  91 sub interpolate_class {
  92     my ($class, %options) = @_;
  93
  94     $class = ref($class) || $class;
  95
  96     if ( my $metaclass_name = delete $options{metaclass} ) {
  97         my $new_class = Moose::Util::resolve_metaclass_alias( Attribute => $metaclass_name );
  98
  99         if ( $class ne $new_class ) {
 100             if ( $new_class->can("interpolate_class") ) {
 101                 return $new_class->interpolate_class(%options);
 102             } else {
 103                 $class = $new_class;
 104             }
 105         }
 106     }
 107
 108     my @traits;
 109
 110     if (my $traits = $options{traits}) {
 111         if ( @traits = grep { not $class->does($_) } map {
 112             Moose::Util::resolve_metatrait_alias( Attribute => $_ )
 113                 or
 114             $_
 115         } @$traits ) {
 116             my $anon_class = Moose::Meta::Class->create_anon_class(
 117                 superclasses => [ $class ],
 118                 roles        => [ @traits ],
 119                 cache        => 1,
 120             );
 121
 122             $class = $anon_class->name;
 123         }
 124     }
 125
 126     return ( wantarray ? ( $class, @traits ) : $class );
 127 }
 128
 129 # ...
 130
 131 my @legal_options_for_inheritance = qw(
 132     default coerce required
 133     documentation lazy handles
 134     builder type_constraint
 135 );
 136
 137 sub legal_options_for_inheritance { @legal_options_for_inheritance }
 138
 139 # NOTE/TODO
 140 # This method *must* be able to handle
 141 # Class::MOP::Attribute instances as
 142 # well. Yes, I know that is wrong, but
 143 # apparently we didn't realize it was
 144 # doing that and now we have some code
 145 # which is dependent on it. The real
 146 # solution of course is to push this
 147 # feature back up into Class::MOP::Attribute
 148 # but I not right now, I am too lazy.
 149 # However if you are reading this and
 150 # looking for something to do,.. please
 151 # be my guest.
 152 # - stevan
 153 sub clone_and_inherit_options {
 154     my ($self, %options) = @_;
 155
 156     my %copy = %options;
 157
 158     my %actual_options;
 159
 160     # NOTE:
 161     # we may want to extends a Class::MOP::Attribute
 162     # in which case we need to be able to use the
 163     # core set of legal options that have always
 164     # been here. But we allows Moose::Meta::Attribute
 165     # instances to changes them.
 166     # - SL
 167     my @legal_options = $self->can('legal_options_for_inheritance')
 168         ? $self->legal_options_for_inheritance
 169         : @legal_options_for_inheritance;
 170
 171     foreach my $legal_option (@legal_options) {
 172         if (exists $options{$legal_option}) {
 173             $actual_options{$legal_option} = $options{$legal_option};
 174             delete $options{$legal_option};
 175         }
 176     }
 177
 178     if ($options{isa}) {
 179         my $type_constraint;
 180         if (blessed($options{isa}) && $options{isa}->isa('Moose::Meta::TypeConstraint')) {
 181             $type_constraint = $options{isa};
 182         }
 183         else {
 184             $type_constraint = Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($options{isa});
 185             (defined $type_constraint)
 186                 || $self->throw_error("Could not find the type constraint '" . $options{isa} . "'", data => $options{isa});
 187         }
 188
 189         $actual_options{type_constraint} = $type_constraint;
 190         delete $options{isa};
 191     }
 192
 193     if ($options{does}) {
 194         my $type_constraint;
 195         if (blessed($options{does}) && $options{does}->isa('Moose::Meta::TypeConstraint')) {
 196             $type_constraint = $options{does};
 197         }
 198         else {
 199             $type_constraint = Moose::Util::TypeConstraints::find_or_create_does_type_constraint($options{does});
 200             (defined $type_constraint)
 201                 || $self->throw_error("Could not find the type constraint '" . $options{does} . "'", data => $options{does});
 202         }
 203
 204         $actual_options{type_constraint} = $type_constraint;
 205         delete $options{does};
 206     }
 207
 208     # NOTE:
 209     # this doesn't apply to Class::MOP::Attributes,
 210     # so we can ignore it for them.
 211     # - SL
 212     if ($self->can('interpolate_class')) {
 213         ( $actual_options{metaclass}, my @traits ) = $self->interpolate_class(%options);
 214
 215         my %seen;
 216         my @all_traits = grep { $seen{$_}++ } @{ $self->applied_traits || [] }, @traits;
 217         $actual_options{traits} = \@all_traits if @all_traits;
 218
 219         delete @options{qw(metaclass traits)};
 220     }
 221
 222     (scalar keys %options == 0)
 223         || $self->throw_error("Illegal inherited options => (" . (join ', ' => keys %options) . ")", data => \%options);
 224
 225
 226     $self->clone(%actual_options);
 227 }
 228
 229 sub clone {
 230     my ( $self, %params ) = @_;
 231
 232     my $class = $params{metaclass} || ref $self;
 233
 234     if ( 0 and $class eq ref $self ) {
 235         return $self->SUPER::clone(%params);
 236     } else {
 237         my ( @init, @non_init );
 238
 239         foreach my $attr ( grep { $_->has_value($self) } $self->meta->compute_all_applicable_attributes ) {
 240             push @{ $attr->has_init_arg ? \@init : \@non_init }, $attr;
 241         }
 242
 243         my %new_params = ( ( map { $_->init_arg => $_->get_value($self) } @init ), %params );
 244
 245         my $name = delete $new_params{name};
 246
 247         my $clone = $class->new($name, %new_params, __hack_no_process_options => 1 );
 248
 249         foreach my $attr ( @non_init ) {
 250             $attr->set_value($clone, $attr->get_value($self));
 251         }
 252
 253
 254         return $clone;
 255     }
 256 }
 257
 258 sub _process_options {
 259     my ($class, $name, $options) = @_;
 260
 261     if (exists $options->{is}) {
 262
 263         ### -------------------------
 264         ## is => ro, writer => _foo    # turns into (reader => foo, writer => _foo) as before
 265         ## is => rw, writer => _foo    # turns into (reader => foo, writer => _foo)
 266         ## is => rw, accessor => _foo  # turns into (accessor => _foo)
 267         ## is => ro, accessor => _foo  # error, accesor is rw
 268         ### -------------------------
 269
 270         if ($options->{is} eq 'ro') {
 271             $class->throw_error("Cannot define an accessor name on a read-only attribute, accessors are read/write", data => $options)
 272                 if exists $options->{accessor};
 273             $options->{reader} ||= $name;
 274         }
 275         elsif ($options->{is} eq 'rw') {
 276             if ($options->{writer}) {
 277                 $options->{reader} ||= $name;
 278             }
 279             else {
 280                 $options->{accessor} ||= $name;
 281             }
 282         }
 283         else {
 284             $class->throw_error("I do not understand this option (is => " . $options->{is} . ") on attribute ($name)", data => $options->{is});
 285         }
 286     }
 287
 288     if (exists $options->{isa}) {
 289         if (exists $options->{does}) {
 290             if (eval { $options->{isa}->can('does') }) {
 291                 ($options->{isa}->does($options->{does}))
 292                     || $class->throw_error("Cannot have an isa option and a does option if the isa does not do the does on attribute ($name)", data => $options);
 293             }
 294             else {
 295                 $class->throw_error("Cannot have an isa option which cannot ->does() on attribute ($name)", data => $options);
 296             }
 297         }
 298
 299         # allow for anon-subtypes here ...
 300         if (blessed($options->{isa}) && $options->{isa}->isa('Moose::Meta::TypeConstraint')) {
 301             $options->{type_constraint} = $options->{isa};
 302         }
 303         else {
 304             $options->{type_constraint} = Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($options->{isa});
 305         }
 306     }
 307     elsif (exists $options->{does}) {
 308         # allow for anon-subtypes here ...
 309         if (blessed($options->{does}) && $options->{does}->isa('Moose::Meta::TypeConstraint')) {
 310                 $options->{type_constraint} = $options->{does};
 311         }
 312         else {
 313             $options->{type_constraint} = Moose::Util::TypeConstraints::find_or_create_does_type_constraint($options->{does});
 314         }
 315     }
 316
 317     if (exists $options->{coerce} && $options->{coerce}) {
 318         (exists $options->{type_constraint})
 319             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)", data => $options);
 320         $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)", data => $options)
 321             if $options->{weak_ref};
 322     }
 323
 324     if (exists $options->{trigger}) {
 325         ('CODE' eq ref $options->{trigger})
 326             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)", data => $options->{trigger});
 327     }
 328
 329     if (exists $options->{auto_deref} && $options->{auto_deref}) {
 330         (exists $options->{type_constraint})
 331             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)", data => $options);
 332         ($options->{type_constraint}->is_a_type_of('ArrayRef') ||
 333          $options->{type_constraint}->is_a_type_of('HashRef'))
 334             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)", data => $options);
 335     }
 336
 337     if (exists $options->{lazy_build} && $options->{lazy_build} == 1) {
 338         $class->throw_error("You can not use lazy_build and default for the same attribute ($name)", data => $options)
 339             if exists $options->{default};
 340         $options->{lazy}      = 1;
 341         $options->{required}  = 1;
 342         $options->{builder} ||= "_build_${name}";
 343         if ($name =~ /^_/) {
 344             $options->{clearer}   ||= "_clear${name}";
 345             $options->{predicate} ||= "_has${name}";
 346         }
 347         else {
 348             $options->{clearer}   ||= "clear_${name}";
 349             $options->{predicate} ||= "has_${name}";
 350         }
 351     }
 352
 353     if (exists $options->{lazy} && $options->{lazy}) {
 354         (exists $options->{default} || defined $options->{builder} )
 355             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it", data => $options);
 356     }
 357
 358     if ( $options->{required} && !( ( !exists $options->{init_arg} || defined $options->{init_arg} ) || exists $options->{default} || defined $options->{builder} ) ) {
 359         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg", data => $options);
 360     }
 361
 362 }
 363
 364 sub initialize_instance_slot {
 365     my ($self, $meta_instance, $instance, $params) = @_;
 366     my $init_arg = $self->init_arg();
 367     # try to fetch the init arg from the %params ...
 368
 369     my $val;
 370     my $value_is_set;
 371     if ( defined($init_arg) and exists $params->{$init_arg}) {
 372         $val = $params->{$init_arg};
 373         $value_is_set = 1;
 374     }
 375     else {
 376         # skip it if it's lazy
 377         return if $self->is_lazy;
 378         # and die if it's required and doesn't have a default value
 379         $self->throw_error("Attribute (" . $self->name . ") is required", object => $instance, data => $params)
 380             if $self->is_required && !$self->has_default && !$self->has_builder;
 381
 382         # if nothing was in the %params, we can use the
 383         # attribute's default value (if it has one)
 384         if ($self->has_default) {
 385             $val = $self->default($instance);
 386             $value_is_set = 1;
 387         }
 388         elsif ($self->has_builder) {
 389             $val = $self->_call_builder($instance);
 390             $value_is_set = 1;
 391         }
 392     }
 393
 394     return unless $value_is_set;
 395
 396     if ($self->has_type_constraint) {
 397         my $type_constraint = $self->type_constraint;
 398         if ($self->should_coerce && $type_constraint->has_coercion) {
 399             $val = $type_constraint->coerce($val);
 400         }
 401         $type_constraint->check($val)
 402             || $self->throw_error("Attribute ("
 403                      . $self->name
 404                      . ") does not pass the type constraint because: "
 405                      . $type_constraint->get_message($val), data => $val, object => $instance);
 406     }
 407
 408     $self->set_initial_value($instance, $val);
 409     $meta_instance->weaken_slot_value($instance, $self->name)
 410         if ref $val && $self->is_weak_ref;
 411 }
 412
 413 sub _call_builder {
 414     my ( $self, $instance ) = @_;
 415
 416     my $builder = $self->builder();
 417
 418     return $instance->$builder()
 419         if $instance->can( $self->builder );
 420
 421     $self->throw_error(  blessed($instance)
 422             . " does not support builder method '"
 423             . $self->builder
 424             . "' for attribute '"
 425             . $self->name
 426             . "'",
 427             object => $instance,
 428      );
 429 }
 430
 431 ## Slot management
 432
 433 # FIXME:
 434 # this duplicates too much code from
 435 # Class::MOP::Attribute, we need to
 436 # refactor these bits eventually.
 437 # - SL
 438 sub _set_initial_slot_value {
 439     my ($self, $meta_instance, $instance, $value) = @_;
 440
 441     my $slot_name = $self->name;
 442
 443     return $meta_instance->set_slot_value($instance, $slot_name, $value)
 444         unless $self->has_initializer;
 445
 446     my ($type_constraint, $can_coerce);
 447     if ($self->has_type_constraint) {
 448         $type_constraint = $self->type_constraint;
 449         $can_coerce      = ($self->should_coerce && $type_constraint->has_coercion);
 450     }
 451
 452     my $callback = sub {
 453         my $val = shift;
 454         if ($type_constraint) {
 455             $val = $type_constraint->coerce($val)
 456                 if $can_coerce;
 457             $type_constraint->check($val)
 458                 || $self->throw_error("Attribute ("
 459                          . $slot_name
 460                          . ") does not pass the type constraint because: "
 461                          . $type_constraint->get_message($val), data => $val, object => $instance);
 462         }
 463         $meta_instance->set_slot_value($instance, $slot_name, $val);
 464     };
 465
 466     my $initializer = $self->initializer;
 467
 468     # most things will just want to set a value, so make it first arg
 469     $instance->$initializer($value, $callback, $self);
 470 }
 471
 472 sub set_value {
 473     my ($self, $instance, @args) = @_;
 474     my $value = $args[0];
 475
 476     my $attr_name = $self->name;
 477
 478     if ($self->is_required and not @args) {
 479         $self->throw_error("Attribute ($attr_name) is required", object => $instance);
 480     }
 481
 482     if ($self->has_type_constraint) {
 483
 484         my $type_constraint = $self->type_constraint;
 485
 486         if ($self->should_coerce) {
 487             $value = $type_constraint->coerce($value);
 488         }
 489         $type_constraint->_compiled_type_constraint->($value)
 490             || $self->throw_error("Attribute ("
 491                      . $self->name
 492                      . ") does not pass the type constraint because "
 493                      . $type_constraint->get_message($value), object => $instance, data => $value);
 494     }
 495
 496     my $meta_instance = Class::MOP::Class->initialize(blessed($instance))
 497                                          ->get_meta_instance;
 498
 499     $meta_instance->set_slot_value($instance, $attr_name, $value);
 500
 501     if (ref $value && $self->is_weak_ref) {
 502         $meta_instance->weaken_slot_value($instance, $attr_name);
 503     }
 504
 505     if ($self->has_trigger) {
 506         $self->trigger->($instance, $value, $self);
 507     }
 508 }
 509
 510 sub get_value {
 511     my ($self, $instance) = @_;
 512
 513     if ($self->is_lazy) {
 514         unless ($self->has_value($instance)) {
 515             my $value;
 516             if ($self->has_default) {
 517                 $value = $self->default($instance);
 518             } elsif ( $self->has_builder ) {
 519                 $value = $self->_call_builder($instance);
 520             }
 521             if ($self->has_type_constraint) {
 522                 my $type_constraint = $self->type_constraint;
 523                 $value = $type_constraint->coerce($value)
 524                     if ($self->should_coerce);
 525                 $type_constraint->check($value)
 526                   || c$self->throw_error("Attribute (" . $self->name
 527                       . ") does not pass the type constraint because: "
 528                       . $type_constraint->get_message($value), type_constraint => $type_constraint, data => $value);
 529             }
 530             $self->set_initial_value($instance, $value);
 531         }
 532     }
 533
 534     if ($self->should_auto_deref) {
 535
 536         my $type_constraint = $self->type_constraint;
 537
 538         if ($type_constraint->is_a_type_of('ArrayRef')) {
 539             my $rv = $self->SUPER::get_value($instance);
 540             return unless defined $rv;
 541             return wantarray ? @{ $rv } : $rv;
 542         }
 543         elsif ($type_constraint->is_a_type_of('HashRef')) {
 544             my $rv = $self->SUPER::get_value($instance);
 545             return unless defined $rv;
 546             return wantarray ? %{ $rv } : $rv;
 547         }
 548         else {
 549             $self->throw_error("Can not auto de-reference the type constraint '" . $type_constraint->name . "'", object => $instance, type_constraint => $type_constraint);
 550         }
 551
 552     }
 553     else {
 554
 555         return $self->SUPER::get_value($instance);
 556     }
 557 }
 558
 559 ## installing accessors
 560
 561 sub accessor_metaclass { 'Moose::Meta::Method::Accessor' }
 562
 563 sub install_accessors {
 564     my $self = shift;
 565     $self->SUPER::install_accessors(@_);
 566     $self->install_delegation if $self->has_handles;
 567     return;
 568 }
 569
 570 sub install_delegation {
 571     my $self = shift;
 572
 573     # NOTE:
 574     # Here we canonicalize the 'handles' option
 575     # this will sort out any details and always
 576     # return an hash of methods which we want
 577     # to delagate to, see that method for details
 578     my %handles = $self->_canonicalize_handles;
 579
 580
 581     # install the delegation ...
 582     my $associated_class = $self->associated_class;
 583     foreach my $handle (keys %handles) {
 584         my $method_to_call = $handles{$handle};
 585         my $class_name = $associated_class->name;
 586         my $name = "${class_name}::${handle}";
 587
 588             (!$associated_class->has_method($handle))
 589                 || $self->throw_error("You cannot overwrite a locally defined method ($handle) with a delegation", method_name => $handle);
 590
 591         # NOTE:
 592         # handles is not allowed to delegate
 593         # any of these methods, as they will
 594         # override the ones in your class, which
 595         # is almost certainly not what you want.
 596
 597         # FIXME warn when $handle was explicitly specified, but not if the source is a regex or something
 598         #cluck("Not delegating method '$handle' because it is a core method") and
 599         next if $class_name->isa("Moose::Object") and $handle =~ /^BUILD|DEMOLISH$/ || Moose::Object->can($handle);
 600
 601         my $method = $self->_make_delegation_method($handle, $method_to_call);
 602
 603         $self->associated_class->add_method($method->name, $method);
 604     }
 605 }
 606
 607 # private methods to help delegation ...
 608
 609 sub _canonicalize_handles {
 610     my $self    = shift;
 611     my $handles = $self->handles;
 612     if (my $handle_type = ref($handles)) {
 613         if ($handle_type eq 'HASH') {
 614             return %{$handles};
 615         }
 616         elsif ($handle_type eq 'ARRAY') {
 617             return map { $_ => $_ } @{$handles};
 618         }
 619         elsif ($handle_type eq 'Regexp') {
 620             ($self->has_type_constraint)
 621                 || $self->throw_error("Cannot delegate methods based on a RegExpr without a type constraint (isa)", data => $handles);
 622             return map  { ($_ => $_) }
 623                    grep { /$handles/ } $self->_get_delegate_method_list;
 624         }
 625         elsif ($handle_type eq 'CODE') {
 626             return $handles->($self, $self->_find_delegate_metaclass);
 627         }
 628         else {
 629             $self->throw_error("Unable to canonicalize the 'handles' option with $handles", data => $handles);
 630         }
 631     }
 632     else {
 633         my $role_meta = eval { $handles->meta };
 634         if ($@) {
 635             $self->throw_error("Unable to canonicalize the 'handles' option with $handles because : $@", data => $handles, error => $@);
 636         }
 637
 638         (blessed $role_meta && $role_meta->isa('Moose::Meta::Role'))
 639             || $self->throw_error("Unable to canonicalize the 'handles' option with $handles because ->meta is not a Moose::Meta::Role", data => $handles);
 640
 641         return map { $_ => $_ } (
 642             $role_meta->get_method_list,
 643             $role_meta->get_required_method_list
 644         );
 645     }
 646 }
 647
 648 sub _find_delegate_metaclass {
 649     my $self = shift;
 650     if (my $class = $self->_isa_metadata) {
 651         # if the class does have
 652         # a meta method, use it
 653         return $class->meta if $class->can('meta');
 654         # otherwise we might be
 655         # dealing with a non-Moose
 656         # class, and need to make
 657         # our own metaclass
 658         return Moose::Meta::Class->initialize($class);
 659     }
 660     elsif (my $role = $self->_does_metadata) {
 661         # our role will always have
 662         # a meta method
 663         return $role->meta;
 664     }
 665     else {
 666         $self->throw_error("Cannot find delegate metaclass for attribute " . $self->name);
 667     }
 668 }
 669
 670 sub _get_delegate_method_list {
 671     my $self = shift;
 672     my $meta = $self->_find_delegate_metaclass;
 673     if ($meta->isa('Class::MOP::Class')) {
 674         return map  { $_->name }  # NOTE: !never! delegate &meta
 675                grep { $_->package_name ne 'Moose::Object' && $_->name ne 'meta' }
 676                     $meta->get_all_methods;
 677     }
 678     elsif ($meta->isa('Moose::Meta::Role')) {
 679         return $meta->get_method_list;
 680     }
 681     else {
 682         $self->throw_error("Unable to recognize the delegate metaclass '$meta'", data => $meta);
 683     }
 684 }
 685
 686 sub _make_delegation_method {
 687     my ( $self, $handle_name, $method_to_call ) = @_;
 688
 689     my $method_body;
 690
 691     $method_body = $method_to_call
 692         if 'CODE' eq ref($method_to_call);
 693
 694     return Moose::Meta::Method::Delegation->new(
 695         name               => $handle_name,
 696         package_name       => $self->associated_class->name,
 697         attribute          => $self,
 698         delegate_to_method => $method_to_call,
 699     );
 700 }
 701
 702 package Moose::Meta::Attribute::Custom::Moose;
 703 sub register_implementation { 'Moose::Meta::Attribute' }
 704
 705 1;
 706
 707 __END__
 708
 709 =pod
 710
 711 =head1 NAME
 712
 713 Moose::Meta::Attribute - The Moose attribute metaclass
 714
 715 =head1 DESCRIPTION
 716
 717 This is a subclass of L<Class::MOP::Attribute> with Moose specific
 718 extensions.
 719
 720 For the most part, the only time you will ever encounter an
 721 instance of this class is if you are doing some serious deep
 722 introspection. To really understand this class, you need to refer
 723 to the L<Class::MOP::Attribute> documentation.
 724
 725 =head1 METHODS
 726
 727 =head2 Overridden methods
 728
 729 These methods override methods in L<Class::MOP::Attribute> and add
 730 Moose specific features. You can safely assume though that they
 731 will behave just as L<Class::MOP::Attribute> does.
 732
 733 =over 4
 734
 735 =item B<new>
 736
 737 =item B<clone>
 738
 739 =item B<does>
 740
 741 =item B<initialize_instance_slot>
 742
 743 =item B<install_accessors>
 744
 745 =item B<install_delegation>
 746
 747 =item B<accessor_metaclass>
 748
 749 =item B<get_value>
 750
 751 =item B<set_value>
 752
 753   eval { $point->meta->get_attribute('x')->set_value($point, 'fourty-two') };
 754   if($@) {
 755     print "Oops: $@\n";
 756   }
 757
 758 I<Attribute (x) does not pass the type constraint (Int) with 'fourty-two'>
 759
 760 Before setting the value, a check is made on the type constraint of
 761 the attribute, if it has one, to see if the value passes it. If the
 762 value fails to pass, the set operation dies with a L<throw_error>.
 763
 764 Any coercion to convert values is done before checking the type constraint.
 765
 766 To check a value against a type constraint before setting it, fetch the
 767 attribute instance using L<Class::MOP::Class/find_attribute_by_name>,
 768 fetch the type_constraint from the attribute using L<Moose::Meta::Attribute/type_constraint>
 769 and call L<Moose::Meta::TypeConstraint/check>. See L<Moose::Cookbook::Basics::Recipe4>
 770 for an example.
 771
 772 =back
 773
 774 =head2 Additional Moose features
 775
 776 Moose attributes support type-constraint checking, weak reference
 777 creation and type coercion.
 778
 779 =over 4
 780
 781 =item B<throw_error>
 782
 783 Delegates to C<associated_class> or C<Moose::Meta::Class> if there is none.
 784
 785 =item B<interpolate_class_and_new>
 786
 787 =item B<interpolate_class>
 788
 789 When called as a class method causes interpretation of the C<metaclass> and
 790 C<traits> options.
 791
 792 =item B<clone_and_inherit_options>
 793
 794 This is to support the C<has '+foo'> feature, it clones an attribute
 795 from a superclass and allows a very specific set of changes to be made
 796 to the attribute.
 797
 798 =item B<legal_options_for_inheritance>
 799
 800 Whitelist with options you can change. You can overload it in your custom
 801 metaclass to allow your options be inheritable.
 802
 803 =item B<has_type_constraint>
 804
 805 Returns true if this meta-attribute has a type constraint.
 806
 807 =item B<type_constraint>
 808
 809 A read-only accessor for this meta-attribute's type constraint. For
 810 more information on what you can do with this, see the documentation
 811 for L<Moose::Meta::TypeConstraint>.
 812
 813 =item B<has_handles>
 814
 815 Returns true if this meta-attribute performs delegation.
 816
 817 =item B<handles>
 818
 819 This returns the value which was passed into the handles option.
 820
 821 =item B<is_weak_ref>
 822
 823 Returns true if this meta-attribute produces a weak reference.
 824
 825 =item B<is_required>
 826
 827 Returns true if this meta-attribute is required to have a value.
 828
 829 =item B<is_lazy>
 830
 831 Returns true if this meta-attribute should be initialized lazily.
 832
 833 NOTE: lazy attributes, B<must> have a C<default> or C<builder> field set.
 834
 835 =item B<is_lazy_build>
 836
 837 Returns true if this meta-attribute should be initialized lazily through
 838 the builder generated by lazy_build. Using C<lazy_build =E<gt> 1> will
 839 make your attribute required and lazy. In addition it will set the builder, clearer
 840 and predicate options for you using the following convention.
 841
 842    #If your attribute name starts with an underscore:
 843    has '_foo' => (lazy_build => 1);
 844    #is the same as
 845    has '_foo' => (lazy => 1, required => 1, predicate => '_has_foo', clearer => '_clear_foo', builder => '_build__foo');
 846    # or
 847    has '_foo' => (lazy => 1, required => 1, predicate => '_has_foo', clearer => '_clear_foo', default => sub{shift->_build__foo});
 848
 849    #If your attribute name does not start with an underscore:
 850    has 'foo' => (lazy_build => 1);
 851    #is the same as
 852    has 'foo' => (lazy => 1, required => 1, predicate => 'has_foo', clearer => 'clear_foo', builder => '_build_foo');
 853    # or
 854    has 'foo' => (lazy => 1, required => 1, predicate => 'has_foo', clearer => 'clear_foo', default => sub{shift->_build_foo});
 855
 856 The reason for the different naming of the C<builder> is that the C<builder>
 857 method is a private method while the C<clearer> and C<predicate> methods
 858 are public methods.
 859
 860 NOTE: This means your class should provide a method whose name matches the value
 861 of the builder part, in this case _build__foo or _build_foo.
 862
 863 =item B<should_coerce>
 864
 865 Returns true if this meta-attribute should perform type coercion.
 866
 867 =item B<should_auto_deref>
 868
 869 Returns true if this meta-attribute should perform automatic
 870 auto-dereferencing.
 871
 872 NOTE: This can only be done for attributes whose type constraint is
 873 either I<ArrayRef> or I<HashRef>.
 874
 875 =item B<has_trigger>
 876
 877 Returns true if this meta-attribute has a trigger set.
 878
 879 =item B<trigger>
 880
 881 This is a CODE reference which will be executed every time the
 882 value of an attribute is assigned. The CODE ref will get two values,
 883 the invocant and the new value. This can be used to handle I<basic>
 884 bi-directional relations.
 885
 886 =item B<documentation>
 887
 888 This is a string which contains the documentation for this attribute.
 889 It serves no direct purpose right now, but it might in the future
 890 in some kind of automated documentation system perhaps.
 891
 892 =item B<has_documentation>
 893
 894 Returns true if this meta-attribute has any documentation.
 895
 896 =item B<applied_traits>
 897
 898 This will return the ARRAY ref of all the traits applied to this
 899 attribute, or if no traits have been applied, it returns C<undef>.
 900
 901 =item B<has_applied_traits>
 902
 903 Returns true if this meta-attribute has any traits applied.
 904
 905 =back
 906
 907 =head1 BUGS
 908
 909 All complex software has bugs lurking in it, and this module is no
 910 exception. If you find a bug please either email me, or add the bug
 911 to cpan-RT.
 912
 913 =head1 AUTHOR
 914
 915 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 916
 917 Yuval Kogman E<lt>nothingmuch@woobling.comE<gt>
 918
 919 =head1 COPYRIGHT AND LICENSE
 920
 921 Copyright 2006-2008 by Infinity Interactive, Inc.
 922
 923 L<http://www.iinteractive.com>
 924
 925 This library is free software; you can redistribute it and/or modify
 926 it under the same terms as Perl itself.
 927
 928 =cut