lib/DBIx/Class/Storage.pm

   1 package DBIx::Class::Storage;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class/;
   7
   8 use Scalar::Util qw/weaken/;
   9 use Carp::Clan qw/^DBIx::Class/;
  10
  11 __PACKAGE__->mk_group_accessors('simple' => qw/debug debugobj schema/);
  12
  13 package # Hide from PAUSE
  14     DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION;
  15
  16 use overload '"' => sub {
  17   'DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION'
  18 };
  19
  20 sub new {
  21   my $class = shift;
  22   my $self = {};
  23   return bless $self, $class;
  24 }
  25
  26 package DBIx::Class::Storage;
  27
  28 =head1 NAME
  29
  30 DBIx::Class::Storage - Generic Storage Handler
  31
  32 =head1 DESCRIPTION
  33
  34 A base implementation of common Storage methods.  For specific
  35 information about L<DBI>-based storage, see L<DBIx::Class::Storage::DBI>.
  36
  37 =head1 METHODS
  38
  39 =head2 new
  40
  41 Arguments: $schema
  42
  43 Instantiates the Storage object.
  44
  45 =cut
  46
  47 sub new {
  48   my ($self, $schema) = @_;
  49
  50   $self = ref $self if ref $self;
  51
  52   my $new = {};
  53   bless $new, $self;
  54
  55   $new->set_schema($schema);
  56   $new->debugobj(new DBIx::Class::Storage::Statistics());
  57
  58   my $fh;
  59
  60   my $debug_env = $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}
  61                   || $ENV{DBIC_TRACE};
  62
  63   if (defined($debug_env) && ($debug_env =~ /=(.+)$/)) {
  64     $fh = IO::File->new($1, 'w')
  65       or $new->throw_exception("Cannot open trace file $1");
  66   } else {
  67     $fh = IO::File->new('>&STDERR');
  68   }
  69
  70   $new->debugfh($fh);
  71   $new->debug(1) if $debug_env;
  72
  73   $new;
  74 }
  75
  76 =head2 set_schema
  77
  78 Used to reset the schema class or object which owns this
  79 storage object, such as during L<DBIx::Class::Schema/clone>.
  80
  81 =cut
  82
  83 sub set_schema {
  84   my ($self, $schema) = @_;
  85   $self->schema($schema);
  86   weaken($self->{schema}) if ref $self->{schema};
  87 }
  88
  89 =head2 connected
  90
  91 Returns true if we have an open storage connection, false
  92 if it is not (yet) open.
  93
  94 =cut
  95
  96 sub connected { die "Virtual method!" }
  97
  98 =head2 disconnect
  99
 100 Closes any open storage connection unconditionally.
 101
 102 =cut
 103
 104 sub disconnect { die "Virtual method!" }
 105
 106 =head2 ensure_connected
 107
 108 Initiate a connection to the storage if one isn't already open.
 109
 110 =cut
 111
 112 sub ensure_connected { die "Virtual method!" }
 113
 114 =head2 throw_exception
 115
 116 Throws an exception - croaks.
 117
 118 =cut
 119
 120 sub throw_exception {
 121   my $self = shift;
 122
 123   $self->schema->throw_exception(@_) if $self->schema;
 124   croak @_;
 125 }
 126
 127 =head2 txn_do
 128
 129 =over 4
 130
 131 =item Arguments: C<$coderef>, @coderef_args?
 132
 133 =item Return Value: The return value of $coderef
 134
 135 =back
 136
 137 Executes C<$coderef> with (optional) arguments C<@coderef_args> atomically,
 138 returning its result (if any). If an exception is caught, a rollback is issued
 139 and the exception is rethrown. If the rollback fails, (i.e. throws an
 140 exception) an exception is thrown that includes a "Rollback failed" message.
 141
 142 For example,
 143
 144   my $author_rs = $schema->resultset('Author')->find(1);
 145   my @titles = qw/Night Day It/;
 146
 147   my $coderef = sub {
 148     # If any one of these fails, the entire transaction fails
 149     $author_rs->create_related('books', {
 150       title => $_
 151     }) foreach (@titles);
 152
 153     return $author->books;
 154   };
 155
 156   my $rs;
 157   eval {
 158     $rs = $schema->txn_do($coderef);
 159   };
 160
 161   if ($@) {                                  # Transaction failed
 162     die "something terrible has happened!"   #
 163       if ($@ =~ /Rollback failed/);          # Rollback failed
 164
 165     deal_with_failed_transaction();
 166   }
 167
 168 In a nested transaction (calling txn_do() from within a txn_do() coderef) only
 169 the outermost transaction will issue a L</txn_commit>, and txn_do() can be
 170 called in void, scalar and list context and it will behave as expected.
 171
 172 =cut
 173
 174 sub txn_do {
 175   my ($self, $coderef, @args) = @_;
 176
 177   ref $coderef eq 'CODE' or $self->throw_exception
 178     ('$coderef must be a CODE reference');
 179
 180   my (@return_values, $return_value);
 181
 182   $self->txn_begin; # If this throws an exception, no rollback is needed
 183
 184   my $wantarray = wantarray; # Need to save this since the context
 185                              # inside the eval{} block is independent
 186                              # of the context that called txn_do()
 187   eval {
 188
 189     # Need to differentiate between scalar/list context to allow for
 190     # returning a list in scalar context to get the size of the list
 191     if ($wantarray) {
 192       # list context
 193       @return_values = $coderef->(@args);
 194     } elsif (defined $wantarray) {
 195       # scalar context
 196       $return_value = $coderef->(@args);
 197     } else {
 198       # void context
 199       $coderef->(@args);
 200     }
 201     $self->txn_commit;
 202   };
 203
 204   if ($@) {
 205     my $error = $@;
 206
 207     eval {
 208       $self->txn_rollback;
 209     };
 210
 211     if ($@) {
 212       my $rollback_error = $@;
 213       my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 214       $self->throw_exception($error)  # propagate nested rollback
 215         if $rollback_error =~ /$exception_class/;
 216
 217       $self->throw_exception(
 218         "Transaction aborted: $error. Rollback failed: ${rollback_error}"
 219       );
 220     } else {
 221       $self->throw_exception($error); # txn failed but rollback succeeded
 222     }
 223   }
 224
 225   return $wantarray ? @return_values : $return_value;
 226 }
 227
 228 =head2 txn_begin
 229
 230 Starts a transaction.
 231
 232 See the preferred L</txn_do> method, which allows for
 233 an entire code block to be executed transactionally.
 234
 235 =cut
 236
 237 sub txn_begin { die "Virtual method!" }
 238
 239 =head2 txn_commit
 240
 241 Issues a commit of the current transaction.
 242
 243 =cut
 244
 245 sub txn_commit { die "Virtual method!" }
 246
 247 =head2 txn_rollback
 248
 249 Issues a rollback of the current transaction. A nested rollback will
 250 throw a L<DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION> exception,
 251 which allows the rollback to propagate to the outermost transaction.
 252
 253 =cut
 254
 255 sub txn_rollback { die "Virtual method!" }
 256
 257 =head2 sql_maker
 258
 259 Returns a C<sql_maker> object - normally an object of class
 260 C<DBIC::SQL::Abstract>.
 261
 262 =cut
 263
 264 sub sql_maker { die "Virtual method!" }
 265
 266 =head2 debug
 267
 268 Causes trace information to be emitted on the C<debugobj> object.
 269 (or C<STDERR> if C<debugobj> has not specifically been set).
 270
 271 This is the equivalent to setting L</DBIC_TRACE> in your
 272 shell environment.
 273
 274 =head2 debugfh
 275
 276 Set or retrieve the filehandle used for trace/debug output.  This should be
 277 an IO::Handle compatible ojbect (only the C<print> method is used.  Initially
 278 set to be STDERR - although see information on the
 279 L<DBIC_TRACE> environment variable.
 280
 281 =cut
 282
 283 sub debugfh {
 284     my $self = shift;
 285
 286     if ($self->debugobj->can('debugfh')) {
 287         return $self->debugobj->debugfh(@_);
 288     }
 289 }
 290
 291 =head2 debugobj
 292
 293 Sets or retrieves the object used for metric collection. Defaults to an instance
 294 of L<DBIx::Class::Storage::Statistics> that is compatible with the original
 295 method of using a coderef as a callback.  See the aforementioned Statistics
 296 class for more information.
 297
 298 =head2 debugcb
 299
 300 Sets a callback to be executed each time a statement is run; takes a sub
 301 reference.  Callback is executed as $sub->($op, $info) where $op is
 302 SELECT/INSERT/UPDATE/DELETE and $info is what would normally be printed.
 303
 304 See L<debugobj> for a better way.
 305
 306 =cut
 307
 308 sub debugcb {
 309     my $self = shift;
 310
 311     if ($self->debugobj->can('callback')) {
 312         return $self->debugobj->callback(@_);
 313     }
 314 }
 315
 316 =head2 cursor
 317
 318 The cursor class for this Storage object.
 319
 320 =cut
 321
 322 sub cursor { die "Virtual method!" }
 323
 324 =head2 deploy
 325
 326 Deploy the tables to storage (CREATE TABLE and friends in a SQL-based
 327 Storage class). This would normally be called through
 328 L<DBIx::Class::Schema/deploy>.
 329
 330 =cut
 331
 332 sub deploy { die "Virtual method!" }
 333
 334 =head2 connect_info
 335
 336 The arguments of C<connect_info> are always a single array reference,
 337 and are Storage-handler specific.
 338
 339 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 340 encapsulates its argument list in an arrayref before calling
 341 C<connect_info> here.
 342
 343 =cut
 344
 345 sub connect_info { die "Virtual method!" }
 346
 347 =head2 select
 348
 349 Handle a select statement.
 350
 351 =cut
 352
 353 sub select { die "Virtual method!" }
 354
 355 =head2 insert
 356
 357 Handle an insert statement.
 358
 359 =cut
 360
 361 sub insert { die "Virtual method!" }
 362
 363 =head2 update
 364
 365 Handle an update statement.
 366
 367 =cut
 368
 369 sub update { die "Virtual method!" }
 370
 371 =head2 delete
 372
 373 Handle a delete statement.
 374
 375 =cut
 376
 377 sub delete { die "Virtual method!" }
 378
 379 =head2 select_single
 380
 381 Performs a select, fetch and return of data - handles a single row
 382 only.
 383
 384 =cut
 385
 386 sub select_single { die "Virtual method!" }
 387
 388 =head2 columns_info_for
 389
 390 Returns metadata for the given source's columns.  This
 391 is *deprecated*, and will be removed before 1.0.  You should
 392 be specifying the metadata yourself if you need it.
 393
 394 =cut
 395
 396 sub columns_info_for { die "Virtual method!" }
 397
 398 =head1 ENVIRONMENT VARIABLES
 399
 400 =head2 DBIC_TRACE
 401
 402 If C<DBIC_TRACE> is set then trace information
 403 is produced (as when the L<debug> method is set).
 404
 405 If the value is of the form C<1=/path/name> then the trace output is
 406 written to the file C</path/name>.
 407
 408 This environment variable is checked when the storage object is first
 409 created (when you call connect on your schema).  So, run-time changes
 410 to this environment variable will not take effect unless you also
 411 re-connect on your schema.
 412
 413 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 414
 415 Old name for DBIC_TRACE
 416
 417 =head1 AUTHORS
 418
 419 Matt S. Trout <mst@shadowcatsystems.co.uk>
 420
 421 Andy Grundman <andy@hybridized.org>
 422
 423 =head1 LICENSE
 424
 425 You may distribute this code under the same terms as Perl itself.
 426
 427 =cut
 428
 429 1;