lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     DBICTEST => $INC{"DBICTest/Util.pm"} ? 1 : 0,
  25
  26     # During 5.13 dev cycle HELEMs started to leak on copy
  27     # add an escape for these perls ON SMOKERS - a user will still get death
  28     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ( "$]" >= 5.013005 and "$]" <= 5.013006) ),
  29
  30     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  31
  32     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  33
  34     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  35
  36     STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE => $ENV{DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE} ? 1 : 0,
  37
  38     STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE => $ENV{DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE} ? 1 : 0,
  39
  40     IV_SIZE => $Config{ivsize},
  41
  42     OS_NAME => $^O,
  43   };
  44
  45   if ( "$]" < 5.009_005) {
  46     require MRO::Compat;
  47     constant->import( OLD_MRO => 1 );
  48   }
  49   else {
  50     require mro;
  51     constant->import( OLD_MRO => 0 );
  52   }
  53 }
  54
  55 # FIXME - this is not supposed to be here
  56 # Carp::Skip to the rescue soon
  57 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  58
  59 use B ();
  60 use Carp 'croak';
  61 use Storable 'nfreeze';
  62 use Scalar::Util qw(weaken blessed reftype refaddr);
  63 use List::Util qw(first);
  64 use Sub::Quote qw(qsub quote_sub);
  65
  66 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  67 BEGIN { *deep_clone = \&Storable::dclone }
  68
  69 use base 'Exporter';
  70 our @EXPORT_OK = qw(
  71   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  72   fail_on_internal_wantarray fail_on_internal_call
  73   refdesc refcount hrefaddr is_exception detected_reinvoked_destructor
  74   quote_sub qsub perlstring serialize deep_clone
  75   UNRESOLVABLE_CONDITION
  76 );
  77
  78 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  79
  80 sub sigwarn_silencer ($) {
  81   my $pattern = shift;
  82
  83   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  84
  85   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  86
  87   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  88 }
  89
  90 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
  91
  92 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
  93
  94 sub refdesc ($) {
  95   croak "Expecting a reference" if ! length ref $_[0];
  96
  97   # be careful not to trigger stringification,
  98   # reuse @_ as a scratch-pad
  99   sprintf '%s%s(0x%x)',
 100     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 101     reftype $_[0],
 102     refaddr($_[0]),
 103   ;
 104 }
 105
 106 sub refcount ($) {
 107   croak "Expecting a reference" if ! length ref $_[0];
 108
 109   # No tempvars - must operate on $_[0], otherwise the pad
 110   # will count as an extra ref
 111   B::svref_2object($_[0])->REFCNT;
 112 }
 113
 114 sub serialize ($) {
 115   local $Storable::canonical = 1;
 116   nfreeze($_[0]);
 117 }
 118
 119 sub is_exception ($) {
 120   my $e = $_[0];
 121
 122   # this is not strictly correct - an eval setting $@ to undef
 123   # is *not* the same as an eval setting $@ to ''
 124   # but for the sake of simplicity assume the following for
 125   # the time being
 126   return 0 unless defined $e;
 127
 128   my ($not_blank, $suberror);
 129   {
 130     local $@;
 131     eval {
 132       $not_blank = ($e ne '') ? 1 : 0;
 133       1;
 134     } or $suberror = $@;
 135   }
 136
 137   if (defined $suberror) {
 138     if (length (my $class = blessed($e) )) {
 139       carp_unique( sprintf(
 140         'External exception class %s implements partial (broken) overloading '
 141       . 'preventing its instances from being used in simple ($x eq $y) '
 142       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 143       . 'handling this type of brokenness is extremely dangerous on '
 144       . 'exception objects, as it may (and often does) result in silent '
 145       . '"exception substitution". DBIx::Class tries to work around this '
 146       . 'as much as possible, but other parts of your software stack may '
 147       . 'not be even aware of this. Please submit a bugreport against the '
 148       . 'distribution containing %s and in the meantime apply a fix similar '
 149       . 'to the one shown at %s, in order to ensure your exception handling '
 150       . 'is saner application-wide. What follows is the actual error text '
 151       . "as generated by Perl itself:\n\n%s\n ",
 152         $class,
 153         $class,
 154         'http://v.gd/DBIC_overload_tempfix/',
 155         $suberror,
 156       ));
 157
 158       # workaround, keeps spice flowing
 159       $not_blank = ("$e" ne '') ? 1 : 0;
 160     }
 161     else {
 162       # not blessed yet failed the 'ne'... this makes 0 sense...
 163       # just throw further
 164       die $suberror
 165     }
 166   }
 167   elsif (
 168     # a ref evaluating to '' is definitively a "null object"
 169     ( not $not_blank )
 170       and
 171     length( my $class = ref $e )
 172   ) {
 173     carp_unique( sprintf(
 174       "Objects of external exception class '%s' stringify to '' (the "
 175     . 'empty string), implementing the so called null-object-pattern. '
 176     . 'Given Perl\'s "globally cooperative" exception handling using this '
 177     . 'class of exceptions is extremely dangerous, as it may (and often '
 178     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 179     . 'work around this as much as possible, but other parts of your '
 180     . 'software stack may not be even aware of the problem. Please submit '
 181     . 'a bugreport against the distribution containing %s.',
 182
 183       ($class) x 2,
 184     ));
 185
 186     $not_blank = 1;
 187   }
 188
 189   return $not_blank;
 190 }
 191
 192 {
 193   my $destruction_registry = {};
 194
 195   sub CLONE {
 196     $destruction_registry = { map
 197       { defined $_ ? ( refaddr($_) => $_ ) : () }
 198       values %$destruction_registry
 199     };
 200   }
 201
 202   # This is almost invariably invoked from within DESTROY
 203   # throwing exceptions won't work
 204   sub detected_reinvoked_destructor {
 205
 206     # quick "garbage collection" pass - prevents the registry
 207     # from slowly growing with a bunch of undef-valued keys
 208     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 209       for keys %$destruction_registry;
 210
 211     if (! length ref $_[0]) {
 212       printf STDERR '%s() expects a blessed reference %s',
 213         (caller(0))[3],
 214         Carp::longmess,
 215       ;
 216       return undef; # don't know wtf to do
 217     }
 218     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 219       weaken( $destruction_registry->{$addr} = $_[0] );
 220       return 0;
 221     }
 222     else {
 223       carp_unique ( sprintf (
 224         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 225       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 226       . 'application, affecting *ALL* classes without active protection against '
 227       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 228       refdesc $_[0],
 229         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 230           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 231           : ''
 232         )
 233       ));
 234
 235       return 1;
 236     }
 237   }
 238 }
 239
 240 sub modver_gt_or_eq ($$) {
 241   my ($mod, $ver) = @_;
 242
 243   croak "Nonsensical module name supplied"
 244     if ! defined $mod or ! length $mod;
 245
 246   croak "Nonsensical minimum version supplied"
 247     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 248
 249   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 250     if SPURIOUS_VERSION_CHECK_WARNINGS;
 251
 252   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 253     unless $mod->VERSION;
 254
 255   local $@;
 256   eval { $mod->VERSION($ver) } ? 1 : 0;
 257 }
 258
 259 sub modver_gt_or_eq_and_lt ($$$) {
 260   my ($mod, $v_ge, $v_lt) = @_;
 261
 262   croak "Nonsensical maximum version supplied"
 263     if ! defined $v_lt or $v_lt =~ /[^0-9\.\_]/;
 264
 265   return (
 266     modver_gt_or_eq($mod, $v_ge)
 267       and
 268     ! modver_gt_or_eq($mod, $v_lt)
 269   ) ? 1 : 0;
 270 }
 271
 272 {
 273   my $list_ctx_ok_stack_marker;
 274
 275   sub fail_on_internal_wantarray () {
 276     return if $list_ctx_ok_stack_marker;
 277
 278     if (! defined wantarray) {
 279       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 280     }
 281
 282     my $cf = 1;
 283     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 284
 285       # these are public API parts that alter behavior on wantarray
 286       search | search_related | slice | search_literal
 287
 288         |
 289
 290       # these are explicitly prefixed, since we only recognize them as valid
 291       # escapes when they come from the guts of CDBICompat
 292       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 293
 294     ) $/x ) {
 295       $cf++;
 296     }
 297
 298     my ($fr, $want, $argdesc);
 299     {
 300       package DB;
 301       $fr = [ CORE::caller($cf) ];
 302       $want = ( CORE::caller($cf-1) )[5];
 303       $argdesc = ref $DB::args[0]
 304         ? DBIx::Class::_Util::refdesc($DB::args[0])
 305         : 'non '
 306       ;
 307     };
 308
 309     if (
 310       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 311     ) {
 312       DBIx::Class::Exception->throw( sprintf (
 313         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 314         $argdesc, @{$fr}[1,2]
 315       ), 'with_stacktrace');
 316     }
 317
 318     my $mark = [];
 319     weaken ( $list_ctx_ok_stack_marker = $mark );
 320     $mark;
 321   }
 322 }
 323
 324 sub fail_on_internal_call {
 325   my ($fr, $argdesc);
 326   {
 327     package DB;
 328     $fr = [ CORE::caller(1) ];
 329     $argdesc = ref $DB::args[0]
 330       ? DBIx::Class::_Util::refdesc($DB::args[0])
 331       : undef
 332     ;
 333   };
 334
 335   if (
 336     $argdesc
 337       and
 338     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 339       and
 340     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 341   ) {
 342     DBIx::Class::Exception->throw( sprintf (
 343       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 344       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 345         require B::Deparse;
 346         no strict 'refs';
 347         B::Deparse->new->coderef2text(\&{$fr->[3]})
 348       }),
 349     ), 'with_stacktrace');
 350   }
 351 }
 352
 353 1;