lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  21
  22     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  23     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  24
  25     # During 5.13 dev cycle HELEMs started to leak on copy
  26     # add an escape for these perls ON SMOKERS - a user will still get death
  27     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  28
  29     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  30
  31     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  32
  33     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  34
  35     IV_SIZE => $Config{ivsize},
  36
  37     OS_NAME => $^O,
  38   };
  39
  40   if ($] < 5.009_005) {
  41     require MRO::Compat;
  42     constant->import( OLD_MRO => 1 );
  43   }
  44   else {
  45     require mro;
  46     constant->import( OLD_MRO => 0 );
  47   }
  48 }
  49
  50 # FIXME - this is not supposed to be here
  51 # Carp::Skip to the rescue soon
  52 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  53
  54 use Carp 'croak';
  55 use Scalar::Util qw(weaken blessed reftype);
  56 use List::Util qw(first);
  57
  58 # DO NOT edit away without talking to riba first, he will just put it back
  59 # BEGIN pre-Moo2 import block
  60 BEGIN {
  61   my $initial_fatal_bits = (${^WARNING_BITS}||'') & $warnings::DeadBits{all};
  62   local $ENV{PERL_STRICTURES_EXTRA} = 0;
  63   require Sub::Quote; Sub::Quote->import('quote_sub');
  64   ${^WARNING_BITS} &= ( $initial_fatal_bits | ~ $warnings::DeadBits{all} );
  65 }
  66 sub qsub ($) { goto &quote_sub }  # no point depping on new Moo just for this
  67 # END pre-Moo2 import block
  68
  69 use base 'Exporter';
  70 our @EXPORT_OK = qw(
  71   sigwarn_silencer modver_gt_or_eq
  72   fail_on_internal_wantarray fail_on_internal_call
  73   refdesc refcount hrefaddr is_exception
  74   quote_sub qsub perlstring
  75   UNRESOLVABLE_CONDITION
  76 );
  77
  78 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  79
  80 sub sigwarn_silencer ($) {
  81   my $pattern = shift;
  82
  83   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  84
  85   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  86
  87   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  88 }
  89
  90 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
  91
  92 sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }
  93
  94 sub refdesc ($) {
  95   croak "Expecting a reference" if ! length ref $_[0];
  96
  97   # be careful not to trigger stringification,
  98   # reuse @_ as a scratch-pad
  99   sprintf '%s%s(0x%x)',
 100     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 101     reftype $_[0],
 102     Scalar::Util::refaddr($_[0]),
 103   ;
 104 }
 105
 106 sub refcount ($) {
 107   croak "Expecting a reference" if ! length ref $_[0];
 108
 109   require B;
 110   # No tempvars - must operate on $_[0], otherwise the pad
 111   # will count as an extra ref
 112   B::svref_2object($_[0])->REFCNT;
 113 }
 114
 115 sub is_exception ($) {
 116   my $e = $_[0];
 117
 118   # this is not strictly correct - an eval setting $@ to undef
 119   # is *not* the same as an eval setting $@ to ''
 120   # but for the sake of simplicity assume the following for
 121   # the time being
 122   return 0 unless defined $e;
 123
 124   my ($not_blank, $suberror);
 125   {
 126     local $@;
 127     eval {
 128       $not_blank = ($e ne '') ? 1 : 0;
 129       1;
 130     } or $suberror = $@;
 131   }
 132
 133   if (defined $suberror) {
 134     if (length (my $class = blessed($e) )) {
 135       carp_unique( sprintf(
 136         'External exception class %s implements partial (broken) overloading '
 137       . 'preventing its instances from being used in simple ($x eq $y) '
 138       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 139       . 'handling this type of brokenness is extremely dangerous on '
 140       . 'exception objects, as it may (and often does) result in silent '
 141       . '"exception substitution". DBIx::Class tries to work around this '
 142       . 'as much as possible, but other parts of your software stack may '
 143       . 'not be even aware of this. Please submit a bugreport against the '
 144       . 'distribution containing %s and in the meantime apply a fix similar '
 145       . 'to the one shown at %s, in order to ensure your exception handling '
 146       . 'is saner application-wide. What follows is the actual error text '
 147       . "as generated by Perl itself:\n\n%s\n ",
 148         $class,
 149         $class,
 150         'http://v.gd/DBIC_overload_tempfix/',
 151         $suberror,
 152       ));
 153
 154       # workaround, keeps spice flowing
 155       $not_blank = ("$e" ne '') ? 1 : 0;
 156     }
 157     else {
 158       # not blessed yet failed the 'ne'... this makes 0 sense...
 159       # just throw further
 160       die $suberror
 161     }
 162   }
 163
 164   return $not_blank;
 165 }
 166
 167 sub modver_gt_or_eq ($$) {
 168   my ($mod, $ver) = @_;
 169
 170   croak "Nonsensical module name supplied"
 171     if ! defined $mod or ! length $mod;
 172
 173   croak "Nonsensical minimum version supplied"
 174     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 175
 176   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 177     if SPURIOUS_VERSION_CHECK_WARNINGS;
 178
 179   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 180     unless $mod->VERSION;
 181
 182   local $@;
 183   eval { $mod->VERSION($ver) } ? 1 : 0;
 184 }
 185
 186 {
 187   my $list_ctx_ok_stack_marker;
 188
 189   sub fail_on_internal_wantarray () {
 190     return if $list_ctx_ok_stack_marker;
 191
 192     if (! defined wantarray) {
 193       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 194     }
 195
 196     my $cf = 1;
 197     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 198
 199       # these are public API parts that alter behavior on wantarray
 200       search | search_related | slice | search_literal
 201
 202         |
 203
 204       # these are explicitly prefixed, since we only recognize them as valid
 205       # escapes when they come from the guts of CDBICompat
 206       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 207
 208     ) $/x ) {
 209       $cf++;
 210     }
 211
 212     my ($fr, $want, $argdesc);
 213     {
 214       package DB;
 215       $fr = [ caller($cf) ];
 216       $want = ( caller($cf-1) )[5];
 217       $argdesc = ref $DB::args[0]
 218         ? DBIx::Class::_Util::refdesc($DB::args[0])
 219         : 'non '
 220       ;
 221     };
 222
 223     if (
 224       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 225     ) {
 226       DBIx::Class::Exception->throw( sprintf (
 227         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 228         $argdesc, @{$fr}[1,2]
 229       ), 'with_stacktrace');
 230     }
 231
 232     my $mark = [];
 233     weaken ( $list_ctx_ok_stack_marker = $mark );
 234     $mark;
 235   }
 236 }
 237
 238 sub fail_on_internal_call {
 239   my ($fr, $argdesc);
 240   {
 241     package DB;
 242     $fr = [ caller(1) ];
 243     $argdesc = ref $DB::args[0]
 244       ? DBIx::Class::_Util::refdesc($DB::args[0])
 245       : undef
 246     ;
 247   };
 248
 249   if (
 250     $argdesc
 251       and
 252     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 253       and
 254     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 255   ) {
 256     DBIx::Class::Exception->throw( sprintf (
 257       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 258       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 259         require B::Deparse;
 260         no strict 'refs';
 261         B::Deparse->new->coderef2text(\&{$fr->[3]})
 262       }),
 263     ), 'with_stacktrace');
 264   }
 265 }
 266
 267 1;