lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  21
  22     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  23     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  24
  25     # During 5.13 dev cycle HELEMs started to leak on copy
  26     PEEPEENESS =>
  27       # request for all tests would force "non-leaky" illusion and vice-versa
  28       defined $ENV{DBICTEST_ALL_LEAKS}                                              ? !$ENV{DBICTEST_ALL_LEAKS}
  29       # otherwise confess that this perl is busted ONLY on smokers
  30     : eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006)  ? 1
  31       # otherwise we are good
  32                                                                                     : 0
  33     ,
  34
  35     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  36
  37     IV_SIZE => $Config{ivsize},
  38
  39     OS_NAME => $^O,
  40   };
  41
  42   if ($] < 5.009_005) {
  43     require MRO::Compat;
  44     constant->import( OLD_MRO => 1 );
  45   }
  46   else {
  47     require mro;
  48     constant->import( OLD_MRO => 0 );
  49   }
  50 }
  51
  52 # FIXME - this is not supposed to be here
  53 # Carp::Skip to the rescue soon
  54 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  55
  56 use Carp 'croak';
  57 use Scalar::Util qw(refaddr weaken blessed reftype);
  58
  59 use base 'Exporter';
  60 our @EXPORT_OK = qw(sigwarn_silencer modver_gt_or_eq fail_on_internal_wantarray refcount is_exception);
  61
  62 sub sigwarn_silencer {
  63   my $pattern = shift;
  64
  65   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  66
  67   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  68
  69   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  70 }
  71
  72 sub refcount {
  73   croak "Expecting a reference" if ! length ref $_[0];
  74
  75   require B;
  76   # No tempvars - must operate on $_[0], otherwise the pad
  77   # will count as an extra ref
  78   B::svref_2object($_[0])->REFCNT;
  79 }
  80
  81 sub is_exception ($) {
  82   my $e = $_[0];
  83
  84   my ($not_blank, $suberror);
  85   {
  86     local $@;
  87     eval {
  88       $not_blank = ($e ne '') ? 1 : 0;
  89       1;
  90     } or $suberror = $@;
  91   }
  92
  93   if (defined $suberror) {
  94     if (length (my $class = blessed($e) )) {
  95       carp_unique( sprintf(
  96         'External exception object %s=%s(0x%x) implements partial (broken) '
  97       . 'overloading preventing it from being used in simple ($x eq $y) '
  98       . 'comparisons. Given Perl\'s "globally cooperative" exception '
  99       . 'handling this type of brokenness is extremely dangerous on '
 100       . 'exception objects, as it may (and often does) result in silent '
 101       . '"exception substitution". DBIx::Class tries to work around this '
 102       . 'as much as possible, but other parts of your software stack may '
 103       . 'not be even aware of this. Please submit a bugreport against the '
 104       . 'distribution containing %s and in the meantime apply a fix similar '
 105       . 'to the one shown at %s, in order to ensure your exception handling '
 106       . 'is saner application-wide. What follows is the actual error text '
 107       . "as generated by Perl itself:\n\n%s\n ",
 108         $class,
 109         reftype $e,
 110         refaddr $e,
 111         $class,
 112         'http://v.gd/DBIC_overload_tempfix/',
 113         $suberror,
 114       ));
 115
 116       # workaround, keeps spice flowing
 117       $not_blank = ("$e" ne '') ? 1 : 0;
 118     }
 119     else {
 120       # not blessed yet failed the 'ne'... this makes 0 sense...
 121       # just throw further
 122       die $suberror
 123     }
 124   }
 125
 126   return $not_blank;
 127 }
 128
 129 sub modver_gt_or_eq {
 130   my ($mod, $ver) = @_;
 131
 132   croak "Nonsensical module name supplied"
 133     if ! defined $mod or ! length $mod;
 134
 135   croak "Nonsensical minimum version supplied"
 136     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 137
 138   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 139     if SPURIOUS_VERSION_CHECK_WARNINGS;
 140
 141   local $@;
 142   eval { $mod->VERSION($ver) } ? 1 : 0;
 143 }
 144
 145 {
 146   my $list_ctx_ok_stack_marker;
 147
 148   sub fail_on_internal_wantarray {
 149     return if $list_ctx_ok_stack_marker;
 150
 151     if (! defined wantarray) {
 152       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 153     }
 154
 155     my $cf = 1;
 156     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 157
 158       # these are public API parts that alter behavior on wantarray
 159       search | search_related | slice | search_literal
 160
 161         |
 162
 163       # these are explicitly prefixed, since we only recognize them as valid
 164       # escapes when they come from the guts of CDBICompat
 165       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 166
 167     ) $/x ) {
 168       $cf++;
 169     }
 170
 171     if (
 172       (caller($cf))[0] =~ /^(?:DBIx::Class|DBICx::)/
 173     ) {
 174       my $obj = shift;
 175
 176       DBIx::Class::Exception->throw( sprintf (
 177         "Improper use of %s(0x%x) instance in list context at %s line %d\n\n\tStacktrace starts",
 178         ref($obj), refaddr($obj), (caller($cf))[1,2]
 179       ), 'with_stacktrace');
 180     }
 181
 182     my $mark = [];
 183     weaken ( $list_ctx_ok_stack_marker = $mark );
 184     $mark;
 185   }
 186 }
 187
 188 1;