lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  25
  26     ( map
  27       #
  28       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  29       # all envvars without further adjusting its scripts
  30       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  31       #
  32       { substr($_, 5) => !!( $ENV{$_} ) }
  33       qw(
  34         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  35         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  36         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  37         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  38         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  39       )
  40     ),
  41
  42     IV_SIZE => $Config{ivsize},
  43
  44     OS_NAME => $^O,
  45   };
  46
  47   if ( "$]" < 5.009_005) {
  48     require MRO::Compat;
  49     constant->import( OLD_MRO => 1 );
  50   }
  51   else {
  52     require mro;
  53     constant->import( OLD_MRO => 0 );
  54   }
  55
  56   # Both of these are no longer used for anything. However bring
  57   # them back after they were purged in 08a8d8f1, as there appear
  58   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
  59   # in their production codebases. There is no point in breaking these
  60   # if whatever they used actually continues to work
  61   my $warned;
  62   my $sigh = sub {
  63
  64     require Carp;
  65     my $cluck = "The @{[ (caller(1))[3] ]} constant is no more - adjust your code" . Carp::longmess();
  66
  67     warn $cluck unless $warned->{$cluck}++;
  68
  69     0;
  70   };
  71   sub DBICTEST () { &$sigh }
  72   sub PEEPEENESS () { &$sigh }
  73 }
  74
  75 # FIXME - this is not supposed to be here
  76 # Carp::Skip to the rescue soon
  77 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  78
  79 use B ();
  80 use Carp 'croak';
  81 use Storable 'nfreeze';
  82 use Scalar::Util qw(weaken blessed reftype refaddr);
  83 use Sub::Quote qw(qsub quote_sub);
  84
  85 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  86 BEGIN { *deep_clone = \&Storable::dclone }
  87
  88 use base 'Exporter';
  89 our @EXPORT_OK = qw(
  90   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  91   fail_on_internal_wantarray fail_on_internal_call
  92   refdesc refcount hrefaddr
  93   scope_guard detected_reinvoked_destructor
  94   is_exception dbic_internal_try
  95   quote_sub qsub perlstring serialize deep_clone dump_value
  96   parent_dir mkdir_p
  97   UNRESOLVABLE_CONDITION
  98 );
  99
 100 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 101
 102 sub sigwarn_silencer ($) {
 103   my $pattern = shift;
 104
 105   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 106
 107   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 108
 109   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 110 }
 111
 112 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 113
 114 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 115
 116 sub refdesc ($) {
 117   croak "Expecting a reference" if ! length ref $_[0];
 118
 119   # be careful not to trigger stringification,
 120   # reuse @_ as a scratch-pad
 121   sprintf '%s%s(0x%x)',
 122     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 123     reftype $_[0],
 124     refaddr($_[0]),
 125   ;
 126 }
 127
 128 sub refcount ($) {
 129   croak "Expecting a reference" if ! length ref $_[0];
 130
 131   # No tempvars - must operate on $_[0], otherwise the pad
 132   # will count as an extra ref
 133   B::svref_2object($_[0])->REFCNT;
 134 }
 135
 136 sub serialize ($) {
 137   local $Storable::canonical = 1;
 138   nfreeze($_[0]);
 139 }
 140
 141 my $dd_obj;
 142 sub dump_value ($) {
 143   local $Data::Dumper::Indent = 1
 144     unless defined $Data::Dumper::Indent;
 145
 146   my $dump_str = (
 147     $dd_obj
 148       ||=
 149     do {
 150       require Data::Dumper;
 151       my $d = Data::Dumper->new([])
 152         ->Purity(0)
 153         ->Pad('')
 154         ->Useqq(1)
 155         ->Terse(1)
 156         ->Freezer('')
 157         ->Quotekeys(0)
 158         ->Bless('bless')
 159         ->Pair(' => ')
 160         ->Sortkeys(1)
 161         ->Deparse(1)
 162       ;
 163
 164       $d->Sparseseen(1) if modver_gt_or_eq (
 165         'Data::Dumper', '2.136'
 166       );
 167
 168       $d;
 169     }
 170   )->Values([$_[0]])->Dump;
 171
 172   $dd_obj->Reset->Values([]);
 173
 174   $dump_str;
 175 }
 176
 177 sub scope_guard (&) {
 178   croak 'Calling scope_guard() in void context makes no sense'
 179     if ! defined wantarray;
 180
 181   # no direct blessing of coderefs - DESTROY is buggy on those
 182   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 183 }
 184 {
 185   package #
 186     DBIx::Class::_Util::ScopeGuard;
 187
 188   sub DESTROY {
 189     &DBIx::Class::_Util::detected_reinvoked_destructor;
 190
 191     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 192
 193     eval {
 194       $_[0]->[0]->();
 195       1;
 196     }
 197       or
 198     Carp::cluck(
 199       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 200     );
 201   }
 202 }
 203
 204
 205 sub is_exception ($) {
 206   my $e = $_[0];
 207
 208   # FIXME
 209   # this is not strictly correct - an eval setting $@ to undef
 210   # is *not* the same as an eval setting $@ to ''
 211   # but for the sake of simplicity assume the following for
 212   # the time being
 213   return 0 unless defined $e;
 214
 215   my ($not_blank, $suberror);
 216   {
 217     local $SIG{__DIE__} if $SIG{__DIE__};
 218     local $@;
 219     eval {
 220       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 221       # will entirely obviate the need for the encolsing eval{}, as the
 222       # condition we guard against is a missing fallback overload
 223       $not_blank = ( $e ne '' );
 224       1;
 225     } or $suberror = $@;
 226   }
 227
 228   if (defined $suberror) {
 229     if (length (my $class = blessed($e) )) {
 230       carp_unique( sprintf(
 231         'External exception class %s implements partial (broken) overloading '
 232       . 'preventing its instances from being used in simple ($x eq $y) '
 233       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 234       . 'handling this type of brokenness is extremely dangerous on '
 235       . 'exception objects, as it may (and often does) result in silent '
 236       . '"exception substitution". DBIx::Class tries to work around this '
 237       . 'as much as possible, but other parts of your software stack may '
 238       . 'not be even aware of this. Please submit a bugreport against the '
 239       . 'distribution containing %s and in the meantime apply a fix similar '
 240       . 'to the one shown at %s, in order to ensure your exception handling '
 241       . 'is saner application-wide. What follows is the actual error text '
 242       . "as generated by Perl itself:\n\n%s\n ",
 243         $class,
 244         $class,
 245         'http://v.gd/DBIC_overload_tempfix/',
 246         $suberror,
 247       ));
 248
 249       # workaround, keeps spice flowing
 250       $not_blank = !!( length $e );
 251     }
 252     else {
 253       # not blessed yet failed the 'ne'... this makes 0 sense...
 254       # just throw further
 255       die $suberror
 256     }
 257   }
 258   elsif (
 259     # a ref evaluating to '' is definitively a "null object"
 260     ( not $not_blank )
 261       and
 262     length( my $class = ref $e )
 263   ) {
 264     carp_unique( sprintf(
 265       "Objects of external exception class '%s' stringify to '' (the "
 266     . 'empty string), implementing the so called null-object-pattern. '
 267     . 'Given Perl\'s "globally cooperative" exception handling using this '
 268     . 'class of exceptions is extremely dangerous, as it may (and often '
 269     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 270     . 'work around this as much as possible, but other parts of your '
 271     . 'software stack may not be even aware of the problem. Please submit '
 272     . 'a bugreport against the distribution containing %s',
 273
 274       ($class) x 2,
 275     ));
 276
 277     $not_blank = 1;
 278   }
 279
 280   return $not_blank;
 281 }
 282
 283 {
 284   my $callstack_state;
 285
 286   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 287   #
 288   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 289   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 290   sub dbic_internal_try (&;@) {
 291
 292     my $try_cref = shift;
 293     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 294
 295     for my $arg (@_) {
 296
 297       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 298
 299         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 300           if $catch_cref;
 301
 302         $catch_cref = $$arg;
 303       }
 304       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 305         croak 'dbic_internal_try() does not support finally{}';
 306       }
 307       else {
 308         croak(
 309           'dbic_internal_try() encountered an unexpected argument '
 310         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 311         . 'a missing semi-colon before or ' # trailing space important
 312         );
 313       }
 314     }
 315
 316     my $wantarray = wantarray;
 317     my $preexisting_exception = $@;
 318
 319     my @ret;
 320     my $all_good = eval {
 321       $@ = $preexisting_exception;
 322
 323       local $callstack_state->{in_internal_try} = 1
 324         unless $callstack_state->{in_internal_try};
 325
 326       # always unset - someone may have snuck it in
 327       local $SIG{__DIE__} if $SIG{__DIE__};
 328
 329       if( $wantarray ) {
 330         @ret = $try_cref->();
 331       }
 332       elsif( defined $wantarray ) {
 333         $ret[0] = $try_cref->();
 334       }
 335       else {
 336         $try_cref->();
 337       }
 338
 339       1;
 340     };
 341
 342     my $exception = $@;
 343     $@ = $preexisting_exception;
 344
 345     if ( $all_good ) {
 346       return $wantarray ? @ret : $ret[0]
 347     }
 348     elsif ( $catch_cref ) {
 349       for ( $exception ) {
 350         return $catch_cref->($exception);
 351       }
 352     }
 353
 354     return;
 355   }
 356
 357   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 358 }
 359
 360 {
 361   my $destruction_registry = {};
 362
 363   sub CLONE {
 364     $destruction_registry = { map
 365       { defined $_ ? ( refaddr($_) => $_ ) : () }
 366       values %$destruction_registry
 367     };
 368
 369     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 370     # collected before leaving this scope. Depending on the code above, this
 371     # may very well be just a preventive measure guarding future modifications
 372     undef;
 373   }
 374
 375   # This is almost invariably invoked from within DESTROY
 376   # throwing exceptions won't work
 377   sub detected_reinvoked_destructor {
 378
 379     # quick "garbage collection" pass - prevents the registry
 380     # from slowly growing with a bunch of undef-valued keys
 381     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 382       for keys %$destruction_registry;
 383
 384     if (! length ref $_[0]) {
 385       printf STDERR '%s() expects a blessed reference %s',
 386         (caller(0))[3],
 387         Carp::longmess,
 388       ;
 389       return undef; # don't know wtf to do
 390     }
 391     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 392       weaken( $destruction_registry->{$addr} = $_[0] );
 393       return 0;
 394     }
 395     else {
 396       carp_unique ( sprintf (
 397         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 398       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 399       . 'application, affecting *ALL* classes without active protection against '
 400       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 401       refdesc $_[0],
 402         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 403           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 404           : ''
 405         )
 406       ));
 407
 408       return 1;
 409     }
 410   }
 411 }
 412
 413 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 414 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 415
 416 sub modver_gt_or_eq ($$) {
 417   my ($mod, $ver) = @_;
 418
 419   croak "Nonsensical module name supplied"
 420     if ! defined $mod or $mod !~ $module_name_rx;
 421
 422   croak "Nonsensical minimum version supplied"
 423     if ! defined $ver or $ver !~ $ver_rx;
 424
 425   no strict 'refs';
 426   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 427     ? {}
 428     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 429   );
 430
 431   ! defined $ver_cache->{$ver}
 432     and
 433   $ver_cache->{$ver} = do {
 434
 435     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 436       if SPURIOUS_VERSION_CHECK_WARNINGS;
 437
 438     local $SIG{__DIE__} if $SIG{__DIE__};
 439     local $@;
 440     eval { $mod->VERSION($ver) } ? 1 : 0;
 441   };
 442
 443   $ver_cache->{$ver};
 444 }
 445
 446 sub modver_gt_or_eq_and_lt ($$$) {
 447   my ($mod, $v_ge, $v_lt) = @_;
 448
 449   croak "Nonsensical maximum version supplied"
 450     if ! defined $v_lt or $v_lt !~ $ver_rx;
 451
 452   return (
 453     modver_gt_or_eq($mod, $v_ge)
 454       and
 455     ! modver_gt_or_eq($mod, $v_lt)
 456   ) ? 1 : 0;
 457 }
 458
 459
 460 #
 461 # Why not just use some higher-level module or at least File::Spec here?
 462 # Because:
 463 # 1)  This is a *very* rarely used function, and the deptree is large
 464 #     enough already as it is
 465 #
 466 # 2)  (more importantly) Our tooling is utter shit in this area. There
 467 #     is no comprehensive support for UNC paths in PathTools and there
 468 #     are also various small bugs in representation across different
 469 #     path-manipulation CPAN offerings.
 470 #
 471 # Since this routine is strictly used for logical path processing (it
 472 # *must* be able to work with not-yet-existing paths), use this seemingly
 473 # simple but I *think* complete implementation to feed to other consumers
 474 #
 475 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 476 # the impulse to bring in an external dependency. During runtime there
 477 # is exactly one spot that could potentially maybe once in a blue moon
 478 # use this function. Keep it lean.
 479 #
 480 sub parent_dir ($) {
 481   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 482     ? (
 483       $_[0]
 484         .
 485       ( ( length($1) and ! length($2) ) ? '/' : '' )
 486         .
 487       '../'
 488     )
 489     : (
 490       require File::Spec
 491         and
 492       File::Spec->catpath (
 493         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 494         '/',
 495       )
 496     )
 497   ;
 498 }
 499
 500 sub mkdir_p ($) {
 501   require File::Path;
 502   # do not ask for a recent version, use 1.x API calls
 503   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 504 }
 505
 506
 507 {
 508   my $list_ctx_ok_stack_marker;
 509
 510   sub fail_on_internal_wantarray () {
 511     return if $list_ctx_ok_stack_marker;
 512
 513     if (! defined wantarray) {
 514       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 515     }
 516
 517     my $cf = 1;
 518     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 519
 520       # these are public API parts that alter behavior on wantarray
 521       search | search_related | slice | search_literal
 522
 523         |
 524
 525       # these are explicitly prefixed, since we only recognize them as valid
 526       # escapes when they come from the guts of CDBICompat
 527       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 528
 529     ) $/x ) {
 530       $cf++;
 531     }
 532
 533     my ($fr, $want, $argdesc);
 534     {
 535       package DB;
 536       $fr = [ CORE::caller($cf) ];
 537       $want = ( CORE::caller($cf-1) )[5];
 538       $argdesc = ref $DB::args[0]
 539         ? DBIx::Class::_Util::refdesc($DB::args[0])
 540         : 'non '
 541       ;
 542     };
 543
 544     if (
 545       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 546     ) {
 547       DBIx::Class::Exception->throw( sprintf (
 548         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 549         $argdesc, @{$fr}[1,2]
 550       ), 'with_stacktrace');
 551     }
 552
 553     my $mark = [];
 554     weaken ( $list_ctx_ok_stack_marker = $mark );
 555     $mark;
 556   }
 557 }
 558
 559 sub fail_on_internal_call {
 560   my ($fr, $argdesc);
 561   {
 562     package DB;
 563     $fr = [ CORE::caller(1) ];
 564     $argdesc = ref $DB::args[0]
 565       ? DBIx::Class::_Util::refdesc($DB::args[0])
 566       : undef
 567     ;
 568   };
 569
 570   if (
 571     $argdesc
 572       and
 573     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 574       and
 575     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 576   ) {
 577     DBIx::Class::Exception->throw( sprintf (
 578       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 579       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 580         require B::Deparse;
 581         no strict 'refs';
 582         B::Deparse->new->coderef2text(\&{$fr->[3]})
 583       }),
 584     ), 'with_stacktrace');
 585   }
 586 }
 587
 588 1;