Fix ordering by 1:M prefetched boolean columns in Pg
[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / Storage / DBIHacks.pm
1 package   #hide from PAUSE
2   DBIx::Class::Storage::DBIHacks;
3
4 #
5 # This module contains code that should never have seen the light of day,
6 # does not belong in the Storage, or is otherwise unfit for public
7 # display. The arrival of SQLA2 should immediately obsolete 90% of this
8 #
9
10 use strict;
11 use warnings;
12
13 use base 'DBIx::Class::Storage';
14 use mro 'c3';
15
16 use List::Util 'first';
17 use Scalar::Util 'blessed';
18 use DBIx::Class::_Util qw(UNRESOLVABLE_CONDITION serialize);
19 use SQL::Abstract qw(is_plain_value is_literal_value);
20 use DBIx::Class::Carp;
21 use namespace::clean;
22
23 #
24 # This code will remove non-selecting/non-restricting joins from
25 # {from} specs, aiding the RDBMS query optimizer
26 #
27 sub _prune_unused_joins {
28   my ($self, $attrs) = @_;
29
30   # only standard {from} specs are supported, and we could be disabled in general
31   return ($attrs->{from}, {})  unless (
32     ref $attrs->{from} eq 'ARRAY'
33       and
34     @{$attrs->{from}} > 1
35       and
36     ref $attrs->{from}[0] eq 'HASH'
37       and
38     ref $attrs->{from}[1] eq 'ARRAY'
39       and
40     $self->_use_join_optimizer
41   );
42
43   my $orig_aliastypes = $self->_resolve_aliastypes_from_select_args($attrs);
44
45   my $new_aliastypes = { %$orig_aliastypes };
46
47   # we will be recreating this entirely
48   my @reclassify = 'joining';
49
50   # a grouped set will not be affected by amount of rows. Thus any
51   # purely multiplicator classifications can go
52   # (will be reintroduced below if needed by something else)
53   push @reclassify, qw(multiplying premultiplied)
54     if $attrs->{_force_prune_multiplying_joins} or $attrs->{group_by};
55
56   # nuke what will be recalculated
57   delete @{$new_aliastypes}{@reclassify};
58
59   my @newfrom = $attrs->{from}[0]; # FROM head is always present
60
61   # recalculate what we need once the multipliers are potentially gone
62   # ignore premultiplies, since they do not add any value to anything
63   my %need_joins;
64   for ( @{$new_aliastypes}{grep { $_ ne 'premultiplied' } keys %$new_aliastypes }) {
65     # add all requested aliases
66     $need_joins{$_} = 1 for keys %$_;
67
68     # add all their parents (as per joinpath which is an AoH { table => alias })
69     $need_joins{$_} = 1 for map { values %$_ } map { @{$_->{-parents}} } values %$_;
70   }
71
72   for my $j (@{$attrs->{from}}[1..$#{$attrs->{from}}]) {
73     push @newfrom, $j if (
74       (! defined $j->[0]{-alias}) # legacy crap
75         ||
76       $need_joins{$j->[0]{-alias}}
77     );
78   }
79
80   # we have a new set of joiners - for everything we nuked pull the classification
81   # off the original stack
82   for my $ctype (@reclassify) {
83     $new_aliastypes->{$ctype} = { map
84       { $need_joins{$_} ? ( $_ => $orig_aliastypes->{$ctype}{$_} ) : () }
85       keys %{$orig_aliastypes->{$ctype}}
86     }
87   }
88
89   return ( \@newfrom, $new_aliastypes );
90 }
91
92 #
93 # This is the code producing joined subqueries like:
94 # SELECT me.*, other.* FROM ( SELECT me.* FROM ... ) JOIN other ON ...
95 #
96 sub _adjust_select_args_for_complex_prefetch {
97   my ($self, $attrs) = @_;
98
99   $self->throw_exception ('Complex prefetches are not supported on resultsets with a custom from attribute') unless (
100     ref $attrs->{from} eq 'ARRAY'
101       and
102     @{$attrs->{from}} > 1
103       and
104     ref $attrs->{from}[0] eq 'HASH'
105       and
106     ref $attrs->{from}[1] eq 'ARRAY'
107   );
108
109   my $root_alias = $attrs->{alias};
110
111   # generate inner/outer attribute lists, remove stuff that doesn't apply
112   my $outer_attrs = { %$attrs };
113   delete @{$outer_attrs}{qw(from bind rows offset group_by _grouped_by_distinct having)};
114
115   my $inner_attrs = { %$attrs, _simple_passthrough_construction => 1 };
116   delete @{$inner_attrs}{qw(for collapse select as)};
117
118   # there is no point of ordering the insides if there is no limit
119   delete $inner_attrs->{order_by} if (
120     delete $inner_attrs->{_order_is_artificial}
121       or
122     ! $inner_attrs->{rows}
123   );
124
125   # generate the inner/outer select lists
126   # for inside we consider only stuff *not* brought in by the prefetch
127   # on the outside we substitute any function for its alias
128   $outer_attrs->{select} = [ @{$attrs->{select}} ];
129
130   my ($root_node, $root_node_offset);
131
132   for my $i (0 .. $#{$inner_attrs->{from}}) {
133     my $node = $inner_attrs->{from}[$i];
134     my $h = (ref $node eq 'HASH')                                ? $node
135           : (ref $node  eq 'ARRAY' and ref $node->[0] eq 'HASH') ? $node->[0]
136           : next
137     ;
138
139     if ( ($h->{-alias}||'') eq $root_alias and $h->{-rsrc} ) {
140       $root_node = $h;
141       $root_node_offset = $i;
142       last;
143     }
144   }
145
146   $self->throw_exception ('Complex prefetches are not supported on resultsets with a custom from attribute')
147     unless $root_node;
148
149   # use the heavy duty resolver to take care of aliased/nonaliased naming
150   my $colinfo = $self->_resolve_column_info($inner_attrs->{from});
151   my $selected_root_columns;
152
153   for my $i (0 .. $#{$outer_attrs->{select}}) {
154     my $sel = $outer_attrs->{select}->[$i];
155
156     next if (
157       $colinfo->{$sel} and $colinfo->{$sel}{-source_alias} ne $root_alias
158     );
159
160     if (ref $sel eq 'HASH' ) {
161       $sel->{-as} ||= $attrs->{as}[$i];
162       $outer_attrs->{select}->[$i] = join ('.', $root_alias, ($sel->{-as} || "inner_column_$i") );
163     }
164     elsif (! ref $sel and my $ci = $colinfo->{$sel}) {
165       $selected_root_columns->{$ci->{-colname}} = 1;
166     }
167
168     push @{$inner_attrs->{select}}, $sel;
169
170     push @{$inner_attrs->{as}}, $attrs->{as}[$i];
171   }
172
173   # We will need to fetch all native columns in the inner subquery, which may
174   # be a part of an *outer* join condition, or an order_by (which needs to be
175   # preserved outside), or wheres. In other words everything but the inner
176   # selector
177   # We can not just fetch everything because a potential has_many restricting
178   # join collapse *will not work* on heavy data types.
179   my $connecting_aliastypes = $self->_resolve_aliastypes_from_select_args({
180     %$inner_attrs,
181     select => [],
182   });
183
184   for (sort map { keys %{$_->{-seen_columns}||{}} } map { values %$_ } values %$connecting_aliastypes) {
185     my $ci = $colinfo->{$_} or next;
186     if (
187       $ci->{-source_alias} eq $root_alias
188         and
189       ! $selected_root_columns->{$ci->{-colname}}++
190     ) {
191       # adding it to both to keep limits not supporting dark selectors happy
192       push @{$inner_attrs->{select}}, $ci->{-fq_colname};
193       push @{$inner_attrs->{as}}, $ci->{-fq_colname};
194     }
195   }
196
197   # construct the inner {from} and lock it in a subquery
198   # we need to prune first, because this will determine if we need a group_by below
199   # throw away all non-selecting, non-restricting multijoins
200   # (since we def. do not care about multiplication of the contents of the subquery)
201   my $inner_subq = do {
202
203     # must use it here regardless of user requests (vastly gentler on optimizer)
204     local $self->{_use_join_optimizer} = 1;
205
206     # throw away multijoins since we def. do not care about those inside the subquery
207     ($inner_attrs->{from}, my $inner_aliastypes) = $self->_prune_unused_joins ({
208       %$inner_attrs, _force_prune_multiplying_joins => 1
209     });
210
211     # uh-oh a multiplier (which is not us) left in, this is a problem for limits
212     # we will need to add a group_by to collapse the resultset for proper counts
213     if (
214       grep { $_ ne $root_alias } keys %{ $inner_aliastypes->{multiplying} || {} }
215         and
216       # if there are user-supplied groups - assume user knows wtf they are up to
217       ( ! $inner_aliastypes->{grouping} or $inner_attrs->{_grouped_by_distinct} )
218     ) {
219
220       my $cur_sel = { map { $_ => 1 } @{$inner_attrs->{select}} };
221
222       # *possibly* supplement the main selection with pks if not already
223       # there, as they will have to be a part of the group_by to collapse
224       # things properly
225       my $inner_select_with_extras;
226       my @pks = map { "$root_alias.$_" } $root_node->{-rsrc}->primary_columns
227         or $self->throw_exception( sprintf
228           'Unable to perform complex limited prefetch off %s without declared primary key',
229           $root_node->{-rsrc}->source_name,
230         );
231       for my $col (@pks) {
232         push @{ $inner_select_with_extras ||= [ @{$inner_attrs->{select}} ] }, $col
233           unless $cur_sel->{$col}++;
234       }
235
236       ($inner_attrs->{group_by}, $inner_attrs->{order_by}) = $self->_group_over_selection({
237         %$inner_attrs,
238         $inner_select_with_extras ? ( select => $inner_select_with_extras ) : (),
239         _aliastypes => $inner_aliastypes,
240       });
241     }
242
243     # we already optimized $inner_attrs->{from} above
244     # and already local()ized
245     $self->{_use_join_optimizer} = 0;
246
247     # generate the subquery
248     $self->_select_args_to_query (
249       @{$inner_attrs}{qw(from select where)},
250       $inner_attrs,
251     );
252   };
253
254   # Generate the outer from - this is relatively easy (really just replace
255   # the join slot with the subquery), with a major caveat - we can not
256   # join anything that is non-selecting (not part of the prefetch), but at
257   # the same time is a multi-type relationship, as it will explode the result.
258   #
259   # There are two possibilities here
260   # - either the join is non-restricting, in which case we simply throw it away
261   # - it is part of the restrictions, in which case we need to collapse the outer
262   #   result by tackling yet another group_by to the outside of the query
263
264   # work on a shallow copy
265   my @orig_from = @{$attrs->{from}};
266
267
268   $outer_attrs->{from} = \ my @outer_from;
269
270   # we may not be the head
271   if ($root_node_offset) {
272     # first generate the outer_from, up to the substitution point
273     @outer_from = splice @orig_from, 0, $root_node_offset;
274
275     # substitute the subq at the right spot
276     push @outer_from, [
277       {
278         -alias => $root_alias,
279         -rsrc => $root_node->{-rsrc},
280         $root_alias => $inner_subq,
281       },
282       # preserve attrs from what is now the head of the from after the splice
283       @{$orig_from[0]}[1 .. $#{$orig_from[0]}],
284     ];
285   }
286   else {
287     @outer_from = {
288       -alias => $root_alias,
289       -rsrc => $root_node->{-rsrc},
290       $root_alias => $inner_subq,
291     };
292   }
293
294   shift @orig_from; # what we just replaced above
295
296   # scan the *remaining* from spec against different attributes, and see which joins are needed
297   # in what role
298   my $outer_aliastypes = $outer_attrs->{_aliastypes} =
299     $self->_resolve_aliastypes_from_select_args({ %$outer_attrs, from => \@orig_from });
300
301   # unroll parents
302   my ($outer_select_chain, @outer_nonselecting_chains) = map { +{
303     map { $_ => 1 } map { values %$_} map { @{$_->{-parents}} } values %{ $outer_aliastypes->{$_} || {} }
304   } } qw/selecting restricting grouping ordering/;
305
306   # see what's left - throw away if not selecting/restricting
307   my $may_need_outer_group_by;
308   while (my $j = shift @orig_from) {
309     my $alias = $j->[0]{-alias};
310
311     if (
312       $outer_select_chain->{$alias}
313     ) {
314       push @outer_from, $j
315     }
316     elsif (first { $_->{$alias} } @outer_nonselecting_chains ) {
317       push @outer_from, $j;
318       $may_need_outer_group_by ||= $outer_aliastypes->{multiplying}{$alias} ? 1 : 0;
319     }
320   }
321
322   # also throw in a synthetic group_by if a non-selecting multiplier,
323   # to guard against cross-join explosions
324   # the logic is somewhat fragile, but relies on the idea that if a user supplied
325   # a group by on their own - they know what they were doing
326   if ( $may_need_outer_group_by and $attrs->{_grouped_by_distinct} ) {
327     ($outer_attrs->{group_by}, $outer_attrs->{order_by}) = $self->_group_over_selection ({
328       %$outer_attrs,
329       from => \@outer_from,
330     });
331   }
332
333   # This is totally horrific - the {where} ends up in both the inner and outer query
334   # Unfortunately not much can be done until SQLA2 introspection arrives, and even
335   # then if where conditions apply to the *right* side of the prefetch, you may have
336   # to both filter the inner select (e.g. to apply a limit) and then have to re-filter
337   # the outer select to exclude joins you didn't want in the first place
338   #
339   # OTOH it can be seen as a plus: <ash> (notes that this query would make a DBA cry ;)
340   return $outer_attrs;
341 }
342
343 #
344 # I KNOW THIS SUCKS! GET SQLA2 OUT THE DOOR SO THIS CAN DIE!
345 #
346 # Due to a lack of SQLA2 we fall back to crude scans of all the
347 # select/where/order/group attributes, in order to determine what
348 # aliases are needed to fulfill the query. This information is used
349 # throughout the code to prune unnecessary JOINs from the queries
350 # in an attempt to reduce the execution time.
351 # Although the method is pretty horrific, the worst thing that can
352 # happen is for it to fail due to some scalar SQL, which in turn will
353 # result in a vocal exception.
354 sub _resolve_aliastypes_from_select_args {
355   my ( $self, $attrs ) = @_;
356
357   $self->throw_exception ('Unable to analyze custom {from}')
358     if ref $attrs->{from} ne 'ARRAY';
359
360   # what we will return
361   my $aliases_by_type;
362
363   # see what aliases are there to work with
364   # and record who is a multiplier and who is premultiplied
365   my $alias_list;
366   for my $node (@{$attrs->{from}}) {
367
368     my $j = $node;
369     $j = $j->[0] if ref $j eq 'ARRAY';
370     my $al = $j->{-alias}
371       or next;
372
373     $alias_list->{$al} = $j;
374
375     $aliases_by_type->{multiplying}{$al} ||= { -parents => $j->{-join_path}||[] }
376       # not array == {from} head == can't be multiplying
377       if ref($node) eq 'ARRAY' and ! $j->{-is_single};
378
379     $aliases_by_type->{premultiplied}{$al} ||= { -parents => $j->{-join_path}||[] }
380       # parts of the path that are not us but are multiplying
381       if grep { $aliases_by_type->{multiplying}{$_} }
382           grep { $_ ne $al }
383            map { values %$_ }
384             @{ $j->{-join_path}||[] }
385   }
386
387   # get a column to source/alias map (including unambiguous unqualified ones)
388   my $colinfo = $self->_resolve_column_info ($attrs->{from});
389
390   # set up a botched SQLA
391   my $sql_maker = $self->sql_maker;
392
393   # these are throw away results, do not pollute the bind stack
394   local $sql_maker->{where_bind};
395   local $sql_maker->{group_bind};
396   local $sql_maker->{having_bind};
397   local $sql_maker->{from_bind};
398
399   # we can't scan properly without any quoting (\b doesn't cut it
400   # everywhere), so unless there is proper quoting set - use our
401   # own weird impossible character.
402   # Also in the case of no quoting, we need to explicitly disable
403   # name_sep, otherwise sorry nasty legacy syntax like
404   # { 'count(foo.id)' => { '>' => 3 } } will stop working >:(
405   local $sql_maker->{quote_char} = $sql_maker->{quote_char};
406   local $sql_maker->{name_sep} = $sql_maker->{name_sep};
407
408   unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
409     $sql_maker->{quote_char} = ["\x00", "\xFF"];
410     # if we don't unset it we screw up retarded but unfortunately working
411     # 'MAX(foo.bar)' => { '>', 3 }
412     $sql_maker->{name_sep} = '';
413   }
414
415   my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
416
417   # generate sql chunks
418   my $to_scan = {
419     restricting => [
420       ($sql_maker->_recurse_where ($attrs->{where}))[0],
421       $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} }),
422     ],
423     grouping => [
424       $sql_maker->_parse_rs_attrs ({ group_by => $attrs->{group_by} }),
425     ],
426     joining => [
427       $sql_maker->_recurse_from (
428         ref $attrs->{from}[0] eq 'ARRAY' ? $attrs->{from}[0][0] : $attrs->{from}[0],
429         @{$attrs->{from}}[1 .. $#{$attrs->{from}}],
430       ),
431     ],
432     selecting => [
433       map { ($sql_maker->_recurse_fields($_))[0] } @{$attrs->{select}},
434     ],
435     ordering => [
436       map { $_->[0] } $self->_extract_order_criteria ($attrs->{order_by}, $sql_maker),
437     ],
438   };
439
440   # throw away empty chunks and all 2-value arrayrefs: the thinking is that these are
441   # bind value specs left in by the sloppy renderer above. It is ok to do this
442   # at this point, since we are going to end up rewriting this crap anyway
443   for my $v (values %$to_scan) {
444     my @nv;
445     for (@$v) {
446       next if (
447         ! defined $_
448           or
449         (
450           ref $_ eq 'ARRAY'
451             and
452           ( @$_ == 0 or @$_ == 2 )
453         )
454       );
455
456       if (ref $_) {
457         require Data::Dumper::Concise;
458         $self->throw_exception("Unexpected ref in scan-plan: " . Data::Dumper::Concise::Dumper($v) );
459       }
460
461       push @nv, $_;
462     }
463
464     $v = \@nv;
465   }
466
467   # kill all selectors which look like a proper subquery
468   # this is a sucky heuristic *BUT* - if we get it wrong the query will simply
469   # fail to run, so we are relatively safe
470   $to_scan->{selecting} = [ grep {
471     $_ !~ / \A \s* \( \s* SELECT \s+ .+? \s+ FROM \s+ .+? \) \s* \z /xsi
472   } @{ $to_scan->{selecting} || [] } ];
473
474   # first see if we have any exact matches (qualified or unqualified)
475   for my $type (keys %$to_scan) {
476     for my $piece (@{$to_scan->{$type}}) {
477       if ($colinfo->{$piece} and my $alias = $colinfo->{$piece}{-source_alias}) {
478         $aliases_by_type->{$type}{$alias} ||= { -parents => $alias_list->{$alias}{-join_path}||[] };
479         $aliases_by_type->{$type}{$alias}{-seen_columns}{$colinfo->{$piece}{-fq_colname}} = $piece;
480       }
481     }
482   }
483
484   # now loop through all fully qualified columns and get the corresponding
485   # alias (should work even if they are in scalarrefs)
486   for my $alias (keys %$alias_list) {
487     my $al_re = qr/
488       $lquote $alias $rquote $sep (?: $lquote ([^$rquote]+) $rquote )?
489         |
490       \b $alias \. ([^\s\)\($rquote]+)?
491     /x;
492
493     for my $type (keys %$to_scan) {
494       for my $piece (@{$to_scan->{$type}}) {
495         if (my @matches = $piece =~ /$al_re/g) {
496           $aliases_by_type->{$type}{$alias} ||= { -parents => $alias_list->{$alias}{-join_path}||[] };
497           $aliases_by_type->{$type}{$alias}{-seen_columns}{"$alias.$_"} = "$alias.$_"
498             for grep { defined $_ } @matches;
499         }
500       }
501     }
502   }
503
504   # now loop through unqualified column names, and try to locate them within
505   # the chunks
506   for my $col (keys %$colinfo) {
507     next if $col =~ / \. /x;   # if column is qualified it was caught by the above
508
509     my $col_re = qr/ $lquote ($col) $rquote /x;
510
511     for my $type (keys %$to_scan) {
512       for my $piece (@{$to_scan->{$type}}) {
513         if ( my @matches = $piece =~ /$col_re/g) {
514           my $alias = $colinfo->{$col}{-source_alias};
515           $aliases_by_type->{$type}{$alias} ||= { -parents => $alias_list->{$alias}{-join_path}||[] };
516           $aliases_by_type->{$type}{$alias}{-seen_columns}{"$alias.$_"} = $_
517             for grep { defined $_ } @matches;
518         }
519       }
520     }
521   }
522
523   # Add any non-left joins to the restriction list (such joins are indeed restrictions)
524   for my $j (values %$alias_list) {
525     my $alias = $j->{-alias} or next;
526     $aliases_by_type->{restricting}{$alias} ||= { -parents => $j->{-join_path}||[] } if (
527       (not $j->{-join_type})
528         or
529       ($j->{-join_type} !~ /^left (?: \s+ outer)? $/xi)
530     );
531   }
532
533   for (keys %$aliases_by_type) {
534     delete $aliases_by_type->{$_} unless keys %{$aliases_by_type->{$_}};
535   }
536
537   return $aliases_by_type;
538 }
539
540 # This is the engine behind { distinct => 1 } and the general
541 # complex prefetch grouper
542 sub _group_over_selection {
543   my ($self, $attrs) = @_;
544
545   my $colinfos = $self->_resolve_column_info ($attrs->{from});
546
547   my (@group_by, %group_index);
548
549   # the logic is: if it is a { func => val } we assume an aggregate,
550   # otherwise if \'...' or \[...] we assume the user knows what is
551   # going on thus group over it
552   for (@{$attrs->{select}}) {
553     if (! ref($_) or ref ($_) ne 'HASH' ) {
554       push @group_by, $_;
555       $group_index{$_}++;
556       if ($colinfos->{$_} and $_ !~ /\./ ) {
557         # add a fully qualified version as well
558         $group_index{"$colinfos->{$_}{-source_alias}.$_"}++;
559       }
560     }
561   }
562
563   my @order_by = $self->_extract_order_criteria($attrs->{order_by})
564     or return (\@group_by, $attrs->{order_by});
565
566   # add any order_by parts that are not already present in the group_by
567   # to maintain SQL cross-compatibility and general sanity
568   #
569   # also in case the original selection is *not* unique, or in case part
570   # of the ORDER BY refers to a multiplier - we will need to replace the
571   # skipped order_by elements with their MIN/MAX equivalents as to maintain
572   # the proper overall order without polluting the group criteria (and
573   # possibly changing the outcome entirely)
574
575   my ($leftovers, $sql_maker, @new_order_by, $order_chunks, $aliastypes);
576
577   my $group_already_unique = $self->_columns_comprise_identifying_set($colinfos, \@group_by);
578
579   for my $o_idx (0 .. $#order_by) {
580
581     # if the chunk is already a min/max function - there is nothing left to touch
582     next if $order_by[$o_idx][0] =~ /^ (?: min | max ) \s* \( .+ \) $/ix;
583
584     # only consider real columns (for functions the user got to do an explicit group_by)
585     my $chunk_ci;
586     if (
587       @{$order_by[$o_idx]} != 1
588         or
589       # only declare an unknown *plain* identifier as "leftover" if we are called with
590       # aliastypes to examine. If there are none - we are still in _resolve_attrs, and
591       # can just assume the user knows what they want
592       ( ! ( $chunk_ci = $colinfos->{$order_by[$o_idx][0]} ) and $attrs->{_aliastypes} )
593     ) {
594       push @$leftovers, $order_by[$o_idx][0];
595     }
596
597     next unless $chunk_ci;
598
599     # no duplication of group criteria
600     next if $group_index{$chunk_ci->{-fq_colname}};
601
602     $aliastypes ||= (
603       $attrs->{_aliastypes}
604         or
605       $self->_resolve_aliastypes_from_select_args({
606         from => $attrs->{from},
607         order_by => $attrs->{order_by},
608       })
609     ) if $group_already_unique;
610
611     # check that we are not ordering by a multiplier (if a check is requested at all)
612     if (
613       $group_already_unique
614         and
615       ! $aliastypes->{multiplying}{$chunk_ci->{-source_alias}}
616         and
617       ! $aliastypes->{premultiplied}{$chunk_ci->{-source_alias}}
618     ) {
619       push @group_by, $chunk_ci->{-fq_colname};
620       $group_index{$chunk_ci->{-fq_colname}}++
621     }
622     else {
623       # We need to order by external columns without adding them to the group
624       # (eiehter a non-unique selection, or a multi-external)
625       #
626       # This doesn't really make sense in SQL, however from DBICs point
627       # of view is rather valid (e.g. order the leftmost objects by whatever
628       # criteria and get the offset/rows many). There is a way around
629       # this however in SQL - we simply tae the direction of each piece
630       # of the external order and convert them to MIN(X) for ASC or MAX(X)
631       # for DESC, and group_by the root columns. The end result should be
632       # exactly what we expect
633       #
634
635       # both populated on the first loop over $o_idx
636       $sql_maker ||= $self->sql_maker;
637       $order_chunks ||= [
638         map { ref $_ eq 'ARRAY' ? $_ : [ $_ ] } $sql_maker->_order_by_chunks($attrs->{order_by})
639       ];
640
641       my ($chunk, $is_desc) = $sql_maker->_split_order_chunk($order_chunks->[$o_idx][0]);
642
643       $new_order_by[$o_idx] = \[
644         sprintf( '%s( %s )%s',
645           $self->_minmax_operator_for_datatype($chunk_ci->{data_type}, $is_desc),
646           $chunk,
647           ($is_desc ? ' DESC' : ''),
648         ),
649         @ {$order_chunks->[$o_idx]} [ 1 .. $#{$order_chunks->[$o_idx]} ]
650       ];
651     }
652   }
653
654   $self->throw_exception ( sprintf
655     'Unable to programatically derive a required group_by from the supplied '
656   . 'order_by criteria. To proceed either add an explicit group_by, or '
657   . 'simplify your order_by to only include plain columns '
658   . '(supplied order_by: %s)',
659     join ', ', map { "'$_'" } @$leftovers,
660   ) if $leftovers;
661
662   # recreate the untouched order parts
663   if (@new_order_by) {
664     $new_order_by[$_] ||= \ $order_chunks->[$_] for ( 0 .. $#$order_chunks );
665   }
666
667   return (
668     \@group_by,
669     (@new_order_by ? \@new_order_by : $attrs->{order_by} ),  # same ref as original == unchanged
670   );
671 }
672
673 sub _minmax_operator_for_datatype {
674   #my ($self, $datatype, $want_max) = @_;
675
676   $_[2] ? 'MAX' : 'MIN';
677 }
678
679 sub _resolve_ident_sources {
680   my ($self, $ident) = @_;
681
682   my $alias2source = {};
683
684   # the reason this is so contrived is that $ident may be a {from}
685   # structure, specifying multiple tables to join
686   if ( blessed $ident && $ident->isa("DBIx::Class::ResultSource") ) {
687     # this is compat mode for insert/update/delete which do not deal with aliases
688     $alias2source->{me} = $ident;
689   }
690   elsif (ref $ident eq 'ARRAY') {
691
692     for (@$ident) {
693       my $tabinfo;
694       if (ref $_ eq 'HASH') {
695         $tabinfo = $_;
696       }
697       if (ref $_ eq 'ARRAY' and ref $_->[0] eq 'HASH') {
698         $tabinfo = $_->[0];
699       }
700
701       $alias2source->{$tabinfo->{-alias}} = $tabinfo->{-rsrc}
702         if ($tabinfo->{-rsrc});
703     }
704   }
705
706   return $alias2source;
707 }
708
709 # Takes $ident, \@column_names
710 #
711 # returns { $column_name => \%column_info, ... }
712 # also note: this adds -result_source => $rsrc to the column info
713 #
714 # If no columns_names are supplied returns info about *all* columns
715 # for all sources
716 sub _resolve_column_info {
717   my ($self, $ident, $colnames) = @_;
718
719   return {} if $colnames and ! @$colnames;
720
721   my $alias2src = $self->_resolve_ident_sources($ident);
722
723   my (%seen_cols, @auto_colnames);
724
725   # compile a global list of column names, to be able to properly
726   # disambiguate unqualified column names (if at all possible)
727   for my $alias (keys %$alias2src) {
728     my $rsrc = $alias2src->{$alias};
729     for my $colname ($rsrc->columns) {
730       push @{$seen_cols{$colname}}, $alias;
731       push @auto_colnames, "$alias.$colname" unless $colnames;
732     }
733   }
734
735   $colnames ||= [
736     @auto_colnames,
737     grep { @{$seen_cols{$_}} == 1 } (keys %seen_cols),
738   ];
739
740   my (%return, $colinfos);
741   foreach my $col (@$colnames) {
742     my ($source_alias, $colname) = $col =~ m/^ (?: ([^\.]+) \. )? (.+) $/x;
743
744     # if the column was seen exactly once - we know which rsrc it came from
745     $source_alias ||= $seen_cols{$colname}[0]
746       if ($seen_cols{$colname} and @{$seen_cols{$colname}} == 1);
747
748     next unless $source_alias;
749
750     my $rsrc = $alias2src->{$source_alias}
751       or next;
752
753     $return{$col} = {
754       %{
755           ( $colinfos->{$source_alias} ||= $rsrc->columns_info )->{$colname}
756             ||
757           $self->throw_exception(
758             "No such column '$colname' on source " . $rsrc->source_name
759           );
760       },
761       -result_source => $rsrc,
762       -source_alias => $source_alias,
763       -fq_colname => $col eq $colname ? "$source_alias.$col" : $col,
764       -colname => $colname,
765     };
766
767     $return{"$source_alias.$colname"} = $return{$col} if $col eq $colname;
768   }
769
770   return \%return;
771 }
772
773 # The DBIC relationship chaining implementation is pretty simple - every
774 # new related_relationship is pushed onto the {from} stack, and the {select}
775 # window simply slides further in. This means that when we count somewhere
776 # in the middle, we got to make sure that everything in the join chain is an
777 # actual inner join, otherwise the count will come back with unpredictable
778 # results (a resultset may be generated with _some_ rows regardless of if
779 # the relation which the $rs currently selects has rows or not). E.g.
780 # $artist_rs->cds->count - normally generates:
781 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
782 # which actually returns the number of artists * (number of cds || 1)
783 #
784 # So what we do here is crawl {from}, determine if the current alias is at
785 # the top of the stack, and if not - make sure the chain is inner-joined down
786 # to the root.
787 #
788 sub _inner_join_to_node {
789   my ($self, $from, $alias) = @_;
790
791   my $switch_branch = $self->_find_join_path_to_node($from, $alias);
792
793   return $from unless @{$switch_branch||[]};
794
795   # So it looks like we will have to switch some stuff around.
796   # local() is useless here as we will be leaving the scope
797   # anyway, and deep cloning is just too fucking expensive
798   # So replace the first hashref in the node arrayref manually
799   my @new_from = ($from->[0]);
800   my $sw_idx = { map { (values %$_), 1 } @$switch_branch }; #there's one k/v per join-path
801
802   for my $j (@{$from}[1 .. $#$from]) {
803     my $jalias = $j->[0]{-alias};
804
805     if ($sw_idx->{$jalias}) {
806       my %attrs = %{$j->[0]};
807       delete $attrs{-join_type};
808       push @new_from, [
809         \%attrs,
810         @{$j}[ 1 .. $#$j ],
811       ];
812     }
813     else {
814       push @new_from, $j;
815     }
816   }
817
818   return \@new_from;
819 }
820
821 sub _find_join_path_to_node {
822   my ($self, $from, $target_alias) = @_;
823
824   # subqueries and other oddness are naturally not supported
825   return undef if (
826     ref $from ne 'ARRAY'
827       ||
828     ref $from->[0] ne 'HASH'
829       ||
830     ! defined $from->[0]{-alias}
831   );
832
833   # no path - the head is the alias
834   return [] if $from->[0]{-alias} eq $target_alias;
835
836   for my $i (1 .. $#$from) {
837     return $from->[$i][0]{-join_path} if ( ($from->[$i][0]{-alias}||'') eq $target_alias );
838   }
839
840   # something else went quite wrong
841   return undef;
842 }
843
844 sub _extract_order_criteria {
845   my ($self, $order_by, $sql_maker) = @_;
846
847   my $parser = sub {
848     my ($sql_maker, $order_by, $orig_quote_chars) = @_;
849
850     return scalar $sql_maker->_order_by_chunks ($order_by)
851       unless wantarray;
852
853     my ($lq, $rq, $sep) = map { quotemeta($_) } (
854       ($orig_quote_chars ? @$orig_quote_chars : $sql_maker->_quote_chars),
855       $sql_maker->name_sep
856     );
857
858     my @chunks;
859     for ($sql_maker->_order_by_chunks ($order_by) ) {
860       my $chunk = ref $_ ? [ @$_ ] : [ $_ ];
861       ($chunk->[0]) = $sql_maker->_split_order_chunk($chunk->[0]);
862
863       # order criteria may have come back pre-quoted (literals and whatnot)
864       # this is fragile, but the best we can currently do
865       $chunk->[0] =~ s/^ $lq (.+?) $rq $sep $lq (.+?) $rq $/"$1.$2"/xe
866         or $chunk->[0] =~ s/^ $lq (.+) $rq $/$1/x;
867
868       push @chunks, $chunk;
869     }
870
871     return @chunks;
872   };
873
874   if ($sql_maker) {
875     return $parser->($sql_maker, $order_by);
876   }
877   else {
878     $sql_maker = $self->sql_maker;
879
880     # pass these in to deal with literals coming from
881     # the user or the deep guts of prefetch
882     my $orig_quote_chars = [$sql_maker->_quote_chars];
883
884     local $sql_maker->{quote_char};
885     return $parser->($sql_maker, $order_by, $orig_quote_chars);
886   }
887 }
888
889 sub _order_by_is_stable {
890   my ($self, $ident, $order_by, $where) = @_;
891
892   my @cols = (
893     ( map { $_->[0] } $self->_extract_order_criteria($order_by) ),
894     ( $where ? keys %{ $self->_extract_fixed_condition_columns($where) } : () ),
895   ) or return 0;
896
897   my $colinfo = $self->_resolve_column_info($ident, \@cols);
898
899   return keys %$colinfo
900     ? $self->_columns_comprise_identifying_set( $colinfo,  \@cols )
901     : 0
902   ;
903 }
904
905 sub _columns_comprise_identifying_set {
906   my ($self, $colinfo, $columns) = @_;
907
908   my $cols_per_src;
909   $cols_per_src -> {$_->{-source_alias}} -> {$_->{-colname}} = $_
910     for grep { defined $_ } @{$colinfo}{@$columns};
911
912   for (values %$cols_per_src) {
913     my $src = (values %$_)[0]->{-result_source};
914     return 1 if $src->_identifying_column_set($_);
915   }
916
917   return 0;
918 }
919
920 # this is almost similar to _order_by_is_stable, except it takes
921 # a single rsrc, and will succeed only if the first portion of the order
922 # by is stable.
923 # returns that portion as a colinfo hashref on success
924 sub _extract_colinfo_of_stable_main_source_order_by_portion {
925   my ($self, $attrs) = @_;
926
927   my $nodes = $self->_find_join_path_to_node($attrs->{from}, $attrs->{alias});
928
929   return unless defined $nodes;
930
931   my @ord_cols = map
932     { $_->[0] }
933     ( $self->_extract_order_criteria($attrs->{order_by}) )
934   ;
935   return unless @ord_cols;
936
937   my $valid_aliases = { map { $_ => 1 } (
938     $attrs->{from}[0]{-alias},
939     map { values %$_ } @$nodes,
940   ) };
941
942   my $colinfos = $self->_resolve_column_info($attrs->{from});
943
944   my ($colinfos_to_return, $seen_main_src_cols);
945
946   for my $col (@ord_cols) {
947     # if order criteria is unresolvable - there is nothing we can do
948     my $colinfo = $colinfos->{$col} or last;
949
950     # if we reached the end of the allowed aliases - also nothing we can do
951     last unless $valid_aliases->{$colinfo->{-source_alias}};
952
953     $colinfos_to_return->{$col} = $colinfo;
954
955     $seen_main_src_cols->{$colinfo->{-colname}} = 1
956       if $colinfo->{-source_alias} eq $attrs->{alias};
957   }
958
959   # FIXME the condition may be singling out things on its own, so we
960   # conceivable could come back wi "stable-ordered by nothing"
961   # not confient enough in the parser yet, so punt for the time being
962   return unless $seen_main_src_cols;
963
964   my $main_src_fixed_cols_from_cond = [ $attrs->{where}
965     ? (
966       map
967       {
968         ( $colinfos->{$_} and $colinfos->{$_}{-source_alias} eq $attrs->{alias} )
969           ? $colinfos->{$_}{-colname}
970           : ()
971       }
972       keys %{ $self->_extract_fixed_condition_columns($attrs->{where}) }
973     )
974     : ()
975   ];
976
977   return $attrs->{result_source}->_identifying_column_set([
978     keys %$seen_main_src_cols,
979     @$main_src_fixed_cols_from_cond,
980   ]) ? $colinfos_to_return : ();
981 }
982
983 # Attempts to flatten a passed in SQLA condition as much as possible towards
984 # a plain hashref, *without* altering its semantics. Required by
985 # create/populate being able to extract definitive conditions from preexisting
986 # resultset {where} stacks
987 #
988 # FIXME - while relatively robust, this is still imperfect, one of the first
989 # things to tackle with DQ
990 sub _collapse_cond {
991   my ($self, $where, $where_is_anded_array) = @_;
992
993   my $fin;
994
995   if (! $where) {
996     return;
997   }
998   elsif ($where_is_anded_array or ref $where eq 'HASH') {
999
1000     my @pairs;
1001
1002     my @pieces = $where_is_anded_array ? @$where : $where;
1003     while (@pieces) {
1004       my $chunk = shift @pieces;
1005
1006       if (ref $chunk eq 'HASH') {
1007         for (sort keys %$chunk) {
1008
1009           # Match SQLA 1.79 behavior
1010           if ($_ eq '') {
1011             is_literal_value($chunk->{$_})
1012               ? carp 'Hash-pairs consisting of an empty string with a literal are deprecated, use -and => [ $literal ] instead'
1013               : $self->throw_exception("Supplying an empty left hand side argument is not supported in hash-pairs")
1014             ;
1015           }
1016
1017           push @pairs, $_ => $chunk->{$_};
1018         }
1019       }
1020       elsif (ref $chunk eq 'ARRAY') {
1021         push @pairs, -or => $chunk
1022           if @$chunk;
1023       }
1024       elsif ( ! length ref $chunk) {
1025
1026         # Match SQLA 1.79 behavior
1027         $self->throw_exception("Supplying an empty left hand side argument is not supported in array-pairs")
1028           if $where_is_anded_array and (! defined $chunk or $chunk eq '');
1029
1030         push @pairs, $chunk, shift @pieces;
1031       }
1032       else {
1033         push @pairs, '', $chunk;
1034       }
1035     }
1036
1037     return unless @pairs;
1038
1039     my @conds = $self->_collapse_cond_unroll_pairs(\@pairs)
1040       or return;
1041
1042     # Consolidate various @conds back into something more compact
1043     for my $c (@conds) {
1044       if (ref $c ne 'HASH') {
1045         push @{$fin->{-and}}, $c;
1046       }
1047       else {
1048         for my $col (sort keys %$c) {
1049
1050           # consolidate all -and nodes
1051           if ($col =~ /^\-and$/i) {
1052             push @{$fin->{-and}},
1053               ref $c->{$col} eq 'ARRAY' ? @{$c->{$col}}
1054             : ref $c->{$col} eq 'HASH' ? %{$c->{$col}}
1055             : { $col => $c->{$col} }
1056             ;
1057           }
1058           elsif ($col =~ /^\-/) {
1059             push @{$fin->{-and}}, { $col => $c->{$col} };
1060           }
1061           elsif (exists $fin->{$col}) {
1062             $fin->{$col} = [ -and => map {
1063               (ref $_ eq 'ARRAY' and ($_->[0]||'') =~ /^\-and$/i )
1064                 ? @{$_}[1..$#$_]
1065                 : $_
1066               ;
1067             } ($fin->{$col}, $c->{$col}) ];
1068           }
1069           else {
1070             $fin->{$col} = $c->{$col};
1071           }
1072         }
1073       }
1074     }
1075   }
1076   elsif (ref $where eq 'ARRAY') {
1077     # we are always at top-level here, it is safe to dump empty *standalone* pieces
1078     my $fin_idx;
1079
1080     for (my $i = 0; $i <= $#$where; $i++ ) {
1081
1082       # Match SQLA 1.79 behavior
1083       $self->throw_exception(
1084         "Supplying an empty left hand side argument is not supported in array-pairs"
1085       ) if (! defined $where->[$i] or ! length $where->[$i]);
1086
1087       my $logic_mod = lc ( ($where->[$i] =~ /^(\-(?:and|or))$/i)[0] || '' );
1088
1089       if ($logic_mod) {
1090         $i++;
1091         $self->throw_exception("Unsupported top-level op/arg pair: [ $logic_mod => $where->[$i] ]")
1092           unless ref $where->[$i] eq 'HASH' or ref $where->[$i] eq 'ARRAY';
1093
1094         my $sub_elt = $self->_collapse_cond({ $logic_mod => $where->[$i] })
1095           or next;
1096
1097         my @keys = keys %$sub_elt;
1098         if ( @keys == 1 and $keys[0] !~ /^\-/ ) {
1099           $fin_idx->{ "COL_$keys[0]_" . serialize $sub_elt } = $sub_elt;
1100         }
1101         else {
1102           $fin_idx->{ "SER_" . serialize $sub_elt } = $sub_elt;
1103         }
1104       }
1105       elsif (! length ref $where->[$i] ) {
1106         my $sub_elt = $self->_collapse_cond({ @{$where}[$i, $i+1] })
1107           or next;
1108
1109         $fin_idx->{ "COL_$where->[$i]_" . serialize $sub_elt } = $sub_elt;
1110         $i++;
1111       }
1112       else {
1113         $fin_idx->{ "SER_" . serialize $where->[$i] } = $self->_collapse_cond( $where->[$i] ) || next;
1114       }
1115     }
1116
1117     if (! $fin_idx) {
1118       return;
1119     }
1120     elsif ( keys %$fin_idx == 1 ) {
1121       $fin = (values %$fin_idx)[0];
1122     }
1123     else {
1124       my @or;
1125
1126       # at this point everything is at most one level deep - unroll if needed
1127       for (sort keys %$fin_idx) {
1128         if ( ref $fin_idx->{$_} eq 'HASH' and keys %{$fin_idx->{$_}} == 1 ) {
1129           my ($l, $r) = %{$fin_idx->{$_}};
1130
1131           if (
1132             ref $r eq 'ARRAY'
1133               and
1134             (
1135               ( @$r == 1 and $l =~ /^\-and$/i )
1136                 or
1137               $l =~ /^\-or$/i
1138             )
1139           ) {
1140             push @or, @$r
1141           }
1142
1143           elsif (
1144             ref $r eq 'HASH'
1145               and
1146             keys %$r == 1
1147               and
1148             $l =~ /^\-(?:and|or)$/i
1149           ) {
1150             push @or, %$r;
1151           }
1152
1153           else {
1154             push @or, $l, $r;
1155           }
1156         }
1157         else {
1158           push @or, $fin_idx->{$_};
1159         }
1160       }
1161
1162       $fin->{-or} = \@or;
1163     }
1164   }
1165   else {
1166     # not a hash not an array
1167     $fin = { -and => [ $where ] };
1168   }
1169
1170   # unroll single-element -and's
1171   while (
1172     $fin->{-and}
1173       and
1174     @{$fin->{-and}} < 2
1175   ) {
1176     my $and = delete $fin->{-and};
1177     last if @$and == 0;
1178
1179     # at this point we have @$and == 1
1180     if (
1181       ref $and->[0] eq 'HASH'
1182         and
1183       ! grep { exists $fin->{$_} } keys %{$and->[0]}
1184     ) {
1185       $fin = {
1186         %$fin, %{$and->[0]}
1187       };
1188     }
1189     else {
1190       $fin->{-and} = $and;
1191       last;
1192     }
1193   }
1194
1195   # compress same-column conds found in $fin
1196   for my $col ( grep { $_ !~ /^\-/ } keys %$fin ) {
1197     next unless ref $fin->{$col} eq 'ARRAY' and ($fin->{$col}[0]||'') =~ /^\-and$/i;
1198     my $val_bag = { map {
1199       (! defined $_ )                          ? ( UNDEF => undef )
1200     : ( ! length ref $_ or is_plain_value $_ ) ? ( "VAL_$_" => $_ )
1201     : ( ( 'SER_' . serialize $_ ) => $_ )
1202     } @{$fin->{$col}}[1 .. $#{$fin->{$col}}] };
1203
1204     if (keys %$val_bag == 1 ) {
1205       ($fin->{$col}) = values %$val_bag;
1206     }
1207     else {
1208       $fin->{$col} = [ -and => map { $val_bag->{$_} } sort keys %$val_bag ];
1209     }
1210   }
1211
1212   return keys %$fin ? $fin : ();
1213 }
1214
1215 sub _collapse_cond_unroll_pairs {
1216   my ($self, $pairs) = @_;
1217
1218   my @conds;
1219
1220   while (@$pairs) {
1221     my ($lhs, $rhs) = splice @$pairs, 0, 2;
1222
1223     if ($lhs eq '') {
1224       push @conds, $self->_collapse_cond($rhs);
1225     }
1226     elsif ( $lhs =~ /^\-and$/i ) {
1227       push @conds, $self->_collapse_cond($rhs, (ref $rhs eq 'ARRAY'));
1228     }
1229     elsif ( $lhs =~ /^\-or$/i ) {
1230       push @conds, $self->_collapse_cond(
1231         (ref $rhs eq 'HASH') ? [ map { $_ => $rhs->{$_} } sort keys %$rhs ] : $rhs
1232       );
1233     }
1234     else {
1235       if (ref $rhs eq 'HASH' and ! keys %$rhs) {
1236         # FIXME - SQLA seems to be doing... nothing...?
1237       }
1238       # normalize top level -ident, for saner extract_fixed_condition_columns code
1239       elsif (ref $rhs eq 'HASH' and keys %$rhs == 1 and exists $rhs->{-ident}) {
1240         push @conds, { $lhs => { '=', $rhs } };
1241       }
1242       elsif (ref $rhs eq 'HASH' and keys %$rhs == 1 and exists $rhs->{-value} and is_plain_value $rhs->{-value}) {
1243         push @conds, { $lhs => $rhs->{-value} };
1244       }
1245       elsif (ref $rhs eq 'HASH' and keys %$rhs == 1 and exists $rhs->{'='}) {
1246         if ( length ref $rhs->{'='} and is_literal_value $rhs->{'='} ) {
1247           push @conds, { $lhs => $rhs };
1248         }
1249         else {
1250           for my $p ($self->_collapse_cond_unroll_pairs([ $lhs => $rhs->{'='} ])) {
1251
1252             # extra sanity check
1253             if (keys %$p > 1) {
1254               require Data::Dumper::Concise;
1255               local $Data::Dumper::Deepcopy = 1;
1256               $self->throw_exception(
1257                 "Internal error: unexpected collapse unroll:"
1258               . Data::Dumper::Concise::Dumper { in => { $lhs => $rhs }, out => $p }
1259               );
1260             }
1261
1262             my ($l, $r) = %$p;
1263
1264             push @conds, (
1265               ! length ref $r
1266                 or
1267               # the unroller recursion may return a '=' prepended value already
1268               ref $r eq 'HASH' and keys %$rhs == 1 and exists $rhs->{'='}
1269                 or
1270               is_plain_value($r)
1271             )
1272               ? { $l => $r }
1273               : { $l => { '=' => $r } }
1274             ;
1275           }
1276         }
1277       }
1278       elsif (ref $rhs eq 'ARRAY') {
1279         # some of these conditionals encounter multi-values - roll them out using
1280         # an unshift, which will cause extra looping in the while{} above
1281         if (! @$rhs ) {
1282           push @conds, { $lhs => [] };
1283         }
1284         elsif ( ($rhs->[0]||'') =~ /^\-(?:and|or)$/i ) {
1285           $self->throw_exception("Value modifier not followed by any values: $lhs => [ $rhs->[0] ] ")
1286             if  @$rhs == 1;
1287
1288           if( $rhs->[0] =~ /^\-and$/i ) {
1289             unshift @$pairs, map { $lhs => $_ } @{$rhs}[1..$#$rhs];
1290           }
1291           # if not an AND then it's an OR
1292           elsif(@$rhs == 2) {
1293             unshift @$pairs, $lhs => $rhs->[1];
1294           }
1295           else {
1296             push @conds, { $lhs => [ @{$rhs}[1..$#$rhs] ] };
1297           }
1298         }
1299         elsif (@$rhs == 1) {
1300           unshift @$pairs, $lhs => $rhs->[0];
1301         }
1302         else {
1303           push @conds, { $lhs => $rhs };
1304         }
1305       }
1306       # unroll func + { -value => ... }
1307       elsif (
1308         ref $rhs eq 'HASH'
1309           and
1310         ( my ($subop) = keys %$rhs ) == 1
1311           and
1312         length ref ((values %$rhs)[0])
1313           and
1314         my $vref = is_plain_value( (values %$rhs)[0] )
1315       ) {
1316         push @conds, { $lhs => { $subop => $$vref } }
1317       }
1318       else {
1319         push @conds, { $lhs => $rhs };
1320       }
1321     }
1322   }
1323
1324   return @conds;
1325 }
1326
1327 # Analyzes a given condition and attempts to extract all columns
1328 # with a definitive fixed-condition criteria. Returns a hashref
1329 # of k/v pairs suitable to be passed to set_columns(), with a
1330 # MAJOR CAVEAT - multi-value (contradictory) equalities are still
1331 # represented as a reference to the UNRESOVABLE_CONDITION constant
1332 # The reason we do this is that some codepaths only care about the
1333 # codition being stable, as opposed to actually making sense
1334 #
1335 # The normal mode is used to figure out if a resultset is constrained
1336 # to a column which is part of a unique constraint, which in turn
1337 # allows us to better predict how ordering will behave etc.
1338 #
1339 # With the optional "consider_nulls" boolean argument, the function
1340 # is instead used to infer inambiguous values from conditions
1341 # (e.g. the inheritance of resultset conditions on new_result)
1342 #
1343 sub _extract_fixed_condition_columns {
1344   my ($self, $where, $consider_nulls) = @_;
1345   my $where_hash = $self->_collapse_cond($_[1]);
1346
1347   my $res = {};
1348   my ($c, $v);
1349   for $c (keys %$where_hash) {
1350     my $vals;
1351
1352     if (!defined ($v = $where_hash->{$c}) ) {
1353       $vals->{UNDEF} = $v if $consider_nulls
1354     }
1355     elsif (
1356       ref $v eq 'HASH'
1357         and
1358       keys %$v == 1
1359     ) {
1360       if (exists $v->{-value}) {
1361         if (defined $v->{-value}) {
1362           $vals->{"VAL_$v->{-value}"} = $v->{-value}
1363         }
1364         elsif( $consider_nulls ) {
1365           $vals->{UNDEF} = $v->{-value};
1366         }
1367       }
1368       # do not need to check for plain values - _collapse_cond did it for us
1369       elsif(
1370         length ref $v->{'='}
1371           and
1372         (
1373           ( ref $v->{'='} eq 'HASH' and keys %{$v->{'='}} == 1 and exists $v->{'='}{-ident} )
1374             or
1375           is_literal_value($v->{'='})
1376         )
1377        ) {
1378         $vals->{ 'SER_' . serialize $v->{'='} } = $v->{'='};
1379       }
1380     }
1381     elsif (
1382       ! length ref $v
1383         or
1384       is_plain_value ($v)
1385     ) {
1386       $vals->{"VAL_$v"} = $v;
1387     }
1388     elsif (ref $v eq 'ARRAY' and ($v->[0]||'') eq '-and') {
1389       for ( @{$v}[1..$#$v] ) {
1390         my $subval = $self->_extract_fixed_condition_columns({ $c => $_ }, 'consider nulls');  # always fish nulls out on recursion
1391         next unless exists $subval->{$c};  # didn't find anything
1392         $vals->{
1393           ! defined $subval->{$c}                                        ? 'UNDEF'
1394         : ( ! length ref $subval->{$c} or is_plain_value $subval->{$c} ) ? "VAL_$subval->{$c}"
1395         : ( 'SER_' . serialize $subval->{$c} )
1396         } = $subval->{$c};
1397       }
1398     }
1399
1400     if (keys %$vals == 1) {
1401       ($res->{$c}) = (values %$vals)
1402         unless !$consider_nulls and exists $vals->{UNDEF};
1403     }
1404     elsif (keys %$vals > 1) {
1405       $res->{$c} = UNRESOLVABLE_CONDITION;
1406     }
1407   }
1408
1409   $res;
1410 }
1411
1412 1;