lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  25     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  26
  27     # During 5.13 dev cycle HELEMs started to leak on copy
  28     # add an escape for these perls ON SMOKERS - a user will still get death
  29     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  30
  31     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  32
  33     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  34
  35     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  36
  37     STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE => $ENV{DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE} ? 1 : 0,
  38
  39     STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE => $ENV{DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE} ? 1 : 0,
  40
  41     IV_SIZE => $Config{ivsize},
  42
  43     OS_NAME => $^O,
  44   };
  45
  46   if ($] < 5.009_005) {
  47     require MRO::Compat;
  48     constant->import( OLD_MRO => 1 );
  49   }
  50   else {
  51     require mro;
  52     constant->import( OLD_MRO => 0 );
  53   }
  54 }
  55
  56 # FIXME - this is not supposed to be here
  57 # Carp::Skip to the rescue soon
  58 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  59
  60 use B ();
  61 use Carp 'croak';
  62 use Storable 'nfreeze';
  63 use Scalar::Util qw(weaken blessed reftype);
  64 use List::Util qw(first);
  65
  66 # DO NOT edit away without talking to riba first, he will just put it back
  67 # BEGIN pre-Moo2 import block
  68 BEGIN {
  69   my $initial_fatal_bits = (${^WARNING_BITS}||'') & $warnings::DeadBits{all};
  70
  71   local $ENV{PERL_STRICTURES_EXTRA} = 0;
  72   # load all of these now, so that lazy-loading does not escape
  73   # the current PERL_STRICTURES_EXTRA setting
  74   require Sub::Quote;
  75   require Sub::Defer;
  76
  77   Sub::Quote->import('quote_sub');
  78   ${^WARNING_BITS} &= ( $initial_fatal_bits | ~ $warnings::DeadBits{all} );
  79 }
  80 sub qsub ($) { goto &quote_sub }  # no point depping on new Moo just for this
  81 # END pre-Moo2 import block
  82
  83 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  84 BEGIN { *deep_clone = \&Storable::dclone }
  85
  86 use base 'Exporter';
  87 our @EXPORT_OK = qw(
  88   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  89   fail_on_internal_wantarray fail_on_internal_call
  90   refdesc refcount hrefaddr is_exception
  91   quote_sub qsub perlstring serialize deep_clone
  92   UNRESOLVABLE_CONDITION
  93 );
  94
  95 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  96
  97 sub sigwarn_silencer ($) {
  98   my $pattern = shift;
  99
 100   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 101
 102   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 103
 104   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 105 }
 106
 107 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 108
 109 sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }
 110
 111 sub refdesc ($) {
 112   croak "Expecting a reference" if ! length ref $_[0];
 113
 114   # be careful not to trigger stringification,
 115   # reuse @_ as a scratch-pad
 116   sprintf '%s%s(0x%x)',
 117     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 118     reftype $_[0],
 119     Scalar::Util::refaddr($_[0]),
 120   ;
 121 }
 122
 123 sub refcount ($) {
 124   croak "Expecting a reference" if ! length ref $_[0];
 125
 126   # No tempvars - must operate on $_[0], otherwise the pad
 127   # will count as an extra ref
 128   B::svref_2object($_[0])->REFCNT;
 129 }
 130
 131 sub serialize ($) {
 132   local $Storable::canonical = 1;
 133   nfreeze($_[0]);
 134 }
 135
 136 sub is_exception ($) {
 137   my $e = $_[0];
 138
 139   # this is not strictly correct - an eval setting $@ to undef
 140   # is *not* the same as an eval setting $@ to ''
 141   # but for the sake of simplicity assume the following for
 142   # the time being
 143   return 0 unless defined $e;
 144
 145   my ($not_blank, $suberror);
 146   {
 147     local $@;
 148     eval {
 149       $not_blank = ($e ne '') ? 1 : 0;
 150       1;
 151     } or $suberror = $@;
 152   }
 153
 154   if (defined $suberror) {
 155     if (length (my $class = blessed($e) )) {
 156       carp_unique( sprintf(
 157         'External exception class %s implements partial (broken) overloading '
 158       . 'preventing its instances from being used in simple ($x eq $y) '
 159       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 160       . 'handling this type of brokenness is extremely dangerous on '
 161       . 'exception objects, as it may (and often does) result in silent '
 162       . '"exception substitution". DBIx::Class tries to work around this '
 163       . 'as much as possible, but other parts of your software stack may '
 164       . 'not be even aware of this. Please submit a bugreport against the '
 165       . 'distribution containing %s and in the meantime apply a fix similar '
 166       . 'to the one shown at %s, in order to ensure your exception handling '
 167       . 'is saner application-wide. What follows is the actual error text '
 168       . "as generated by Perl itself:\n\n%s\n ",
 169         $class,
 170         $class,
 171         'http://v.gd/DBIC_overload_tempfix/',
 172         $suberror,
 173       ));
 174
 175       # workaround, keeps spice flowing
 176       $not_blank = ("$e" ne '') ? 1 : 0;
 177     }
 178     else {
 179       # not blessed yet failed the 'ne'... this makes 0 sense...
 180       # just throw further
 181       die $suberror
 182     }
 183   }
 184
 185   return $not_blank;
 186 }
 187
 188 sub modver_gt_or_eq ($$) {
 189   my ($mod, $ver) = @_;
 190
 191   croak "Nonsensical module name supplied"
 192     if ! defined $mod or ! length $mod;
 193
 194   croak "Nonsensical minimum version supplied"
 195     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 196
 197   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 198     if SPURIOUS_VERSION_CHECK_WARNINGS;
 199
 200   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 201     unless $mod->VERSION;
 202
 203   local $@;
 204   eval { $mod->VERSION($ver) } ? 1 : 0;
 205 }
 206
 207 sub modver_gt_or_eq_and_lt ($$$) {
 208   my ($mod, $v_ge, $v_lt) = @_;
 209
 210   croak "Nonsensical maximum version supplied"
 211     if ! defined $v_lt or $v_lt =~ /[^0-9\.\_]/;
 212
 213   return (
 214     modver_gt_or_eq($mod, $v_ge)
 215       and
 216     ! modver_gt_or_eq($mod, $v_lt)
 217   ) ? 1 : 0;
 218 }
 219
 220 {
 221   my $list_ctx_ok_stack_marker;
 222
 223   sub fail_on_internal_wantarray () {
 224     return if $list_ctx_ok_stack_marker;
 225
 226     if (! defined wantarray) {
 227       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 228     }
 229
 230     my $cf = 1;
 231     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 232
 233       # these are public API parts that alter behavior on wantarray
 234       search | search_related | slice | search_literal
 235
 236         |
 237
 238       # these are explicitly prefixed, since we only recognize them as valid
 239       # escapes when they come from the guts of CDBICompat
 240       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 241
 242     ) $/x ) {
 243       $cf++;
 244     }
 245
 246     my ($fr, $want, $argdesc);
 247     {
 248       package DB;
 249       $fr = [ caller($cf) ];
 250       $want = ( caller($cf-1) )[5];
 251       $argdesc = ref $DB::args[0]
 252         ? DBIx::Class::_Util::refdesc($DB::args[0])
 253         : 'non '
 254       ;
 255     };
 256
 257     if (
 258       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 259     ) {
 260       DBIx::Class::Exception->throw( sprintf (
 261         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 262         $argdesc, @{$fr}[1,2]
 263       ), 'with_stacktrace');
 264     }
 265
 266     my $mark = [];
 267     weaken ( $list_ctx_ok_stack_marker = $mark );
 268     $mark;
 269   }
 270 }
 271
 272 sub fail_on_internal_call {
 273   my ($fr, $argdesc);
 274   {
 275     package DB;
 276     $fr = [ caller(1) ];
 277     $argdesc = ref $DB::args[0]
 278       ? DBIx::Class::_Util::refdesc($DB::args[0])
 279       : undef
 280     ;
 281   };
 282
 283   if (
 284     $argdesc
 285       and
 286     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 287       and
 288     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 289   ) {
 290     DBIx::Class::Exception->throw( sprintf (
 291       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 292       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 293         require B::Deparse;
 294         no strict 'refs';
 295         B::Deparse->new->coderef2text(\&{$fr->[3]})
 296       }),
 297     ), 'with_stacktrace');
 298   }
 299 }
 300
 301 1;