lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use IO::File;
  13
  14 __PACKAGE__->mk_group_accessors(
  15   'simple' =>
  16     qw/_connect_info _dbh _sql_maker _sql_maker_opts _conn_pid _conn_tid
  17        disable_sth_caching cursor on_connect_do transaction_depth/
  18 );
  19
  20 BEGIN {
  21
  22 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  23
  24 use base qw/SQL::Abstract::Limit/;
  25
  26 # This prevents the caching of $dbh in S::A::L, I believe
  27 sub new {
  28   my $self = shift->SUPER::new(@_);
  29
  30   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  31   #   it with what it resolves to:
  32   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  33     if ref $self->{limit_dialect};
  34
  35   $self;
  36 }
  37
  38 sub _RowNumberOver {
  39   my ($self, $sql, $order, $rows, $offset ) = @_;
  40
  41   $offset += 1;
  42   my $last = $rows + $offset;
  43   my ( $order_by ) = $self->_order_by( $order );
  44
  45   $sql = <<"";
  46 SELECT * FROM
  47 (
  48    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  49       $sql
  50       $order_by
  51    ) Q1
  52 ) Q2
  53 WHERE ROW_NUM BETWEEN $offset AND $last
  54
  55   return $sql;
  56 }
  57
  58
  59 # While we're at it, this should make LIMIT queries more efficient,
  60 #  without digging into things too deeply
  61 use Scalar::Util 'blessed';
  62 sub _find_syntax {
  63   my ($self, $syntax) = @_;
  64   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  65   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  66     return 'RowNumberOver';
  67   }
  68
  69   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  70 }
  71
  72 sub select {
  73   my ($self, $table, $fields, $where, $order, @rest) = @_;
  74   $table = $self->_quote($table) unless ref($table);
  75   local $self->{rownum_hack_count} = 1
  76     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  77   @rest = (-1) unless defined $rest[0];
  78   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  79     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  80   local $self->{having_bind} = [];
  81   my ($sql, @ret) = $self->SUPER::select(
  82     $table, $self->_recurse_fields($fields), $where, $order, @rest
  83   );
  84   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  85 }
  86
  87 sub insert {
  88   my $self = shift;
  89   my $table = shift;
  90   $table = $self->_quote($table) unless ref($table);
  91   $self->SUPER::insert($table, @_);
  92 }
  93
  94 sub update {
  95   my $self = shift;
  96   my $table = shift;
  97   $table = $self->_quote($table) unless ref($table);
  98   $self->SUPER::update($table, @_);
  99 }
 100
 101 sub delete {
 102   my $self = shift;
 103   my $table = shift;
 104   $table = $self->_quote($table) unless ref($table);
 105   $self->SUPER::delete($table, @_);
 106 }
 107
 108 sub _emulate_limit {
 109   my $self = shift;
 110   if ($_[3] == -1) {
 111     return $_[1].$self->_order_by($_[2]);
 112   } else {
 113     return $self->SUPER::_emulate_limit(@_);
 114   }
 115 }
 116
 117 sub _recurse_fields {
 118   my ($self, $fields) = @_;
 119   my $ref = ref $fields;
 120   return $self->_quote($fields) unless $ref;
 121   return $$fields if $ref eq 'SCALAR';
 122
 123   if ($ref eq 'ARRAY') {
 124     return join(', ', map {
 125       $self->_recurse_fields($_)
 126       .(exists $self->{rownum_hack_count}
 127          ? ' AS col'.$self->{rownum_hack_count}++
 128          : '')
 129      } @$fields);
 130   } elsif ($ref eq 'HASH') {
 131     foreach my $func (keys %$fields) {
 132       return $self->_sqlcase($func)
 133         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 134     }
 135   }
 136 }
 137
 138 sub _order_by {
 139   my $self = shift;
 140   my $ret = '';
 141   my @extra;
 142   if (ref $_[0] eq 'HASH') {
 143     if (defined $_[0]->{group_by}) {
 144       $ret = $self->_sqlcase(' group by ')
 145                .$self->_recurse_fields($_[0]->{group_by});
 146     }
 147     if (defined $_[0]->{having}) {
 148       my $frag;
 149       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 150       push(@{$self->{having_bind}}, @extra);
 151       $ret .= $self->_sqlcase(' having ').$frag;
 152     }
 153     if (defined $_[0]->{order_by}) {
 154       $ret .= $self->_order_by($_[0]->{order_by});
 155     }
 156   } elsif (ref $_[0] eq 'SCALAR') {
 157     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 158   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 159     my @order = @{+shift};
 160     $ret = $self->_sqlcase(' order by ')
 161           .join(', ', map {
 162                         my $r = $self->_order_by($_, @_);
 163                         $r =~ s/^ ?ORDER BY //i;
 164                         $r;
 165                       } @order);
 166   } else {
 167     $ret = $self->SUPER::_order_by(@_);
 168   }
 169   return $ret;
 170 }
 171
 172 sub _order_directions {
 173   my ($self, $order) = @_;
 174   $order = $order->{order_by} if ref $order eq 'HASH';
 175   return $self->SUPER::_order_directions($order);
 176 }
 177
 178 sub _table {
 179   my ($self, $from) = @_;
 180   if (ref $from eq 'ARRAY') {
 181     return $self->_recurse_from(@$from);
 182   } elsif (ref $from eq 'HASH') {
 183     return $self->_make_as($from);
 184   } else {
 185     return $from; # would love to quote here but _table ends up getting called
 186                   # twice during an ->select without a limit clause due to
 187                   # the way S::A::Limit->select works. should maybe consider
 188                   # bypassing this and doing S::A::select($self, ...) in
 189                   # our select method above. meantime, quoting shims have
 190                   # been added to select/insert/update/delete here
 191   }
 192 }
 193
 194 sub _recurse_from {
 195   my ($self, $from, @join) = @_;
 196   my @sqlf;
 197   push(@sqlf, $self->_make_as($from));
 198   foreach my $j (@join) {
 199     my ($to, $on) = @$j;
 200
 201     # check whether a join type exists
 202     my $join_clause = '';
 203     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 204     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 205       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 206     } else {
 207       $join_clause = ' JOIN ';
 208     }
 209     push(@sqlf, $join_clause);
 210
 211     if (ref $to eq 'ARRAY') {
 212       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 213     } else {
 214       push(@sqlf, $self->_make_as($to));
 215     }
 216     push(@sqlf, ' ON ', $self->_join_condition($on));
 217   }
 218   return join('', @sqlf);
 219 }
 220
 221 sub _make_as {
 222   my ($self, $from) = @_;
 223   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 224                      reverse each %{$self->_skip_options($from)});
 225 }
 226
 227 sub _skip_options {
 228   my ($self, $hash) = @_;
 229   my $clean_hash = {};
 230   $clean_hash->{$_} = $hash->{$_}
 231     for grep {!/^-/} keys %$hash;
 232   return $clean_hash;
 233 }
 234
 235 sub _join_condition {
 236   my ($self, $cond) = @_;
 237   if (ref $cond eq 'HASH') {
 238     my %j;
 239     for (keys %$cond) {
 240       my $v = $cond->{$_};
 241       if (ref $v) {
 242         # XXX no throw_exception() in this package and croak() fails with strange results
 243         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 244             if ref($v) ne 'SCALAR';
 245         $j{$_} = $v;
 246       }
 247       else {
 248         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 249       }
 250     };
 251     return scalar($self->_recurse_where(\%j));
 252   } elsif (ref $cond eq 'ARRAY') {
 253     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 254   } else {
 255     die "Can't handle this yet!";
 256   }
 257 }
 258
 259 sub _quote {
 260   my ($self, $label) = @_;
 261   return '' unless defined $label;
 262   return "*" if $label eq '*';
 263   return $label unless $self->{quote_char};
 264   if(ref $self->{quote_char} eq "ARRAY"){
 265     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 266       if !defined $self->{name_sep};
 267     my $sep = $self->{name_sep};
 268     return join($self->{name_sep},
 269         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 270        split(/\Q$sep\E/,$label));
 271   }
 272   return $self->SUPER::_quote($label);
 273 }
 274
 275 sub limit_dialect {
 276     my $self = shift;
 277     $self->{limit_dialect} = shift if @_;
 278     return $self->{limit_dialect};
 279 }
 280
 281 sub quote_char {
 282     my $self = shift;
 283     $self->{quote_char} = shift if @_;
 284     return $self->{quote_char};
 285 }
 286
 287 sub name_sep {
 288     my $self = shift;
 289     $self->{name_sep} = shift if @_;
 290     return $self->{name_sep};
 291 }
 292
 293 } # End of BEGIN block
 294
 295 =head1 NAME
 296
 297 DBIx::Class::Storage::DBI - DBI storage handler
 298
 299 =head1 SYNOPSIS
 300
 301 =head1 DESCRIPTION
 302
 303 This class represents the connection to an RDBMS via L<DBI>.  See
 304 L<DBIx::Class::Storage> for general information.  This pod only
 305 documents DBI-specific methods and behaviors.
 306
 307 =head1 METHODS
 308
 309 =cut
 310
 311 sub new {
 312   my $new = shift->next::method(@_);
 313
 314   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 315   $new->transaction_depth(0);
 316   $new->_sql_maker_opts({});
 317   $new->{_in_dbh_do} = 0;
 318   $new->{_dbh_gen} = 0;
 319
 320   $new;
 321 }
 322
 323 =head2 connect_info
 324
 325 The arguments of C<connect_info> are always a single array reference.
 326
 327 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 328 encapsulates its argument list in an arrayref before calling
 329 C<connect_info> here.
 330
 331 The arrayref can either contain the same set of arguments one would
 332 normally pass to L<DBI/connect>, or a lone code reference which returns
 333 a connected database handle.
 334
 335 In either case, if the final argument in your connect_info happens
 336 to be a hashref, C<connect_info> will look there for several
 337 connection-specific options:
 338
 339 =over 4
 340
 341 =item on_connect_do
 342
 343 This can be set to an arrayref of literal sql statements, which will
 344 be executed immediately after making the connection to the database
 345 every time we [re-]connect.
 346
 347 =item disable_sth_caching
 348
 349 If set to a true value, this option will disable the caching of
 350 statement handles via L<DBI/prepare_cached>.
 351
 352 =item limit_dialect
 353
 354 Sets the limit dialect. This is useful for JDBC-bridge among others
 355 where the remote SQL-dialect cannot be determined by the name of the
 356 driver alone.
 357
 358 =item quote_char
 359
 360 Specifies what characters to use to quote table and column names. If
 361 you use this you will want to specify L<name_sep> as well.
 362
 363 quote_char expects either a single character, in which case is it is placed
 364 on either side of the table/column, or an arrayref of length 2 in which case the
 365 table/column name is placed between the elements.
 366
 367 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 368 use C<quote_char =E<gt> [qw/[ ]/]>.
 369
 370 =item name_sep
 371
 372 This only needs to be used in conjunction with L<quote_char>, and is used to
 373 specify the charecter that seperates elements (schemas, tables, columns) from
 374 each other. In most cases this is simply a C<.>.
 375
 376 =back
 377
 378 These options can be mixed in with your other L<DBI> connection attributes,
 379 or placed in a seperate hashref after all other normal L<DBI> connection
 380 arguments.
 381
 382 Every time C<connect_info> is invoked, any previous settings for
 383 these options will be cleared before setting the new ones, regardless of
 384 whether any options are specified in the new C<connect_info>.
 385
 386 Important note:  DBIC expects the returned database handle provided by
 387 a subref argument to have RaiseError set on it.  If it doesn't, things
 388 might not work very well, YMMV.  If you don't use a subref, DBIC will
 389 force this setting for you anyways.  Setting HandleError to anything
 390 other than simple exception object wrapper might cause problems too.
 391
 392 Examples:
 393
 394   # Simple SQLite connection
 395   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 396
 397   # Connect via subref
 398   ->connect_info([ sub { DBI->connect(...) } ]);
 399
 400   # A bit more complicated
 401   ->connect_info(
 402     [
 403       'dbi:Pg:dbname=foo',
 404       'postgres',
 405       'my_pg_password',
 406       { AutoCommit => 0 },
 407       { quote_char => q{"}, name_sep => q{.} },
 408     ]
 409   );
 410
 411   # Equivalent to the previous example
 412   ->connect_info(
 413     [
 414       'dbi:Pg:dbname=foo',
 415       'postgres',
 416       'my_pg_password',
 417       { AutoCommit => 0, quote_char => q{"}, name_sep => q{.} },
 418     ]
 419   );
 420
 421   # Subref + DBIC-specific connection options
 422   ->connect_info(
 423     [
 424       sub { DBI->connect(...) },
 425       {
 426           quote_char => q{`},
 427           name_sep => q{@},
 428           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 429           disable_sth_caching => 1,
 430       },
 431     ]
 432   );
 433
 434 =cut
 435
 436 sub connect_info {
 437   my ($self, $info_arg) = @_;
 438
 439   return $self->_connect_info if !$info_arg;
 440
 441   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 442   #  the new set of options
 443   $self->_sql_maker(undef);
 444   $self->_sql_maker_opts({});
 445
 446   my $info = [ @$info_arg ]; # copy because we can alter it
 447   my $last_info = $info->[-1];
 448   if(ref $last_info eq 'HASH') {
 449     for my $storage_opt (qw/on_connect_do disable_sth_caching/) {
 450       if(my $value = delete $last_info->{$storage_opt}) {
 451         $self->$storage_opt($value);
 452       }
 453     }
 454     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 455       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 456         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 457       }
 458     }
 459
 460     # Get rid of any trailing empty hashref
 461     pop(@$info) if !keys %$last_info;
 462   }
 463
 464   $self->_connect_info($info);
 465 }
 466
 467 =head2 on_connect_do
 468
 469 This method is deprecated in favor of setting via L</connect_info>.
 470
 471 =head2 dbh_do
 472
 473 Arguments: $subref, @extra_coderef_args?
 474
 475 Execute the given subref using the new exception-based connection management.
 476
 477 The first two arguments will be the storage object that C<dbh_do> was called
 478 on and a database handle to use.  Any additional arguments will be passed
 479 verbatim to the called subref as arguments 2 and onwards.
 480
 481 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 482 exception handling and reconnection (or failover in future subclasses).
 483
 484 Your subref should have no side-effects outside of the database, as
 485 there is the potential for your subref to be partially double-executed
 486 if the database connection was stale/dysfunctional.
 487
 488 Example:
 489
 490   my @stuff = $schema->storage->dbh_do(
 491     sub {
 492       my ($storage, $dbh, @cols) = @_;
 493       my $cols = join(q{, }, @cols);
 494       $dbh->selectrow_array("SELECT $cols FROM foo");
 495     },
 496     @column_list
 497   );
 498
 499 =cut
 500
 501 sub dbh_do {
 502   my $self = shift;
 503   my $coderef = shift;
 504
 505   ref $coderef eq 'CODE' or $self->throw_exception
 506     ('$coderef must be a CODE reference');
 507
 508   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do};
 509   local $self->{_in_dbh_do} = 1;
 510
 511   my @result;
 512   my $want_array = wantarray;
 513
 514   eval {
 515     $self->_verify_pid if $self->_dbh;
 516     $self->_populate_dbh if !$self->_dbh;
 517     if($want_array) {
 518         @result = $coderef->($self, $self->_dbh, @_);
 519     }
 520     elsif(defined $want_array) {
 521         $result[0] = $coderef->($self, $self->_dbh, @_);
 522     }
 523     else {
 524         $coderef->($self, $self->_dbh, @_);
 525     }
 526   };
 527
 528   my $exception = $@;
 529   if(!$exception) { return $want_array ? @result : $result[0] }
 530
 531   $self->throw_exception($exception) if $self->connected;
 532
 533   # We were not connected - reconnect and retry, but let any
 534   #  exception fall right through this time
 535   $self->_populate_dbh;
 536   $coderef->($self, $self->_dbh, @_);
 537 }
 538
 539 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 540 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 541 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 542 sub txn_do {
 543   my $self = shift;
 544   my $coderef = shift;
 545
 546   ref $coderef eq 'CODE' or $self->throw_exception
 547     ('$coderef must be a CODE reference');
 548
 549   local $self->{_in_dbh_do} = 1;
 550
 551   my @result;
 552   my $want_array = wantarray;
 553
 554   my $tried = 0;
 555   while(1) {
 556     eval {
 557       $self->_verify_pid if $self->_dbh;
 558       $self->_populate_dbh if !$self->_dbh;
 559
 560       $self->txn_begin;
 561       if($want_array) {
 562           @result = $coderef->(@_);
 563       }
 564       elsif(defined $want_array) {
 565           $result[0] = $coderef->(@_);
 566       }
 567       else {
 568           $coderef->(@_);
 569       }
 570       $self->txn_commit;
 571     };
 572
 573     my $exception = $@;
 574     if(!$exception) { return $want_array ? @result : $result[0] }
 575
 576     if($tried++ > 0 || $self->connected) {
 577       eval { $self->txn_rollback };
 578       my $rollback_exception = $@;
 579       if($rollback_exception) {
 580         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 581         $self->throw_exception($exception)  # propagate nested rollback
 582           if $rollback_exception =~ /$exception_class/;
 583
 584         $self->throw_exception(
 585           "Transaction aborted: ${exception}. "
 586           . "Rollback failed: ${rollback_exception}"
 587         );
 588       }
 589       $self->throw_exception($exception)
 590     }
 591
 592     # We were not connected, and was first try - reconnect and retry
 593     # via the while loop
 594     $self->_populate_dbh;
 595   }
 596 }
 597
 598 =head2 disconnect
 599
 600 Our C<disconnect> method also performs a rollback first if the
 601 database is not in C<AutoCommit> mode.
 602
 603 =cut
 604
 605 sub disconnect {
 606   my ($self) = @_;
 607
 608   if( $self->connected ) {
 609     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 610     $self->_dbh->disconnect;
 611     $self->_dbh(undef);
 612     $self->{_dbh_gen}++;
 613   }
 614 }
 615
 616 sub connected {
 617   my ($self) = @_;
 618
 619   if(my $dbh = $self->_dbh) {
 620       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 621           $self->_dbh(undef);
 622           $self->{_dbh_gen}++;
 623           return;
 624       }
 625       else {
 626           $self->_verify_pid;
 627       }
 628       return ($dbh->FETCH('Active') && $dbh->ping);
 629   }
 630
 631   return 0;
 632 }
 633
 634 # handle pid changes correctly
 635 #  NOTE: assumes $self->_dbh is a valid $dbh
 636 sub _verify_pid {
 637   my ($self) = @_;
 638
 639   return if $self->_conn_pid == $$;
 640
 641   $self->_dbh->{InactiveDestroy} = 1;
 642   $self->_dbh(undef);
 643   $self->{_dbh_gen}++;
 644
 645   return;
 646 }
 647
 648 sub ensure_connected {
 649   my ($self) = @_;
 650
 651   unless ($self->connected) {
 652     $self->_populate_dbh;
 653   }
 654 }
 655
 656 =head2 dbh
 657
 658 Returns the dbh - a data base handle of class L<DBI>.
 659
 660 =cut
 661
 662 sub dbh {
 663   my ($self) = @_;
 664
 665   $self->ensure_connected;
 666   return $self->_dbh;
 667 }
 668
 669 sub _sql_maker_args {
 670     my ($self) = @_;
 671
 672     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 673 }
 674
 675 sub sql_maker {
 676   my ($self) = @_;
 677   unless ($self->_sql_maker) {
 678     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 679   }
 680   return $self->_sql_maker;
 681 }
 682
 683 sub _populate_dbh {
 684   my ($self) = @_;
 685   my @info = @{$self->_connect_info || []};
 686   $self->_dbh($self->_connect(@info));
 687
 688   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 689     my $driver = $self->_dbh->{Driver}->{Name};
 690     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 691       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 692       $self->_rebless() if $self->can('_rebless');
 693     }
 694   }
 695
 696   # if on-connect sql statements are given execute them
 697   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 698     $self->debugobj->query_start($sql_statement) if $self->debug();
 699     $self->_dbh->do($sql_statement);
 700     $self->debugobj->query_end($sql_statement) if $self->debug();
 701   }
 702
 703   $self->_conn_pid($$);
 704   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 705 }
 706
 707 sub _connect {
 708   my ($self, @info) = @_;
 709
 710   $self->throw_exception("You failed to provide any connection info")
 711       if !@info;
 712
 713   my ($old_connect_via, $dbh);
 714
 715   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 716       $old_connect_via = $DBI::connect_via;
 717       $DBI::connect_via = 'connect';
 718   }
 719
 720   eval {
 721     if(ref $info[0] eq 'CODE') {
 722        $dbh = &{$info[0]}
 723     }
 724     else {
 725        $dbh = DBI->connect(@info);
 726        $dbh->{RaiseError} = 1;
 727        $dbh->{PrintError} = 0;
 728        $dbh->{PrintWarn} = 0;
 729     }
 730   };
 731
 732   $DBI::connect_via = $old_connect_via if $old_connect_via;
 733
 734   if (!$dbh || $@) {
 735     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 736   }
 737
 738   $dbh;
 739 }
 740
 741 sub _dbh_txn_begin {
 742   my ($self, $dbh) = @_;
 743   if ($dbh->{AutoCommit}) {
 744     $self->debugobj->txn_begin()
 745       if ($self->debug);
 746     $dbh->begin_work;
 747   }
 748 }
 749
 750 sub txn_begin {
 751   my $self = shift;
 752   $self->dbh_do($self->can('_dbh_txn_begin'))
 753     if $self->{transaction_depth}++ == 0;
 754 }
 755
 756 sub _dbh_txn_commit {
 757   my ($self, $dbh) = @_;
 758   if ($self->{transaction_depth} == 0) {
 759     unless ($dbh->{AutoCommit}) {
 760       $self->debugobj->txn_commit()
 761         if ($self->debug);
 762       $dbh->commit;
 763     }
 764   }
 765   else {
 766     if (--$self->{transaction_depth} == 0) {
 767       $self->debugobj->txn_commit()
 768         if ($self->debug);
 769       $dbh->commit;
 770     }
 771   }
 772 }
 773
 774 sub txn_commit {
 775   my $self = shift;
 776   $self->dbh_do($self->can('_dbh_txn_commit'));
 777 }
 778
 779 sub _dbh_txn_rollback {
 780   my ($self, $dbh) = @_;
 781   if ($self->{transaction_depth} == 0) {
 782     unless ($dbh->{AutoCommit}) {
 783       $self->debugobj->txn_rollback()
 784         if ($self->debug);
 785       $dbh->rollback;
 786     }
 787   }
 788   else {
 789     if (--$self->{transaction_depth} == 0) {
 790       $self->debugobj->txn_rollback()
 791         if ($self->debug);
 792       $dbh->rollback;
 793     }
 794     else {
 795       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 796     }
 797   }
 798 }
 799
 800 sub txn_rollback {
 801   my $self = shift;
 802
 803   eval { $self->dbh_do($self->can('_dbh_txn_rollback')) };
 804   if ($@) {
 805     my $error = $@;
 806     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 807     $error =~ /$exception_class/ and $self->throw_exception($error);
 808     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 809     $self->throw_exception($error);          # resets the transaction depth
 810   }
 811 }
 812
 813 # This used to be the top-half of _execute.  It was split out to make it
 814 #  easier to override in NoBindVars without duping the rest.  It takes up
 815 #  all of _execute's args, and emits $sql, @bind.
 816 sub _prep_for_execute {
 817   my ($self, $op, $extra_bind, $ident, @args) = @_;
 818
 819   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 820   unshift(@bind,
 821     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 822       if $extra_bind;
 823   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 824
 825   return ($sql, @bind);
 826 }
 827
 828 sub _execute {
 829   my ($self, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 830
 831   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 832   unshift(@bind,
 833     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 834       if $extra_bind;
 835   if ($self->debug) {
 836       my @debug_bind =
 837         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 838       $self->debugobj->query_start($sql, @debug_bind);
 839   }
 840   my $sth = eval { $self->sth($sql,$op) };
 841
 842   if (!$sth || $@) {
 843     $self->throw_exception(
 844       'no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql"
 845     );
 846   }
 847
 848   my $rv;
 849   if ($sth) {
 850     my $time = time();
 851
 852     $rv = eval {
 853
 854       my $placeholder_index = 1;
 855
 856       foreach my $bound (@bind) {
 857
 858         my $attributes = {};
 859         my($column_name, $data) = @$bound;
 860
 861         if( $bind_attributes ) {
 862           $attributes = $bind_attributes->{$column_name}
 863           if defined $bind_attributes->{$column_name};
 864         }
 865
 866         $data = ref $data ? ''.$data : $data; # stringify args
 867
 868         $sth->bind_param($placeholder_index, $data, $attributes);
 869         $placeholder_index++;
 870       }
 871       $sth->execute;
 872     };
 873
 874     if ($@ || !$rv) {
 875       $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr));
 876     }
 877   } else {
 878     $self->throw_exception("'$sql' did not generate a statement.");
 879   }
 880   if ($self->debug) {
 881      my @debug_bind =
 882        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 883      $self->debugobj->query_end($sql, @debug_bind);
 884   }
 885   return (wantarray ? ($rv, $sth, @bind) : $rv);
 886 }
 887
 888 sub insert {
 889   my ($self, $source, $to_insert) = @_;
 890
 891   my $ident = $source->from;
 892   my $bind_attributes;
 893   foreach my $column ($source->columns) {
 894
 895     my $data_type = $source->column_info($column)->{data_type} || '';
 896     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
 897          if $data_type;
 898   }
 899
 900   $self->throw_exception(
 901     "Couldn't insert ".join(', ',
 902       map "$_ => $to_insert->{$_}", keys %$to_insert
 903     )." into ${ident}"
 904   ) unless ($self->_execute('insert' => [], $ident, $bind_attributes, $to_insert));
 905   return $to_insert;
 906 }
 907
 908 ## Still not quite perfect, and EXPERIMENTAL
 909 ## Currently it is assumed that all values passed will be "normal", i.e. not
 910 ## scalar refs, or at least, all the same type as the first set, the statement is
 911 ## only prepped once.
 912 sub insert_bulk {
 913   my ($self, $source, $cols, $data) = @_;
 914   my %colvalues;
 915   my $table = $source->from;
 916   @colvalues{@$cols} = (0..$#$cols);
 917   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 918
 919   if ($self->debug) {
 920       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 921       $self->debugobj->query_start($sql, @debug_bind);
 922   }
 923   my $sth = $self->sth($sql);
 924
 925 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 926
 927   my $rv;
 928
 929   ## This must be an arrayref, else nothing works!
 930
 931   my $tuple_status = [];
 932
 933   ##use Data::Dumper;
 934   ##print STDERR Dumper( $data, $sql, [@bind] );
 935
 936   if ($sth) {
 937
 938     my $time = time();
 939
 940     #$rv = eval {
 941         #
 942         #  $sth->execute_array({
 943
 944         #    ArrayTupleFetch => sub {
 945
 946         #      my $values = shift @$data;
 947     #      return if !$values;
 948     #      return [ @{$values}[@bind] ];
 949         #    },
 950
 951         #    ArrayTupleStatus => $tuple_status,
 952         #  })
 953     #};
 954
 955         ## Get the bind_attributes, if any exist
 956
 957     my $bind_attributes;
 958     foreach my $column ($source->columns) {
 959
 960       my $data_type = $source->column_info($column)->{data_type} || '';
 961
 962       $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
 963            if $data_type;
 964     }
 965
 966         ## Bind the values and execute
 967
 968         $rv = eval {
 969
 970      my $placeholder_index = 1;
 971
 972         foreach my $bound (@bind) {
 973
 974           my $attributes = {};
 975           my ($column_name, $data_index) = @$bound;
 976
 977           if( $bind_attributes ) {
 978             $attributes = $bind_attributes->{$column_name}
 979             if defined $bind_attributes->{$column_name};
 980           }
 981
 982                   my @data = map { $_->[$data_index] } @$data;
 983
 984           $sth->bind_param_array( $placeholder_index, [@data], $attributes );
 985           $placeholder_index++;
 986       }
 987           $sth->execute_array( {ArrayTupleStatus => $tuple_status} );
 988
 989         };
 990
 991 #print STDERR Dumper($tuple_status);
 992 #print STDERR "RV: $rv\n";
 993
 994     if ($@ || !defined $rv) {
 995       my $errors = '';
 996       foreach my $tuple (@$tuple_status)
 997       {
 998           $errors .= "\n" . $tuple->[1] if(ref $tuple);
 999       }
1000       $self->throw_exception("Error executing '$sql': ".($@ || $errors));
1001     }
1002   } else {
1003     $self->throw_exception("'$sql' did not generate a statement.");
1004   }
1005   if ($self->debug) {
1006       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
1007       $self->debugobj->query_end($sql, @debug_bind);
1008   }
1009   return (wantarray ? ($rv, $sth, @bind) : $rv);
1010 }
1011
1012 sub update {
1013   my $self = shift @_;
1014   my $source = shift @_;
1015
1016   my $bind_attributes;
1017   foreach my $column ($source->columns) {
1018
1019     my $data_type = $source->column_info($column)->{data_type} || '';
1020     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1021          if $data_type;
1022   }
1023
1024   my $ident = $source->from;
1025   return $self->_execute('update' => [], $ident, $bind_attributes, @_);
1026 }
1027
1028
1029 sub delete {
1030   my $self = shift @_;
1031   my $source = shift @_;
1032
1033   my $bind_attrs = {}; ## If ever it's needed...
1034   my $ident = $source->from;
1035
1036   return $self->_execute('delete' => [], $ident, $bind_attrs, @_);
1037 }
1038
1039 sub _select {
1040   my ($self, $ident, $select, $condition, $attrs) = @_;
1041   my $order = $attrs->{order_by};
1042   if (ref $condition eq 'SCALAR') {
1043     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1044   }
1045   if (exists $attrs->{group_by} || $attrs->{having}) {
1046     $order = {
1047       group_by => $attrs->{group_by},
1048       having => $attrs->{having},
1049       ($order ? (order_by => $order) : ())
1050     };
1051   }
1052   my $bind_attrs = {}; ## Future support
1053   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1054   if ($attrs->{software_limit} ||
1055       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1056         $attrs->{software_limit} = 1;
1057   } else {
1058     $self->throw_exception("rows attribute must be positive if present")
1059       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1060     push @args, $attrs->{rows}, $attrs->{offset};
1061   }
1062   return $self->_execute(@args);
1063 }
1064
1065 =head2 select
1066
1067 =over 4
1068
1069 =item Arguments: $ident, $select, $condition, $attrs
1070
1071 =back
1072
1073 Handle a SQL select statement.
1074
1075 =cut
1076
1077 sub select {
1078   my $self = shift;
1079   my ($ident, $select, $condition, $attrs) = @_;
1080   return $self->cursor->new($self, \@_, $attrs);
1081 }
1082
1083 sub select_single {
1084   my $self = shift;
1085   my ($rv, $sth, @bind) = $self->_select(@_);
1086   my @row = $sth->fetchrow_array;
1087   # Need to call finish() to work round broken DBDs
1088   $sth->finish();
1089   return @row;
1090 }
1091
1092 =head2 sth
1093
1094 =over 4
1095
1096 =item Arguments: $sql
1097
1098 =back
1099
1100 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1101
1102 =cut
1103
1104 sub _dbh_sth {
1105   my ($self, $dbh, $sql) = @_;
1106
1107   # 3 is the if_active parameter which avoids active sth re-use
1108   my $sth = $self->disable_sth_caching
1109     ? $dbh->prepare($sql)
1110     : $dbh->prepare_cached($sql, {}, 3);
1111
1112   $self->throw_exception(
1113     'no sth generated via sql (' . ($@ || $dbh->errstr) . "): $sql"
1114   ) if !$sth;
1115
1116   $sth;
1117 }
1118
1119 sub sth {
1120   my ($self, $sql) = @_;
1121   $self->dbh_do($self->can('_dbh_sth'), $sql);
1122 }
1123
1124 sub _dbh_columns_info_for {
1125   my ($self, $dbh, $table) = @_;
1126
1127   if ($dbh->can('column_info')) {
1128     my %result;
1129     eval {
1130       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1131       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1132       $sth->execute();
1133       while ( my $info = $sth->fetchrow_hashref() ){
1134         my %column_info;
1135         $column_info{data_type}   = $info->{TYPE_NAME};
1136         $column_info{size}      = $info->{COLUMN_SIZE};
1137         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1138         $column_info{default_value} = $info->{COLUMN_DEF};
1139         my $col_name = $info->{COLUMN_NAME};
1140         $col_name =~ s/^\"(.*)\"$/$1/;
1141
1142         $result{$col_name} = \%column_info;
1143       }
1144     };
1145     return \%result if !$@ && scalar keys %result;
1146   }
1147
1148   my %result;
1149   my $sth = $dbh->prepare("SELECT * FROM $table WHERE 1=0");
1150   $sth->execute;
1151   my @columns = @{$sth->{NAME_lc}};
1152   for my $i ( 0 .. $#columns ){
1153     my %column_info;
1154     my $type_num = $sth->{TYPE}->[$i];
1155     my $type_name;
1156     if(defined $type_num && $dbh->can('type_info')) {
1157       my $type_info = $dbh->type_info($type_num);
1158       $type_name = $type_info->{TYPE_NAME} if $type_info;
1159     }
1160     $column_info{data_type} = $type_name ? $type_name : $type_num;
1161     $column_info{size} = $sth->{PRECISION}->[$i];
1162     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1163
1164     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1165       $column_info{data_type} = $1;
1166       $column_info{size}    = $2;
1167     }
1168
1169     $result{$columns[$i]} = \%column_info;
1170   }
1171
1172   return \%result;
1173 }
1174
1175 sub columns_info_for {
1176   my ($self, $table) = @_;
1177   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1178 }
1179
1180 =head2 last_insert_id
1181
1182 Return the row id of the last insert.
1183
1184 =cut
1185
1186 sub _dbh_last_insert_id {
1187     my ($self, $dbh, $source, $col) = @_;
1188     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1189     $dbh->func('last_insert_rowid');
1190 }
1191
1192 sub last_insert_id {
1193   my $self = shift;
1194   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1195 }
1196
1197 =head2 sqlt_type
1198
1199 Returns the database driver name.
1200
1201 =cut
1202
1203 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1204
1205 =head2 bind_attribute_by_data_type
1206
1207 Given a datatype from column info, returns a database specific bind attribute for
1208 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1209 just handle it.
1210
1211 Generally only needed for special case column types, like bytea in postgres.
1212
1213 =cut
1214
1215 sub bind_attribute_by_data_type {
1216     return;
1217 }
1218
1219 =head2 create_ddl_dir (EXPERIMENTAL)
1220
1221 =over 4
1222
1223 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1224
1225 =back
1226
1227 Creates a SQL file based on the Schema, for each of the specified
1228 database types, in the given directory.
1229
1230 Note that this feature is currently EXPERIMENTAL and may not work correctly
1231 across all databases, or fully handle complex relationships.
1232
1233 =cut
1234
1235 sub create_ddl_dir
1236 {
1237   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1238
1239   if(!$dir || !-d $dir)
1240   {
1241     warn "No directory given, using ./\n";
1242     $dir = "./";
1243   }
1244   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1245   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1246   $version ||= $schema->VERSION || '1.x';
1247   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1248
1249   eval "use SQL::Translator";
1250   $self->throw_exception("Can't create a ddl file without SQL::Translator: $@") if $@;
1251
1252   my $sqlt = SQL::Translator->new({
1253 #      debug => 1,
1254       add_drop_table => 1,
1255   });
1256   foreach my $db (@$databases)
1257   {
1258     $sqlt->reset();
1259     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1260 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1261     $sqlt = $self->configure_sqlt($sqlt, $db);
1262     $sqlt->data($schema);
1263     $sqlt->producer($db);
1264
1265     my $file;
1266     my $filename = $schema->ddl_filename($db, $dir, $version);
1267     if(-e $filename)
1268     {
1269       warn("$filename already exists, skipping $db");
1270       next;
1271     }
1272
1273     my $output = $sqlt->translate;
1274     if(!$output)
1275     {
1276       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1277       next;
1278     }
1279     if(!open($file, ">$filename"))
1280     {
1281         $self->throw_exception("Can't open $filename for writing ($!)");
1282         next;
1283     }
1284     print $file $output;
1285     close($file);
1286
1287     if($preversion)
1288     {
1289       eval "use SQL::Translator::Diff";
1290       if($@)
1291       {
1292         warn("Can't diff versions without SQL::Translator::Diff: $@");
1293         next;
1294       }
1295
1296       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1297 #      print "Previous version $prefilename\n";
1298       if(!-e $prefilename)
1299       {
1300         warn("No previous schema file found ($prefilename)");
1301         next;
1302       }
1303       #### We need to reparse the SQLite file we just wrote, so that
1304       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1305       ##   FIXME: rip Diff to pieces!
1306 #      my $target_schema = $sqlt->schema;
1307 #      unless ( $target_schema->name ) {
1308 #        $target_schema->name( $filename );
1309 #      }
1310       my @input;
1311       push @input, {file => $prefilename, parser => $db};
1312       push @input, {file => $filename, parser => $db};
1313       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1314         my $file   = $_->{'file'};
1315         my $parser = $_->{'parser'};
1316
1317         my $t = SQL::Translator->new;
1318         $t->debug( 0 );
1319         $t->trace( 0 );
1320         $t->parser( $parser )            or die $t->error;
1321         my $out = $t->translate( $file ) or die $t->error;
1322         my $schema = $t->schema;
1323         unless ( $schema->name ) {
1324           $schema->name( $file );
1325         }
1326         ($schema, $parser);
1327       } @input;
1328
1329       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1330                                                     $target_schema, $db,
1331                                                     {}
1332                                                    );
1333       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1334       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1335       if(-e $difffile)
1336       {
1337         warn("$difffile already exists, skipping");
1338         next;
1339       }
1340       if(!open $file, ">$difffile")
1341       {
1342         $self->throw_exception("Can't write to $difffile ($!)");
1343         next;
1344       }
1345       print $file $diff;
1346       close($file);
1347     }
1348   }
1349 }
1350
1351 sub configure_sqlt() {
1352   my $self = shift;
1353   my $tr = shift;
1354   my $db = shift || $self->sqlt_type;
1355   if ($db eq 'PostgreSQL') {
1356     $tr->quote_table_names(0);
1357     $tr->quote_field_names(0);
1358   }
1359   return $tr;
1360 }
1361
1362 =head2 deployment_statements
1363
1364 =over 4
1365
1366 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1367
1368 =back
1369
1370 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1371 The database driver name is given by C<$type>, though the value from
1372 L</sqlt_type> is used if it is not specified.
1373
1374 C<$directory> is used to return statements from files in a previously created
1375 L</create_ddl_dir> directory and is optional. The filenames are constructed
1376 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1377
1378 If no C<$directory> is specified then the statements are constructed on the
1379 fly using L<SQL::Translator> and C<$version> is ignored.
1380
1381 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1382
1383 =cut
1384
1385 sub deployment_statements {
1386   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1387   # Need to be connected to get the correct sqlt_type
1388   $self->ensure_connected() unless $type;
1389   $type ||= $self->sqlt_type;
1390   $version ||= $schema->VERSION || '1.x';
1391   $dir ||= './';
1392   my $filename = $schema->ddl_filename($type, $dir, $version);
1393   if(-f $filename)
1394   {
1395       my $file;
1396       open($file, "<$filename")
1397         or $self->throw_exception("Can't open $filename ($!)");
1398       my @rows = <$file>;
1399       close($file);
1400       return join('', @rows);
1401   }
1402
1403   eval "use SQL::Translator";
1404   if(!$@)
1405   {
1406     eval "use SQL::Translator::Parser::DBIx::Class;";
1407     $self->throw_exception($@) if $@;
1408     eval "use SQL::Translator::Producer::${type};";
1409     $self->throw_exception($@) if $@;
1410
1411     # sources needs to be a parser arg, but for simplicty allow at top level
1412     # coming in
1413     $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1414         if exists $sqltargs->{sources};
1415
1416     my $tr = SQL::Translator->new(%$sqltargs);
1417     SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1418     return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1419   }
1420
1421   $self->throw_exception("No SQL::Translator, and no Schema file found, aborting deploy");
1422   return;
1423
1424 }
1425
1426 sub deploy {
1427   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1428   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1429     for ( split(";\n", $statement)) {
1430       next if($_ =~ /^--/);
1431       next if(!$_);
1432 #      next if($_ =~ /^DROP/m);
1433       next if($_ =~ /^BEGIN TRANSACTION/m);
1434       next if($_ =~ /^COMMIT/m);
1435       next if $_ =~ /^\s+$/; # skip whitespace only
1436       $self->debugobj->query_start($_) if $self->debug;
1437       $self->dbh->do($_) or warn "SQL was:\n $_"; # XXX exceptions?
1438       $self->debugobj->query_end($_) if $self->debug;
1439     }
1440   }
1441 }
1442
1443 =head2 datetime_parser
1444
1445 Returns the datetime parser class
1446
1447 =cut
1448
1449 sub datetime_parser {
1450   my $self = shift;
1451   return $self->{datetime_parser} ||= $self->build_datetime_parser(@_);
1452 }
1453
1454 =head2 datetime_parser_type
1455
1456 Defines (returns) the datetime parser class - currently hardwired to
1457 L<DateTime::Format::MySQL>
1458
1459 =cut
1460
1461 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1462
1463 =head2 build_datetime_parser
1464
1465 See L</datetime_parser>
1466
1467 =cut
1468
1469 sub build_datetime_parser {
1470   my $self = shift;
1471   my $type = $self->datetime_parser_type(@_);
1472   eval "use ${type}";
1473   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1474   return $type;
1475 }
1476
1477 sub DESTROY {
1478   my $self = shift;
1479   return if !$self->_dbh;
1480   $self->_verify_pid;
1481   $self->_dbh(undef);
1482 }
1483
1484 1;
1485
1486 =head1 SQL METHODS
1487
1488 The module defines a set of methods within the DBIC::SQL::Abstract
1489 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1490 SQL query functions.
1491
1492 The following methods are extended:-
1493
1494 =over 4
1495
1496 =item delete
1497
1498 =item insert
1499
1500 =item select
1501
1502 =item update
1503
1504 =item limit_dialect
1505
1506 See L</connect_info> for details.
1507 For setting, this method is deprecated in favor of L</connect_info>.
1508
1509 =item quote_char
1510
1511 See L</connect_info> for details.
1512 For setting, this method is deprecated in favor of L</connect_info>.
1513
1514 =item name_sep
1515
1516 See L</connect_info> for details.
1517 For setting, this method is deprecated in favor of L</connect_info>.
1518
1519 =back
1520
1521 =head1 AUTHORS
1522
1523 Matt S. Trout <mst@shadowcatsystems.co.uk>
1524
1525 Andy Grundman <andy@hybridized.org>
1526
1527 =head1 LICENSE
1528
1529 You may distribute this code under the same terms as Perl itself.
1530
1531 =cut