lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 # Temporary - tempextlib
   8 use namespace::clean;
   9 BEGIN {
  10   require Module::Runtime;
  11   require File::Spec;
  12
  13   # There can be only one of these, make sure we get the bundled part and
  14   # *not* something off the site lib
  15   for (qw(
  16     DBIx::Class::SQLMaker
  17     SQL::Abstract
  18     SQL::Abstract::Test
  19   )) {
  20     if ($INC{Module::Runtime::module_notional_filename($_)}) {
  21       die "\nUnable to continue - a part of the bundled templib contents "
  22         . "was already loaded (likely an older version from CPAN). "
  23         . "Make sure that @{[ __PACKAGE__ ]} is loaded before $_\n\n"
  24       ;
  25     }
  26   }
  27
  28   our ($HERE) = File::Spec->rel2abs(
  29     File::Spec->catdir( (File::Spec->splitpath(__FILE__))[1], '_TempExtlib' )
  30   ) =~ /^(.*)$/; # screw you, taint mode
  31
  32   die "TempExtlib $HERE does not seem to exist - perhaps you need to run `perl Makefile.PL` in the DBIC checkout?\n"
  33     unless -d $HERE;
  34
  35   unshift @INC, $HERE;
  36 }
  37
  38 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
  39
  40 BEGIN {
  41   package # hide from pause
  42     DBIx::Class::_ENV_;
  43
  44   use Config;
  45
  46   use constant {
  47
  48     # but of course
  49     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  50
  51     BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
  52
  53     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  54
  55     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  56     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  57
  58     # During 5.13 dev cycle HELEMs started to leak on copy
  59     # add an escape for these perls ON SMOKERS - a user will still get death
  60     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  61
  62     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  63
  64     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  65
  66     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  67
  68     IV_SIZE => $Config{ivsize},
  69
  70     OS_NAME => $^O,
  71   };
  72
  73   if ($] < 5.009_005) {
  74     require MRO::Compat;
  75     constant->import( OLD_MRO => 1 );
  76   }
  77   else {
  78     require mro;
  79     constant->import( OLD_MRO => 0 );
  80   }
  81 }
  82
  83 # FIXME - this is not supposed to be here
  84 # Carp::Skip to the rescue soon
  85 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  86
  87 use Carp 'croak';
  88 use Scalar::Util qw(weaken blessed reftype);
  89 use List::Util qw(first);
  90
  91 # DO NOT edit away without talking to riba first, he will just put it back
  92 # BEGIN pre-Moo2 import block
  93 BEGIN {
  94   my $initial_fatal_bits = (${^WARNING_BITS}||'') & $warnings::DeadBits{all};
  95   local $ENV{PERL_STRICTURES_EXTRA} = 0;
  96   require Sub::Quote; Sub::Quote->import('quote_sub');
  97   ${^WARNING_BITS} &= ( $initial_fatal_bits | ~ $warnings::DeadBits{all} );
  98 }
  99 sub qsub ($) { goto &quote_sub }  # no point depping on new Moo just for this
 100 # END pre-Moo2 import block
 101
 102 use base 'Exporter';
 103 our @EXPORT_OK = qw(
 104   sigwarn_silencer modver_gt_or_eq
 105   fail_on_internal_wantarray fail_on_internal_call
 106   refdesc refcount hrefaddr is_exception
 107   quote_sub qsub perlstring serialize
 108   UNRESOLVABLE_CONDITION
 109 );
 110
 111 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 112
 113 sub sigwarn_silencer ($) {
 114   my $pattern = shift;
 115
 116   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 117
 118   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 119
 120   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 121 }
 122
 123 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 124
 125 sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }
 126
 127 sub refdesc ($) {
 128   croak "Expecting a reference" if ! length ref $_[0];
 129
 130   # be careful not to trigger stringification,
 131   # reuse @_ as a scratch-pad
 132   sprintf '%s%s(0x%x)',
 133     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 134     reftype $_[0],
 135     Scalar::Util::refaddr($_[0]),
 136   ;
 137 }
 138
 139 sub refcount ($) {
 140   croak "Expecting a reference" if ! length ref $_[0];
 141
 142   require B;
 143   # No tempvars - must operate on $_[0], otherwise the pad
 144   # will count as an extra ref
 145   B::svref_2object($_[0])->REFCNT;
 146 }
 147
 148 sub serialize ($) {
 149   require Storable;
 150   local $Storable::canonical = 1;
 151   Storable::nfreeze($_[0]);
 152 }
 153
 154 sub is_exception ($) {
 155   my $e = $_[0];
 156
 157   # this is not strictly correct - an eval setting $@ to undef
 158   # is *not* the same as an eval setting $@ to ''
 159   # but for the sake of simplicity assume the following for
 160   # the time being
 161   return 0 unless defined $e;
 162
 163   my ($not_blank, $suberror);
 164   {
 165     local $@;
 166     eval {
 167       $not_blank = ($e ne '') ? 1 : 0;
 168       1;
 169     } or $suberror = $@;
 170   }
 171
 172   if (defined $suberror) {
 173     if (length (my $class = blessed($e) )) {
 174       carp_unique( sprintf(
 175         'External exception class %s implements partial (broken) overloading '
 176       . 'preventing its instances from being used in simple ($x eq $y) '
 177       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 178       . 'handling this type of brokenness is extremely dangerous on '
 179       . 'exception objects, as it may (and often does) result in silent '
 180       . '"exception substitution". DBIx::Class tries to work around this '
 181       . 'as much as possible, but other parts of your software stack may '
 182       . 'not be even aware of this. Please submit a bugreport against the '
 183       . 'distribution containing %s and in the meantime apply a fix similar '
 184       . 'to the one shown at %s, in order to ensure your exception handling '
 185       . 'is saner application-wide. What follows is the actual error text '
 186       . "as generated by Perl itself:\n\n%s\n ",
 187         $class,
 188         $class,
 189         'http://v.gd/DBIC_overload_tempfix/',
 190         $suberror,
 191       ));
 192
 193       # workaround, keeps spice flowing
 194       $not_blank = ("$e" ne '') ? 1 : 0;
 195     }
 196     else {
 197       # not blessed yet failed the 'ne'... this makes 0 sense...
 198       # just throw further
 199       die $suberror
 200     }
 201   }
 202
 203   return $not_blank;
 204 }
 205
 206 sub modver_gt_or_eq ($$) {
 207   my ($mod, $ver) = @_;
 208
 209   croak "Nonsensical module name supplied"
 210     if ! defined $mod or ! length $mod;
 211
 212   croak "Nonsensical minimum version supplied"
 213     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 214
 215   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 216     if SPURIOUS_VERSION_CHECK_WARNINGS;
 217
 218   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 219     unless $mod->VERSION;
 220
 221   local $@;
 222   eval { $mod->VERSION($ver) } ? 1 : 0;
 223 }
 224
 225 {
 226   my $list_ctx_ok_stack_marker;
 227
 228   sub fail_on_internal_wantarray () {
 229     return if $list_ctx_ok_stack_marker;
 230
 231     if (! defined wantarray) {
 232       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 233     }
 234
 235     my $cf = 1;
 236     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 237
 238       # these are public API parts that alter behavior on wantarray
 239       search | search_related | slice | search_literal
 240
 241         |
 242
 243       # these are explicitly prefixed, since we only recognize them as valid
 244       # escapes when they come from the guts of CDBICompat
 245       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 246
 247     ) $/x ) {
 248       $cf++;
 249     }
 250
 251     my ($fr, $want, $argdesc);
 252     {
 253       package DB;
 254       $fr = [ caller($cf) ];
 255       $want = ( caller($cf-1) )[5];
 256       $argdesc = ref $DB::args[0]
 257         ? DBIx::Class::_Util::refdesc($DB::args[0])
 258         : 'non '
 259       ;
 260     };
 261
 262     if (
 263       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 264     ) {
 265       DBIx::Class::Exception->throw( sprintf (
 266         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 267         $argdesc, @{$fr}[1,2]
 268       ), 'with_stacktrace');
 269     }
 270
 271     my $mark = [];
 272     weaken ( $list_ctx_ok_stack_marker = $mark );
 273     $mark;
 274   }
 275 }
 276
 277 sub fail_on_internal_call {
 278   my ($fr, $argdesc);
 279   {
 280     package DB;
 281     $fr = [ caller(1) ];
 282     $argdesc = ref $DB::args[0]
 283       ? DBIx::Class::_Util::refdesc($DB::args[0])
 284       : undef
 285     ;
 286   };
 287
 288   if (
 289     $argdesc
 290       and
 291     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 292       and
 293     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 294   ) {
 295     DBIx::Class::Exception->throw( sprintf (
 296       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 297       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 298         require B::Deparse;
 299         no strict 'refs';
 300         B::Deparse->new->coderef2text(\&{$fr->[3]})
 301       }),
 302     ), 'with_stacktrace');
 303   }
 304 }
 305
 306 1;