lib/Moose/Meta/Attribute/Native/Trait.pm

   1
   2 package Moose::Meta::Attribute::Native::Trait;
   3 use Moose::Role;
   4
   5 use List::MoreUtils qw( any uniq );
   6 use Moose::Util::TypeConstraints;
   7 use Moose::Deprecated;
   8
   9 requires '_helper_type';
  10
  11 has _used_default_is => (
  12     is      => 'rw',
  13     isa     => 'Bool',
  14     default => 0,
  15 );
  16
  17 before '_process_options' => sub {
  18     my ( $self, $name, $options ) = @_;
  19
  20     $self->_check_helper_type( $options, $name );
  21
  22     if ( !( any { exists $options->{$_} } qw( is reader writer accessor ) )
  23         && $self->can('_default_is') ) {
  24
  25         $options->{is} = $self->_default_is;
  26
  27         $options->{_used_default_is} = 1;
  28     }
  29
  30     if (
  31         !(
  32             $options->{required}
  33             || any { exists $options->{$_} } qw( default builder lazy_build )
  34         )
  35         && $self->can('_default_default')
  36         ) {
  37
  38         $options->{default} = $self->_default_default;
  39
  40         Moose::Deprecated::deprecated(
  41             feature => 'default default for Native Trait',
  42             message =>
  43                 'Allowing a native trait to automatically supply a default is deprecated.'
  44                 . ' You can avoid this warning by supplying a default, builder, or making the attribute required'
  45         );
  46     }
  47 };
  48
  49 after 'install_accessors' => sub {
  50     my $self = shift;
  51
  52     return unless $self->_used_default_is;
  53
  54     my @methods
  55         = $self->_default_is eq 'rw'
  56         ? qw( reader writer accessor )
  57         : 'reader';
  58
  59     my $name = $self->name;
  60     my $class = $self->associated_class->name;
  61
  62     for my $meth ( uniq grep {defined} map { $self->$_ } @methods ) {
  63
  64         my $message
  65             = "The $meth method in the $class class was automatically created"
  66             . " by the native delegation trait for the $name attribute."
  67             . q{ This "default is" feature is deprecated.}
  68             . q{ Explicitly set "is" or define accessor names to avoid this};
  69
  70         $self->associated_class->add_before_method_modifier(
  71             $meth => sub {
  72                 Moose::Deprecated::deprecated(
  73                     feature => 'default is for Native Trait',
  74                     message =>$message,
  75                 );
  76             }
  77         );
  78     }
  79     };
  80
  81 sub _check_helper_type {
  82     my ( $self, $options, $name ) = @_;
  83
  84     my $type = $self->_helper_type;
  85
  86     $options->{isa} = $type
  87         unless exists $options->{isa};
  88
  89     my $isa = Moose::Util::TypeConstraints::find_or_create_type_constraint(
  90         $options->{isa} );
  91
  92     ( $isa->is_a_type_of($type) )
  93         || confess
  94         "The type constraint for $name must be a subtype of $type but it's a $isa";
  95 }
  96
  97 before 'install_accessors' => sub { (shift)->_check_handles_values };
  98
  99 sub _check_handles_values {
 100     my $self = shift;
 101
 102     my %handles = $self->_canonicalize_handles;
 103
 104     for my $original_method ( values %handles ) {
 105         my $name = $original_method->[0];
 106
 107         my $accessor_class = $self->_native_accessor_class_for($name);
 108
 109         ( $accessor_class && $accessor_class->can('new') )
 110             || confess
 111             "$name is an unsupported method type - $accessor_class";
 112     }
 113 }
 114
 115 around '_canonicalize_handles' => sub {
 116     shift;
 117     my $self    = shift;
 118     my $handles = $self->handles;
 119
 120     return unless $handles;
 121
 122     unless ( 'HASH' eq ref $handles ) {
 123         $self->throw_error(
 124             "The 'handles' option must be a HASH reference, not $handles");
 125     }
 126
 127     return
 128         map { $_ => $self->_canonicalize_handles_value( $handles->{$_} ) }
 129         keys %$handles;
 130 };
 131
 132 sub _canonicalize_handles_value {
 133     my $self  = shift;
 134     my $value = shift;
 135
 136     if ( ref $value && 'ARRAY' ne ref $value ) {
 137         $self->throw_error(
 138             "All values passed to handles must be strings or ARRAY references, not $value"
 139         );
 140     }
 141
 142     return ref $value ? $value : [$value];
 143 }
 144
 145 around '_make_delegation_method' => sub {
 146     my $next = shift;
 147     my ( $self, $handle_name, $method_to_call ) = @_;
 148
 149     my ( $name, @curried_args ) = @$method_to_call;
 150
 151     my $accessor_class = $self->_native_accessor_class_for($name);
 152
 153     die "Cannot find an accessor class for $name"
 154         unless $accessor_class && $accessor_class->can('new');
 155
 156     return $accessor_class->new(
 157         name               => $handle_name,
 158         package_name       => $self->associated_class->name,
 159         delegate_to_method => $name,
 160         attribute          => $self,
 161         is_inline          => 1,
 162         curried_arguments  => \@curried_args,
 163         root_types         => [ $self->_root_types ],
 164     );
 165 };
 166
 167 sub _root_types {
 168     return $_[0]->_helper_type;
 169 }
 170
 171 sub _native_accessor_class_for {
 172     my ( $self, $suffix ) = @_;
 173
 174     my $role
 175         = 'Moose::Meta::Method::Accessor::Native::'
 176         . $self->_native_type . '::'
 177         . $suffix;
 178
 179     Class::MOP::load_class($role);
 180     return Moose::Meta::Class->create_anon_class(
 181         superclasses =>
 182             [ $self->accessor_metaclass, $self->delegation_metaclass ],
 183         roles => [$role],
 184         cache => 1,
 185     )->name;
 186 }
 187
 188 sub _build_native_type {
 189     my $self = shift;
 190
 191     for my $role_name ( map { $_->name } $self->meta->calculate_all_roles ) {
 192         return $1 if $role_name =~ /::Native::Trait::(\w+)$/;
 193     }
 194
 195     die "Cannot calculate native type for " . ref $self;
 196 }
 197
 198 has '_native_type' => (
 199     is      => 'ro',
 200     isa     => 'Str',
 201     lazy    => 1,
 202     builder => '_build_native_type',
 203 );
 204
 205 no Moose::Role;
 206 no Moose::Util::TypeConstraints;
 207
 208 1;
 209
 210 # ABSTRACT: Shared role for native delegation traits
 211
 212 __END__
 213
 214 =head1 BUGS
 215
 216 See L<Moose/BUGS> for details on reporting bugs.
 217
 218 =head1 SEE ALSO
 219
 220 Documentation for Moose native traits can be found in
 221 L<Moose::Meta::Attribute::Native>.
 222
 223 =cut