lib/Moose/Cookbook/FAQ.pod

   1
   2 =pod
   3
   4 =head1 NAME
   5
   6 Moose::Cookbook::FAQ - Frequently asked questions about Moose
   7
   8 =head1 FREQUENTLY ASKED QUESTIONS
   9
  10 =head2 Module Stability
  11
  12 =head3 Is Moose "production ready"?
  13
  14 Yes! Many sites with household names are using Moose to build
  15 high-traffic services. Countless others are using Moose in
  16 production.
  17
  18 As of this writing, Moose is a dependency of several hundred CPAN
  19 modules. L<http://cpants.perl.org/dist/used_by/Moose>
  20
  21 =head3 Is Moose's API stable?
  22
  23 Yes. The sugary API, the one 95% of users will interact with, is
  24 B<very stable>. Any changes will be B<100% backwards compatible>.
  25
  26 The meta API is less set in stone. We reserve the right to tweak
  27 parts of it to improve efficiency or consistency. This will not be
  28 done lightly. We do perform deprecation cycles. We I<really>
  29 do not like making ourselves look bad by breaking your code.
  30 Submitting test cases is the best way to ensure that your code is not
  31 inadvertantly broken by refactoring.
  32
  33 =head3 I heard Moose is slow, is this true?
  34
  35 Again, this one is tricky, so Yes I<and> No.
  36
  37 First let me say that I<nothing> in life is free, and that some
  38 Moose features do cost more than others. It is also the
  39 policy of Moose to B<only charge you for the features you use>,
  40 and to do our absolute best to not place any extra burdens on
  41 the execution of your code for features you are not using. Of
  42 course using Moose itself does involve some overhead, but it
  43 is mostly compile time. At this point we do have some options
  44 available for getting the speed you need.
  45
  46 Currently we have the option of making your classes immutable
  47 as a means of boosting speed. This will mean a slightly larger compile
  48 time cost, but the runtime speed increase (especially in object
  49 construction) is pretty significant. This is not very well
  50 documented yet, so please ask on the list or on #moose for more
  51 information.
  52
  53 We are also discussing and experimenting with L<Module::Compile>,
  54 and the idea of compiling highly optimized C<.pmc> files. In
  55 addition, we have mapped out some core methods as candidates for
  56 conversion to XS.
  57
  58 =head3 When will Moose 1.0 be ready?
  59
  60 It is right now, I declared 0.18 to be "ready to use".
  61
  62 =head2 Constructors
  63
  64 =head3 How do I write custom constructors with Moose?
  65
  66 Ideally, you should never write your own C<new> method, and should
  67 use Moose's other features to handle your specific object construction
  68 needs. Here are a few scenarios, and the Moose way to solve them;
  69
  70 If you need to call initialization code post instance construction,
  71 then use the C<BUILD> method. This feature is taken directly from
  72 Perl 6. Every C<BUILD> method in your inheritance chain is called
  73 (in the correct order) immediately after the instance is constructed.
  74 This allows you to ensure that all your superclasses are initialized
  75 properly as well. This is the best approach to take (when possible)
  76 because it makes subclassing your class much easier.
  77
  78 If you need to affect the constructor's parameters prior to the
  79 instance actually being constructed, you have a number of options.
  80
  81 To change the parameter processing as a whole, you can use
  82 the C<BUILDARGS> method. The default implementation accepts key/value
  83 pairs or a hash reference. You can override it to take positional args,
  84 or any other format
  85
  86 To change the handling of individual parameters, there are I<coercions>
  87 (See the L<Moose::Cookbook::Basics::Recipe5> for a complete example and
  88 explanation of coercions). With coercions it is possible to morph
  89 argument values into the correct expected types. This approach is the
  90 most flexible and robust, but does have a slightly higher learning
  91 curve.
  92
  93 =head3 How do I make non-Moose constructors work with Moose?
  94
  95 Usually the correct approach to subclassing a non Moose class is
  96 delegation.  Moose makes this easy using the C<handles> keyword,
  97 coercions, and C<lazy_build>, so subclassing is often not the
  98 ideal route.
  99
 100 That said, the default Moose constructor is inherited from
 101 L<Moose::Object>. When inheriting from a non-Moose class, the
 102 inheritance chain to L<Moose::Object> is broken. The simplest way
 103 to fix this is to simply explicitly inherit from L<Moose::Object>
 104 yourself.
 105
 106 However, this does not always fix the issue of actually calling the Moose
 107 constructor. Fortunately, the modules L<MooseX::NonMoose> and
 108 L<MooseX::Alien> aim to make subclassing non-Moose classes easier.
 109
 110 If neither extension fills your specific needs, you can use
 111 L<Class::MOP::Class/new_object>. This low-level constructor accepts the
 112 special C<__INSTANCE__> parameter, allowing you to instantiate your Moose
 113 attributes:
 114
 115   package My::HTML::Template;
 116   use Moose;
 117
 118   # explicit inheritance
 119   extends 'HTML::Template', 'Moose::Object';
 120
 121   # explicit constructor
 122   sub new {
 123       my $class = shift;
 124       # call HTML::Template's constructor
 125       my $obj = $class->SUPER::new(@_);
 126       return $class->meta->new_object(
 127           # pass in the constructed object
 128           # using the special key __INSTANCE__
 129           __INSTANCE__ => $obj,
 130           @_, # pass in the normal args
 131       );
 132   }
 133
 134 Of course, this only works if both your Moose class and the
 135 inherited non-Moose class use the same instance type (typically
 136 HASH refs).
 137
 138 Note that this doesn't call C<BUILDALL> automatically, you must do that
 139 yourself.
 140
 141 Other techniques can be used as well, such as creating the object
 142 using C<Moose::Object::new>, but calling the inherited non-Moose
 143 class's initialization methods (if available).
 144
 145 In short, there are several ways to extend non-Moose classes. It is
 146 best to evaluate each case based on the class you wish to extend,
 147 and the features you wish to employ. As always, both IRC and the
 148 mailing list are great ways to get help finding the best approach.
 149
 150 =head2 Accessors
 151
 152 =head3 How do I tell Moose to use get/set accessors?
 153
 154 The easiest way to accomplish this is to use the C<reader> and
 155 C<writer> attribute options. Here is some example code:
 156
 157   has 'bar' => (
 158       isa    => 'Baz',
 159       reader => 'get_bar',
 160       writer => 'set_bar',
 161   );
 162
 163 Moose will still take advantage of type constraints, triggers, etc.
 164 when creating these methods.
 165
 166 If you do not like this much typing, and wish it to be a default for your
 167 class, please see L<MooseX::FollowPBP>. This will allow you to write:
 168
 169   has 'bar' => (
 170       isa => 'Baz',
 171       is  => 'rw',
 172   );
 173
 174 And have Moose create separate C<get_bar> and C<set_bar> methods
 175 instead of a single C<bar> method.
 176
 177 NOTE: This B<cannot> be set globally in Moose, as that would break
 178 other classes which are built with Moose.
 179
 180 =head3 How can I get Moose to inflate/deflate values in the accessor?
 181
 182 Well, the first question to ask is if you actually need both inflate
 183 and deflate.
 184
 185 If you only need to inflate, then I suggest using coercions. Here is
 186 some basic sample code for inflating a L<DateTime> object:
 187
 188   subtype 'DateTime'
 189       => as 'Object'
 190       => where { $_->isa('DateTime') };
 191
 192   coerce 'DateTime'
 193       => from 'Str'
 194         => via { DateTime::Format::MySQL->parse_datetime($_) };
 195
 196   has 'timestamp' => (is => 'rw', isa => 'DateTime', coerce => 1);
 197
 198 This creates a custom subtype for L<DateTime> objects, then attaches
 199 a coercion to that subtype. The C<timestamp> attribute is then told
 200 to expect a C<DateTime> type, and to try to coerce it. When a C<Str>
 201 type is given to the C<timestamp> accessor, it will attempt to
 202 coerce the value into a C<DateTime> object using the code in found
 203 in the C<via> block.
 204
 205 For a more comprehensive example of using coercions, see the
 206 L<Moose::Cookbook::Basics::Recipe5>.
 207
 208 If you need to deflate your attribute, the current best practice is to
 209 add an C<around> modifier to your accessor. Here is some example code:
 210
 211   # a timestamp which stores as
 212   # seconds from the epoch
 213   has 'timestamp' => (is => 'rw', isa => 'Int');
 214
 215   around 'timestamp' => sub {
 216       my $next = shift;
 217       my ($self, $timestamp) = @_;
 218       # assume we get a DateTime object ...
 219       $next->($self, $timestamp->epoch);
 220   };
 221
 222 It is also possible to do deflation using coercion, but this tends
 223 to get quite complex and require many subtypes. An example of this
 224 is outside the scope of this document, ask on #moose or send a mail
 225 to the list.
 226
 227 Still another option is to write a custom attribute metaclass, which
 228 is also outside the scope of this document, but I would be happy to
 229 explain it on #moose or the mailing list.
 230
 231 =head2 Method Modifiers
 232
 233 =head3 How can I affect the values in C<@_> using C<before>?
 234
 235 You can't, actually: C<before> only runs before the main method,
 236 and it cannot easily affect the method's execution.
 237
 238 You similarly can't use C<after> to affect the return value of a
 239 method.
 240
 241 We limit C<before> and C<after> because this lets you write more
 242 concise code. You do not have to worry about passing C<@_> to the
 243 original method, or forwarding its response (being careful to preserve
 244 context).
 245
 246 The C<around> method modifier has neither of these limitations.
 247
 248 =head3 Can I use C<before> to stop execution of a method?
 249
 250 Yes, but only if you throw an exception. If this is too drastic a
 251 measure then I suggest using C<around> instead. The C<around> method
 252 modifier is the only modifier which can gracefully prevent execution
 253 of the main method. Here is an example:
 254
 255   around 'baz' => sub {
 256       my $next = shift;
 257       my ($self, %options) = @_;
 258       unless ($options->{bar} eq 'foo') {
 259         return 'bar';
 260       }
 261       $next->($self, %options);
 262   };
 263
 264 By choosing not to call the C<$next> method, you can stop the
 265 execution of the main method.
 266
 267 =head2 Type Constraints
 268
 269 =head3 How can I have a custom error message for a type constraint?
 270
 271 Use the C<message> option when building the subtype, like so:
 272
 273   subtype 'NaturalLessThanTen'
 274       => as 'Natural'
 275       => where { $_ < 10 }
 276       => message { "This number ($_) is not less than ten!" };
 277
 278 This will be called when a value fails to pass the C<NaturalLessThanTen>
 279 constraint check.
 280
 281 =head3 Can I turn off type constraint checking?
 282
 283 Not yet, but soon. This option will likely be coming in the next
 284 release.
 285
 286 =head2 Roles
 287
 288 =head3 How do I get Moose to call BUILD in all my composed roles?
 289
 290 See L<Moose::Cookbook::WTF> and specifically the B<Why is BUILD
 291 not called for my composed roles?> question in the B<Roles> section.
 292
 293 =head3 What are Traits, and how are they different from Roles?
 294
 295 In Moose, a trait is almost exactly the same thing as a role, except
 296 that traits typically register themselves, which allows you to refer
 297 to them by a short name ("Big" vs "MyApp::Role::Big").
 298
 299 In Moose-speak, a I<Role> is usually composed into a I<class> at
 300 compile time, whereas a I<Trait> is usually composed into an instance
 301 of a class at runtime to add or modify the behavior of B<just that
 302 instance>.
 303
 304 Outside the context of Moose, traits and roles generally mean exactly the
 305 same thing. The original paper called them Traits, however Perl 6 will call
 306 them Roles.
 307
 308 =head1 AUTHOR
 309
 310 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 311
 312 =head1 COPYRIGHT AND LICENSE
 313
 314 Copyright 2006-2009 by Infinity Interactive, Inc.
 315
 316 L<http://www.iinteractive.com>
 317
 318 This library is free software; you can redistribute it and/or modify
 319 it under the same terms as Perl itself.
 320
 321 =cut