lib/Moose/Error/Default.pm

   1 package Moose::Error::Default;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp::Heavy;
   7 use Class::MOP::MiniTrait;
   8
   9 use base 'Class::MOP::Object';
  10
  11 Class::MOP::MiniTrait::apply(__PACKAGE__, 'Moose::Meta::Object::Trait');
  12
  13 sub new {
  14     my ( $self, @args ) = @_;
  15     if (defined $ENV{MOOSE_ERROR_STYLE} && $ENV{MOOSE_ERROR_STYLE} eq 'croak') {
  16         $self->create_error_croak( @args );
  17     }
  18     else {
  19         $self->create_error_confess( @args );
  20     }
  21 }
  22
  23 sub _inline_new {
  24     my ( $self, @args ) = @_;
  25
  26     return '(do { '
  27              . '(defined $ENV{MOOSE_ERROR_STYLE} && $ENV{MOOSE_ERROR_STYLE} eq "croak"'
  28                . ' ? ' . $self->_inline_create_error_carpmess(@args)
  29                . ' : ' . $self->_inline_create_error_carpmess(@args, longmess => 1)
  30          . ')})';
  31 }
  32
  33 sub create_error_croak {
  34     my ( $self, @args ) = @_;
  35     $self->_create_error_carpmess( @args );
  36 }
  37
  38 sub create_error_confess {
  39     my ( $self, @args ) = @_;
  40     $self->_create_error_carpmess( @args, longmess => 1 );
  41 }
  42
  43 sub _create_error_carpmess {
  44     my ( $self, %args ) = @_;
  45
  46     my $carp_level = 3 + ( $args{depth} || 1 );
  47     local $Carp::MaxArgNums = 20; # default is 8, usually we use named args which gets messier though
  48
  49     my @args = exists $args{message} ? $args{message} : ();
  50
  51     if ( $args{longmess} || $Carp::Verbose ) {
  52         local $Carp::CarpLevel = ( $Carp::CarpLevel || 0 ) + $carp_level;
  53         return Carp::longmess(@args);
  54     } else {
  55         return Carp::ret_summary($carp_level, @args);
  56     }
  57 }
  58
  59 sub _inline_create_error_carpmess {
  60     my ( $self, %args ) = @_;
  61
  62     my $carp_level = $args{depth} || 0;
  63
  64     my $create_message = 'Carp::longmess(' . $args{message} . ')';
  65
  66     if (!$args{longmess}) {
  67         $create_message =
  68             '($Carp::Verbose '
  69               . '? ' . $create_message . ' '
  70               . ': Carp::ret_summary('
  71                   . $carp_level . ', ' . $args{message}
  72               . '))';
  73     }
  74
  75     return
  76         '(do { '
  77           . 'local $Carp::MaxArgNums = 20; '
  78           . 'local $Carp::CarpLevel = ($Carp::CarpLevel || 0) + '
  79               . $carp_level . '; '
  80           . $create_message
  81       . '})';
  82 }
  83
  84 1;
  85
  86 # ABSTRACT: L<Carp> based error generation for Moose.
  87
  88 __END__
  89
  90 =pod
  91
  92 =head1 DESCRIPTION
  93
  94 This class implements L<Carp> based error generation.
  95
  96 The default behavior is like L<Moose::Error::Confess>. To override this to
  97 default to L<Moose::Error::Croak>'s behaviour on a system wide basis, set the
  98 MOOSE_ERROR_STYLE environment variable to C<croak>. The use of this
  99 environment variable is considered experimental, and may change in a future
 100 release.
 101
 102 =head1 METHODS
 103
 104 =over 4
 105
 106 =item B<< Moose::Error::Default->new(@args) >>
 107
 108 Create a new error. Delegates to C<create_error_confess> or
 109 C<create_error_croak>.
 110
 111 =item B<< $error->create_error_confess(@args) >>
 112
 113 =item B<< $error->create_error_croak(@args) >>
 114
 115 Creates a new errors string of the specified style.
 116
 117 =back
 118
 119 =cut
 120
 121