lib/Moose/Meta/Attribute/Trait/Native/MethodProvider/String.pm

   1
   2 package Moose::Meta::Attribute::Trait::Native::MethodProvider::String;
   3 use Moose::Role;
   4
   5 our $VERSION   = '0.87';
   6 $VERSION = eval $VERSION;
   7 our $AUTHORITY = 'cpan:STEVAN';
   8
   9 sub append : method {
  10     my ( $attr, $reader, $writer ) = @_;
  11
  12     return sub { $writer->( $_[0], $reader->( $_[0] ) . $_[1] ) };
  13 }
  14
  15 sub prepend : method {
  16     my ( $attr, $reader, $writer ) = @_;
  17
  18     return sub { $writer->( $_[0], $_[1] . $reader->( $_[0] ) ) };
  19 }
  20
  21 sub replace : method {
  22     my ( $attr, $reader, $writer ) = @_;
  23
  24     return sub {
  25         my ( $self, $regex, $replacement ) = @_;
  26         my $v = $reader->( $_[0] );
  27
  28         if ( ( ref($replacement) || '' ) eq 'CODE' ) {
  29             $v =~ s/$regex/$replacement->()/e;
  30         }
  31         else {
  32             $v =~ s/$regex/$replacement/;
  33         }
  34
  35         $writer->( $_[0], $v );
  36     };
  37 }
  38
  39 sub match : method {
  40     my ( $attr, $reader, $writer ) = @_;
  41     return sub { $reader->( $_[0] ) =~ $_[1] };
  42 }
  43
  44 sub chop : method {
  45     my ( $attr, $reader, $writer ) = @_;
  46     return sub {
  47         my $v = $reader->( $_[0] );
  48         CORE::chop($v);
  49         $writer->( $_[0], $v );
  50     };
  51 }
  52
  53 sub chomp : method {
  54     my ( $attr, $reader, $writer ) = @_;
  55     return sub {
  56         my $v = $reader->( $_[0] );
  57         chomp($v);
  58         $writer->( $_[0], $v );
  59     };
  60 }
  61
  62 sub inc : method {
  63     my ( $attr, $reader, $writer ) = @_;
  64     return sub {
  65         my $v = $reader->( $_[0] );
  66         $v++;
  67         $writer->( $_[0], $v );
  68     };
  69 }
  70
  71 sub clear : method {
  72     my ( $attr, $reader, $writer ) = @_;
  73     return sub { $writer->( $_[0], '' ) }
  74 }
  75
  76 sub length : method {
  77     my ($attr, $reader, $writer) = @_;
  78     return sub {
  79         my $v = $reader->($_[0]);
  80         return CORE::length($v);
  81     };
  82 }
  83
  84 sub substr : method {
  85     my ( $attr, $reader, $writer ) = @_;
  86     return sub {
  87         my $self = shift;
  88         my $v    = $reader->($self);
  89
  90         my $offset      = defined $_[0] ? shift : 0;
  91         my $length      = defined $_[0] ? shift : CORE::length($v);
  92         my $replacement = defined $_[0] ? shift : undef;
  93
  94         my $ret;
  95         if ( defined $replacement ) {
  96             $ret = CORE::substr( $v, $offset, $length, $replacement );
  97             $writer->( $self, $v );
  98         }
  99         else {
 100             $ret = CORE::substr( $v, $offset, $length );
 101         }
 102
 103         return $ret;
 104     };
 105 }
 106
 107 1;
 108
 109 __END__
 110
 111 =pod
 112
 113 =head1 NAME
 114
 115 Moose::Meta::Attribute::Trait::Native::MethodProvider::String
 116
 117 =head1 DESCRIPTION
 118
 119 This is a role which provides the method generators for
 120 L<Moose::Meta::Attribute::Trait::Native::String>.
 121
 122 =head1 METHODS
 123
 124 =over 4
 125
 126 =item B<meta>
 127
 128 =back
 129
 130 =head1 PROVIDED METHODS
 131
 132 =over 4
 133
 134 =item B<append>
 135
 136 =item B<prepend>
 137
 138 =item B<replace>
 139
 140 =item B<match>
 141
 142 =item B<chomp>
 143
 144 =item B<chop>
 145
 146 =item B<inc>
 147
 148 =item B<clear>
 149
 150 =item B<length>
 151
 152 =item B<substr>
 153
 154 =back
 155
 156 =head1 BUGS
 157
 158 All complex software has bugs lurking in it, and this module is no
 159 exception. If you find a bug please either email me, or add the bug
 160 to cpan-RT.
 161
 162 =head1 AUTHOR
 163
 164 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 165
 166 =head1 COPYRIGHT AND LICENSE
 167
 168 Copyright 2007-2009 by Infinity Interactive, Inc.
 169
 170 L<http://www.iinteractive.com>
 171
 172 This library is free software; you can redistribute it and/or modify
 173 it under the same terms as Perl itself.
 174
 175 =cut