lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 # load es early as we can, usually a noop
   5 use DBIx::Class::StartupCheck;
   6
   7 use warnings;
   8 use strict;
   9
  10 # For the love of everything that is crab-like: DO NOT reach into this
  11 # The entire thing is really fragile and should not be screwed with
  12 # unless absolutely and unavoidably necessary
  13 our $__describe_class_query_cache;
  14
  15 BEGIN {
  16   package # hide from pause
  17     DBIx::Class::_ENV_;
  18
  19   use Config;
  20
  21   use constant {
  22     PERL_VERSION => "$]",
  23     OS_NAME => "$^O",
  24   };
  25
  26   use constant {
  27
  28     # but of course
  29     BROKEN_FORK => (OS_NAME eq 'MSWin32') ? 1 : 0,
  30
  31     BROKEN_GOTO => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  32
  33     # perl -MScalar::Util=weaken -e 'weaken( $hash{key} = \"value" )'
  34     BROKEN_WEAK_SCALARREF_VALUES => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  35
  36     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  37
  38     TAINT_MODE => 0 + ${^TAINT}, # tri-state: 0, 1, -1
  39
  40     UNSTABLE_DOLLARAT => ( PERL_VERSION < 5.013002 ) ? 1 : 0,
  41
  42     ( map
  43       #
  44       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  45       # all envvars without further adjusting its scripts
  46       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  47       #
  48       { substr($_, 5) => !!( $ENV{$_} ) }
  49       qw(
  50         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  51         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  52         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  53         DBIC_ASSERT_NO_ERRONEOUS_METAINSTANCE_USE
  54         DBIC_ASSERT_NO_FAILING_SANITY_CHECKS
  55         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  56         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  57       )
  58     ),
  59
  60     IV_SIZE => $Config{ivsize},
  61   };
  62
  63   if ( PERL_VERSION < 5.009_005) {
  64     require MRO::Compat;
  65     constant->import( OLD_MRO => 1 );
  66
  67     #
  68     # Yes, I know this is a rather PHP-ish name, but please first read
  69     # https://metacpan.org/source/BOBTFISH/MRO-Compat-0.12/lib/MRO/Compat.pm#L363-368
  70     #
  71     # Even if we are using Class::C3::XS it still won't work, as doing
  72     #   defined( *{ "SubClass::"->{$_} }{CODE} )
  73     # will set pkg_gen to the same value for SubClass and *ALL PARENTS*
  74     #
  75     *DBIx::Class::_Util::get_real_pkg_gen = sub ($) {
  76       require Digest::MD5;
  77       require Math::BigInt;
  78
  79       my $cur_class;
  80       no strict 'refs';
  81
  82       # the non-assign-unless-there-is-a-hash is deliberate
  83       ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{gen} ||= (
  84         Math::BigInt->new( '0x' . ( Digest::MD5::md5_hex( join "\0", map {
  85
  86           ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_}{methlist} ||= (
  87
  88             $cur_class = $_
  89
  90               and
  91
  92             # RV to be hashed up and turned into a number
  93             join "\0", (
  94               $cur_class,
  95               map
  96                 {(
  97                   # stringification should be sufficient, ignore names/refaddr entirely
  98                   $_,
  99                   do {
 100                     my @attrs;
 101                     local $@;
 102                     local $SIG{__DIE__} if $SIG{__DIE__};
 103                     # attributes::get may throw on blessed-false crefs :/
 104                     eval { @attrs = attributes::get( $_ ); 1 }
 105                       or warn "Unable to determine attributes of coderef $_ due to the following error: $@";
 106                     @attrs;
 107                   },
 108                 )}
 109                 map
 110                   {(
 111                     # skip dummy C::C3 helper crefs
 112                     ! ( ( $Class::C3::MRO{$cur_class} || {} )->{methods}{$_} )
 113                       and
 114                     (
 115                       ref(\ "${cur_class}::"->{$_} ) ne 'GLOB'
 116                         or
 117                       defined( *{ "${cur_class}::"->{$_} }{CODE} )
 118                     )
 119                   )
 120                     ? ( \&{"${cur_class}::$_"} )
 121                     : ()
 122                   }
 123                   keys %{ "${cur_class}::" }
 124             )
 125           )
 126         } (
 127
 128           @{
 129             ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{linear_isa}
 130               ||=
 131             mro::get_linear_isa($_[0])
 132           },
 133
 134           ((
 135             ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{is_universal}
 136               ||=
 137             mro::is_universal($_[0])
 138           ) ? () : @{
 139             ( $__describe_class_query_cache->{'!internal!'} || {} )->{UNIVERSAL}{linear_isa}
 140               ||=
 141             mro::get_linear_isa("UNIVERSAL")
 142           } ),
 143
 144         ) ) ) )
 145       );
 146     };
 147   }
 148   else {
 149     require mro;
 150     constant->import( OLD_MRO => 0 );
 151     *DBIx::Class::_Util::get_real_pkg_gen = \&mro::get_pkg_gen;
 152   }
 153
 154   # Both of these are no longer used for anything. However bring
 155   # them back after they were purged in 08a8d8f1, as there appear
 156   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
 157   # in their production codebases. There is no point in breaking these
 158   # if whatever they used actually continues to work
 159   my $sigh = sub {
 160     DBIx::Class::_Util::emit_loud_diag(
 161       skip_frames => 1,
 162       msg => "The @{[ (caller(1))[3] ]} constant is no more - adjust your code"
 163     );
 164
 165     0;
 166   };
 167   sub DBICTEST () { &$sigh }
 168   sub PEEPEENESS () { &$sigh }
 169 }
 170
 171 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( DBIx::Class::_ENV_::PERL_VERSION < 5.010 ? 1 : 0);
 172
 173 # FIXME - this is not supposed to be here
 174 # Carp::Skip to the rescue soon
 175 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
 176
 177 # Ensure it is always there, in case we need to do a $schema-less throw()
 178 use DBIx::Class::Exception ();
 179
 180 use B ();
 181 use Carp 'croak';
 182 use Storable 'nfreeze';
 183 use Scalar::Util qw(weaken blessed reftype refaddr);
 184 use Sub::Name ();
 185 use attributes ();
 186
 187 # Usually versions are not specified anywhere aside the Makefile.PL
 188 # (writing them out in-code is extremely obnoxious)
 189 # However without a recent enough Moo the quote_sub override fails
 190 # in very puzzling and hard to detect ways: so add a version check
 191 # just this once
 192 use Sub::Quote qw(qsub);
 193 BEGIN { Sub::Quote->VERSION('2.002002') }
 194
 195 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
 196 BEGIN { *deep_clone = \&Storable::dclone }
 197
 198 use base 'Exporter';
 199 our @EXPORT_OK = qw(
 200   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
 201   fail_on_internal_wantarray fail_on_internal_call
 202   refdesc refcount hrefaddr set_subname get_subname describe_class_methods
 203   scope_guard detected_reinvoked_destructor emit_loud_diag
 204   true false
 205   is_exception dbic_internal_try dbic_internal_catch visit_namespaces
 206   quote_sub qsub perlstring serialize deep_clone dump_value uniq
 207   parent_dir mkdir_p
 208   UNRESOLVABLE_CONDITION DUMMY_ALIASPAIR
 209 );
 210
 211 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 212
 213 use constant DUMMY_ALIASPAIR => (
 214   foreign_alias => "!!!\xFF()!!!_DUMMY_FOREIGN_ALIAS_SHOULD_NEVER_BE_SEEN_IN_USE_!!!()\xFF!!!",
 215   self_alias => "!!!\xFE()!!!_DUMMY_SELF_ALIAS_SHOULD_NEVER_BE_SEEN_IN_USE_!!!()\xFE!!!",
 216 );
 217
 218 # Override forcing no_defer, and adding naming consistency checks
 219 our %refs_closed_over_by_quote_sub_installed_crefs;
 220 sub quote_sub {
 221   Carp::confess( "Anonymous quoting not supported by the DBIC quote_sub override - supply a sub name" ) if
 222     @_ < 2
 223       or
 224     ! defined $_[1]
 225       or
 226     length ref $_[1]
 227   ;
 228
 229   Carp::confess( "The DBIC quote_sub override expects sub name '$_[0]' to be fully qualified" )
 230     unless (my $stash) = $_[0] =~ /^(.+)::/;
 231
 232   Carp::confess(
 233     "The DBIC sub_quote override does not support 'no_install'"
 234   ) if (
 235     $_[3]
 236       and
 237     $_[3]->{no_install}
 238   );
 239
 240   Carp::confess(
 241     'The DBIC quote_sub override expects the namespace-part of sub name '
 242   . "'$_[0]' to match the supplied package argument '$_[3]->{package}'"
 243   ) if (
 244     $_[3]
 245       and
 246     defined $_[3]->{package}
 247       and
 248     $stash ne $_[3]->{package}
 249   );
 250
 251   my @caller = caller(0);
 252   my $sq_opts = {
 253     package => $caller[0],
 254     hints => $caller[8],
 255     warning_bits => $caller[9],
 256     hintshash => $caller[10],
 257     %{ $_[3] || {} },
 258
 259     # explicitly forced for everything
 260     no_defer => 1,
 261   };
 262
 263   weaken (
 264     # just use a growing counter, no need to perform neither compaction
 265     # nor any special ithread-level handling
 266     $refs_closed_over_by_quote_sub_installed_crefs
 267      { scalar keys %refs_closed_over_by_quote_sub_installed_crefs }
 268       = $_
 269   ) for grep {
 270     length ref $_
 271       and
 272     (
 273       ! DBIx::Class::_ENV_::BROKEN_WEAK_SCALARREF_VALUES
 274         or
 275       ref $_ ne 'SCALAR'
 276     )
 277   } values %{ $_[2] || {} };
 278
 279   Sub::Quote::quote_sub( $_[0], $_[1], $_[2]||{}, $sq_opts );
 280 }
 281
 282 sub sigwarn_silencer ($) {
 283   my $pattern = shift;
 284
 285   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 286
 287   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 288
 289   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 290 }
 291
 292 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 293
 294 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 295
 296 sub refdesc ($) {
 297   croak "Expecting a reference" if ! length ref $_[0];
 298
 299   # be careful not to trigger stringification,
 300   # reuse @_ as a scratch-pad
 301   sprintf '%s%s(0x%x)',
 302     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 303     reftype $_[0],
 304     refaddr($_[0]),
 305   ;
 306 }
 307
 308 sub refcount ($) {
 309   croak "Expecting a reference" if ! length ref $_[0];
 310
 311   # No tempvars - must operate on $_[0], otherwise the pad
 312   # will count as an extra ref
 313   B::svref_2object($_[0])->REFCNT;
 314 }
 315
 316 sub visit_namespaces {
 317   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 318
 319   my $visited_count = 1;
 320
 321   # A package and a namespace are subtly different things
 322   $args->{package} ||= 'main';
 323   $args->{package} = 'main' if $args->{package} =~ /^ :: (?: main )? $/x;
 324   $args->{package} =~ s/^:://;
 325
 326   if ( $args->{action}->($args->{package}) ) {
 327     my $ns =
 328       ( ($args->{package} eq 'main') ? '' :  $args->{package} )
 329         .
 330       '::'
 331     ;
 332
 333     $visited_count += visit_namespaces( %$args, package => $_ ) for
 334       grep
 335         # this happens sometimes on %:: traversal
 336         { $_ ne '::main' }
 337         map
 338           { $_ =~ /^(.+?)::$/ ? "$ns$1" : () }
 339           do { no strict 'refs'; keys %$ns }
 340     ;
 341   }
 342
 343   $visited_count;
 344 }
 345
 346 # FIXME In another life switch these to a polyfill like the ones in namespace::clean
 347 sub get_subname ($) {
 348   my $gv = B::svref_2object( $_[0] )->GV;
 349   wantarray
 350     ? ( $gv->STASH->NAME, $gv->NAME )
 351     : ( join '::', $gv->STASH->NAME, $gv->NAME )
 352   ;
 353 }
 354 sub set_subname ($$) {
 355
 356   # fully qualify name
 357   splice @_, 0, 1, caller(0) . "::$_[0]"
 358     if $_[0] !~ /::|'/;
 359
 360   &Sub::Name::subname;
 361 }
 362
 363 sub serialize ($) {
 364   # stable hash order
 365   local $Storable::canonical = 1;
 366
 367   # explicitly false - there is nothing sensible that can come out of
 368   # an attempt at CODE serialization
 369   local $Storable::Deparse;
 370
 371   # take no chances
 372   local $Storable::forgive_me;
 373
 374   # FIXME
 375   # A number of codepaths *expect* this to be Storable.pm-based so that
 376   # the STORABLE_freeze hooks in the metadata subtree get executed properly
 377   nfreeze($_[0]);
 378 }
 379
 380 sub uniq {
 381   my( %seen, $seen_undef, $numeric_preserving_copy );
 382   grep { not (
 383     defined $_
 384       ? $seen{ $numeric_preserving_copy = $_ }++
 385       : $seen_undef++
 386   ) } @_;
 387 }
 388
 389 my $dd_obj;
 390 sub dump_value ($) {
 391   local $Data::Dumper::Indent = 1
 392     unless defined $Data::Dumper::Indent;
 393
 394   my $dump_str = (
 395     $dd_obj
 396       ||=
 397     do {
 398       require Data::Dumper;
 399       my $d = Data::Dumper->new([])
 400         ->Purity(0)
 401         ->Pad('')
 402         ->Useqq(1)
 403         ->Terse(1)
 404         ->Freezer('')
 405         ->Quotekeys(0)
 406         ->Bless('bless')
 407         ->Pair(' => ')
 408         ->Sortkeys(1)
 409         ->Deparse(1)
 410       ;
 411
 412       # FIXME - this is kinda ridiculous - there ought to be a
 413       # Data::Dumper->new_with_defaults or somesuch...
 414       #
 415       if( modver_gt_or_eq ( 'Data::Dumper', '2.136' ) ) {
 416         $d->Sparseseen(1);
 417
 418         if( modver_gt_or_eq ( 'Data::Dumper', '2.153' ) ) {
 419           $d->Maxrecurse(1000);
 420
 421           if( modver_gt_or_eq ( 'Data::Dumper', '2.160' ) ) {
 422             $d->Trailingcomma(1);
 423           }
 424         }
 425       }
 426
 427       $d;
 428     }
 429   )->Values([$_[0]])->Dump;
 430
 431   $dd_obj->Reset->Values([]);
 432
 433   $dump_str;
 434 }
 435
 436 my $seen_loud_screams;
 437 sub emit_loud_diag {
 438   my $args = { ref $_[0] eq 'HASH' ? %{$_[0]} : @_ };
 439
 440   unless ( defined $args->{msg} and length $args->{msg} ) {
 441     emit_loud_diag(
 442       msg => "No 'msg' value supplied to emit_loud_diag()"
 443     );
 444     exit 70;
 445   }
 446
 447   my $msg = "\n" . join( ': ',
 448     ( $0 eq '-e' ? () : $0 ),
 449     $args->{msg}
 450   );
 451
 452   # when we die - we usually want to keep doing it
 453   $args->{emit_dups} = !!$args->{confess}
 454     unless exists $args->{emit_dups};
 455
 456   local $Carp::CarpLevel =
 457     ( $args->{skip_frames} || 0 )
 458       +
 459     $Carp::CarpLevel
 460       +
 461     # hide our own frame
 462     1
 463   ;
 464
 465   my $longmess = Carp::longmess();
 466
 467   # different object references will thwart deduplication without this
 468   ( my $key = "${msg}\n${longmess}" ) =~ s/\b0x[0-9a-f]+\b/0x.../gi;
 469
 470   return $seen_loud_screams->{$key} if
 471     $seen_loud_screams->{$key}++
 472       and
 473     ! $args->{emit_dups}
 474   ;
 475
 476   $msg .= $longmess
 477     unless $msg =~ /\n\z/;
 478
 479   print STDERR "$msg\n"
 480     or
 481   print STDOUT "\n!!!STDERR ISN'T WRITABLE!!!:$msg\n";
 482
 483   return $seen_loud_screams->{$key}
 484     unless $args->{confess};
 485
 486   # increment *again*, because... Carp.
 487   $Carp::CarpLevel++;
 488
 489   # not $msg - Carp will reapply the longmess on its own
 490   Carp::confess($args->{msg});
 491 }
 492
 493
 494 ###
 495 ### This is *NOT* boolean.pm - deliberately not using a singleton
 496 ###
 497 {
 498   package # hide from pause
 499     DBIx::Class::_Util::_Bool;
 500   use overload
 501     bool => sub { ${$_[0]} },
 502     fallback => 1,
 503   ;
 504 }
 505 sub true () { my $x = 1; bless \$x, "DBIx::Class::_Util::_Bool" }
 506 sub false () { my $x = 0; bless \$x, "DBIx::Class::_Util::_Bool" }
 507
 508 sub scope_guard (&) {
 509   croak 'Calling scope_guard() in void context makes no sense'
 510     if ! defined wantarray;
 511
 512   # no direct blessing of coderefs - DESTROY is buggy on those
 513   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 514 }
 515 {
 516   package #
 517     DBIx::Class::_Util::ScopeGuard;
 518
 519   sub DESTROY {
 520     &DBIx::Class::_Util::detected_reinvoked_destructor;
 521
 522     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 523
 524     eval {
 525       $_[0]->[0]->();
 526       1;
 527     }
 528       or
 529     DBIx::Class::_Util::emit_loud_diag(
 530       emit_dups => 1,
 531       msg => "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@\n "
 532     );
 533   }
 534 }
 535
 536
 537 sub is_exception ($) {
 538   my $e = $_[0];
 539
 540   # FIXME
 541   # this is not strictly correct - an eval setting $@ to undef
 542   # is *not* the same as an eval setting $@ to ''
 543   # but for the sake of simplicity assume the following for
 544   # the time being
 545   return 0 unless defined $e;
 546
 547   my ($not_blank, $suberror);
 548   {
 549     local $SIG{__DIE__} if $SIG{__DIE__};
 550     local $@;
 551     eval {
 552       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 553       # will entirely obviate the need for the encolsing eval{}, as the
 554       # condition we guard against is a missing fallback overload
 555       $not_blank = ( $e ne '' );
 556       1;
 557     } or $suberror = $@;
 558   }
 559
 560   if (defined $suberror) {
 561     if (length (my $class = blessed($e) )) {
 562       carp_unique( sprintf(
 563         'External exception class %s implements partial (broken) overloading '
 564       . 'preventing its instances from being used in simple ($x eq $y) '
 565       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 566       . 'handling this type of brokenness is extremely dangerous on '
 567       . 'exception objects, as it may (and often does) result in silent '
 568       . '"exception substitution". DBIx::Class tries to work around this '
 569       . 'as much as possible, but other parts of your software stack may '
 570       . 'not be even aware of this. Please submit a bugreport against the '
 571       . 'distribution containing %s and in the meantime apply a fix similar '
 572       . 'to the one shown at %s, in order to ensure your exception handling '
 573       . 'is saner application-wide. What follows is the actual error text '
 574       . "as generated by Perl itself:\n\n%s\n ",
 575         $class,
 576         $class,
 577         'http://v.gd/DBIC_overload_tempfix/',
 578         $suberror,
 579       ));
 580
 581       # workaround, keeps spice flowing
 582       $not_blank = !!( length $e );
 583     }
 584     else {
 585       # not blessed yet failed the 'ne'... this makes 0 sense...
 586       # just throw further
 587       die $suberror
 588     }
 589   }
 590   elsif (
 591     # a ref evaluating to '' is definitively a "null object"
 592     ( not $not_blank )
 593       and
 594     length( my $class = ref $e )
 595   ) {
 596     carp_unique(
 597       "Objects of external exception class '$class' stringify to '' (the "
 598     . 'empty string), implementing the so called null-object-pattern. '
 599     . 'Given Perl\'s "globally cooperative" exception handling using this '
 600     . 'class of exceptions is extremely dangerous, as it may (and often '
 601     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 602     . 'work around this as much as possible, but other parts of your '
 603     . 'software stack may not be even aware of the problem. Please submit '
 604     . "a bugreport against the distribution containing '$class'",
 605     );
 606
 607     $not_blank = 1;
 608   }
 609
 610   return $not_blank;
 611 }
 612
 613 {
 614   my $callstack_state;
 615
 616   # Recreate the logic of Try::Tiny, but without the crazy Sub::Name
 617   # invocations and without support for finally() altogether
 618   # ( yes, these days Try::Tiny is so "tiny" it shows *ON TOP* of most
 619   #   random profiles https://youtu.be/PYCbumw0Fis?t=1919 )
 620   sub dbic_internal_try (&;@) {
 621
 622     my $try_cref = shift;
 623     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 624
 625     for my $arg (@_) {
 626
 627       croak 'dbic_internal_try() may not be followed by multiple dbic_internal_catch() blocks'
 628         if $catch_cref;
 629
 630       ($catch_cref = $$arg), next
 631         if ref($arg) eq 'DBIx::Class::_Util::Catch';
 632
 633       croak( 'Mixing dbic_internal_try() with Try::Tiny::catch() is not supported' )
 634         if ref($arg) eq 'Try::Tiny::Catch';
 635
 636       croak( 'dbic_internal_try() does not support finally{}' )
 637         if ref($arg) eq 'Try::Tiny::Finally';
 638
 639       croak(
 640         'dbic_internal_try() encountered an unexpected argument '
 641       . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 642       . 'a missing semi-colon before or ' # trailing space important
 643       );
 644     }
 645
 646     my $wantarray = wantarray;
 647     my $preexisting_exception = $@;
 648
 649     my @ret;
 650     my $saul_goodman = eval {
 651       $@ = $preexisting_exception;
 652
 653       local $callstack_state->{in_internal_try} = 1
 654         unless $callstack_state->{in_internal_try};
 655
 656       # always unset - someone may have snuck it in
 657       local $SIG{__DIE__} if $SIG{__DIE__};
 658
 659       if( $wantarray ) {
 660         @ret = $try_cref->();
 661       }
 662       elsif( defined $wantarray ) {
 663         $ret[0] = $try_cref->();
 664       }
 665       else {
 666         $try_cref->();
 667       }
 668
 669       1;
 670     };
 671
 672     my $exception = $@;
 673     $@ = $preexisting_exception;
 674
 675     if ( $saul_goodman ) {
 676       return $wantarray ? @ret : $ret[0]
 677     }
 678     elsif ( $catch_cref ) {
 679       for ( $exception ) {
 680         return $catch_cref->($exception);
 681       }
 682     }
 683
 684     return;
 685   }
 686
 687   sub dbic_internal_catch (&;@) {
 688
 689     croak( 'Useless use of bare dbic_internal_catch()' )
 690       unless wantarray;
 691
 692     croak( 'dbic_internal_catch() must receive exactly one argument at end of expression' )
 693       if @_ > 1;
 694
 695     bless(
 696       \( $_[0] ),
 697       'DBIx::Class::_Util::Catch'
 698     ),
 699   }
 700
 701   sub in_internal_try () {
 702     !! $callstack_state->{in_internal_try}
 703   }
 704 }
 705
 706 {
 707   my $destruction_registry = {};
 708
 709   sub DBIx::Class::__Util_iThreads_handler__::CLONE {
 710     %$destruction_registry = map {
 711       (defined $_)
 712         ? ( refaddr($_) => $_ )
 713         : ()
 714     } values %$destruction_registry;
 715
 716     weaken($_) for values %$destruction_registry;
 717
 718     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 719     # collected before leaving this scope. Depending on the code above, this
 720     # may very well be just a preventive measure guarding future modifications
 721     undef;
 722   }
 723
 724   # This is almost invariably invoked from within DESTROY
 725   # throwing exceptions won't work
 726   sub detected_reinvoked_destructor {
 727
 728     # quick "garbage collection" pass - prevents the registry
 729     # from slowly growing with a bunch of undef-valued keys
 730     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 731       for keys %$destruction_registry;
 732
 733     if (! length ref $_[0]) {
 734       emit_loud_diag(
 735         emit_dups => 1,
 736         msg => (caller(0))[3] . '() expects a blessed reference'
 737       );
 738       return undef; # don't know wtf to do
 739     }
 740     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 741       weaken( $destruction_registry->{$addr} = $_[0] );
 742       return 0;
 743     }
 744     else {
 745       emit_loud_diag( msg => sprintf (
 746         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 747       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 748       . 'application, affecting *ALL* classes without active protection against '
 749       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 750       refdesc $_[0],
 751         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 752           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 753           : ''
 754         )
 755       ));
 756
 757       return 1;
 758     }
 759   }
 760 }
 761
 762 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 763 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 764
 765 sub modver_gt_or_eq ($$) {
 766   my ($mod, $ver) = @_;
 767
 768   croak "Nonsensical module name supplied"
 769     if ! defined $mod or $mod !~ $module_name_rx;
 770
 771   croak "Nonsensical minimum version supplied"
 772     if ! defined $ver or $ver !~ $ver_rx;
 773
 774   my $ver_cache = do {
 775     no strict 'refs';
 776     ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= {}
 777   };
 778
 779   ! defined $ver_cache->{$ver}
 780     and
 781   $ver_cache->{$ver} = do {
 782
 783     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 784       if SPURIOUS_VERSION_CHECK_WARNINGS;
 785
 786     # prevent captures by potential __WARN__ hooks or the like:
 787     # there is nothing of value that can be happening here, and
 788     # leaving a hook in-place can only serve to fail some test
 789     local $SIG{__WARN__} if (
 790       ! SPURIOUS_VERSION_CHECK_WARNINGS
 791         and
 792       $SIG{__WARN__}
 793     );
 794
 795     croak "$mod does not seem to provide a version (perhaps it never loaded)"
 796       unless $mod->VERSION;
 797
 798     local $SIG{__DIE__} if $SIG{__DIE__};
 799     local $@;
 800     eval { $mod->VERSION($ver) } ? 1 : 0;
 801   };
 802
 803   $ver_cache->{$ver};
 804 }
 805
 806 sub modver_gt_or_eq_and_lt ($$$) {
 807   my ($mod, $v_ge, $v_lt) = @_;
 808
 809   croak "Nonsensical maximum version supplied"
 810     if ! defined $v_lt or $v_lt !~ $ver_rx;
 811
 812   return (
 813     modver_gt_or_eq($mod, $v_ge)
 814       and
 815     ! modver_gt_or_eq($mod, $v_lt)
 816   ) ? 1 : 0;
 817 }
 818
 819 {
 820
 821   sub describe_class_methods {
 822     my $args = (
 823       ref $_[0] eq 'HASH'                 ? $_[0]
 824     : ( @_ == 1 and ! length ref $_[0] )  ? { class => $_[0] }
 825     :                                       { @_ }
 826     );
 827
 828     my ($class, $requested_mro) = @{$args}{qw( class use_mro )};
 829
 830     croak "Expecting a class name either as the sole argument or a 'class' option"
 831       if not defined $class or $class !~ $module_name_rx;
 832
 833     croak(
 834       "The supplied 'class' argument is tainted: this is *extremely* "
 835     . 'dangerous, fix your code ASAP!!! ( for more details read through '
 836     . 'https://is.gd/perl_mro_taint_wtf )'
 837     ) if (
 838       DBIx::Class::_ENV_::TAINT_MODE
 839         and
 840       Scalar::Util::tainted($class)
 841     );
 842
 843     $requested_mro ||= mro::get_mro($class);
 844
 845     # mro::set_mro() does not bump pkg_gen - WHAT THE FUCK?!
 846     my $query_cache_key = "$class|$requested_mro";
 847
 848     my $internal_cache_key =
 849       ( mro::get_mro($class) eq $requested_mro )
 850         ? $class
 851         : $query_cache_key
 852     ;
 853
 854     # use a cache on old MRO, since while we are recursing in this function
 855     # nothing can possibly change (the speedup is immense)
 856     # (yes, people could be tie()ing the stash and adding methods on access
 857     # but there is a limit to how much crazy can be supported here)
 858     #
 859     # we use the cache for linear_isa lookups on new MRO as well - it adds
 860     # a *tiny* speedup, and simplifies the code a lot
 861     #
 862     local $__describe_class_query_cache->{'!internal!'} = {}
 863       unless $__describe_class_query_cache->{'!internal!'};
 864
 865     my $my_gen = 0;
 866
 867     $my_gen += get_real_pkg_gen($_) for ( my @full_ISA = (
 868
 869       @{
 870         $__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa}
 871           ||=
 872         mro::get_linear_isa($class, $requested_mro)
 873       },
 874
 875       ((
 876         $__describe_class_query_cache->{'!internal!'}{$class}{is_universal}
 877           ||=
 878         mro::is_universal($class)
 879       ) ? () : @{
 880         $__describe_class_query_cache->{'!internal!'}{UNIVERSAL}{linear_isa}
 881           ||=
 882         mro::get_linear_isa("UNIVERSAL")
 883       }),
 884
 885     ));
 886
 887     my $slot = $__describe_class_query_cache->{$query_cache_key} ||= {};
 888
 889     unless ( ($slot->{cumulative_gen}||0) == $my_gen ) {
 890
 891       # reset
 892       %$slot = (
 893         class => $class,
 894         isa => { map { $_ => 1 } @full_ISA },
 895         linear_isa => [
 896           @{ $__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa} }
 897             [ 1 .. $#{$__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa}} ]
 898         ],
 899         mro => {
 900           type => $requested_mro,
 901           is_c3 => ( ($requested_mro eq 'c3') ? 1 : 0 ),
 902         },
 903         cumulative_gen => $my_gen,
 904       );
 905
 906       # remove ourselves from ISA
 907       shift @full_ISA;
 908
 909       # ensure the cache is populated for the parents, code below can then
 910       # efficiently operate over the query_cache directly
 911       describe_class_methods($_) for reverse @full_ISA;
 912
 913       no strict 'refs';
 914
 915       # combine full ISA-order inherited and local method list into a
 916       # "shadowing stack"
 917
 918       (
 919         unshift @{ $slot->{methods}{$_->{name}} }, $_
 920
 921           and
 922
 923         (
 924           $_->{via_class} ne $class
 925             or
 926           $slot->{methods_defined_in_class}{$_->{name}} = $_
 927         )
 928
 929           and
 930
 931         @{ $slot->{methods}{$_->{name}} } > 1
 932
 933           and
 934
 935         $slot->{methods_with_supers}{$_->{name}} = $slot->{methods}{$_->{name}}
 936
 937       ) for (
 938
 939         # what describe_class_methods for @full_ISA produced above
 940         ( map { values %{
 941           $__describe_class_query_cache->{$_}{methods_defined_in_class} || {}
 942         } } map { "$_|" . mro::get_mro($_) } reverse @full_ISA ),
 943
 944         # our own non-cleaned subs + their attributes
 945         ( map {
 946           (
 947             # need to account for dummy helper crefs under OLD_MRO
 948             (
 949               ! DBIx::Class::_ENV_::OLD_MRO
 950                 or
 951               ! ( ( $Class::C3::MRO{$class} || {} )->{methods}{$_} )
 952             )
 953               and
 954             # these 2 OR-ed checks are sufficient for 5.10+
 955             (
 956               ref(\ "${class}::"->{$_} ) ne 'GLOB'
 957                 or
 958               defined( *{ "${class}::"->{$_} }{CODE} )
 959             )
 960           ) ? {
 961               via_class => $class,
 962               name => $_,
 963               attributes => { map { $_ => 1 } do {
 964                 my @attrs;
 965                 local $@;
 966                 local $SIG{__DIE__} if $SIG{__DIE__};
 967                 # attributes::get may throw on blessed-false crefs :/
 968                 eval { @attrs = attributes::get( \&{"${class}::${_}"} ); 1 }
 969                   or warn "Unable to determine attributes of the \\&${class}::$_ method due to following error: $@";
 970                 @attrs;
 971               } },
 972             }
 973             : ()
 974         } keys %{"${class}::"} )
 975       );
 976
 977
 978       # recalculate the pkg_gen on newer perls under Taint mode,
 979       # because of shit like:
 980       # perl -T -Mmro -e 'package Foo; sub bar {}; defined( *{ "Foo::"->{bar}}{CODE} ) and warn mro::get_pkg_gen("Foo") for (1,2,3)'
 981       #
 982       if (
 983         ! DBIx::Class::_ENV_::OLD_MRO
 984           and
 985         DBIx::Class::_ENV_::TAINT_MODE
 986       ) {
 987
 988         $slot->{cumulative_gen} = 0;
 989         $slot->{cumulative_gen} += get_real_pkg_gen($_)
 990           for $class, @full_ISA;
 991       }
 992     }
 993
 994     # RV
 995     +{ %$slot };
 996   }
 997 }
 998
 999
1000 #
1001 # Why not just use some higher-level module or at least File::Spec here?
1002 # Because:
1003 # 1)  This is a *very* rarely used function, and the deptree is large
1004 #     enough already as it is
1005 #
1006 # 2)  (more importantly) Our tooling is utter shit in this area. There
1007 #     is no comprehensive support for UNC paths in PathTools and there
1008 #     are also various small bugs in representation across different
1009 #     path-manipulation CPAN offerings.
1010 #
1011 # Since this routine is strictly used for logical path processing (it
1012 # *must* be able to work with not-yet-existing paths), use this seemingly
1013 # simple but I *think* complete implementation to feed to other consumers
1014 #
1015 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
1016 # the impulse to bring in an external dependency. During runtime there
1017 # is exactly one spot that could potentially maybe once in a blue moon
1018 # use this function. Keep it lean.
1019 #
1020 sub parent_dir ($) {
1021   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
1022     ? (
1023       $_[0]
1024         .
1025       ( ( length($1) and ! length($2) ) ? '/' : '' )
1026         .
1027       '../'
1028     )
1029     : (
1030       require File::Spec
1031         and
1032       File::Spec->catpath (
1033         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
1034         '/',
1035       )
1036     )
1037   ;
1038 }
1039
1040 sub mkdir_p ($) {
1041   require File::Path;
1042   # do not ask for a recent version, use 1.x API calls
1043   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
1044 }
1045
1046
1047 {
1048   my $list_ctx_ok_stack_marker;
1049
1050   sub fail_on_internal_wantarray () {
1051     return if $list_ctx_ok_stack_marker;
1052
1053     if (! defined wantarray) {
1054       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
1055     }
1056
1057     my $cf = 1;
1058     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
1059
1060       # these are public API parts that alter behavior on wantarray
1061       search | search_related | slice | search_literal
1062
1063         |
1064
1065       # these are explicitly prefixed, since we only recognize them as valid
1066       # escapes when they come from the guts of CDBICompat
1067       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
1068
1069     ) $/x ) {
1070       $cf++;
1071     }
1072
1073     my ($fr, $want, $argdesc);
1074     {
1075       package DB;
1076       $fr = [ CORE::caller($cf) ];
1077       $want = ( CORE::caller($cf-1) )[5];
1078       $argdesc = ref $DB::args[0]
1079         ? DBIx::Class::_Util::refdesc($DB::args[0])
1080         : 'non '
1081       ;
1082     };
1083
1084     if (
1085       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
1086     ) {
1087       DBIx::Class::Exception->throw( sprintf (
1088         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
1089         $argdesc, @{$fr}[1,2]
1090       ), 'with_stacktrace');
1091     }
1092
1093     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
1094
1095     $mark;
1096   }
1097 }
1098
1099 sub fail_on_internal_call {
1100   my ($fr, $argdesc);
1101   {
1102     package DB;
1103     $fr = [ CORE::caller(1) ];
1104     $argdesc =
1105       ( not defined $DB::args[0] )  ? 'UNAVAILABLE'
1106     : ( length ref $DB::args[0] )   ? DBIx::Class::_Util::refdesc($DB::args[0])
1107     : $DB::args[0] . ''
1108     ;
1109   };
1110
1111   my @fr2;
1112   # need to make allowance for a proxy-yet-direct call
1113   my $check_fr = (
1114     $fr->[0] eq 'DBIx::Class::ResultSourceProxy'
1115       and
1116     @fr2 = (CORE::caller(2))
1117       and
1118     (
1119       ( $fr->[3] =~ /([^:])+$/ )[0]
1120         eq
1121       ( $fr2[3] =~ /([^:])+$/ )[0]
1122     )
1123   )
1124     ? \@fr2
1125     : $fr
1126   ;
1127
1128
1129   die "\nMethod $fr->[3] is not marked with the 'DBIC_method_is_indirect_sugar' attribute\n\n" unless (
1130
1131     # unlikely but who knows...
1132     ! @$fr
1133
1134       or
1135
1136     # This is a weird-ass double-purpose method, only one branch of which is marked
1137     # as an illegal indirect call
1138     # Hence the 'indirect' attribute makes no sense
1139     # FIXME - likely need to mark this in some other manner
1140     $fr->[3] eq 'DBIx::Class::ResultSet::new'
1141
1142       or
1143
1144     # RsrcProxy stuff is special and not attr-annotated on purpose
1145     # Yet it is marked (correctly) as fail_on_internal_call(), as DBIC
1146     # itself should not call these methods as first-entry
1147     $fr->[3] =~ /^DBIx::Class::ResultSourceProxy::[^:]+$/
1148
1149       or
1150
1151     # FIXME - there is likely a more fine-graned way to escape "foreign"
1152     # callers, based on annotations... (albeit a slower one)
1153     # For the time being just skip in a dumb way
1154     $fr->[3] !~ /^DBIx::Class|^DBICx::|^DBICTest::/
1155
1156       or
1157
1158     grep
1159       { $_ eq 'DBIC_method_is_indirect_sugar' }
1160       do { no strict 'refs'; attributes::get( \&{ $fr->[3] }) }
1161   );
1162
1163
1164   if (
1165     defined $fr->[0]
1166       and
1167     $check_fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
1168       and
1169     $check_fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
1170   ) {
1171     DBIx::Class::Exception->throw( sprintf (
1172       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
1173       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
1174         require B::Deparse;
1175         no strict 'refs';
1176         B::Deparse->new->coderef2text(\&{$fr->[3]})
1177       }),
1178     ), 'with_stacktrace');
1179   }
1180 }
1181
1182 if (DBIx::Class::_ENV_::ASSERT_NO_ERRONEOUS_METAINSTANCE_USE) {
1183
1184   no warnings 'redefine';
1185
1186   my $next_bless = defined(&CORE::GLOBAL::bless)
1187     ? \&CORE::GLOBAL::bless
1188     : sub { CORE::bless($_[0], $_[1]) }
1189   ;
1190
1191   *CORE::GLOBAL::bless = sub {
1192     my $class = (@_ > 1) ? $_[1] : CORE::caller();
1193
1194     # allow for reblessing (role application)
1195     return $next_bless->( $_[0], $class )
1196       if defined blessed $_[0];
1197
1198     my $obj = $next_bless->( $_[0], $class );
1199
1200     my $calling_sub = (CORE::caller(1))[3] || '';
1201
1202     (
1203       # before 5.18 ->isa() will choke on the "0" package
1204       # which we test for in several obscure cases, sigh...
1205       !( DBIx::Class::_ENV_::PERL_VERSION < 5.018 )
1206         or
1207       $class
1208     )
1209       and
1210     (
1211       (
1212         $calling_sub !~ /^ (?:
1213           DBIx::Class::Schema::clone
1214             |
1215           DBIx::Class::DB::setup_schema_instance
1216         )/x
1217           and
1218         $class->isa("DBIx::Class::Schema")
1219       )
1220         or
1221       (
1222         $calling_sub ne 'DBIx::Class::ResultSource::new'
1223           and
1224         $class->isa("DBIx::Class::ResultSource")
1225       )
1226     )
1227       and
1228     local $Carp::CarpLevel = $Carp::CarpLevel + 1
1229       and
1230     Carp::confess("Improper instantiation of '$obj': you *MUST* call the corresponding constructor");
1231
1232
1233     $obj;
1234   };
1235 }
1236
1237 1;