lib/Moose/Meta/Attribute/Trait/Native/MethodProvider/String.pm

   1
   2 package Moose::Meta::Attribute::Trait::Native::MethodProvider::String;
   3 use Moose::Role;
   4
   5 our $VERSION   = '0.87';
   6 $VERSION = eval $VERSION;
   7 our $AUTHORITY = 'cpan:STEVAN';
   8
   9 sub append : method {
  10     my ( $attr, $reader, $writer ) = @_;
  11
  12     return sub { $writer->( $_[0], $reader->( $_[0] ) . $_[1] ) };
  13 }
  14
  15 sub prepend : method {
  16     my ( $attr, $reader, $writer ) = @_;
  17
  18     return sub { $writer->( $_[0], $_[1] . $reader->( $_[0] ) ) };
  19 }
  20
  21 sub replace : method {
  22     my ( $attr, $reader, $writer ) = @_;
  23
  24     return sub {
  25         my ( $self, $regex, $replacement ) = @_;
  26         my $v = $reader->( $_[0] );
  27
  28         if ( ( ref($replacement) || '' ) eq 'CODE' ) {
  29             $v =~ s/$regex/$replacement->()/e;
  30         }
  31         else {
  32             $v =~ s/$regex/$replacement/;
  33         }
  34
  35         $writer->( $_[0], $v );
  36     };
  37 }
  38
  39 sub match : method {
  40     my ( $attr, $reader, $writer ) = @_;
  41     return sub { $reader->( $_[0] ) =~ $_[1] };
  42 }
  43
  44 sub chop : method {
  45     my ( $attr, $reader, $writer ) = @_;
  46     return sub {
  47         my $v = $reader->( $_[0] );
  48         CORE::chop($v);
  49         $writer->( $_[0], $v );
  50     };
  51 }
  52
  53 sub chomp : method {
  54     my ( $attr, $reader, $writer ) = @_;
  55     return sub {
  56         my $v = $reader->( $_[0] );
  57         chomp($v);
  58         $writer->( $_[0], $v );
  59     };
  60 }
  61
  62 sub inc : method {
  63     my ( $attr, $reader, $writer ) = @_;
  64     return sub {
  65         my $v = $reader->( $_[0] );
  66         $v++;
  67         $writer->( $_[0], $v );
  68     };
  69 }
  70
  71 sub clear : method {
  72     my ( $attr, $reader, $writer ) = @_;
  73     return sub { $writer->( $_[0], '' ) }
  74 }
  75
  76 sub substr : method {
  77     my ( $attr, $reader, $writer ) = @_;
  78     return sub {
  79         my $self = shift;
  80         my $v    = $reader->($self);
  81
  82         my $offset      = defined $_[0] ? shift : 0;
  83         my $length      = defined $_[0] ? shift : CORE::length($v);
  84         my $replacement = defined $_[0] ? shift : undef;
  85
  86         my $ret;
  87         if ( defined $replacement ) {
  88             $ret = CORE::substr( $v, $offset, $length, $replacement );
  89             $writer->( $self, $v );
  90         }
  91         else {
  92             $ret = CORE::substr( $v, $offset, $length );
  93         }
  94
  95         return $ret;
  96     };
  97 }
  98
  99 1;
 100
 101 __END__
 102
 103 =pod
 104
 105 =head1 NAME
 106
 107 Moose::Meta::Attribute::Trait::Native::MethodProvider::String
 108
 109 =head1 DESCRIPTION
 110
 111 This is a role which provides the method generators for
 112 L<Moose::Meta::Attribute::Trait::Native::String>.
 113
 114 =head1 METHODS
 115
 116 =over 4
 117
 118 =item B<meta>
 119
 120 =back
 121
 122 =head1 PROVIDED METHODS
 123
 124 =over 4
 125
 126 =item B<append>
 127
 128 =item B<prepend>
 129
 130 =item B<replace>
 131
 132 =item B<match>
 133
 134 =item B<chomp>
 135
 136 =item B<chop>
 137
 138 =item B<inc>
 139
 140 =item B<clear>
 141
 142 =item B<substr>
 143
 144 =back
 145
 146 =head1 BUGS
 147
 148 All complex software has bugs lurking in it, and this module is no
 149 exception. If you find a bug please either email me, or add the bug
 150 to cpan-RT.
 151
 152 =head1 AUTHOR
 153
 154 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 155
 156 =head1 COPYRIGHT AND LICENSE
 157
 158 Copyright 2007-2009 by Infinity Interactive, Inc.
 159
 160 L<http://www.iinteractive.com>
 161
 162 This library is free software; you can redistribute it and/or modify
 163 it under the same terms as Perl itself.
 164
 165 =cut